configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_AC_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject
  21 # and GThread as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=2
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_AC_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 case $GLIB_MINOR_VERSION in
  97 *[[13579]]) debug_default=yes ;;
  98 *)          debug_default=minimum ;;
  99 esac[]dnl
 100 ])
 101
 102 dnl declare --enable-* args and collect ac_help strings
 103 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 104 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 105 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 106 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 107 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 108                     , enable_ansi=no)
 109 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 110                           ([=no] will override --with-threads)],,enable_threads=yes)
 111 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 112
 113 if test "x$enable_threads" != "xyes"; then
 114   enable_threads=no
 115 fi
 116
 117 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 118         [Whether glib was compiled with debugging enabled])
 119
 120 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 121 if test "x$enable_gc_friendly" = "xyes"; then
 122   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 123   AC_SUBST(ENABLE_GC_FRIENDLY)
 124   AC_MSG_RESULT(yes)
 125 else
 126   AC_MSG_RESULT(no)
 127 fi
 128
 129 AC_MSG_CHECKING(whether to disable memory pools)
 130 if test "x$disable_mem_pools" = "xno"; then
 131   AC_MSG_RESULT(no)
 132 else
 133   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 134   AC_SUBST(DISABLE_MEM_POOLS)
 135   AC_MSG_RESULT(yes)
 136 fi
 137
 138 if test "x$enable_msg_prefix" = "xyes"; then
 139   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1,
 140                      [Enable prefixing of error messages with program names])
 141 fi
 142
 143 dnl Checks for programs.
 144 AC_PROG_CC
 145
 146 AM_PROG_CC_STDC
 147 AC_PROG_INSTALL
 148
 149 if test "x$enable_debug" = "xyes"; then
 150   if test x$cflags_set != xset ; then
 151       case " $CFLAGS " in
 152       *[[\ \    ]]-g[[\ \       ]]*) ;;
 153       *) CFLAGS="$CFLAGS -g" ;;
 154       esac
 155   fi
 156
 157   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 158 else
 159   if test "x$enable_debug" = "xno"; then
 160     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 161   fi
 162 fi
 163
 164 AC_CYGWIN
 165 AC_EXEEXT
 166
 167 # define a MAINT-like variable REBUILD which is set if Perl
 168 # and awk are found, so autogenerated sources can be rebuilt
 169 AC_PROG_AWK
 170 AC_CHECK_PROGS(PERL, perl5 perl)
 171 # We would like indent, but don't require it.
 172 AC_CHECK_PROG(INDENT, indent, indent)
 173 REBUILD=\#
 174 if test "x$enable_rebuilds" = "xyes" && \
 175      test -n "$PERL" && \
 176      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 177      test -n "$AWK" ; then
 178   REBUILD=
 179 fi
 180 AC_SUBST(REBUILD)
 181
 182
 183 dnl
 184 dnl gettext support
 185 dnl
 186
 187 ALL_LINGUAS="de fr no ru sl tr uk"
 188 AM_GLIB_GNU_GETTEXT
 189 LIBS="$LIBS $INTLLIBS"
 190
 191 GETTEXT_PACKAGE=glib20
 192 AC_SUBST(GETTEXT_PACKAGE)
 193 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 194
 195 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 196 # this is the directory where the *.{mo,gmo} files are installed
 197 GLIB_LOCALE_DIR="${prefix}/${DATADIRNAME}/locale"
 198 AC_DEFINE_UNQUOTED(GLIB_LOCALE_DIR,"$GLIB_LOCALE_DIR")
 199
 200 dnl Initialize libtool
 201 AC_LIBTOOL_WIN32_DLL
 202 AM_PROG_LIBTOOL
 203
 204 if test "x$GCC" = "xyes"; then
 205   case " $CFLAGS " in
 206   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 207   *) CFLAGS="$CFLAGS -Wall" ;;
 208   esac
 209
 210   if test "x$enable_ansi" = "xyes"; then
 211     case " $CFLAGS " in
 212     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 213     *) CFLAGS="$CFLAGS -ansi" ;;
 214     esac
 215
 216     case " $CFLAGS " in
 217     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 218     *) CFLAGS="$CFLAGS -pedantic" ;;
 219     esac
 220   fi
 221 fi
 222
 223 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 224 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 225 glib_save_LIBS=$LIBS
 226 LIBS="$LIBS -lm"
 227 AC_TRY_RUN([#include <math.h>
 228              int main (void) { return (log(1) != log(1.)); }],
 229      AC_MSG_RESULT(none needed),
 230      glib_save_CFLAGS=$CFLAGS
 231      CFLAGS="$CFLAGS -std1"
 232      AC_TRY_RUN([#include <math.h>
 233                  int main (void) { return (log(1) != log(1.)); }],
 234          AC_MSG_RESULT(-std1),
 235          AC_MSG_RESULT()
 236          CFLAGS=$glib_save_CFLAGS
 237          AC_MSG_WARN(
 238                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 239      )
 240 )
 241 LIBS=$glib_save_LIBS
 242
 243 dnl NeXTStep cc seems to need this
 244 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 245 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 246   AC_MSG_RESULT(none needed),
 247   glib_save_CFLAGS=$CFLAGS
 248   CFLAGS="$CFLAGS -posix"
 249   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 250     AC_MSG_RESULT(-posix),
 251     AC_MSG_RESULT()
 252     CFLAGS=$glib_save_CFLAGS
 253     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 254
 255 # Checks for header files.
 256 AC_HEADER_STDC
 257
 258 # Checks for library functions.
 259 AC_FUNC_VPRINTF
 260
 261 AC_FUNC_ALLOCA
 262
 263 AC_CHECK_FUNCS(atexit on_exit)
 264
 265 AC_CHECK_SIZEOF(char)
 266 AC_CHECK_SIZEOF(short)
 267 AC_CHECK_SIZEOF(long)
 268 AC_CHECK_SIZEOF(int)
 269 AC_CHECK_SIZEOF(void *)
 270 AC_CHECK_SIZEOF(long long)
 271
 272 if test x$ac_cv_sizeof_long_long = x8; then
 273         # long long is a 64 bit integer.
 274         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 275         AC_CACHE_VAL(glib_cv_long_long_format,[
 276                 for format in ll q I64; do
 277                   AC_TRY_RUN([#include <stdio.h>
 278                         int main()
 279                         {
 280                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 281                           char buffer[1000];
 282                           sprintf (buffer, "%${format}u", a);
 283                           sscanf (buffer, "%${format}u", &b);
 284                           exit (b!=a);
 285                         }
 286                         ],
 287                         glib_cv_long_long_format=${format}
 288                         break)
 289                 done])
 290         if test -n "$glib_cv_long_long_format"; then
 291           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 292         else
 293           AC_MSG_RESULT(none)
 294         fi
 295 fi
 296
 297 dnl long doubles were not used, and a portability problem
 298 dnl AC_C_LONG_DOUBLE
 299 AC_C_CONST
 300
 301 dnl ok, here we try to check whether the systems prototypes for
 302 dnl malloc and friends actually match the prototypes provided
 303 dnl by gmem.h (keep in sync). i currently only know how to check
 304 dnl this reliably with gcc (-Werror), improvements for other
 305 dnl compilers are apprechiated.
 306 SANE_MALLOC_PROTOS=no
 307 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 308 glib_save_CFLAGS=$CFLAGS
 309 if test "x$GCC" = "xyes"; then
 310   CFLAGS="$CFLAGS -Werror"
 311   AC_TRY_COMPILE([#include <stdlib.h>], [
 312     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 313     void* (*my_malloc_p)  (size_t)         = malloc;
 314     void  (*my_free_p)    (void*)          = free;
 315     void* (*my_realloc_p) (void*, size_t)  = realloc;
 316     my_calloc_p = 0;
 317     my_malloc_p = 0;
 318     my_free_p = 0;
 319     my_realloc_p = 0;
 320   ],
 321     AC_DEFINE(SANE_MALLOC_PROTOS)
 322     SANE_MALLOC_PROTOS=yes)
 323 fi
 324 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 325 CFLAGS=$glib_save_CFLAGS
 326
 327
 328 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 329 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 330 dnl actually supported.
 331 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 332         AC_TRY_RUN([
 333         __inline int foo () { return 0; }
 334         int main () { return foo (); }
 335         ],
 336         glib_cv_has__inline=yes
 337         ,
 338         glib_cv_has__inline=no
 339         ,)
 340 ])
 341 case x$glib_cv_has__inline in
 342 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 343 esac
 344 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 345         AC_TRY_RUN([
 346         __inline__ int foo () { return 0; }
 347         int main () { return foo (); }
 348         ],
 349         glib_cv_has__inline__=yes
 350         ,
 351         glib_cv_has__inline__=no
 352         ,)
 353 ])
 354 case x$glib_cv_has__inline__ in
 355 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 356 esac
 357 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 358         AC_TRY_RUN([
 359         inline int foo () { return 0; }
 360         int main () { return foo (); }
 361         ],
 362         glib_cv_hasinline=yes
 363         ,
 364         glib_cv_hasinline=no
 365         ,)
 366 ])
 367 case x$glib_cv_hasinline in
 368 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 369 esac
 370
 371 # check for bytesex stuff
 372 AC_C_BIGENDIAN
 373
 374 # check for header files
 375 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 376 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 377
 378 AC_MSG_CHECKING(whether make is GNU Make)
 379 STRIP_BEGIN=
 380 STRIP_END=
 381 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 382         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 383         STRIP_END=')'
 384         AC_MSG_RESULT(yes)
 385 else
 386         AC_MSG_RESULT(no)
 387 fi
 388 STRIP_DUMMY=
 389 AC_SUBST(STRIP_DUMMY)
 390 AC_SUBST(STRIP_BEGIN)
 391 AC_SUBST(STRIP_END)
 392
 393 # check additional type sizes
 394 size_includes=["
 395 #include <stdarg.h>
 396 #include <stdio.h>
 397 #include <ctype.h>
 398 #include <string.h>
 399 "]
 400 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 401   size_includes=["$size_includes
 402 #include <stdint.h>
 403 "]
 404 fi
 405 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 406   size_includes=["$size_includes
 407 #include <unistd.h>
 408 "]
 409 fi
 410 GLIB_SIZEOF([$size_includes], size_t, size_t)
 411 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 412 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 413
 414 # Check for some functions
 415 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd)
 416
 417 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 418 # The check is borrowed from the PERL Configure script.
 419 if test "$ac_cv_func_memmove" != "yes"; then
 420   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 421     glib_cv_working_bcopy,[AC_TRY_RUN([
 422       int main() {
 423         char buf[128], abc[128], *b;
 424         int len, off, align;
 425         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 426         for (align = 7; align >= 0; align--) {
 427           for (len = 36; len; len--) {
 428             b = buf+align; bcopy(abc, b, len);
 429             for (off = 1; off <= len; off++) {
 430               bcopy(b, b+off, len); bcopy(b+off, b, len);
 431                 if (bcmp(b, abc, len)) return(1);
 432             }
 433           }
 434         }
 435         return(0);
 436       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 437   if test "$glib_cv_working_bcopy" = "yes"; then
 438     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 439   fi
 440 fi
 441
 442 # Check for sys_errlist
 443 AC_MSG_CHECKING(for sys_errlist)
 444 AC_TRY_LINK(, [
 445 extern char *sys_errlist[];
 446 extern int sys_nerr;
 447 sys_errlist[sys_nerr-1][0] = 0;
 448 ], glib_ok=yes, glib_ok=no)
 449 AC_MSG_RESULT($glib_ok)
 450 if test $glib_ok = no; then
 451     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 452 fi
 453
 454 # Check for sys_siglist
 455 AC_MSG_CHECKING(for sys_siglist)
 456 AC_TRY_LINK(, [
 457 extern char *sys_siglist[];
 458 exit (sys_siglist[0]);
 459 ], glib_ok=yes, glib_ok=no)
 460 AC_MSG_RESULT($glib_ok)
 461 if test $glib_ok = no; then
 462     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 463 fi
 464
 465 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 466 AC_MSG_CHECKING(for sys_siglist declaration)
 467 AC_TRY_COMPILE([#include <signal.h>], [
 468 strlen (sys_siglist[0]);
 469 ], glib_ok=yes, glib_ok=no)
 470 AC_MSG_RESULT($glib_ok)
 471 if test $glib_ok = no; then
 472     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 473 fi
 474
 475 # Check if <sys/select.h> needs to be included for fd_set
 476 AC_MSG_CHECKING([for fd_set])
 477 AC_TRY_COMPILE([#include <sys/types.h>],
 478         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 479 if test $gtk_ok = yes; then
 480     AC_MSG_RESULT([yes, found in sys/types.h])
 481 else
 482     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 483     if test $gtk_ok = yes; then
 484         # *** FIXME: give it a different name
 485         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 486         AC_MSG_RESULT([yes, found in sys/select.h])
 487     else
 488         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 489         AC_MSG_RESULT(no)
 490     fi
 491 fi
 492
 493 dnl *** check for sane realloc() ***
 494 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 495         AC_TRY_RUN([
 496         #include <stdlib.h>
 497         int main() {
 498           return realloc (0, sizeof (int)) == 0;
 499         }],
 500         [glib_cv_sane_realloc=yes],
 501         [glib_cv_sane_realloc=no],
 502         [])
 503 ])
 504 if test x$glib_cv_sane_realloc = xyes; then
 505   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 506 fi
 507
 508 dnl Check for nl_langinfo and CODESET
 509
 510 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 511 AC_TRY_COMPILE([#include <langinfo.h>],
 512         [char *codeset = nl_langinfo (CODESET);],
 513    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 514    have_codeset=yes,
 515    have_codeset=no)
 516 AC_MSG_RESULT($have_codeset)
 517
 518
 519 dnl ****************************************
 520 dnl *** strlcpy/strlcat                  ***
 521 dnl ****************************************
 522 # Check for strlcpy
 523 AC_MSG_CHECKING(for strlcpy/strlcat)
 524 AC_TRY_LINK([#include <stdlib.h>
 525 #include <string.h>], [
 526 char *p = malloc(10);
 527 (void) strlcpy(p, "hi", 10);
 528 (void) strlcat(p, "bye", 10);
 529 ], glib_ok=yes, glib_ok=no)
 530 AC_MSG_RESULT($glib_ok)
 531 if test $glib_ok = yes; then
 532     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 533 fi
 534
 535
 536 dnl **********************
 537 dnl *** va_copy checks ***
 538 dnl **********************
 539 dnl we currently check for all three va_copy possibilities, so we get
 540 dnl all results in config.log for bug reports.
 541 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 542         AC_TRY_RUN([
 543         #include <stdarg.h>
 544         void f (int i, ...) {
 545         va_list args1, args2;
 546         va_start (args1, i);
 547         va_copy (args2, args1);
 548         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 549           exit (1);
 550         va_end (args1); va_end (args2);
 551         }
 552         int main() {
 553           f (0, 42);
 554           return 0;
 555         }],
 556         [glib_cv_va_copy=yes],
 557         [glib_cv_va_copy=no],
 558         [])
 559 ])
 560 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 561         AC_TRY_RUN([
 562         #include <stdarg.h>
 563         void f (int i, ...) {
 564         va_list args1, args2;
 565         va_start (args1, i);
 566         __va_copy (args2, args1);
 567         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 568           exit (1);
 569         va_end (args1); va_end (args2);
 570         }
 571         int main() {
 572           f (0, 42);
 573           return 0;
 574         }],
 575         [glib_cv___va_copy=yes],
 576         [glib_cv___va_copy=no],
 577         [])
 578 ])
 579
 580 if test "x$glib_cv_va_copy" = "xyes"; then
 581   g_va_copy_func=va_copy
 582 else if test "x$glib_cv___va_copy" = "xyes"; then
 583   g_va_copy_func=__va_copy
 584 fi
 585 fi
 586
 587 if test -n "$g_va_copy_func"; then
 588   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 589 fi
 590
 591 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 592         AC_TRY_RUN([
 593         #include <stdarg.h>
 594         void f (int i, ...) {
 595         va_list args1, args2;
 596         va_start (args1, i);
 597         args2 = args1;
 598         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 599           exit (1);
 600         va_end (args1); va_end (args2);
 601         }
 602         int main() {
 603           f (0, 42);
 604           return 0;
 605         }],
 606         [glib_cv_va_val_copy=yes],
 607         [glib_cv_va_val_copy=no],
 608         [])
 609 ])
 610
 611 if test "x$glib_cv_va_val_copy" = "xno"; then
 612   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 613 fi
 614
 615 dnl ***********************
 616 dnl *** g_module checks ***
 617 dnl ***********************
 618 G_MODULE_LIBS=
 619 G_MODULE_LIBS_EXTRA=
 620 G_MODULE_PLUGIN_LIBS=
 621 G_MODULE_LDFLAGS=
 622 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 623 G_MODULE_NEED_USCORE=0
 624 G_MODULE_BROKEN_RTLD_GLOBAL=0
 625 G_MODULE_HAVE_DLERROR=0
 626 dnl *** force native WIN32 shared lib loader
 627 if test -z "$G_MODULE_IMPL"; then
 628   case "$host" in
 629   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
 630   esac
 631 fi
 632 dnl *** dlopen() and dlsym() in system libraries
 633 if test -z "$G_MODULE_IMPL"; then
 634         AC_CHECK_FUNC(dlopen,
 635                       [AC_CHECK_FUNC(dlsym,
 636                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 637                       [])
 638 fi
 639 dnl *** load_image (BeOS)
 640 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 641   AC_CHECK_LIB(root, load_image,
 642       [G_MODULE_LIBS="-lbe -lroot -lglib"
 643       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 644       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 645       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 646       [])
 647 fi
 648 # *** dlopen() and dlsym() in libdl
 649 if test -z "$G_MODULE_IMPL"; then
 650         AC_CHECK_LIB(dl, dlopen,
 651                      [AC_CHECK_LIB(dl, dlsym,
 652                                    [G_MODULE_LIBS=-ldl
 653                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 654                      [])
 655 fi
 656 dnl *** shl_load() in libdld (HP-UX)
 657 if test -z "$G_MODULE_IMPL"; then
 658         AC_MSG_CHECKING(how to export all symbols)
 659         SAVED_LDFLAGS=$LDFLAGS
 660         LDFLAGS="$LDFLAGS -Wl,-E"
 661         AC_TRY_LINK(,[ return 0; ],
 662                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 663                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 664                 AC_TRY_LINK(,[ return 0; ],
 665                         [G_MODULE_LDFLAGS="-bexpall"],
 666                         [G_MODULE_LDFLAGS="none"])
 667         ])
 668         LDFLAGS=$SAVED_LDFLAGS
 669         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 670         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 671                 G_MODULE_LDFLAGS=
 672         fi
 673         AC_CHECK_LIB(dld, shl_load,
 674                 [G_MODULE_LIBS=-ldld
 675                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 676                 [])
 677 fi
 678 dnl *** additional checks for G_MODULE_IMPL_DL
 679 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 680         case "$host_os" in
 681           linux*)
 682             G_MODULE_LDFLAGS='-rdynamic'
 683             ;;
 684         esac
 685         LIBS_orig="$LIBS"
 686         LDFLAGS_orig="$LDFLAGS"
 687         LIBS="$LIBS $G_MODULE_LIBS"
 688         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 689 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
 690         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
 691                 glib_cv_rtldglobal_broken,[
 692                 AC_TRY_RUN([
 693                 #include <dlfcn.h>
 694                 #ifndef RTLD_GLOBAL
 695                 #define RTLD_GLOBAL 0
 696                 #endif
 697                 #ifndef RTLD_LAZY
 698                 #define RTLD_LAZY 0
 699                 #endif
 700                 int pthread_create;
 701                 int main () {
 702                 void *handle, *global, *local;
 703                 global = &pthread_create;
 704                 handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
 705                 if (!handle) return 0;
 706                 local = dlsym (handle, "pthread_create");
 707                 return global == local;
 708                 }],
 709                         [glib_cv_rtldglobal_broken=no],
 710                         [glib_cv_rtldglobal_broken=yes],
 711                         [])
 712                 rm -f plugin.c plugin.o plugin.lo
 713         ])
 714         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
 715                 G_MODULE_BROKEN_RTLD_GLOBAL=1
 716         else
 717                 G_MODULE_BROKEN_RTLD_GLOBAL=0
 718         fi
 719 dnl *** check whether we need preceeding underscores
 720         AC_CACHE_CHECK([for preceeding underscore in symbols],
 721                 glib_cv_uscore,[
 722                 AC_TRY_RUN([
 723                 #include <dlfcn.h>
 724                 int glib_underscore_test (void) { return 42; }
 725                 int main() {
 726                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 727                   handle = dlopen ((void*)0, 0);
 728                   if (handle) {
 729                     f1 = dlsym (handle, "glib_underscore_test");
 730                     f2 = dlsym (handle, "_glib_underscore_test");
 731                   } return (!f2 || f1);
 732                 }],
 733                         [glib_cv_uscore=yes],
 734                         [glib_cv_uscore=no],
 735                         [])
 736                 rm -f plugin.c plugin.$ac_objext plugin.lo
 737         ])
 738         if test "x$glib_cv_uscore" = "xyes"; then
 739                 G_MODULE_NEED_USCORE=1
 740         else
 741                 G_MODULE_NEED_USCORE=0
 742         fi
 743
 744         LDFLAGS="$LDFLAGS_orig"
 745 dnl *** check for having dlerror()
 746         AC_CHECK_FUNC(dlerror,
 747                 [G_MODULE_HAVE_DLERROR=1],
 748                 [G_MODULE_HAVE_DLERROR=0])
 749         LIBS="$LIBS_orig"
 750 fi
 751 dnl *** done, have we got an implementation?
 752 if test -z "$G_MODULE_IMPL"; then
 753         G_MODULE_IMPL=0
 754 fi
 755
 756 AC_MSG_CHECKING(for the suffix of shared libraries)
 757 case "$host_os" in
 758   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 759     glib_gmodule_suffix='sl'
 760     ;;
 761   cygwin* | mingw*)
 762     glib_gmodule_suffix='dll'
 763     ;;
 764   *)
 765     glib_gmodule_suffix='so'
 766     ;;
 767 esac
 768 AC_MSG_RESULT(.$glib_gmodule_suffix)
 769
 770 AC_SUBST(G_MODULE_IMPL)
 771 AC_SUBST(G_MODULE_LIBS)
 772 AC_SUBST(G_MODULE_LIBS_EXTRA)
 773 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 774 AC_SUBST(G_MODULE_LDFLAGS)
 775 AC_SUBST(G_MODULE_HAVE_DLERROR)
 776 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
 777 AC_SUBST(G_MODULE_NEED_USCORE)
 778 AC_SUBST(GLIB_DEBUG_FLAGS)
 779
 780 dnl **********************
 781 dnl *** g_spawn checks ***
 782 dnl **********************
 783
 784 AC_MSG_CHECKING(for gspawn implementation)
 785 case "$host" in
 786   *-*-mingw*)
 787     GSPAWN=gspawn-win32.lo
 788     ;;
 789   *)
 790     GSPAWN=gspawn.lo
 791     ;;
 792 esac
 793 AC_MSG_RESULT($GSPAWN)
 794 AC_SUBST(GSPAWN)
 795
 796 dnl *************************
 797 dnl *** GIOChannel checks ***
 798 dnl *************************
 799
 800 AC_MSG_CHECKING(for GIOChannel implementation)
 801 case "$host" in
 802   *-*-mingw*)
 803     GIO=giowin32.lo
 804     ;;
 805   *)
 806     GIO=giounix.lo
 807     ;;
 808 esac
 809 AC_MSG_RESULT($GIO)
 810 AC_SUBST(GIO)
 811
 812 dnl ****************************************
 813 dnl *** platform dependent source checks ***
 814 dnl ****************************************
 815
 816 AC_MSG_CHECKING(for platform-dependent source)
 817 case "$host" in
 818   *-*-cygwin*|*-*-mingw*)
 819     PLATFORMDEP=gwin32.lo
 820     ;;
 821   *)
 822     PLATFORMDEP=
 823     ;;
 824 esac
 825 AC_MSG_RESULT($PLATFORMDEP)
 826 AC_SUBST(PLATFORMDEP)
 827
 828 AC_MSG_CHECKING([whether to compile timeloop])
 829 case "$host" in
 830   *-*-cygwin*|*-*-mingw*)
 831     enable_timeloop=no
 832     ;;
 833   *)
 834     enable_timeloop=yes
 835     ;;
 836 esac
 837 AC_MSG_RESULT($enable_timeloop)
 838 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
 839
 840 AC_MSG_CHECKING([if building for some Win32 platform])
 841 case "$host" in
 842   *-*-mingw*|*-*-cygwin*)
 843     platform_win32=yes
 844     ;;
 845   *)
 846     platform_win32=no
 847     ;;
 848 esac
 849 AC_MSG_RESULT($platform_win32)
 850 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 851
 852 AC_MSG_CHECKING([if building for pure Win32])
 853 case "$host" in
 854   *-*-mingw*)
 855     os_win32=yes
 856     ;;
 857   *)
 858     os_win32=no
 859     ;;
 860 esac
 861 AC_MSG_RESULT($os_win32)
 862 AM_CONDITIONAL(OS_WIN32, test x$os_win32 = xyes)
 863
 864 dnl ***********************
 865 dnl *** g_thread checks ***
 866 dnl ***********************
 867
 868 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 869         if test "x$with_threads" = x; then
 870                 want_threads=yes
 871         else
 872                 want_threads=$with_threads
 873         fi,
 874         want_threads=yes)
 875 if test "x$enable_threads" = "xno"; then
 876         want_threads=no
 877 fi
 878 if test "x$want_threads" = "xnone"; then
 879         want_threads=no
 880 fi
 881
 882 dnl error and warning message
 883 dnl *************************
 884
 885 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 886                 computer. GLib will not have a default thread implementation."
 887
 888 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 889                 platform (normally it's "_REENTRANT"). I'll not use any flag on
 890                 compilation now, but then your programs might not work.
 891                 Please provide information on how it is done on your system."
 892
 893 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 894                 "
 895
 896 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 897                 provide information on your thread implementation.
 898                 You can also run 'configure --disable-threads'
 899                 to compile without thread support."
 900
 901 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 902                 functions will not be MT-safe during their first call because
 903                 there is no working 'getpwuid_r' on your system."
 904
 905 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 906                 because there is no 'localtime_r' on your system."
 907
 908 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 909                 crude surrogate will be used. If you happen to know a
 910                 yield function for your system, please inform the GLib
 911                 developers."
 912
 913 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 914                 threads on your system. Thus threads can only have the default
 915                 priority. If you happen to know these main/max
 916                 priorities, please inform the GLib developers."
 917
 918
 919 dnl determination of thread implementation
 920 dnl ***************************************
 921
 922 have_threads=none
 923 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 924         case $host in
 925                 *-*-solaris*)
 926                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 927                 ;;
 928         esac
 929 fi
 930 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 931                                 || test "x$want_threads" = xdce; then
 932         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 933         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 934         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 935         glib_save_CPPFLAGS="$CPPFLAGS"
 936         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 937         if test "x$have_threads" = xnone; then
 938                 AC_TRY_COMPILE([#include <pthread.h>],
 939                         [pthread_attr_t attr; pthread_attr_init(&attr);],
 940                         have_threads=posix)
 941         fi
 942         if test "x$have_threads" = xnone; then
 943                 AC_TRY_COMPILE([#include <pthread.h>],
 944                         [pthread_attr_t attr; pthread_attr_create(&attr);],
 945                         have_threads=posix)
 946         fi
 947         CPPFLAGS="$glib_save_CPPFLAGS"
 948 fi
 949
 950 AC_MSG_CHECKING(for thread implementation)
 951
 952 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 953         AC_MSG_RESULT(none available)
 954         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 955 else
 956         AC_MSG_RESULT($have_threads)
 957 fi
 958
 959
 960 dnl determination of G_THREAD_CFLAGS
 961 dnl ********************************
 962
 963 G_THREAD_LIBS=
 964 G_THREAD_LIBS_EXTRA=
 965 G_THREAD_CFLAGS=
 966
 967 if test x"$have_threads" != xnone; then
 968
 969     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 970
 971     case $host in
 972         *-aix*)
 973                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 974                 if test x"$GCC" = xyes; then
 975                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 976                 fi
 977                 ;;
 978         *-freebsd2.2*)
 979                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 980
 981                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 982                 # -mthreads flag.
 983                 ;;
 984         *-sysv5uw7*)  # UnixWare 7
 985                 if test "$GCC" != "yes"; then
 986                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 987                 else
 988                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 989                 fi
 990                 ;;
 991         *-dg-dgux*)  # DG/UX
 992                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 993     esac
 994
 995     # if we are not finding the ctime_r function, then we probably are
 996     # not using the proper multithread flag
 997
 998     glib_save_CPPFLAGS="$CPPFLAGS"
 999     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1000
