configure.in

   1 AC_PREREQ([2.67])
   2 AC_INIT([cryptsetup],[1.2.0])
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=2:0:1
   7
   8 AC_CONFIG_SRCDIR(src/cryptsetup.c)
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 AC_CONFIG_HEADERS([config.h:config.h.in])
  12 AM_INIT_AUTOMAKE(dist-bzip2)
  13
  14 if test "x$prefix" = "xNONE"; then
  15         sysconfdir=/etc
  16 fi
  17 AC_PREFIX_DEFAULT(/usr)
  18
  19 AC_CANONICAL_HOST
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_PROG_CC
  22 AM_PROG_CC_C_O
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26 AC_ENABLE_STATIC(no)
  27 LT_INIT
  28
  29 AC_HEADER_DIRENT
  30 AC_HEADER_STDC
  31 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  32         ctype.h unistd.h locale.h)
  33
  34 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR('You need the uuid library')])
  35 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR('You need the device-mapper library')])
  36
  37 saved_LIBS=$LIBS
  38 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR('You need the uuid library')])
  39 AC_SUBST(UUID_LIBS, $LIBS)
  40 LIBS=$saved_LIBS
  41
  42 AC_CHECK_FUNCS([posix_memalign])
  43
  44 AC_C_CONST
  45 AC_C_BIGENDIAN
  46 AC_TYPE_OFF_T
  47 AC_SYS_LARGEFILE
  48
  49 AC_PROG_GCC_TRADITIONAL
  50
  51 dnl ==========================================================================
  52
  53 AM_GNU_GETTEXT([external],[need-ngettext])
  54 AM_GNU_GETTEXT_VERSION([0.15])
  55
  56 dnl ==========================================================================
  57
  58 saved_LIBS=$LIBS
  59 AC_CHECK_LIB(popt, poptConfigFileToString,,
  60         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  61 AC_SUBST(POPT_LIBS, $LIBS)
  62 LIBS=$saved_LIBS
  63
  64 dnl ==========================================================================
  65 dnl Crypto backend functions
  66
  67 AC_DEFUN([CONFIGURE_GCRYPT], [
  68         AM_PATH_LIBGCRYPT(1.1.42,,[AC_MSG_ERROR('You need the gcrypt library')])
  69
  70         if test x$enable_static_cryptsetup = xyes; then
  71                 saved_LIBS=$LIBS
  72                 LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
  73                 AC_CHECK_LIB(gcrypt, gcry_check_version,,
  74                         AC_MSG_ERROR([Cannot find static gcrypt library.]),
  75                         [-lgpg-error])
  76                 LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
  77                 LIBS=$saved_LIBS
  78         fi
  79
  80         CRYPTO_CFLAGS=$LIBGCRYPT_CFLAGS
  81         CRYPTO_LIBS=$LIBGCRYPT_LIBS
  82         CRYPTO_STATIC_LIBS=$LIBGCRYPT_STATIC_LIBS
  83 ])
  84
  85 AC_DEFUN([CONFIGURE_OPENSSL], [
  86         PKG_CHECK_MODULES([OPENSSL], [openssl >= 0.9.8],,
  87                 AC_MSG_ERROR('You need openssl library'))
  88         CRYPTO_CFLAGS=$OPENSSL_CFLAGS
  89         CRYPTO_LIBS=$OPENSSL_LIBS
  90
  91         if test x$enable_static_cryptsetup = xyes; then
  92                 saved_PKG_CONFIG=$PKG_CONFIG
  93                 PKG_CONFIG="$PKG_CONFIG --static"
  94                 PKG_CHECK_MODULES([OPENSSL], [openssl])
  95                 CRYPTO_STATIC_LIBS=$OPENSSL_LIBS
  96                 PKG_CONFIG=$saved_PKG_CONFIG
  97         fi
  98 ])
  99
 100 AC_DEFUN([CONFIGURE_NSS], [
 101         if test x$enable_static_cryptsetup = xyes; then
 102                 AC_MSG_ERROR([Static build of cryptsetup is not supported with NSS.]),
 103         fi
 104
 105         PKG_CHECK_MODULES([NSS], [nss],,
 106                 AC_MSG_ERROR('You need nss library'))
 107         CRYPTO_CFLAGS=$NSS_CFLAGS
 108         CRYPTO_LIBS=$NSS_LIBS
 109 ])
 110
 111 AC_DEFUN([CONFIGURE_KERNEL], [
 112         AC_CHECK_HEADERS(linux/if_alg.h,,
 113                 [AC_MSG_ERROR('You need Linux kernel with userspace crypto interface.')])
 114 #       AC_CHECK_DECLS([AF_ALG],,
 115 #               [AC_MSG_ERROR('You need Linux kernel with userspace crypto interface.')],
 116 #               [#include <sys/socket.h>])
 117
 118 ])
 119
 120 dnl ==========================================================================
 121 saved_LIBS=$LIBS
 122
 123 AC_ARG_ENABLE([static-cryptsetup],
 124         AS_HELP_STRING([--enable-static-cryptsetup],
 125         [enable build of static cryptsetup binary]), [
 126         if test x$enable_static = xno; then
 127                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
 128                 enable_static=yes
 129         fi
 130         enable_static_cryptsetup=yes])
 131 AM_CONDITIONAL(STATIC_CRYPTSETUP, test x$enable_static_cryptsetup = xyes)
 132
 133 AC_ARG_ENABLE(selinux,
 134         AS_HELP_STRING([--disable-selinux],
 135         [disable selinux support [default=auto]]),[], [])
 136
 137 AC_ARG_ENABLE([udev],
 138         AS_HELP_STRING([--disable-udev],
 139         [disable udev support]),[], enable_udev=yes)
 140
 141 dnl Try to use pkg-config for devmapper, but fallback to old detection
 142 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
 143         AC_CHECK_LIB(devmapper, dm_task_set_name,,
 144                 [AC_MSG_ERROR([You need the device-mapper library.])])
 145         AC_CHECK_LIB(devmapper, dm_task_set_message,,
 146                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
 147         DEVMAPPER_LIBS=$LIBS
 148 ])
 149 LIBS=$saved_LIBS
 150
 151 LIBS="$LIBS $DEVMAPPER_LIBS"
 152 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 153 if test "x$enable_udev" = xyes; then
 154         if test "x$have_cookie" = xno; then
 155                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 156         else
 157                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 158         fi
 159 fi
 160 LIBS=$saved_LIBS
 161
 162 dnl Crypto backend configuration.
 163 AC_ARG_WITH([crypto_backend],
 164         AS_HELP_STRING([--with-crypto_backend], [crypto backend (gcrypt/openssl/nss/kernel) [gcrypt]]),
 165         [], with_crypto_backend=gcrypt
 166 )
 167 case $with_crypto_backend in
 168         gcrypt)  CONFIGURE_GCRYPT([]) ;;
 169         openssl) CONFIGURE_OPENSSL([]) ;;
 170         nss)     CONFIGURE_NSS([]) ;;
 171         kernel)  CONFIGURE_KERNEL([]) ;;
 172         *) AC_MSG_ERROR([Unknown crypto backend.]) ;;
 173 esac
 174 AM_CONDITIONAL(CRYPTO_BACKEND_GCRYPT,  test $with_crypto_backend = gcrypt)
 175 AM_CONDITIONAL(CRYPTO_BACKEND_OPENSSL, test $with_crypto_backend = openssl)
 176 AM_CONDITIONAL(CRYPTO_BACKEND_NSS,     test $with_crypto_backend = nss)
 177 AM_CONDITIONAL(CRYPTO_BACKEND_KERNEL,  test $with_crypto_backend = kernel)
 178
 179 dnl Magic for cryptsetup.static build.
 180 if test x$enable_static_cryptsetup = xyes; then
 181         saved_PKG_CONFIG=$PKG_CONFIG
 182         PKG_CONFIG="$PKG_CONFIG --static"
 183
 184         LIBS="$saved_LIBS -static"
 185         AC_CHECK_LIB(popt, poptGetContext,,
 186                 AC_MSG_ERROR([Cannot find static popt library.]))
 187
 188         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 189         LIBS="$saved_LIBS -static"
 190         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 191                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 192                 if test "x$enable_selinux" != xno; then
 193                         AC_CHECK_LIB(sepol, sepol_bool_set)
 194                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 195                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 196                 fi
 197         ])
 198         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 199         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 200                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 201
 202         LIBS=$saved_LIBS
 203         PKG_CONFIG=$saved_PKG_CONFIG
 204 fi
 205
 206 AC_SUBST([DEVMAPPER_LIBS])
 207 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 208
 209 AC_SUBST([CRYPTO_CFLAGS])
 210 AC_SUBST([CRYPTO_LIBS])
 211 AC_SUBST([CRYPTO_STATIC_LIBS])
 212
 213 AC_SUBST([LIBCRYPTSETUP_VERSION])
 214 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 215
 216 dnl ==========================================================================
 217 AC_ARG_ENABLE([dev-random], AS_HELP_STRING([--enable-dev-random],
 218 [use blocking /dev/random by default for key generator (otherwise use /dev/urandom)]),
 219 [default_rng=/dev/random], [default_rng=/dev/urandom])
 220 AC_DEFINE_UNQUOTED(DEFAULT_RNG, ["$default_rng"], [default RNG type for key generator])
 221
 222 dnl ==========================================================================
 223 AC_DEFUN([CS_DEFINE],
 224         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 225 ])
 226
 227 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 228         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 229         [CS_DEFINE([$1], ["$withval"], [$2])],
 230         [CS_DEFINE([$1], ["$3"], [$2])]
 231 )])
 232
 233 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 234         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 235         [CS_DEFINE([$1], [$withval], [$2])],
 236         [CS_DEFINE([$1], [$3], [$2])]
 237 )])
 238
 239 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 240 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 241 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 242 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 243
 244 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 245 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 246 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 247 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 248
 249
 250 dnl ==========================================================================
 251
 252 AC_CONFIG_FILES([ Makefile
 253 lib/Makefile
 254 lib/libcryptsetup.pc
 255 lib/crypto_backend/Makefile
 256 lib/luks1/Makefile
 257 src/Makefile
 258 po/Makefile.in
 259 man/Makefile
 260 tests/Makefile
 261 ])
 262 AC_OUTPUT