configure.in

   1 #  FLAC - Free Lossless Audio Codec
   2 #  Copyright (C) 2001,2002,2003,2004  Josh Coalson
   3 #
   4 #  This file is part the FLAC project.  FLAC is comprised of several
   5 #  components distributed under difference licenses.  The codec libraries
   6 #  are distributed under Xiph.Org's BSD-like license (see the file
   7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
   8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
   9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
  10 #  FLAC distribution contains at the top the terms under which it may be
  11 #  distributed.
  12 #
  13 #  Since this particular file is relevant to all components of FLAC,
  14 #  it may be distributed under the Xiph.Org license, which is the least
  15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
  16 #  distribution.
  17
  18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
  19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
  20
  21 AC_INIT(src/flac/main.c)
  22 AM_INIT_AUTOMAKE(flac, 1.1.1)
  23
  24 # Don't automagically regenerate autoconf/automake generated files unless
  25 # explicitly requested.  Eases autobuilding -mdz
  26 AM_MAINTAINER_MODE
  27
  28 # Function to configure paths for id3lib; search for 'meat' to get to the end.
  29 # adapted from ogg.m4
  30 # This is here until id3lib comes with an equivalent.
  31 # It is inline with configure.in instead of a separate file as a courtesy to users unaware of the -I flag to aclocal
  32 dnl LOCAL__PATH_ID3LIB([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
  33 dnl Test for libid3, and define ID3LIB_CFLAGS and ID3LIB_LIBS
  34 dnl
  35 AC_DEFUN([LOCAL__PATH_ID3LIB],
  36 [dnl
  37 dnl Get the cflags and libraries
  38 dnl
  39 AC_ARG_WITH(id3lib,[  --with-id3lib=PFX   Prefix where libid3 is installed (optional)], id3lib_prefix="$withval", id3lib_prefix="")
  40 AC_ARG_WITH(id3lib-libraries,[  --with-id3lib-libraries=DIR   Directory where libid3 library is installed (optional)], id3lib_libraries="$withval", id3lib_libraries="")
  41 AC_ARG_WITH(id3lib-includes,[  --with-id3lib-includes=DIR   Directory where libid3 header files are installed (optional)], id3lib_includes="$withval", id3lib_includes="")
  42 AC_ARG_ENABLE(id3libtest, [  --disable-id3libtest       Do not try to compile and run a test id3lib program],, enable_id3libtest=yes)
  43
  44         if test "x$id3lib_libraries" != "x" ; then
  45                 ID3LIB_LIBS="-L$id3lib_libraries"
  46         elif test "x$id3lib_prefix" != "x" ; then
  47                 ID3LIB_LIBS="-L$id3lib_prefix/lib"
  48         elif test "x$prefix" != "xNONE" ; then
  49                 ID3LIB_LIBS="-L$libdir"
  50         fi
  51
  52         ID3LIB_LIBS="$ID3LIB_LIBS -lid3"
  53
  54         if test "x$id3lib_includes" != "x" ; then
  55                 ID3LIB_CFLAGS="-I$id3lib_includes"
  56         elif test "x$id3lib_prefix" != "x" ; then
  57                 ID3LIB_CFLAGS="-I$id3lib_prefix/include"
  58         elif test "$prefix" != "xNONE"; then
  59                 ID3LIB_CFLAGS="-I$prefix/include"
  60         fi
  61
  62         AC_MSG_CHECKING(for id3lib)
  63
  64
  65         if test "x$enable_id3libtest" = "xyes" ; then
  66                 id3lib_found=""
  67         else
  68                 id3lib_found="yes"
  69         fi
  70         dnl There is some confusion over what libraries libid3 needs
  71         dnl so we must be pessimistic and try all permutations:
  72         dnl "-lid3" "-lid3 -lstdc++" "-lid3 -lz" "-lid3 -lz -lstdc++"
  73         for xtra_stdcpp in "" " -lstdc++" ; do
  74                 for xtra_z in "" " -lz" ; do
  75                         if test "x$id3lib_found" = "x" ; then
  76                                 ac_save_CFLAGS="$CFLAGS"
  77                                 ac_save_LIBS="$LIBS"
  78                                 CFLAGS="$CFLAGS $ID3LIB_CFLAGS"
  79                                 LIBS="$LIBS $ID3LIB_LIBS$xtra_stdcpp$xtra_z"
  80                                 rm -f conf.id3libtest
  81                                 AC_TRY_RUN([
  82 #include <stdio.h>
  83 #include <stdlib.h>
  84 #include <string.h>
  85 #include <id3.h>
  86 int main () { system("touch conf.id3libtest"); return 0; }
  87 ], id3lib_found=yes,,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
  88                                 CFLAGS="$ac_save_CFLAGS"
  89                                 LIBS="$ac_save_LIBS"
  90                         fi
  91                         if test "x$id3lib_found" = "xyes" ; then
  92                                 ID3LIB_LIBS="$ID3LIB_LIBS$xtra_stdcpp$xtra_z"
  93                         fi
  94                 done
  95         done
  96
  97         if test "x$id3lib_found" = "xyes" ; then
  98                 AC_MSG_RESULT(yes)
  99                 ifelse([$1], , :, [$1])
 100         else
 101                 AC_MSG_RESULT(no)
 102                 if test -f conf.id3libtest ; then
 103                         :
 104                 else
 105                         echo "*** Could not run id3lib test program, checking why..."
 106                         CFLAGS="$CFLAGS $ID3LIB_CFLAGS"
 107                         LIBS="$LIBS $ID3LIB_LIBS"
 108                         AC_TRY_LINK([
 109 #include <stdio.h>
 110 #include <id3.h>
 111 ],     [ return 0; ],
 112                         [ echo "*** The test program compiled, but did not run. This usually means"
 113                         echo "*** that the run-time linker is not finding id3lib or finding the wrong"
 114                         echo "*** version of id3lib. If it is not finding id3lib, you'll need to set your"
 115                         echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 116                         echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 117                         echo "*** is required on your system"
 118                         echo "***"
 119                         echo "*** If you have an old version installed, it is best to remove it, although"
 120                         echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
 121                         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 122                         echo "*** exact error that occured. This usually means id3lib was incorrectly installed"
 123                         echo "*** or that you have moved id3lib since it was installed." ])
 124                         CFLAGS="$ac_save_CFLAGS"
 125                         LIBS="$ac_save_LIBS"
 126                 fi
 127                 ID3LIB_CFLAGS=""
 128                 ID3LIB_LIBS=""
 129                 ifelse([$2], , :, [$2])
 130         fi
 131         AC_SUBST(ID3LIB_CFLAGS)
 132         AC_SUBST(ID3LIB_LIBS)
 133         rm -f conf.id3libtest
 134 ])
 135
 136
 137 dnl Now the meat of configure.in:
 138
 139 # We need two libtools, one that builds both shared and static, and
 140 # one that builds only static.  This is because the resulting libtool
 141 # does not allow us to choose which to build at runtime.
 142 AM_PROG_LIBTOOL
 143 sed -e 's/^build_old_libs=yes/build_old_libs=no/' libtool > libtool-disable-static
 144 chmod +x libtool-disable-static
 145
 146 AM_PROG_AS
 147 AC_PROG_CXX
 148 AC_PROG_MAKE_SET
 149
 150 dnl check for getopt in standard library
 151 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
 152 AC_CHECK_FUNCS(getopt_long, [], [])
 153
 154 AC_CANONICAL_HOST
 155 case "$host_cpu" in
 156         i*86)   cpu_ia32=true ; AC_DEFINE(FLAC__CPU_IA32) ;;
 157         powerpc)        cpu_ppc=true ; AC_DEFINE(FLAC__CPU_PPC) ;;
 158         sparc)  cpu_sparc=true ; AC_DEFINE(FLAC__CPU_SPARC) ;;
 159 esac
 160 AM_CONDITIONAL(FLaC__CPU_IA32, test x$cpu_ia32 = xtrue)
 161 AM_CONDITIONAL(FLaC__CPU_PPC, test x$cpu_ppc = xtrue)
 162 AM_CONDITIONAL(FLaC__CPU_SPARC, test x$cpu_sparc = xtrue)
 163 case "$host" in
 164         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
 165         *) OBJ_FORMAT=elf ;;
 166 esac
 167 AC_SUBST(OBJ_FORMAT)
 168
 169 if test x$cpu_ia32 = xtrue ; then
 170 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
 171 fi
 172
 173 AC_ARG_ENABLE(asm-optimizations, [  --disable-asm-optimizations    Don't use any assembly optimization routines], asm_opt=no, asm_opt=yes)
 174 AM_CONDITIONAL(FLaC__NO_ASM, test x$asm_opt = xno)
 175 if test x$asm_opt = xno ; then
 176 AC_DEFINE(FLAC__NO_ASM)
 177 fi
 178
 179 AC_ARG_ENABLE(debug,
 180 [  --enable-debug                 Turn on debugging],
 181 [case "${enableval}" in
 182         yes) debug=true ;;
 183         no)  debug=false ;;
 184         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 185 esac],[debug=false])
 186 AM_CONDITIONAL(DEBUG, test x$debug = xtrue)
 187
 188 AC_ARG_ENABLE(sse,
 189 [  --enable-sse                   Enable SSE support by asserting that the OS supports SSE instructions],
 190 [case "${enableval}" in
 191         yes) sse_os=true ;;
 192         no)  sse_os=false ;;
 193         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
 194 esac],[sse_os=false])
 195 AM_CONDITIONAL(FLaC__SSE_OS, test x$sse_os = xtrue)
 196 if test x$sse_os = xtrue ; then
 197 AC_DEFINE(FLAC__SSE_OS)
 198 fi
 199
 200 AC_ARG_ENABLE(3dnow,
 201 [  --disable-3dnow                Disable 3DNOW! optimizations],
 202 [case "${enableval}" in
 203         yes) use_3dnow=true ;;
 204         no)  use_3dnow=false ;;
 205         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
 206 esac],[use_3dnow=true])
 207 AM_CONDITIONAL(FLaC__USE_3DNOW, test x$use_3dnow = xtrue)
 208 if test x$use_3dnow = xtrue ; then
 209 AC_DEFINE(FLAC__USE_3DNOW)
 210 fi
 211
 212 AC_ARG_ENABLE(altivec,
 213 [  --disable-altivec              Disable Altivec optimizations],
 214 [case "${enableval}" in
 215         yes) use_altivec=true ;;
 216         no)  use_altivec=false ;;
 217         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
 218 esac],[use_altivec=true])
 219 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test x$use_altivec = xtrue)
 220 if test x$use_altivec = xtrue ; then
 221 AC_DEFINE(FLAC__USE_ALTIVEC)
 222 fi
 223
 224 AC_ARG_ENABLE(local-xmms-plugin,
 225 [  --enable-local-xmms-plugin     Install XMMS plugin to ~/.xmms/Plugins instead of system location],
 226 [case "${enableval}" in
 227         yes) install_xmms_plugin_locally=true ;;
 228         no)  install_xmms_plugin_locally=false ;;
 229         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
 230 esac],[install_xmms_plugin_locally=false])
 231 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test x$install_xmms_plugin_locally = xtrue)
 232
 233 AC_ARG_ENABLE(exhaustive-tests,
 234 [  --enable-exhaustive-tests      Enable exhaustive testing],
 235 [case "${enableval}" in
 236         yes) exhaustive_tests=true ;;
 237         no)  exhaustive_tests=false ;;
 238         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
 239 esac],[exhaustive_tests=false])
 240 AM_CONDITIONAL(FLaC__EXHAUSTIVE_TESTS, test x$exhaustive_tests = xtrue)
 241 if test x$exhaustive_tests = xtrue ; then
 242 AC_DEFINE(FLAC__EXHAUSTIVE_TESTS)
 243 fi
 244
 245 AC_ARG_ENABLE(valgrind-testing,
 246 [  --enable-valgrind-testing      Run all tests inside Valgrind],
 247 [case "${enableval}" in
 248         yes) valgrind_testing=true ;;
 249         no)  valgrind_testing=false ;;
 250         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
 251 esac],[valgrind_testing=false])
 252 AM_CONDITIONAL(FLaC__VALGRIND_TESTING, test x$valgrind_testing = xtrue)
 253 if test x$valgrind_testing = xtrue ; then
 254 AC_DEFINE(FLAC__VALGRIND_TESTING)
 255 fi
 256
 257 dnl check for ogg library
 258 XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
 259 AM_CONDITIONAL(FLaC__HAS_OGG, [test x$have_ogg = xyes])
 260 if test x$have_ogg = xyes ; then
 261 AC_DEFINE(FLAC__HAS_OGG)
 262 fi
 263
 264 AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - xmms support will not be built]))
 265 AM_CONDITIONAL(FLaC__HAS_XMMS, test x$XMMS_INPUT_PLUGIN_DIR != x)
 266
 267 dnl check for i18n(internationalization); these are from libiconv/gettext
 268 AM_ICONV
 269 AM_LANGINFO_CODESET
 270
 271 dnl check for id3lib library
 272 dnl LOCAL__PATH_ID3LIB is defined by us, and will be until such time as id3lib supplies one
 273 LOCAL__PATH_ID3LIB(have_id3lib=yes, AC_MSG_WARN([*** id3lib not found - id3v2 support will not be built]))
 274 AM_CONDITIONAL(FLaC__HAS_ID3LIB, [test x$have_id3lib = xyes])
 275 if test x$have_id3lib = xyes ; then
 276 AC_DEFINE(FLAC__HAS_ID3LIB)
 277
 278 dnl expected id3lib version for cross compiling
 279 ID3LIB_MAJOR=3
 280 ID3LIB_MINOR=8
 281 ID3LIB_PATCH=0
 282
 283 CFLAGS_save_blah_blah_blah=$CFLAGS
 284 CFLAGS="$ID3LIB_CFLAGS $CFLAGS"
 285 LIBS_save_blah_blah_blah=$LIBS
 286 LIBS="$ID3LIB_LIBS $LIBS"
 287 AC_MSG_CHECKING(for id3lib version)
 288       AC_TRY_RUN([
 289 #include <id3.h>
 290 #include <stdio.h>
 291 int
 292 main ()
 293 {
 294         FILE *output;
 295         output=fopen("conftest.id3","w");
 296         fprintf(output,"ID3LIB_MAJOR=%d\nID3LIB_MINOR=%d\nID3LIB_PATCH=%d\n",ID3LIB_MAJOR_VERSION,ID3LIB_MINOR_VERSION,ID3LIB_PATCH_VERSION);
 297         fclose(output);
 298         exit(0);
 299 }
 300 ], . ./conftest.id3; echo "${ID3LIB_MAJOR}.${ID3LIB_MINOR}.${ID3LIB_PATCH}", AC_MSG_WARN(could not determine id3lib version),[echo $ac_n "cross compiling; assuming ${ID3LIB_MAJOR}.${ID3LIB_MINOR}.${ID3LIB_PATCH} $ac_c"])
 301 AC_DEFINE_UNQUOTED(ID3LIB_MAJOR, $ID3LIB_MAJOR)
 302 AC_DEFINE_UNQUOTED(ID3LIB_MINOR, $ID3LIB_MINOR)
 303 AC_DEFINE_UNQUOTED(ID3LIB_PATCH, $ID3LIB_PATCH)
 304 CFLAGS=$CFLAGS_save_blah_blah_blah
 305 LIBS=$LIBS_save_blah_blah_blah
 306 fi
 307
 308 AC_CHECK_PROGS(DOXYGEN, doxygen)
 309 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
 310 if test -n "$DOXYGEN" ; then
 311 AC_DEFINE(FLAC__HAS_DOXYGEN)
 312 fi
 313
 314 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
 315 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
 316 if test -n "$DOCBOOK_TO_MAN" ; then
 317 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
 318 fi
 319
 320 AC_CHECK_PROGS(NASM, nasm)
 321 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
 322 if test -n "$NASM" ; then
 323 AC_DEFINE(FLAC__HAS_NASM)
 324 fi
 325
 326 OUR_CFLAGS_HEAD='-I$(top_builddir) -I$(srcdir)/include -I$(top_srcdir)/include'
 327 if test x$debug = xtrue; then
 328         OUR_CFLAGS_HEAD="$OUR_CFLAGS_HEAD -g -O0 -DDEBUG"
 329 else
 330         OUR_CFLAGS_HEAD="$OUR_CFLAGS_HEAD -O2 -DNDEBUG"
 331         if test x$GCC = xyes; then
 332                 OUR_CFLAGS_HEAD="$OUR_CFLAGS_HEAD -O3 -fomit-frame-pointer -funroll-loops -finline-functions -Wall -W -Winline -DFLaC__INLINE=__inline__"
 333         fi
 334 fi
 335 CFLAGS="$OUR_CFLAGS_HEAD $CFLAGS"
 336 CXXFLAGS="$OUR_CFLAGS_HEAD $CXXFLAGS"
 337
 338 AM_CONFIG_HEADER(config.h)
 339 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA,  [define to align allocated memory on 32-byte boundaries])
 340 AH_TEMPLATE(FLAC__CPU_IA32,  [define if building for ia32/i386])
 341 AH_TEMPLATE(FLAC__CPU_PPC,  [define if building for PowerPC])
 342 AH_TEMPLATE(FLAC__CPU_SPARC,  [define if building for SPARC])
 343 AH_TEMPLATE(FLAC__EXHAUSTIVE_TESTS,  [define to run even more tests])
 344 AH_TEMPLATE(FLAC__VALGRIND_TESTING,  [define to enable use of Valgrind in testers])
 345 AH_TEMPLATE(FLAC__HAS_DOXYGEN,  [define if you have Doxygen])
 346 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN,  [define if you have docbook-to-man or docbook2man])
 347 AH_TEMPLATE(FLAC__HAS_ID3LIB,  [define if you have the id3lib library])
 348 AH_TEMPLATE(FLAC__HAS_NASM,  [define if you have the NASM assembler])
 349 AH_TEMPLATE(FLAC__HAS_OGG,  [define if you have the ogg library])
 350 AH_TEMPLATE(FLAC__NO_ASM,  [define to disable use of assembly code])
 351 AH_TEMPLATE(FLAC__SSE_OS,  [define if your operating system supports SSE instructions])
 352 AH_TEMPLATE(FLAC__USE_3DNOW,  [define to enable use of 3Dnow! instructions])
 353 AH_TEMPLATE(FLAC__USE_ALTIVEC,  [define to enable use of Altivec instructions])
 354 AH_TEMPLATE(ID3LIB_MAJOR,  [define to major version number of id3lib])
 355 AH_TEMPLATE(ID3LIB_MINOR,  [define to minor version number of id3lib])
 356 AH_TEMPLATE(ID3LIB_PATCH,  [define to patch level of id3lib])
 357
 358 AC_OUTPUT( \
 359         Makefile \
 360         src/Makefile \
 361         src/libFLAC/Makefile \
 362         src/libFLAC/ia32/Makefile \
 363         src/libFLAC/ppc/Makefile \
 364         src/libFLAC/include/Makefile \
 365         src/libFLAC/include/private/Makefile \
 366         src/libFLAC/include/protected/Makefile \
 367         src/libFLAC++/Makefile \
 368         src/libOggFLAC/Makefile \
 369         src/libOggFLAC/include/Makefile \
 370         src/libOggFLAC/include/private/Makefile \
 371         src/libOggFLAC/include/protected/Makefile \
 372         src/libOggFLAC++/Makefile \
 373         src/flac/Makefile \
 374         src/metaflac/Makefile \
 375         src/monkeys_audio_utilities/Makefile \
 376         src/monkeys_audio_utilities/flac_mac/Makefile \
 377         src/monkeys_audio_utilities/flac_ren/Makefile \
 378         src/plugin_common/Makefile \
 379         src/plugin_winamp2/Makefile \
 380         src/plugin_winamp2/include/Makefile \
 381         src/plugin_winamp2/include/winamp2/Makefile \
 382         src/plugin_xmms/Makefile \
 383         src/share/Makefile \
 384         src/share/getopt/Makefile \
 385         src/share/grabbag/Makefile \
 386         src/share/replaygain_analysis/Makefile \
 387         src/share/replaygain_synthesis/Makefile \
 388         src/share/replaygain_synthesis/include/Makefile \
 389         src/share/replaygain_synthesis/include/private/Makefile \
 390         src/share/utf8/Makefile \
 391         src/test_grabbag/Makefile \
 392         src/test_grabbag/cuesheet/Makefile \
 393         src/test_libFLAC/Makefile \
 394         src/test_libFLAC++/Makefile \
 395         src/test_libOggFLAC/Makefile \
 396         src/test_libOggFLAC++/Makefile \
 397         src/test_seeking/Makefile \
 398         src/test_streams/Makefile \
 399         include/Makefile \
 400         include/FLAC/Makefile \
 401         include/FLAC++/Makefile \
 402         include/OggFLAC/Makefile \
 403         include/OggFLAC++/Makefile \
 404         include/share/Makefile \
 405         include/share/grabbag/Makefile \
 406         doc/Makefile \
 407         doc/html/Makefile \
 408         doc/html/images/Makefile \
 409         doc/html/ru/Makefile \
 410         man/Makefile \
 411         test/Makefile \
 412         test/cuesheets/Makefile \
 413         build/Makefile \
 414         obj/Makefile \
 415         obj/debug/Makefile \
 416         obj/debug/bin/Makefile \
 417         obj/debug/lib/Makefile \
 418         obj/release/Makefile \
 419         obj/release/bin/Makefile \
 420         obj/release/lib/Makefile \
 421         flac.pbproj/Makefile \
 422 )