1001     AC_TRY_COMPILE([#include <time.h>],
1002         [time_t t; char b[30]; ctime_r (&t, b);], ,
1003             [AC_TRY_COMPILE([#include <time.h>],
1004                 [time_t t; char b[30]; ctime_r (&t, b, 30);], ,
1005                         AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1006
1007     CPPFLAGS="$glib_save_CPPFLAGS"
1008
1009     AC_MSG_CHECKING(thread related cflags)
1010     AC_MSG_RESULT($G_THREAD_CFLAGS)
1011     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
1012 fi
1013
1014 dnl determination of G_THREAD_LIBS
1015 dnl ******************************
1016
1017 mutex_has_default=no
1018 case $have_threads in
1019         posix|dce)
1020            glib_save_CPPFLAGS="$CPPFLAGS"
1021            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1022            G_THREAD_LIBS=error
1023            glib_save_LIBS="$LIBS"
1024            case $host in
1025              *-sysv5uw7*) # UnixWare 7
1026                 if test "$GCC" != "yes"; then
1027                         G_THREAD_LIBS="-Kthread"
1028                 else
1029                         G_THREAD_LIBS="-pthread"
1030                 fi
1031                 ;;
1032              *)
1033                 for thread_lib in "" pthread pthread32 pthreads c_r thread dce; do
1034                         if test x"$thread_lib" = x; then
1035                                 add_thread_lib=""
1036                                 IN=""
1037                         else
1038                                 add_thread_lib="-l$thread_lib"
1039                                 IN=" in -l$thread_lib"
1040                         fi
1041                         if test x"$have_threads" = xposix; then
1042                                 defattr=0
1043                         else
1044                                 defattr=pthread_attr_default
1045                         fi
1046
1047                         LIBS="$glib_save_LIBS $add_thread_lib"
1048
1049                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1050                         AC_TRY_RUN([#include <pthread.h>
1051                                 int check_me = 0;
1052                                 void* func(void* data) {check_me = 42;}
1053                                 main()
1054                                 { pthread_t t;
1055                                   void *ret;
1056                                   pthread_create (&t, $defattr, func, 0);
1057                                   pthread_join (t, &ret);
1058                                   exit (check_me != 42);
1059                                 }],
1060                                 [AC_MSG_RESULT(yes)
1061                                 G_THREAD_LIBS="$add_thread_lib"
1062                                 break],
1063                                 [AC_MSG_RESULT(no)])
1064                 done
1065                 if test "x$G_THREAD_LIBS" = xerror; then
1066                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1067                 fi
1068                 for thread_lib in "" rt rte; do
1069                         if test x"$thread_lib" = x; then
1070                                 add_thread_lib=""
1071                                 IN=""
1072                         else
1073                                 add_thread_lib="-l$thread_lib"
1074                                 IN=" in -l$thread_lib"
1075                         fi
1076                         LIBS="$glib_save_LIBS $add_thread_lib"
1077
1078                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
1079                         AC_TRY_RUN([#include <sched.h>
1080                                 #include <errno.h>
1081                                 int main() {
1082                                 errno = 0;
1083                                 return sched_get_priority_min(SCHED_OTHER)==-1
1084                                         && errno != 0;
1085                                 }],
1086                                 [AC_MSG_RESULT(yes)
1087                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1088                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1089                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1090                                 break],
1091                                 [AC_MSG_RESULT(no)])
1092                 done
1093                 LIBS="$glib_save_LIBS"
1094                 ;;
1095            esac
1096            mutex_has_default=yes
1097            mutex_default_type='pthread_mutex_t'
1098            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1099            mutex_header_file='pthread.h'
1100            if test "x$have_threads" = "xposix"; then
1101              g_threads_impl="POSIX"
1102            else
1103              g_threads_impl="DCE"
1104              have_threads="posix"
1105            fi
1106            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1107            CPPFLAGS="$glib_save_CPPFLAGS"
1108            ;;
1109         solaris)
1110            G_THREAD_LIBS=error
1111            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
1112            mutex_has_default=yes
1113            mutex_default_type='mutex_t'
1114            mutex_default_init="DEFAULTMUTEX"
1115            mutex_header_file='thread.h'
1116            g_threads_impl="SOLARIS"
1117            ;;
1118         none)
1119            g_threads_impl="NONE"
1120            ;;
1121         *)
1122            g_threads_impl="NONE"
1123            G_THREAD_LIBS=error
1124            ;;
1125 esac
1126
1127 if test "x$G_THREAD_LIBS" = xerror; then
1128         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1129 fi
1130
1131 case $host in
1132   *-*-beos*)
1133     G_THREAD_LIBS="-lbe -lroot -lglib "
1134     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1135     ;;
1136   *)
1137     ;;
1138 esac
1139
1140 AC_MSG_CHECKING(thread related libraries)
1141 AC_MSG_RESULT($G_THREAD_LIBS)
1142
1143 dnl check for mt safe function variants and some posix functions
1144 dnl ************************************************************
1145
1146 if test x"$have_threads" != xnone; then
1147         glib_save_LIBS="$LIBS"
1148         # we are not doing the following for now, as this might require glib
1149         # to always be linked with the thread libs on some platforms.
1150         # LIBS="$LIBS $G_THREAD_LIBS"
1151         AC_CHECK_FUNCS(localtime_r)
1152         if test "$ac_cv_header_pwd_h" = "yes"; then
1153                 AC_CACHE_CHECK([for posix getpwuid_r],
1154                         ac_cv_func_posix_getpwuid_r,
1155                         [AC_TRY_RUN([#include <errno.h>
1156                                 #include <pwd.h>
1157                                 int main () { char buffer[10000];
1158                                 struct passwd pwd, *pwptr = &pwd;
1159                                 int error;
1160                                 errno = 0;
1161                                 error = getpwuid_r (0, &pwd, buffer,
1162                                         sizeof (buffer), &pwptr);
1163                                 return (error < 0 && errno == ENOSYS)
1164                                         || error == ENOSYS; }],
1165                                 [ac_cv_func_posix_getpwuid_r=yes],
1166                                 [ac_cv_func_posix_getpwuid_r=no])])
1167                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1168                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1169                                 [Have POSIX function getpwuid_r])
1170                 else
1171                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1172                                 ac_cv_func_nonposix_getpwuid_r,
1173                                 [AC_TRY_COMPILE([#include <pwd.h>],
1174                                         [char buffer[10000];
1175                                         struct passwd pwd;
1176                                         getpwuid_r (0, &pwd, buffer,
1177                                                         sizeof (buffer));],
1178                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1179                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1180                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1181                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1182                                         [Have non-POSIX function getpwuid_r])
1183                         fi
1184                 fi
1185         fi
1186         LIBS="$LIBS $G_THREAD_LIBS"
1187         if test x"$have_threads" = xposix; then
1188                 glib_save_CPPFLAGS="$CPPFLAGS"
1189                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1190                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1191                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1192                 # This is not AC_CHECK_FUNC to also work with function
1193                 # name mangling in header files.
1194                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1195                 AC_TRY_LINK([#include <pthread.h>],
1196                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1197                         [AC_MSG_RESULT(yes)
1198                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1199                                   [Have function pthread_attr_setstacksize])],
1200                         [AC_MSG_RESULT(no)])
1201                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1202                 if test x"$posix_priority_min" = xnone; then
1203                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1204                                 PX_PRIO_MIN],,[
1205                                 posix_priority_min=PX_PRIO_MIN
1206                                 posix_priority_max=PX_PRIO_MAX])
1207                 fi
1208                 if test x"$posix_priority_min" = xnone; then
1209                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1210                                 PRI_OTHER_MIN],,[
1211                                 posix_priority_min=PRI_OTHER_MIN
1212                                 posix_priority_max=PRI_OTHER_MAX])
1213                 fi
1214                 if test x"$posix_priority_min" = x; then
1215                         AC_MSG_RESULT(none found)
1216                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1217                         posix_priority_min=-1
1218                         posix_priority_max=-1
1219                 else
1220                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1221                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1222                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1223                 fi
1224                 posix_yield_func=none
1225                 AC_MSG_CHECKING(for posix yield function)
1226                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1227                                                         thr_yield; do
1228                         AC_TRY_LINK([#include <pthread.h>],
1229                                 [$yield_func()],
1230                                 [posix_yield_func="$yield_func"
1231                                 break])
1232                 done
1233                 if test x"$posix_yield_func" = xnone; then
1234                         AC_MSG_RESULT(none found)
1235                         AC_MSG_WARN($POSIX_NO_YIELD)
1236                         posix_yield_func="g_usleep(1000)"
1237                 else
1238                         AC_MSG_RESULT($posix_yield_func)
1239                         posix_yield_func="$posix_yield_func()"
1240                 fi
1241                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1242                 CPPFLAGS="$glib_save_CPPFLAGS"
1243
1244                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1245                 AC_TRY_RUN([#include <pthread.h>
1246                         #include <sys/types.h>
1247                         #include <unistd.h>
1248                         pid_t other_pid = 0;
1249
1250                         void* func(void* data) {other_pid = getpid();}
1251                         main()
1252                         { pthread_t t;
1253                           void *ret;
1254                           pthread_create (&t, $defattr, func, NULL);
1255                           pthread_join (t, &ret);
1256                           exit (getpid()==other_pid ||
1257                                 $posix_priority_min != $posix_priority_max);
1258                         }],
1259                         [AC_MSG_RESULT(yes),
1260                           AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1, [whether to use the PID niceness surrogate for thread priorities])
1261                         ],
1262                         [AC_MSG_RESULT(no)])
1263         else # solaris threads
1264                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1265         fi
1266
1267         LIBS="$glib_save_LIBS"
1268
1269         # now spit out all the warnings.
1270         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1271            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1272                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1273         fi
1274         if test "$ac_cv_func_localtime_r" != "yes"; then
1275                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1276         fi
1277 else
1278         # If no thread implementation exists, we will provide enough
1279         # space for a pointer
1280         GLIB_SIZEOF(, void*, system_thread)
1281 fi
1282
1283 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1284                    [Source file containing theread implementation])
1285 AC_SUBST(G_THREAD_CFLAGS)
1286 AC_SUBST(G_THREAD_LIBS)
1287 AC_SUBST(G_THREAD_LIBS_EXTRA)
1288
1289 dnl **********************************************
1290 dnl *** GDefaultMutex setup and initialization ***
1291 dnl **********************************************
1292 dnl
1293 dnl if mutex_has_default = yes, we also got
1294 dnl mutex_default_type, mutex_default_init and mutex_header_file
1295 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1296         glib_save_CPPFLAGS="$CPPFLAGS"
1297         glib_save_LIBS="$LIBS"
1298         LIBS="$LIBS $G_THREAD_LIBS"
1299         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1300         GLIB_SIZEOF([#include <$mutex_header_file>],
1301                     $mutex_default_type,
1302                     gmutex,
1303                     )
1304         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1305                            $mutex_default_type,
1306                            gmutex,
1307                            $glib_cv_sizeof_gmutex,
1308                            $mutex_default_init)
1309         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1310                 mutex_has_default=no
1311         fi
1312         CPPFLAGS="$glib_save_CPPFLAGS"
1313         LIBS="$glib_save_LIBS"
1314         ,
1315 )
1316
1317
1318 dnl ****************************************
1319 dnl *** GLib POLL* compatibility defines ***
1320 dnl ****************************************
1321 GLIB_SYSDEFS(
1322 [#include <sys/types.h>
1323 #include <sys/poll.h>],
1324         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1325         glibconfig-sysdefs.h,
1326         =)
1327
1328 dnl **********************
1329 dnl *** Win32 API libs ***
1330 dnl **********************
1331
1332 case $host in
1333   *-*-cygwin*)
1334         G_LIBS_EXTRA="-luser32 -lwsock32 -lkernel32"
1335     ;;
1336   *-*-mingw*)
1337         G_LIBS_EXTRA="-lwsock32"
1338     ;;
1339   *)
1340         G_LIBS_EXTRA=""
1341     ;;
1342 esac
1343 AC_SUBST(G_LIBS_EXTRA)
1344
1345 dnl ***********************
1346 dnl *** Tests for iconv ***
1347 dnl ***********************
1348
1349 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1350
1351 found_iconv=no
1352
1353 if test "x$with_libiconv" != "xyes" ; then
1354    #
1355    # Check in the C library
1356    #
1357    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1358 fi
1359
1360 if test "x$with_libiconv" != "xno" ; then
1361    #
1362    # Check for libiconv
1363    #
1364    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1365 fi
1366
1367 if test "x$found_iconv" = "xno" ; then
1368    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1369 fi
1370
1371 if test "x$with_libiconv" = "xyes" ; then
1372   ICONV_LIBS="-liconv"
1373   AC_DEFINE(USE_LIBICONV)
1374 fi
1375 AC_SUBST(ICONV_LIBS)
1376
1377 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1378 dnl since we need it for g_iconv()
1379
1380 AC_MSG_CHECKING([for EILSEQ])
1381 AC_TRY_COMPILE([
1382 #include <errno.h>
1383 ],
1384 [
1385 int error = EILSEQ;
1386 ], have_eilseq=yes, have_eilseq=no);
1387 AC_MSG_RESULT($have_eilseq)
1388
1389 dnl **************************
1390 dnl *** Checks for gtk-doc ***
1391 dnl **************************
1392
1393 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1394
1395 if test "x$with_html_dir" = "x" ; then
1396   HTML_DIR='${datadir}/gtk-doc/html'
1397 else
1398   HTML_DIR=$with_html_dir
1399 fi
1400
1401 AC_SUBST(HTML_DIR)
1402
1403 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1404
1405 gtk_doc_min_version=0.6
1406 if $GTKDOC ; then
1407     gtk_doc_version=`gtkdoc-mkdb --version`
1408     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1409     if perl <<EOF ; then
1410       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1411             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1412 EOF
1413       AC_MSG_RESULT(yes)
1414    else
1415       AC_MSG_RESULT(no)
1416       GTKDOC=false
1417    fi
1418 fi
1419
1420 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1421 AC_SUBST(HAVE_GTK_DOC)
1422
1423 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1424 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1425
1426 dnl Let people disable the gtk-doc stuff.
1427 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1428
1429 if test x$enable_gtk_doc = xauto ; then
1430   if test x$GTKDOC = xtrue ; then
1431     enable_gtk_doc=yes
1432   else
1433     enable_gtk_doc=no
1434   fi
1435 fi
1436
1437 dnl NOTE: We need to use a separate automake conditional for this
1438 dnl       to make this work with the tarballs.
1439 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1440
1441 dnl ******************************
1442 dnl *** output the whole stuff ***
1443 dnl ******************************
1444
1445 AC_OUTPUT_COMMANDS([
1446
1447 ## Generate `glibconfig.h' in two cases
1448 ## 1. `config.status' is run either explicitly, or via configure.
1449 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1450 ##     config.h
1451 ## 2. CONFIG_OTHER is set explicitly
1452 ##
1453 ## Case 1 is difficult.  We know that `automake' sets one of
1454 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1455 ## only when AM_CONFIG_HEADER is set, however.
1456
1457 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1458   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1459   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1460 fi
1461 case "$CONFIG_OTHER" in
1462 *glibconfig.h*)
1463         echo creating glibconfig.h
1464         outfile=glibconfig.h-tmp
1465         cat > $outfile <<\_______EOF
1466 /* glibconfig.h
1467  *
1468  * This is a generated file.  Please modify 'configure.in'
1469  */
1470
1471 #ifndef __G_LIBCONFIG_H__
1472 #define __G_LIBCONFIG_H__
1473
1474 #include <gmacros.h>
1475
1476 _______EOF
1477
1478         if test x$glib_limits_h = xyes; then
1479           echo '#include <limits.h>' >> $outfile
1480         fi
1481         if test x$glib_float_h = xyes; then
1482           echo '#include <float.h>' >> $outfile
1483         fi
1484         if test x$glib_values_h = xyes; then
1485           echo '#include <values.h>' >> $outfile
1486         fi
1487         if test "$glib_header_alloca_h" = "yes"; then
1488           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1489         fi
1490         if test x$glib_sys_poll_h = xyes; then
1491           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1492         fi
1493
1494         cat >> $outfile <<_______EOF
1495
1496 G_BEGIN_DECLS
1497
1498 #define G_MINFLOAT      $glib_mf
1499 #define G_MAXFLOAT      $glib_Mf
1500 #define G_MINDOUBLE     $glib_md
1501 #define G_MAXDOUBLE     $glib_Md
1502 #define G_MINSHORT      $glib_ms
1503 #define G_MAXSHORT      $glib_Ms
1504 #define G_MAXUSHORT     $glib_Mus
1505 #define G_MININT        $glib_mi
1506 #define G_MAXINT        $glib_Mi
1507 #define G_MAXUINT       $glib_Mui
1508 #define G_MINLONG       $glib_ml
1509 #define G_MAXLONG       $glib_Ml
1510 #define G_MAXULONG      $glib_Mul
1511
1512 _______EOF
1513
1514
1515         ### this should always be true in a modern C/C++ compiler
1516         cat >>$outfile <<_______EOF
1517 typedef signed char gint8;
1518 typedef unsigned char guint8;
1519 _______EOF
1520
1521
1522         if test -n "$gint16"; then
1523           cat >>$outfile <<_______EOF
1524 typedef signed $gint16 gint16;
1525 typedef unsigned $gint16 guint16;
1526 #define G_GINT16_FORMAT $gint16_format
1527 #define G_GUINT16_FORMAT $guint16_format
1528 _______EOF
1529         fi
1530
1531
1532         if test -n "$gint32"; then
1533           cat >>$outfile <<_______EOF
1534 typedef signed $gint32 gint32;
1535 typedef unsigned $gint32 guint32;
1536 #define G_GINT32_FORMAT $gint32_format
1537 #define G_GUINT32_FORMAT $guint32_format
1538 _______EOF
1539         fi
1540
1541
1542         if test -n "$gint64"; then
1543           cat >>$outfile <<_______EOF
1544 #define G_HAVE_GINT64 1
1545
1546 ${glib_extension}typedef signed $gint64 gint64;
1547 ${glib_extension}typedef unsigned $gint64 guint64;
1548
1549 #define G_GINT64_CONSTANT(val)  $gint64_constant
1550 _______EOF
1551                 if test -n "$gint64_format"; then
1552           cat >>$outfile <<_______EOF
1553 #define G_GINT64_FORMAT $gint64_format
1554 #define G_GUINT64_FORMAT $guint64_format
1555 _______EOF
1556                 fi
1557         fi
1558
1559         cat >>$outfile <<_______EOF
1560
1561 #define GLIB_SIZEOF_VOID_P $glib_void_p
1562 #define GLIB_SIZEOF_LONG   $glib_long
1563
1564 _______EOF
1565
1566         case x$glib_size_t in
1567         x2) echo "typedef gint16  gssize;" >> $outfile
1568             echo "typedef guint16 gsize;"  >> $outfile
1569             ;;
1570         x4) echo "typedef gint32  gssize;" >> $outfile
1571             echo "typedef guint32 gsize;"  >> $outfile
1572             ;;
1573         x8) echo "typedef gint64  gssize;" >> $outfile
1574             echo "typedef guint64 gsize;"  >> $outfile
1575             ;;
1576         *)  echo "#error size of size_t is unknown" >> $outfile
1577             ;;
1578         esac
1579
1580         if test -z "$glib_unknown_void_p"; then
1581           cat >>$outfile <<_______EOF
1582
1583 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1584 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1585
1586 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1587 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1588 _______EOF
1589         else
1590           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1591         fi
1592
1593
1594
1595         cat >>$outfile <<_______EOF
1596 $glib_atexit
1597 $glib_memmove
1598 $glib_defines
1599 $glib_os
1600
1601 $glib_vacopy
1602
1603 #ifdef  __cplusplus
1604 #define G_HAVE_INLINE   1
1605 #else   /* !__cplusplus */
1606 $glib_inline
1607 #endif  /* !__cplusplus */
1608 _______EOF
1609
1610         echo >>$outfile
1611         if test x$g_have_eilseq = xno; then
1612                 cat >>$outfile <<_______EOF
1613 #ifndef EILSEQ
1614 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1615  * The correspondence between this and the corresponding definition
1616  * in libiconv is essential.
1617  */
1618 #  define EILSEQ ENOENT
1619 #endif
1620 _______EOF
1621
1622         fi
1623
1624         echo >>$outfile
1625         if test x$g_mutex_has_default = xyes; then
1626                 cat >>$outfile <<_______EOF
1627 $g_enable_threads_def G_THREADS_ENABLED
1628 #define G_THREADS_IMPL_$g_threads_impl_def
1629 typedef struct _GStaticMutex GStaticMutex;
1630 struct _GStaticMutex
1631 {
1632   struct _GMutex *runtime_mutex;
1633   union {
1634     char   pad[$g_mutex_sizeof];
1635     double dummy_double;
1636     void  *dummy_pointer;
1637     long   dummy_long;
1638   } static_mutex;
1639 };
1640 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1641 #define g_static_mutex_get_mutex(mutex) \
1642   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1643    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1644 _______EOF
1645         else
1646                 cat >>$outfile <<_______EOF
1647 $g_enable_threads_def G_THREADS_ENABLED
1648 #define G_THREADS_IMPL_$g_threads_impl_def
1649 typedef struct _GMutex* GStaticMutex;
1650 #define G_STATIC_MUTEX_INIT NULL
1651 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1652 _______EOF
1653         fi
1654
1655         cat >>$outfile <<_______EOF
1656 /* This represents a system thread as used by the implementation. An
1657  * alien implementaion, as loaded by g_thread_init can only count on
1658  * "sizeof (gpointer)" bytes to store their info. We however need more
1659  * for some of our native implementations. */
1660 typedef union _GSystemThread GSystemThread;
1661 union _GSystemThread
1662 {
1663   char   data[$g_system_thread_sizeof];
1664   double dummy_double;
1665   void  *dummy_pointer;
1666   long   dummy_long;
1667 };
1668 _______EOF
1669
1670         echo >>$outfile
1671         g_bit_sizes="16 32"
1672         if test -n "$gint64"; then
1673           g_bit_sizes="$g_bit_sizes 64"
1674         fi
1675         for bits in $g_bit_sizes; do
1676           cat >>$outfile <<_______EOF
1677 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1678 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1679 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1680 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1681 _______EOF
1682         done
1683
1684         cat >>$outfile <<_______EOF
1685 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1686 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1687 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1688 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1689 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1690 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1691 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1692 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1693 #define G_BYTE_ORDER $g_byte_order
1694
1695 _______EOF
1696
1697         if test -r glibconfig-sysdefs.h; then
1698           cat glibconfig-sysdefs.h >>$outfile
1699         fi
1700
1701         cat >>$outfile <<_______EOF
1702
1703 #define G_MODULE_SUFFIX "$g_module_suffix"
1704
1705 G_END_DECLS
1706
1707 #endif /* GLIBCONFIG_H */
1708 _______EOF
1709
1710
1711         if cmp -s $outfile glibconfig.h; then
1712           echo glibconfig.h is unchanged
1713           rm -f $outfile
1714         else
1715           mv $outfile glibconfig.h
1716         fi ;;
1717 esac
1718 ],[
1719
1720 # Note that if two cases are the same, case goes with the first one.
1721 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1722 # on variable expansion in case labels.  Look at the generated config.status
1723 # for a hint.
1724
1725 glib_header_alloca_h="$ac_cv_header_alloca_h"
1726
1727 case xyes in
1728 x$ac_cv_header_float_h)
1729   glib_float_h=yes
1730   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1731   glib_md=DBL_MIN glib_Md=DBL_MAX
1732   ;;
1733 x$ac_cv_header_values_h)
1734   glib_values_h=yes
1735   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1736   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1737   ;;
1738 esac
1739
1740 case xyes in
1741 x$ac_cv_header_limits_h)
1742   glib_limits_h=yes
1743   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1744   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1745   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1746   ;;
1747 x$ac_cv_header_values_h)
1748   glib_values_h=yes
1749   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1750   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1751   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1752   ;;
1753 esac
1754
1755 if test x$ac_cv_header_sys_poll_h = xyes ; then
1756   glib_sys_poll_h=yes
1757 fi
1758
1759 case 2 in
1760 $ac_cv_sizeof_short)
1761   gint16=short
1762   gint16_format='"hi"'
1763   guint16_format='"hu"'
1764   ;;
1765 $ac_cv_sizeof_int)
1766   gint16=int
1767   gint16_format='"i"'
1768   guint16_format='"u"'
1769   ;;
1770 esac
1771 case 4 in
1772 $ac_cv_sizeof_short)
1773   gint32=short
1774   gint32_format='"hi"'
1775   guint32_format='"hu"'
1776   ;;
1777 $ac_cv_sizeof_int)
1778   gint32=int
1779   gint32_format='"i"'
1780   guint32_format='"u"'
1781   ;;
1782 $ac_cv_sizeof_long)
1783   gint32=long
1784   gint32_format='"li"'
1785   guint32_format='"lu"'
1786   ;;
1787 esac
1788 case 8 in
1789 $ac_cv_sizeof_int)
1790   gint64=int
1791   gint64_format='"i"'
1792   guint64_format='"u"'
1793   glib_extension=
1794   gint64_constant='(val)'
1795   ;;
1796 $ac_cv_sizeof_long)
1797   gint64=long
1798   gint64_format='"li"'
1799   guint64_format='"lu"'
1800   glib_extension=
1801   gint64_constant='(val##L)'
1802   ;;
1803 $ac_cv_sizeof_long_long)
1804   gint64='long long'
1805   if test -n "$glib_cv_long_long_format"; then
1806     gint64_format='"'$glib_cv_long_long_format'i"'
1807     guint64_format='"'$glib_cv_long_long_format'u"'
1808   fi
1809   glib_extension='G_GNUC_EXTENSION '
1810   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1811   ;;
1812 esac
1813 glib_size_t=$glib_cv_sizeof_size_t
1814 glib_void_p=$ac_cv_sizeof_long
1815 glib_long=$ac_cv_sizeof_void_p
1816
1817 gintbits=`expr $ac_cv_sizeof_int \* 8`
1818 glongbits=`expr $ac_cv_sizeof_long \* 8`
1819
1820
1821 case $ac_cv_sizeof_void_p in
1822 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1823 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1824 *)                      glib_unknown_void_p=yes ;;
1825 esac
1826
1827
1828 case xyes in
1829 x$ac_cv_func_atexit)
1830   glib_atexit="
1831 #ifdef NeXT /* @#%@! NeXTStep */
1832 # define g_ATEXIT(proc) (!atexit (proc))
1833 #else
1834 # define g_ATEXIT(proc) (atexit (proc))
1835 #endif"
1836   ;;
1837 x$ac_cv_func_on_exit)
1838   glib_atexit="
1839 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1840   ;;
1841 esac
1842
1843 case xyes in
1844 x$ac_cv_func_memmove)
1845   glib_memmove='
1846 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1847   ;;
1848 x$glib_cv_working_bcopy)
1849   glib_memmove="
1850 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1851 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1852   ;;
1853 *)
1854   glib_memmove="
1855 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1856  * so we have to roll our own copy routine. */
1857 void g_memmove (void* dest, const void * src, unsigned long len);"
1858   ;;
1859 esac
1860
1861 glib_defines="
1862 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1863 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1864 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1865 "
1866
1867 case xyes in
1868 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1869 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1870 *)                      glib_vacopy=''
1871 esac
1872
1873 if test x$glib_cv_va_val_copy = xno; then
1874   glib_vacopy="\$glib_vacopy
1875 #define G_VA_COPY_AS_ARRAY 1"
1876 fi
1877
1878 if test x$glib_cv_hasinline = xyes; then
1879     glib_inline='#define G_HAVE_INLINE 1'
1880 fi
1881 if test x$glib_cv_has__inline = xyes; then
1882     glib_inline="\$glib_inline
1883 #define G_HAVE___INLINE 1"
1884 fi
1885 if test x$glib_cv_has__inline__ = xyes; then
1886     glib_inline="\$glib_inline
1887 #define G_HAVE___INLINE__ 1"
1888 fi
1889
1890 case xyes in
1891 x$ac_cv_c_bigendian)
1892   g_byte_order=G_BIG_ENDIAN
1893   g_bs_native=BE
1894   g_bs_alien=LE
1895   ;;
1896 *)
1897   g_byte_order=G_LITTLE_ENDIAN
1898   g_bs_native=LE
1899   g_bs_alien=BE
1900   ;;
1901 esac
1902
1903 g_have_eilseq=$have_eilseq
1904
1905 case x$have_threads in
1906 xnone)  g_enable_threads_def="#undef";;
1907 *)      g_enable_threads_def="#define";;
1908 esac
1909
1910 g_threads_impl_def=$g_threads_impl
1911
1912 g_mutex_has_default="$mutex_has_default"
1913 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1914 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1915 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1916
1917 g_module_suffix="$glib_gmodule_suffix"
1918
1919 case $host in
1920   *-*-beos*)
1921     glib_os="#define G_OS_BEOS"
1922     ;;
1923   *-*-cygwin*)
1924     glib_os="#define G_OS_UNIX
1925 #define G_PLATFORM_WIN32
1926 #define G_WITH_CYGWIN"
1927     ;;
1928   *-*-mingw*)
1929     glib_os="#define G_OS_WIN32
1930 #define G_PLATFORM_WIN32"
1931     ;;
1932   *)
1933     glib_os="#define G_OS_UNIX"
1934     ;;
1935 esac
1936 ])
1937
1938 AC_OUTPUT([
1939 glib-2.0.pc
1940 glib-config-2.0
1941 gmodule-2.0.pc
1942 gthread-2.0.pc
1943 gobject-2.0.pc
1944 glib.spec
1945 Makefile
1946 build/Makefile
1947 build/win32/Makefile
1948 gmodule/gmoduleconf.h
1949 gmodule/Makefile
1950 gobject/Makefile
1951 gthread/Makefile
1952 po/Makefile.in
1953 docs/Makefile
1954 docs/glib-config.1
1955 docs/reference/Makefile
1956 docs/reference/glib/Makefile
1957 docs/reference/gobject/Makefile
1958 tests/Makefile
1959 ],[case "$CONFIG_FILES" in
1960 *glib-config-2.0*)chmod +x glib-config-2.0;;
1961 esac
1962 echo ""
1963 echo " *** IMPORTANT *** "
1964 echo ""
1965 echo "This is a development version of GLib.  You should be using a stable"
1966 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1967 echo "version you just configured is meant for developers of GLib only:"
1968 echo ""
1969 echo "  * You should not base stable software on this version of GLib."
1970 echo "  * GNOME developers should use a stable version of GLib."
1971 echo ""
1972 echo "If you install this version of GLib, we strongly recommend that you"
1973 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1974 echo "argument to configure to do this.  Otherwise, you will not be able to"
1975 echo "do development with GLib 1.2 any longer."
1976 echo ""
1977 echo " *** You should be using GLib 1.2 instead. ***"
1978 ])