configure.in

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ(2.52)
   3
   4 AC_INIT(dbus/dbus.h)
   5
   6 AM_INIT_AUTOMAKE(dbus, 0.6)
   7
   8 AM_CONFIG_HEADER(config.h)
   9
  10 # Honor aclocal flags
  11 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  12
  13 GETTEXT_PACKAGE=dbus-1
  14 AC_SUBST(GETTEXT_PACKAGE)
  15 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  16
  17  ## must come before we use the $USE_MAINTAINER_MODE variable later
  18 AM_MAINTAINER_MODE
  19
  20 AC_PROG_CC
  21 AC_PROG_CXX
  22 AC_ISC_POSIX
  23 AC_HEADER_STDC
  24 AM_PROG_LIBTOOL
  25
  26 AC_ARG_ENABLE(qt,      [  --enable-qt      enable Qt-friendly client library],enable_qt=$enableval,enable_qt=auto)
  27 AC_ARG_ENABLE(glib,    [  --enable-glib    enable GLib-friendly client library],enable_glib=$enableval,enable_glib=auto)
  28 AC_ARG_ENABLE(tests,   [  --enable-tests   enable unit test code],enable_tests=$enableval,enable_tests=$USE_MAINTAINER_MODE)
  29 AC_ARG_ENABLE(ansi,    [  --enable-ansi    enable -ansi -pedantic gcc flags],enable_ansi=$enableval,enable_ansi=no)
  30 AC_ARG_ENABLE(verbose-mode, [  --enable-verbose-mode support verbose debug mode],enable_verbose_mode=$enableval,enable_verbose_mode=yes)
  31 AC_ARG_ENABLE(asserts, [  --enable-asserts include assertion checks],enable_asserts=$enableval,enable_asserts=yes)
  32 AC_ARG_ENABLE(gcov,    [  --enable-gcov compile with coverage profiling instrumentation (gcc only)],enable_gcov=$enableval,enable_gcov=no)
  33
  34 AC_ARG_WITH(xml,          [  --with-xml=[libxml/expat] XML library to use])
  35 AC_ARG_WITH(init-scripts, [  --with-init-scripts=[redhat] Style of init scripts to install])
  36
  37 dnl DBUS_BUILD_TESTS controls unit tests built in to .c files
  38 dnl and also some stuff in the test/ subdir
  39 AM_CONDITIONAL(DBUS_BUILD_TESTS, test x$enable_tests = xyes)
  40 if test x$enable_tests = xyes; then
  41     AC_DEFINE(DBUS_BUILD_TESTS,1,[Build test code])
  42 fi
  43
  44 if test x$enable_verbose_mode = xyes; then
  45     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
  46 fi
  47 if test x$enable_asserts = xno; then
  48     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
  49 fi
  50
  51 #### gcc warning flags
  52
  53 if test "x$GCC" = "xyes"; then
  54   changequote(,)dnl
  55   case " $CFLAGS " in
  56   *[\ \ ]-Wall[\ \      ]*) ;;
  57   *) CFLAGS="$CFLAGS -Wall" ;;
  58   esac
  59
  60   case " $CFLAGS " in
  61   *[\ \ ]-Wchar-subscripts[\ \  ]*) ;;
  62   *) CFLAGS="$CFLAGS -Wchar-subscripts" ;;
  63   esac
  64
  65   case " $CFLAGS " in
  66   *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
  67   *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
  68   esac
  69
  70   case " $CFLAGS " in
  71   *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
  72   *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
  73   esac
  74
  75   case " $CFLAGS " in
  76   *[\ \ ]-Wnested-externs[\ \   ]*) ;;
  77   *) CFLAGS="$CFLAGS -Wnested-externs" ;;
  78   esac
  79
  80   case " $CFLAGS " in
  81   *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
  82   *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
  83   esac
  84
  85   case " $CFLAGS " in
  86   *[\ \ ]-Wcast-align[\ \       ]*) ;;
  87   *) CFLAGS="$CFLAGS -Wcast-align" ;;
  88   esac
  89
  90   case " $CFLAGS " in
  91   *[\ \ ]-Wsign-compare[\ \     ]*) ;;
  92   *) CFLAGS="$CFLAGS -Wsign-compare" ;;
  93   esac
  94
  95   if test "x$enable_ansi" = "xyes"; then
  96     case " $CFLAGS " in
  97     *[\ \       ]-ansi[\ \      ]*) ;;
  98     *) CFLAGS="$CFLAGS -ansi" ;;
  99     esac
 100
 101     case " $CFLAGS " in
 102     *[\ \       ]-pedantic[\ \  ]*) ;;
 103     *) CFLAGS="$CFLAGS -pedantic" ;;
 104     esac
 105   fi
 106   if test x$enable_gcov = xyes; then
 107     case " $CFLAGS " in
 108     *[\ \       ]-fprofile-arcs[\ \     ]*) ;;
 109     *) CFLAGS="$CFLAGS -fprofile-arcs" ;;
 110     esac
 111     case " $CFLAGS " in
 112     *[\ \       ]-ftest-coverage[\ \    ]*) ;;
 113     *) CFLAGS="$CFLAGS -ftest-coverage" ;;
 114     esac
 115
 116     ## remove optimization
 117     CFLAGS=`echo "$CFLAGS" | sed -e 's/-O[0-9]*//g'`
 118   fi
 119   changequote([,])dnl
 120 else
 121   if test x$enable_gcov = xyes; then
 122     AC_MSG_ERROR([--enable-gcov can only be used with gcc])
 123   fi
 124 fi
 125
 126 #### Assorted checks
 127
 128 AC_CHECK_SIZEOF(char)
 129 AC_CHECK_SIZEOF(short)
 130 AC_CHECK_SIZEOF(long)
 131 AC_CHECK_SIZEOF(int)
 132 AC_CHECK_SIZEOF(void *)
 133 AC_CHECK_SIZEOF(long long)
 134 AC_CHECK_SIZEOF(__int64)
 135
 136 ## byte order
 137 AC_C_BIGENDIAN
 138
 139 AC_CHECK_LIB(socket,socket)
 140 AC_CHECK_LIB(nsl,gethostbyname)
 141
 142 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep poll setenv socketpair getgrouplist)
 143
 144 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 145
 146 AC_CACHE_CHECK([for posix getpwnam_r],
 147                 ac_cv_func_posix_getpwnam_r,
 148                 [AC_TRY_RUN([
 149 #include <errno.h>
 150 #include <pwd.h>
 151 int main () {
 152     char buffer[10000];
 153     struct passwd pwd, *pwptr = &pwd;
 154     int error;
 155     errno = 0;
 156     error = getpwnam_r ("", &pwd, buffer,
 157                         sizeof (buffer), &pwptr);
 158    return (error < 0 && errno == ENOSYS)
 159            || error == ENOSYS;
 160 }               ],
 161         [ac_cv_func_posix_getpwnam_r=yes],
 162         [ac_cv_func_posix_getpwnam_r=no])])
 163 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 164         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 165                 [Have POSIX function getpwnam_r])
 166 else
 167         AC_CACHE_CHECK([for nonposix getpwnam_r],
 168                 ac_cv_func_nonposix_getpwnam_r,
 169                 [AC_TRY_LINK([#include <pwd.h>],
 170                         [char buffer[10000];
 171                         struct passwd pwd;
 172                         getpwnam_r ("", &pwd, buffer,
 173                                         sizeof (buffer));],
 174                         [ac_cv_func_nonposix_getpwnam_r=yes],
 175                         [ac_cv_func_nonposix_getpwnam_r=no])])
 176                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 177                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 178                         [Have non-POSIX function getpwnam_r])
 179         fi
 180 fi
 181
 182 dnl check for writev header and writev function so we're
 183 dnl good to go if HAVE_WRITEV gets defined.
 184 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 185
 186 dnl check for flavours of varargs macros (test from GLib)
 187 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 188 AC_TRY_COMPILE([],[
 189 int a(int p1, int p2, int p3);
 190 #define call_a(...) a(1,__VA_ARGS__)
 191 call_a(2,3);
 192 ],dbus_have_iso_c_varargs=yes,dbus_have_iso_c_varargs=no)
 193 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 194
 195 AC_MSG_CHECKING(for GNUC varargs macros)
 196 AC_TRY_COMPILE([],[
 197 int a(int p1, int p2, int p3);
 198 #define call_a(params...) a(1,params)
 199 call_a(2,3);
 200 ],dbus_have_gnuc_varargs=yes,dbus_have_gnuc_varargs=no)
 201 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 202
 203 dnl Output varargs tests
 204 if test x$dbus_have_iso_c_varargs = xyes; then
 205     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 206 fi
 207 if test x$dbus_have_gnuc_varargs = xyes; then
 208     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 209 fi
 210
 211 dnl Check for various credentials.
 212 AC_MSG_CHECKING(for struct cmsgcred)
 213 AC_TRY_COMPILE([
 214 #include <sys/types.h>
 215 #include <sys/socket.h>
 216 ],[
 217 struct cmsgcred cred;
 218
 219 cred.cmcred_pid = 0;
 220 ],dbus_have_struct_cmsgcred=yes,dbus_have_struct_cmsgcred=no)
 221 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 222
 223 if test x$dbus_have_struct_cmsgcred = xyes; then
 224     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 225 fi
 226
 227
 228 #### Sort out XML library
 229
 230 # see what we have
 231 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 232              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 233              have_expat=false)
 234
 235 PKG_CHECK_MODULES(LIBXML, libxml-2.0, have_libxml=true, have_libxml=false)
 236
 237 # see what we want to use
 238 dbus_use_libxml=false
 239 dbus_use_expat=false
 240 if test x$with_xml = xexpat; then
 241         dbus_use_expat=true
 242         if ! $have_expat ; then
 243            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 244         fi
 245 elif test x$with_xml = xlibxml; then
 246         dbus_use_libxml=true
 247         if ! $have_libxml ; then
 248            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 249         fi
 250 else
 251         ### expat is the default because libxml can't currently survive
 252         ### our brutal OOM-handling unit test setup.
 253         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 254         if $have_expat ; then
 255                 with_xml=expat
 256                 dbus_use_expat=true
 257         elif $have_libxml ; then
 258                 with_xml=libxml
 259                 dbus_use_libxml=true
 260         else
 261                 AC_MSG_ERROR([No XML library found, check config.log for failed attempts])
 262         fi
 263 fi
 264
 265 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 266 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 267
 268 if $dbus_use_expat; then
 269    XML_LIBS=-lexpat
 270    XML_CFLAGS=
 271 fi
 272 if $dbus_use_libxml; then
 273    XML_LIBS=$LIBXML_LIBS
 274    XML_CFLAGS=$LIBXML_CFLAGS
 275 fi
 276
 277 #### Set up final flags
 278 DBUS_CLIENT_CFLAGS=
 279 DBUS_CLIENT_LIBS=
 280 AC_SUBST(DBUS_CLIENT_CFLAGS)
 281 AC_SUBST(DBUS_CLIENT_LIBS)
 282
 283 DBUS_BUS_CFLAGS=$XML_CFLAGS
 284 DBUS_BUS_LIBS=$XML_LIBS
 285 AC_SUBST(DBUS_BUS_CFLAGS)
 286 AC_SUBST(DBUS_BUS_LIBS)
 287
 288 DBUS_TEST_CFLAGS=
 289 DBUS_TEST_LIBS=
 290 AC_SUBST(DBUS_TEST_CFLAGS)
 291 AC_SUBST(DBUS_TEST_LIBS)
 292
 293 # Glib detection
 294 PKG_CHECK_MODULES(DBUS_GLIB, glib-2.0, have_glib=yes, have_glib=no)
 295 PKG_CHECK_MODULES(DBUS_GLIB_THREADS, glib-2.0 gthread-2.0, have_glib_threads=yes, have_glib_threads=no)
 296
 297 if test x$have_glib = xno ; then
 298     AC_MSG_WARN([GLib development libraries not found])
 299 fi
 300
 301 if test x$enable_glib = xyes; then
 302     if test x$have_glib = xno; then
 303         AC_MSG_ERROR([GLib explicitly required, and GLib development libraries not found])
 304     fi
 305 fi
 306
 307 if test x$enable_glib = xno; then
 308    have_glib=no;
 309 fi
 310
 311 AM_CONDITIONAL(HAVE_GLIB, test x$have_glib = xyes)
 312 AM_CONDITIONAL(HAVE_GLIB_THREADS, test x$have_glib_threads = xyes)
 313
 314 dnl GLib flags
 315 AC_SUBST(DBUS_GLIB_CFLAGS)
 316 AC_SUBST(DBUS_GLIB_LIBS)
 317 AC_SUBST(DBUS_GLIB_THREADS_LIBS)
 318
 319 # Qt detection
 320 have_qt=no
 321 if test -n "$QTDIR" -a -f $QTDIR/include/qglobal.h; then
 322     have_qt=yes
 323     DBUS_QT_CXXFLAGS=-I$QTDIR/include
 324 fi
 325
 326 dnl linking to kdecore will give us a bit of help from libtool
 327 if (! kde-config >& /dev/null); then
 328     have_qt=no
 329 else
 330     kdelibs=`kde-config --install lib --expandvars 2>/dev/null`
 331     if test -z $kdelibs -a -f $kdelibs/libkdecore.la; then
 332         have_qt=no
 333     else
 334         DBUS_QT_LIBS=$kdelibs/libkdecore.la
 335     fi
 336 fi
 337
 338 if test x$have_qt = xno ; then
 339     AC_MSG_WARN([Qt development libraries not found])
 340 fi
 341
 342 if test x$enable_qt = xyes; then
 343     if test x$have_qt = xno; then
 344         AC_MSG_ERROR([Qt integration explicitly required, and Qt libraries not found])
 345     fi
 346 fi
 347
 348 if test x$enable_qt = xno; then
 349    have_qt=no;
 350 fi
 351
 352 AM_CONDITIONAL(HAVE_QT, test x$have_qt = xyes)
 353
 354 dnl Qt flags
 355 AC_SUBST(DBUS_QT_CXXFLAGS)
 356 AC_SUBST(DBUS_QT_LIBS)
 357
 358 ##### Set up location for system bus socket
 359 ## name of socket relative to localstatedir
 360 DBUS_SYSTEM_SOCKET=run/dbus/system_bus_socket
 361 AC_SUBST(DBUS_SYSTEM_SOCKET)
 362
 363 #### find the actual value for $prefix that we'll end up with
 364 REAL_PREFIX=
 365 if test "x$prefix" = "xNONE"; then
 366   REAL_PREFIX=$ac_default_prefix
 367 else
 368   REAL_PREFIX=$prefix
 369 fi
 370
 371 #### Have to go $localstatedir->$prefix/var->/usr/local/var
 372 #### someone please fix this a better way...
 373 LOCALSTATEDIR_TMP="$localstatedir"
 374 old_prefix=$prefix
 375 prefix=$REAL_PREFIX
 376 EXPANDED_LOCALSTATEDIR=`eval echo $LOCALSTATEDIR_TMP`
 377 prefix=$old_prefix
 378 AC_SUBST(EXPANDED_LOCALSTATEDIR)
 379
 380 SYSCONFDIR_TMP="$sysconfdir"
 381 old_prefix=$prefix
 382 prefix=$REAL_PREFIX
 383 EXPANDED_SYSCONFDIR=`eval echo $SYSCONFDIR_TMP`
 384 prefix=$old_prefix
 385 AC_SUBST(EXPANDED_SYSCONFDIR)
 386
 387 BINDIR_TMP="$bindir"
 388 old_prefix=$prefix
 389 prefix=$REAL_PREFIX
 390 EXPANDED_BINDIR=`eval echo $BINDIR_TMP`
 391 prefix=$old_prefix
 392 AC_SUBST(EXPANDED_BINDIR)
 393
 394 #### Sort out init scripts
 395
 396 if test x$with_init_scripts = x; then
 397         if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
 398                 with_init_scripts=redhat
 399         else
 400                 with_init_scripts=none
 401         fi
 402 fi
 403
 404 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
 405
 406 AC_OUTPUT([
 407 Doxyfile
 408 bus/system.conf
 409 bus/session.conf
 410 bus/messagebus
 411 Makefile
 412 dbus/Makefile
 413 glib/Makefile
 414 qt/Makefile
 415 bus/Makefile
 416 test/Makefile
 417 doc/Makefile
 418 dbus-1.0.pc
 419 dbus-glib-1.0.pc
 420 ])
 421
 422 dnl ==========================================================================
 423 echo "
 424                     D-BUS $VERSION
 425                   ==============
 426
 427         prefix:                 ${prefix}
 428         source code location:   ${srcdir}
 429         compiler:               ${CC}
 430         cflags:                 ${CFLAGS}
 431
 432         Maintainer mode:        ${USE_MAINTAINER_MODE}
 433         gcc coverage profiling: ${enable_gcov}
 434         Building unit tests:    ${enable_tests}
 435         Building verbose mode:  ${enable_verbose_mode}
 436         Building assertions:    ${enable_asserts}
 437         Building Qt bindings:   ${have_qt}
 438         Building GLib bindings: ${have_glib}
 439         Using XML parser:       ${with_xml}
 440         System bus socket:      ${EXPANDED_LOCALSTATEDIR}/${DBUS_SYSTEM_SOCKET}
 441         Init scripts style:     ${with_init_scripts}
 442 "
 443
 444 if test x$enable_tests = xyes; then
 445         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
 446 fi
 447 if test x$enable_gcov = xyes; then
 448         echo "NOTE: building with coverage profiling is definitely for developers only."
 449 fi
 450 if test x$enable_verbose_mode = xyes; then
 451         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and may cause a slight performance decrease, but aids debugging."
 452 fi
 453 if test x$enable_asserts = xyes; then
 454         echo "NOTE: building with assertions increases library size, but will help a lot when tracking down bugs in software using D-BUS."
 455 fi