configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [3])
  30 m4_define([glib_micro_version], [3])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 126     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 127     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 128     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 129     GLIB_DEF=glib.def
 130     GMODULE_DEF=gmodule.def
 131     GOBJECT_DEF=gobject.def
 132     GTHREAD_DEF=gthread.def
 133     TESTGMODULE_EXP=testgmodule.exp
 134     glib_pid_type=HANDLE
 135     ;;
 136   *)
 137     glib_native_win32=no
 138     G_LIB_WIN32_RESOURCE=
 139     G_MODULE_WIN32_RESOURCE=
 140     G_OBJECT_WIN32_RESOURCE=
 141     G_THREAD_WIN32_RESOURCE=
 142     GLIB_DEF=
 143     GMODULE_DEF=
 144     GOBJECT_DEF=
 145     GTHREAD_DEF=
 146     TESTGMODULE_EXP=
 147     glib_pid_type=int
 148     ;;
 149 esac
 150 AC_MSG_RESULT([$glib_native_win32])
 151 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 152 AC_SUBST(G_LIB_WIN32_RESOURCE)
 153 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 154 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 155 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 156 AC_SUBST(GLIB_DEF)
 157 AC_SUBST(GMODULE_DEF)
 158 AC_SUBST(GOBJECT_DEF)
 159 AC_SUBST(GTHREAD_DEF)
 160 AC_SUBST(TESTGMODULE_EXP)
 161
 162 if test "$glib_native_win32" = "yes"; then
 163   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 164 fi
 165 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 166
 167 dnl declare --enable-* args and collect ac_help strings
 168 AC_ARG_ENABLE(debug,
 169               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 170                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 171               enable_debug=glib_debug_default)
 172
 173 AC_ARG_ENABLE(gc_friendly,
 174               [AC_HELP_STRING([--enable-gc-friendly],
 175                               [turn on garbage collector friendliness [default=no]])],,
 176               [enable_gc_friendly=no])
 177 AC_ARG_ENABLE(mem_pools,
 178               [AC_HELP_STRING([--disable-mem-pools],
 179                               [disable all glib memory pools])],,
 180               [disable_mem_pools=no])
 181 AC_ARG_ENABLE(ansi,
 182               [AC_HELP_STRING([--enable-ansi],
 183                               [turn on strict ansi [default=no]])],,
 184               [enable_ansi=no])
 185 AC_ARG_ENABLE(threads,
 186               [AC_HELP_STRING([--enable-threads],
 187                               [turn on basic thread support [default=yes]
 188 ([=no] will override --with-threads)])],,
 189               [enable_threads=yes])
 190 AC_ARG_ENABLE(rebuilds,
 191               [AC_HELP_STRING([--disable-rebuilds],
 192                               [disable all source autogeneration rules])],,
 193               [enable_rebuilds=yes])
 194
 195 if test "x$enable_threads" != "xyes"; then
 196   enable_threads=no
 197 fi
 198
 199 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 200         [Whether glib was compiled with debugging enabled])
 201
 202 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 203 if test "x$enable_gc_friendly" = "xyes"; then
 204   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 205   AC_SUBST(ENABLE_GC_FRIENDLY)
 206   AC_MSG_RESULT([yes])
 207 else
 208   AC_MSG_RESULT([no])
 209 fi
 210
 211 AC_MSG_CHECKING([whether to disable memory pools])
 212 if test "x$disable_mem_pools" = "xno"; then
 213   AC_MSG_RESULT([no])
 214 else
 215   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 216   AC_SUBST(DISABLE_MEM_POOLS)
 217   AC_MSG_RESULT([yes])
 218 fi
 219
 220 if test "$glib_native_win32" = "yes"; then
 221   if test x$enable_static = xyes -o x$enable_static = x; then
 222     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 223     enable_static=no
 224   fi
 225   if test x$enable_shared = xno; then
 226     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 227   fi
 228   enable_shared=yes
 229 fi
 230
 231 dnl Checks for programs.
 232 AC_PROG_CC
 233
 234 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 235 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 236 AC_LANG_SAVE
 237 AC_LANG_CPLUSPLUS
 238 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 239 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 240 AC_LANG_RESTORE
 241
 242 AM_PROG_CC_STDC
 243 AC_PROG_INSTALL
 244
 245 AC_SYS_LARGEFILE
 246
 247 #
 248 # Find pkg-config
 249 #
 250 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 251 if test x$PKG_CONFIG = xno ; then
 252   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 253 fi
 254
 255 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 256   :
 257 else
 258   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 259 fi
 260
 261 if test "x$enable_debug" = "xyes"; then
 262   if test x$cflags_set != xset ; then
 263       case " $CFLAGS " in
 264       *[[\ \    ]]-g[[\ \       ]]*) ;;
 265       *) CFLAGS="$CFLAGS -g" ;;
 266       esac
 267   fi
 268
 269   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 270 else
 271   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 272
 273   if test "x$enable_debug" = "xno"; then
 274     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 275   fi
 276 fi
 277
 278 # Ensure MSVC-compatible struct packing convention is used when
 279 # compiling for Win32 with gcc.
 280 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 281 # gcc2 uses "-fnative-struct".
 282 if test x"$glib_native_win32" = xyes; then
 283   if test x"$GCC" = xyes; then
 284     msnative_struct=''
 285     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 286     if test -z "$ac_cv_prog_CC"; then
 287       our_gcc="$CC"
 288     else
 289       our_gcc="$ac_cv_prog_CC"
 290     fi
 291     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 292       2.)
 293         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 294           msnative_struct='-fnative-struct'
 295         fi
 296         ;;
 297       *)
 298         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 299           msnative_struct='-mms-bitfields'
 300         fi
 301         ;;
 302     esac
 303     if test x"$msnative_struct" = x ; then
 304       AC_MSG_RESULT([no way])
 305       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 306     else
 307       CFLAGS="$CFLAGS $msnative_struct"
 308       AC_MSG_RESULT([${msnative_struct}])
 309     fi
 310   fi
 311 fi
 312
 313 AC_CYGWIN
 314 AC_EXEEXT
 315
 316 # define a MAINT-like variable REBUILD which is set if Perl
 317 # and awk are found, so autogenerated sources can be rebuilt
 318 AC_PROG_AWK
 319 AC_CHECK_PROGS(PERL, [perl5 perl])
 320 # We would like indent, but don't require it.
 321 AC_CHECK_PROG(INDENT, indent, indent)
 322 REBUILD=\#
 323 if test "x$enable_rebuilds" = "xyes" && \
 324      test -n "$PERL" && \
 325      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 326      test -n "$AWK" ; then
 327   REBUILD=
 328 fi
 329 AC_SUBST(REBUILD)
 330
 331 # Need full path to Perl for glib-mkenums
 332 #
 333 if test "x$PERL" != x ; then
 334   AC_PATH_PROG(PERL_PATH, [$PERL])
 335 else
 336   PERL_PATH="/usr/bin/env perl"
 337 fi
 338 AC_SUBST(PERL_PATH)
 339
 340 dnl ***********************
 341 dnl *** Tests for iconv ***
 342 dnl ***********************
 343 dnl
 344 dnl We do this before the gettext checks, to avoid distortion
 345
 346 AC_ARG_WITH(libiconv,
 347             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 348                             [use the libiconv library])],,
 349             [with_libiconv=maybe])
 350
 351 found_iconv=no
 352 case $with_libiconv in
 353   maybe)
 354     # Check in the C library first
 355     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 356     # Check if we have GNU libiconv
 357     if test $found_iconv = "no"; then
 358       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 359     fi
 360     # Check if we have a iconv in -liconv, possibly from vendor
 361     if test $found_iconv = "no"; then
 362       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 363     fi
 364     ;;
 365   no)
 366     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 367     ;;
 368   gnu|yes)
 369     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 370     ;;
 371   native)
 372     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 373     ;;
 374 esac
 375
 376 if test "x$found_iconv" = "xno" ; then
 377    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 378 fi
 379
 380 dnl
 381 dnl gettext support
 382 dnl
 383
 384 ALL_LINGUAS="am ar az be bg bn ca cs cy da de el eo es et eu fa fi fr gl he hi hr id is it ja ko lt lv mk mn ms nl nn no pl pt pt_BR ro ru sk sl sq sr sr@Latn sv ta tr uk vi yi zh_CN zh_TW"
 385 GLIB_GNU_GETTEXT
 386
 387 if test "$gt_cv_have_gettext" != "yes" ; then
 388   AC_MSG_ERROR([
 389 *** You must have either have gettext support in your C library, or use the
 390 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 391 ])
 392 fi
 393
 394 LIBS="$INTLLIBS $LIBS"
 395
 396 GETTEXT_PACKAGE=glib20
 397 AC_SUBST(GETTEXT_PACKAGE)
 398 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 399   [Define the gettext package to be used])
 400
 401 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 402
 403 dnl
 404 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 405 dnl
 406
 407 if test x$with_libiconv != xno ; then
 408   case " $INTLLIBS " in
 409   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 410   *) ICONV_LIBS="-liconv" ;;
 411   esac
 412 fi
 413 AC_SUBST(ICONV_LIBS)
 414
 415 case $with_libiconv in
 416   gnu)
 417     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 418     ;;
 419   native)
 420     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 421     ;;
 422 esac
 423
 424 dnl Initialize libtool
 425 AM_DISABLE_STATIC
 426 AM_PROG_LIBTOOL
 427
 428 if test "x$GCC" = "xyes"; then
 429   case " $CFLAGS " in
 430   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 431   *) CFLAGS="$CFLAGS -Wall" ;;
 432   esac
 433
 434   if test "x$enable_ansi" = "xyes"; then
 435     case " $CFLAGS " in
 436     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 437     *) CFLAGS="$CFLAGS -ansi" ;;
 438     esac
 439
 440     case " $CFLAGS " in
 441     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 442     *) CFLAGS="$CFLAGS -pedantic" ;;
 443     esac
 444   fi
 445 fi
 446
 447 dnl
 448 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 449 dnl
 450 if test $cross_compiling != yes ; then
 451     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 452     glib_save_LIBS=$LIBS
 453     LIBS="$LIBS -lm"
 454     AC_TRY_RUN([#include <math.h>
 455                  int main (void) { return (log(1) != log(1.)); }],
 456          AC_MSG_RESULT(none needed),
 457          glib_save_CFLAGS=$CFLAGS
 458          CFLAGS="$CFLAGS -std1"
 459          AC_TRY_RUN([#include <math.h>
 460                      int main (void) { return (log(1) != log(1.)); }],
 461              AC_MSG_RESULT(-std1),
 462              AC_MSG_RESULT()
 463              CFLAGS=$glib_save_CFLAGS
 464              AC_MSG_WARN(
 465                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 466          )
 467     )
 468     LIBS=$glib_save_LIBS
 469 fi
 470
 471 dnl NeXTStep cc seems to need this
 472 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 473 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 474   AC_MSG_RESULT(none needed),
 475   glib_save_CFLAGS=$CFLAGS
 476   CFLAGS="$CFLAGS -posix"
 477   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 478     AC_MSG_RESULT(-posix),
 479     AC_MSG_RESULT()
 480     CFLAGS=$glib_save_CFLAGS
 481     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 482
 483 # Checks for header files.
 484 AC_HEADER_STDC
 485
 486 # Checks for library functions.
 487 AC_FUNC_VPRINTF
 488
 489 AC_FUNC_ALLOCA
 490
 491 AC_CHECK_FUNCS(atexit on_exit)
 492
 493 AC_CHECK_SIZEOF(char)
 494 AC_CHECK_SIZEOF(short)
 495 AC_CHECK_SIZEOF(long)
 496 AC_CHECK_SIZEOF(int)
 497 AC_CHECK_SIZEOF(void *)
 498 AC_CHECK_SIZEOF(long long)
 499 AC_CHECK_SIZEOF(__int64)
 500
 501 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 502   :
 503 else
 504   AC_MSG_ERROR([
 505 *** GLib requires a 64 bit type. You might want to consider
 506 *** using the GNU C compiler.
 507 ])
 508 fi
 509
 510 if test x$ac_cv_sizeof_long_long = x8; then
 511         # long long is a 64 bit integer.
 512         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 513         AC_CACHE_VAL(glib_cv_long_long_format,[
 514                 for format in ll q I64; do
 515                   AC_TRY_RUN([#include <stdio.h>
 516                         int main()
 517                         {
 518                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 519                           char buffer[1000];
 520                           sprintf (buffer, "%${format}u", a);
 521                           sscanf (buffer, "%${format}u", &b);
 522                           exit (b!=a);
 523                         }
 524                         ],
 525                         [glib_cv_long_long_format=${format}
 526                         break],
 527                         [],[:])
 528                 done])
 529         if test -n "$glib_cv_long_long_format"; then
 530           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 531           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 532         else
 533           AC_MSG_RESULT(none)
 534         fi
 535 elif test x$ac_cv_sizeof___int64 = x8; then
 536         # __int64 is a 64 bit integer.
 537         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 538         # We know this is MSVC, and what the formats are
 539         glib_cv_long_long_format=I64
 540         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 541         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 542         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing __int64 with format I64])
 543 fi
 544
 545 dnl long doubles were not used, and a portability problem
 546 dnl AC_C_LONG_DOUBLE
 547 AC_C_CONST
 548
 549 dnl ok, here we try to check whether the systems prototypes for
 550 dnl malloc and friends actually match the prototypes provided
 551 dnl by gmem.h (keep in sync). i currently only know how to check
 552 dnl this reliably with gcc (-Werror), improvements for other
 553 dnl compilers are apprechiated.
 554 SANE_MALLOC_PROTOS=no
 555 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 556 glib_save_CFLAGS=$CFLAGS
 557 if test "x$GCC" = "xyes"; then
 558   CFLAGS="$CFLAGS -Werror"
 559   AC_TRY_COMPILE([#include <stdlib.h>], [
 560     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 561     void* (*my_malloc_p)  (size_t)         = malloc;
 562     void  (*my_free_p)    (void*)          = free;
 563     void* (*my_realloc_p) (void*, size_t)  = realloc;
 564     my_calloc_p = 0;
 565     my_malloc_p = 0;
 566     my_free_p = 0;
 567     my_realloc_p = 0;
 568   ],
 569     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 570       [Define if you have correct malloc prototypes])
 571     SANE_MALLOC_PROTOS=yes)
 572 fi
 573 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 574 CFLAGS=$glib_save_CFLAGS
 575
 576 dnl
 577 dnl check in which direction the stack grows
 578 dnl
 579 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 580         AC_TRY_RUN([
 581         volatile int *a = 0, *b = 0;
 582         void foo (void);
 583         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 584         void foo (void) { volatile int x = 5; b = &x; }
 585         ],
 586         glib_cv_stack_grows=no
 587         ,
 588         glib_cv_stack_grows=yes
 589         ,)
 590 ])
 591
 592 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 593 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 594 dnl actually supported.
 595 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 596         AC_COMPILE_IFELSE([
 597         __inline int foo () { return 0; }
 598         int main () { return foo (); }
 599         ],
 600         glib_cv_has__inline=yes
 601         ,
 602         glib_cv_has__inline=no
 603         ,)
 604 ])
 605 case x$glib_cv_has__inline in
 606 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 607 esac
 608 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 609         AC_COMPILE_IFELSE([
 610         __inline__ int foo () { return 0; }
 611         int main () { return foo (); }
 612         ],
 613         glib_cv_has__inline__=yes
 614         ,
 615         glib_cv_has__inline__=no
 616         ,)
 617 ])
 618 case x$glib_cv_has__inline__ in
 619 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 620 esac
 621 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 622         AC_COMPILE_IFELSE([
 623         #undef inline
 624         inline int foo () { return 0; }
 625         int main () { return foo (); }
 626         ],
 627         glib_cv_hasinline=yes
 628         ,
 629         glib_cv_hasinline=no
 630         ,)
 631 ])
 632 case x$glib_cv_hasinline in
 633 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 634 esac
 635
 636 # check for flavours of varargs macros
 637 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 638 AC_TRY_COMPILE([],[
 639 int a(int p1, int p2, int p3);
 640 #define call_a(...) a(1,__VA_ARGS__)
 641 call_a(2,3);
 642 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 643 AC_MSG_RESULT($g_have_iso_c_varargs)
 644
 645 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 646 if test "$CXX" = ""; then
 647 dnl No C++ compiler
 648   g_have_iso_cxx_varargs=no
 649 else
 650   AC_LANG_CPLUSPLUS
 651   AC_TRY_COMPILE([],[
 652 int a(int p1, int p2, int p3);
 653 #define call_a(...) a(1,__VA_ARGS__)
 654 call_a(2,3);
 655 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 656   AC_LANG_C
 657 fi
 658 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 659
 660 AC_MSG_CHECKING(for GNUC varargs macros)
 661 AC_TRY_COMPILE([],[
 662 int a(int p1, int p2, int p3);
 663 #define call_a(params...) a(1,params)
 664 call_a(2,3);
 665 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 666 AC_MSG_RESULT($g_have_gnuc_varargs)
 667
 668 # check for bytesex stuff
 669 AC_C_BIGENDIAN
 670
 671 # check for header files
 672 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
 673 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 674
 675 # Checks for libcharset
 676 jm_LANGINFO_CODESET
 677 jm_GLIBC21
 678 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 679 AC_CHECK_FUNCS(setlocale)
 680
 681 # check additional type sizes
 682 AC_CHECK_SIZEOF(size_t)
 683
 684 dnl Try to figure out whether gsize, gssize should be long or int
 685 AC_MSG_CHECKING([for the appropriate definition for size_t])
 686
 687 case $ac_cv_sizeof_size_t in
 688   $ac_cv_sizeof_short)
 689       glib_size_type=short
 690       ;;
 691   $ac_cv_sizeof_int)
 692       glib_size_type=int
 693       ;;
 694   $ac_cv_sizeof_long)
 695       glib_size_type=long
 696       ;;
 697   *)  AC_MSG_ERROR([No type matching size_t in size])
 698       ;;
 699 esac
 700
 701 dnl If int/long are the same size, we see which one produces
 702 dnl warnings when used in the location as size_t. (This matters
 703 dnl on AIX with xlc)
 704 dnl
 705 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 706    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 707   GLIB_CHECK_COMPILE_WARNINGS([
 708 #include <stddef.h>
 709 int main ()
 710 {
 711   size_t s = 1;
 712   unsigned int *size_int = &s;
 713   return (int)*size_int;
 714 }
 715     ],glib_size_type=int,
 716       [GLIB_CHECK_COMPILE_WARNINGS([
 717 #include <stddef.h>
 718 int main ()
 719 {
 720    size_t s = 1;
 721    unsigned long *size_long = &s;
 722    return (int)*size_long;
 723 }
 724         ],glib_size_type=long)])
 725 fi
 726
 727 AC_MSG_RESULT(unsigned $glib_size_type)
 728
 729 # Check for some functions
 730 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 731
 732 AC_FUNC_VSNPRINTF_C99
 733 AC_FUNC_PRINTF_UNIX98
 734
 735 #
 736 # Check whether to use an included printf
 737 #
 738
 739 AC_ARG_ENABLE(included-printf,
 740               [AC_HELP_STRING([--enable-included-printf],
 741                               [use included printf [default=auto]])],
 742               enable_included_printf="$enableval")
 743
 744 need_included_printf=no
 745 if test "x$enable_included_printf" = "xyes" ; then
 746   need_included_printf=yes
 747 fi
 748 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 749   need_included_printf=yes
 750 fi
 751 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 752   need_included_printf=yes
 753 fi
 754 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 755    test -z "$glib_cv_long_long_format" ; then
 756   need_included_printf=yes
 757 fi
 758
 759 if test "x$enable_included_printf" = "xno" &&
 760    test "x$need_included_printf" = "xyes" ; then
 761   AC_MSG_ERROR([
 762 *** Your C library's printf doesn't appear to have the features that
 763 *** GLib needs, but you specified --enable-included-printf=no.])
 764 fi
 765
 766 enable_included_printf=$need_included_printf
 767
 768 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 769 if test "$enable_included_printf" != "yes" ; then
 770   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 771 else
 772   if test -z "$glib_cv_long_long_format" ; then
 773     glib_cv_long_long_format="ll"
 774   fi
 775   AC_DEFINE(HAVE_VASPRINTF,1)
 776 fi
 777
 778 # Checks needed for gnulib vasnprintf
 779 bh_C_SIGNED
 780 jm_AC_TYPE_LONG_LONG
 781 gt_TYPE_LONGDOUBLE
 782 gt_TYPE_WCHAR_T
 783 gt_TYPE_WINT_T
 784 AC_TYPE_SIZE_T
 785 AC_CHECK_TYPES(ptrdiff_t)
 786 jm_AC_TYPE_INTMAX_T
 787 AC_CHECK_FUNCS(snprintf)
 788 AC_FUNC_SNPRINTF_C99
 789
 790 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 791 # The check is borrowed from the PERL Configure script.
 792 if test "$ac_cv_func_memmove" != "yes"; then
 793   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 794     glib_cv_working_bcopy,[AC_TRY_RUN([
 795       int main() {
 796         char buf[128], abc[128], *b;
 797         int len, off, align;
 798         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 799         for (align = 7; align >= 0; align--) {
 800           for (len = 36; len; len--) {
 801             b = buf+align; bcopy(abc, b, len);
 802             for (off = 1; off <= len; off++) {
 803               bcopy(b, b+off, len); bcopy(b+off, b, len);
 804                 if (bcmp(b, abc, len)) return(1);
 805             }
 806           }
 807         }
 808         return(0);
 809       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 810
 811   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 812   if test "$glib_cv_working_bcopy" = "yes"; then
 813     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 814   fi
 815 fi
 816
 817 # Check for sys_errlist
 818 AC_MSG_CHECKING(for sys_errlist)
 819 AC_TRY_LINK(, [
 820 extern char *sys_errlist[];
 821 extern int sys_nerr;
 822 sys_errlist[sys_nerr-1][0] = 0;
 823 ], glib_ok=yes, glib_ok=no)
 824 AC_MSG_RESULT($glib_ok)
 825 if test "$glib_ok" = "no"; then
 826     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 827 fi
 828
 829 # Check for sys_siglist
 830 AC_MSG_CHECKING(for sys_siglist)
 831 AC_TRY_LINK(, [
 832 extern char *sys_siglist[];
 833 exit (sys_siglist[0]);
 834 ], glib_ok=yes, glib_ok=no)
 835 AC_MSG_RESULT($glib_ok)
 836 if test "$glib_ok" = "no"; then
 837     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 838 fi
 839
 840 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 841 AC_MSG_CHECKING(for sys_siglist declaration)
 842 AC_TRY_COMPILE([#include <signal.h>], [
 843 strlen (sys_siglist[0]);
 844 ], glib_ok=yes, glib_ok=no)
 845 AC_MSG_RESULT($glib_ok)
 846 if test "$glib_ok" = "no"; then
 847     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 848 fi
 849
 850 # Check if <sys/select.h> needs to be included for fd_set
 851 AC_MSG_CHECKING([for fd_set])
 852 AC_TRY_COMPILE([#include <sys/types.h>],
 853         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 854 if test "$gtk_ok" = "yes"; then
 855     AC_MSG_RESULT([yes, found in sys/types.h])
 856 else
 857     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 858     if test "$gtk_ok" = "yes"; then
 859         # *** FIXME: give it a different name
 860         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 861         AC_MSG_RESULT([yes, found in sys/select.h])
 862     else
 863         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 864         AC_MSG_RESULT(no)
 865     fi
 866 fi
 867
 868 dnl *** check for sane realloc() ***
 869 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 870         AC_TRY_RUN([#include <stdlib.h>
 871         int main() {
 872           return realloc (0, sizeof (int)) == 0;
 873         }],
 874         [glib_cv_sane_realloc=yes],
 875         [glib_cv_sane_realloc=no],
 876         [glib_cv_sane_realloc=yes])
 877 ])
 878 if test x$glib_cv_sane_realloc = xyes; then
 879   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 880 fi
 881
 882 dnl Check for nl_langinfo and CODESET
 883
 884 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 885 AC_TRY_COMPILE([#include <langinfo.h>],
 886         [char *codeset = nl_langinfo (CODESET);],
 887    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 888    have_codeset=yes,
 889    have_codeset=no)
 890 AC_MSG_RESULT($have_codeset)
 891
 892
 893 dnl ****************************************
 894 dnl *** strlcpy/strlcat                  ***
 895 dnl ****************************************
 896 # Check for strlcpy
 897 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
 898 AC_TRY_RUN([#include <stdlib.h>
 899 #include <string.h>
 900 int main() {
 901   char p[10];
 902   (void) strlcpy (p, "hi", 10);
 903   if (strlcat (p, "bye", 0) != 3)
 904     return 1;
 905   return 0;
 906 }], glib_cv_have_strlcpy=yes,
 907     glib_cv_have_strlcpy=no,
 908     glib_cv_have_strlcpy=no)])
 909 if test "$glib_cv_have_strlcpy" = "yes"; then
 910     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 911 fi
 912
 913
 914 dnl **********************
 915 dnl *** va_copy checks ***
 916 dnl **********************
 917 dnl we currently check for all three va_copy possibilities, so we get
 918 dnl all results in config.log for bug reports.
 919 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 920         AC_LINK_IFELSE([#include <stdarg.h>
 921         void f (int i, ...) {
 922         va_list args1, args2;
 923         va_start (args1, i);
 924         va_copy (args2, args1);
 925         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 926           exit (1);
 927         va_end (args1); va_end (args2);
 928         }
 929         int main() {
 930           f (0, 42);
 931           return 0;
 932         }],
 933         [glib_cv_va_copy=yes],
 934         [glib_cv_va_copy=no])
 935 ])
 936 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 937         AC_LINK_IFELSE([#include <stdarg.h>
 938         void f (int i, ...) {
 939         va_list args1, args2;
 940         va_start (args1, i);
 941         __va_copy (args2, args1);
 942         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 943           exit (1);
 944         va_end (args1); va_end (args2);
 945         }
 946         int main() {
 947           f (0, 42);
 948           return 0;
 949         }],
 950         [glib_cv___va_copy=yes],
 951         [glib_cv___va_copy=no])
 952 ])
 953
 954 if test "x$glib_cv_va_copy" = "xyes"; then
 955   g_va_copy_func=va_copy
 956 else if test "x$glib_cv___va_copy" = "xyes"; then
 957   g_va_copy_func=__va_copy
 958 fi
 959 fi
 960
 961 if test -n "$g_va_copy_func"; then
 962   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 963 fi
 964
 965 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 966         AC_TRY_RUN([#include <stdarg.h>
 967         void f (int i, ...) {
 968         va_list args1, args2;
 969         va_start (args1, i);
 970         args2 = args1;
 971         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 972           exit (1);
 973         va_end (args1); va_end (args2);
 974         }
 975         int main() {
 976           f (0, 42);
 977           return 0;
 978         }],
 979         [glib_cv_va_val_copy=yes],
 980         [glib_cv_va_val_copy=no],
 981         [glib_cv_va_val_copy=yes])
 982 ])
 983
 984 if test "x$glib_cv_va_val_copy" = "xno"; then
 985   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 986 fi
 987
 988 dnl ***********************
 989 dnl *** g_module checks ***
 990 dnl ***********************
 991 G_MODULE_LIBS=
 992 G_MODULE_LIBS_EXTRA=
 993 G_MODULE_PLUGIN_LIBS=
 994 if test x"$glib_native_win32" = xyes; then
 995   dnl No use for this on Win32
 996   G_MODULE_LDFLAGS=
 997 else
 998   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
 999 fi
1000 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1001 G_MODULE_NEED_USCORE=0
1002 G_MODULE_BROKEN_RTLD_GLOBAL=0
1003 G_MODULE_HAVE_DLERROR=0
1004 dnl *** force native WIN32 shared lib loader
1005 if test -z "$G_MODULE_IMPL"; then
1006   case "$host" in
1007   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1008   esac
1009 fi
1010 dnl *** force native AIX library loader
1011 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1012 if test -z "$G_MODULE_IMPL"; then
1013   case "$host" in
1014   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1015   esac
1016 fi
1017 dnl *** dlopen() and dlsym() in system libraries
1018 if test -z "$G_MODULE_IMPL"; then
1019         AC_CHECK_FUNC(dlopen,
1020                       [AC_CHECK_FUNC(dlsym,
1021                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1022                       [])
1023 fi
1024 dnl *** load_image (BeOS)
1025 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1026   AC_CHECK_LIB(root, load_image,
1027       [G_MODULE_LIBS="-lbe -lroot -lglib"
1028       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1029       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1030       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1031       [])
1032 fi
1033 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1034 if test -z "$G_MODULE_IMPL"; then
1035         AC_CHECK_FUNC(NSLinkModule,
1036                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1037                        G_MODULE_NEED_USCORE=1],
1038                       [])
1039 fi
1040 dnl *** dlopen() and dlsym() in libdl
1041 if test -z "$G_MODULE_IMPL"; then
1042         AC_CHECK_LIB(dl, dlopen,
1043                      [AC_CHECK_LIB(dl, dlsym,
1044                                    [G_MODULE_LIBS=-ldl
1045                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1046                      [])
1047 fi
1048 dnl *** shl_load() in libdld (HP-UX)
1049 if test -z "$G_MODULE_IMPL"; then
1050         AC_CHECK_LIB(dld, shl_load,
1051                 [G_MODULE_LIBS=-ldld
1052                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1053                 [])
1054 fi
1055 dnl *** additional checks for G_MODULE_IMPL_DL
1056 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1057         LIBS_orig="$LIBS"
1058         LDFLAGS_orig="$LDFLAGS"
1059         LIBS="$G_MODULE_LIBS $LIBS"
1060         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1061 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1062         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1063                 glib_cv_rtldglobal_broken,[
1064                 AC_TRY_RUN([
1065 #include <dlfcn.h>
1066 #ifndef RTLD_GLOBAL
1067 #  define RTLD_GLOBAL 0
1068 #endif
1069 #ifndef RTLD_LAZY
1070 #  define RTLD_LAZY 0
1071 #endif
1072 int pthread_create;
1073 int main () {
1074     void *handle, *global, *local;
1075     global = &pthread_create;
1076     handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
1077     if (!handle) return 0;
1078     local = dlsym (handle, "pthread_create");
1079     return global == local;
1080 }                       ],
1081                         [glib_cv_rtldglobal_broken=no],
1082                         [glib_cv_rtldglobal_broken=yes],
1083                         [glib_cv_rtldglobal_broken=no])
1084                 rm -f plugin.c plugin.o plugin.lo
1085         ])
1086         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1087                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1088         else
1089                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1090         fi
1091 dnl *** check whether we need preceeding underscores
1092         AC_CACHE_CHECK([for preceeding underscore in symbols],
1093                 glib_cv_uscore,[
1094                 AC_TRY_RUN([#include <dlfcn.h>
1095                 int glib_underscore_test (void) { return 42; }
1096                 int main() {
1097                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1098                   handle = dlopen ((void*)0, 0);
1099                   if (handle) {
1100                     f1 = dlsym (handle, "glib_underscore_test");
1101                     f2 = dlsym (handle, "_glib_underscore_test");
1102                   } return (!f2 || f1);
1103                 }],
1104                         [glib_cv_uscore=yes],
1105                         [glib_cv_uscore=no],
1106                         [])
1107                 rm -f plugin.c plugin.$ac_objext plugin.lo
1108         ])
1109         GLIB_ASSERT_SET(glib_cv_uscore)
1110         if test "x$glib_cv_uscore" = "xyes"; then
1111                 G_MODULE_NEED_USCORE=1
1112         else
1113                 G_MODULE_NEED_USCORE=0
1114         fi
1115
1116         LDFLAGS="$LDFLAGS_orig"
1117 dnl *** check for having dlerror()
1118         AC_CHECK_FUNC(dlerror,
1119                 [G_MODULE_HAVE_DLERROR=1],
1120                 [G_MODULE_HAVE_DLERROR=0])
1121         LIBS="$LIBS_orig"
1122 fi
1123 dnl *** done, have we got an implementation?
1124 if test -z "$G_MODULE_IMPL"; then
1125         G_MODULE_IMPL=0
1126         G_MODULE_SUPPORTED=false
1127 else
1128         G_MODULE_SUPPORTED=true
1129 fi
1130
1131 AC_MSG_CHECKING(for the suffix of shared libraries)
1132 case "$host_os" in
1133   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1134     glib_gmodule_suffix='sl'
1135     ;;
1136   cygwin* | mingw*)
1137     glib_gmodule_suffix='dll'
1138     ;;
1139   aix*)
1140     glib_gmodule_suffix='a'
1141     ;;
1142   *)
1143     glib_gmodule_suffix='so'
1144     ;;
1145 esac
1146 AC_MSG_RESULT(.$glib_gmodule_suffix)
1147
1148 AC_SUBST(G_MODULE_SUPPORTED)
1149 AC_SUBST(G_MODULE_IMPL)
1150 AC_SUBST(G_MODULE_LIBS)
1151 AC_SUBST(G_MODULE_LIBS_EXTRA)
1152 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1153 AC_SUBST(G_MODULE_LDFLAGS)
1154 AC_SUBST(G_MODULE_HAVE_DLERROR)
1155 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1156 AC_SUBST(G_MODULE_NEED_USCORE)
1157 AC_SUBST(GLIB_DEBUG_FLAGS)
1158
1159 dnl **********************
1160 dnl *** g_spawn checks ***
1161 dnl **********************
1162
1163 AC_MSG_CHECKING(for gspawn implementation)
1164 case "$host" in
1165   *-*-mingw*)
1166     GSPAWN=gspawn-win32.lo
1167     ;;
1168   *)
1169     GSPAWN=gspawn.lo
1170     ;;
1171 esac
1172 AC_MSG_RESULT($GSPAWN)
1173 AC_SUBST(GSPAWN)
1174
1175 dnl *************************
1176 dnl *** GIOChannel checks ***
1177 dnl *************************
1178
1179 AC_MSG_CHECKING(for GIOChannel implementation)
1180 case "$host" in
1181   *-*-mingw*)
1182     GIO=giowin32.lo
1183     ;;
1184   *)
1185     GIO=giounix.lo
1186     ;;
1187 esac
1188 AC_MSG_RESULT($GIO)
1189 AC_SUBST(GIO)
1190
1191 dnl check for cpu to enable double checked locking when possible
1192 dnl ************************************************************
1193
1194 if test x"$have_threads" != xno; then
1195         AC_MSG_CHECKING(whether double checked locking is safe)
1196         # According to glibc/linuxthreads the following platforms do
1197         # not have the notion of a read or write memory barrier and
1198         # therefore the double checked locking should be safe. Have a
1199         # look at pthread_once in glibc/linuxthreads/mutex.c to see,
1200         # what this means.
1201         case $host_cpu in
1202                 arm|hppa|i386|i686|ia64|m68k|sh|cris|x86_64)
1203                         g_use_double_checked_locking=yes
1204                 ;;
1205                 *)
1206                         g_use_double_checked_locking=no
1207                 ;;
1208         esac
1209         AC_MSG_RESULT($g_use_double_checked_locking)
1210 fi
1211
1212 dnl ****************************************
1213 dnl *** platform dependent source checks ***
1214 dnl ****************************************
1215
1216 AC_MSG_CHECKING(for platform-dependent source)
1217 case "$host" in
1218   *-*-cygwin*|*-*-mingw*)
1219     PLATFORMDEP=gwin32.lo
1220     ;;
1221   *)
1222     PLATFORMDEP=
1223     ;;
1224 esac
1225 AC_MSG_RESULT($PLATFORMDEP)
1226 AC_SUBST(PLATFORMDEP)
1227
1228 AC_MSG_CHECKING([whether to compile timeloop])
1229 case "$host" in
1230   *-*-cygwin*|*-*-mingw*)
1231     enable_timeloop=no
1232     ;;
1233   *)
1234     enable_timeloop=yes
1235     ;;
1236 esac
1237 AC_MSG_RESULT($enable_timeloop)
1238 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1239
1240 AC_MSG_CHECKING([if building for some Win32 platform])
1241 case "$host" in
1242   *-*-mingw*|*-*-cygwin*)
1243     platform_win32=yes
1244     ;;
1245   *)
1246     platform_win32=no
1247     ;;
1248 esac
1249 AC_MSG_RESULT($platform_win32)
1250 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1251
1252 dnl ***********************
1253 dnl *** g_thread checks ***
1254 dnl ***********************
1255
1256 AC_ARG_WITH(threads,
1257            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/solaris/win32@:>@],
1258                            [specify a thread implementation to use])],
1259            [if test "x$with_threads" = x; then
1260                 want_threads=yes
1261             else
1262                 want_threads=$with_threads
1263             fi],
1264            [want_threads=yes])
1265 if test "x$enable_threads" = "xno"; then
1266         want_threads=no
1267 fi
1268
1269 dnl error and warning message
1270 dnl *************************
1271
1272 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1273                 computer. GLib will not have a default thread implementation."
1274
1275 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1276                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1277                 compilation now, but then your programs might not work.
1278                 Please provide information on how it is done on your system."
1279
1280 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1281                 "
1282
1283 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1284                 provide information on your thread implementation.
1285                 You can also run 'configure --disable-threads'
1286                 to compile without thread support."
1287
1288 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1289                 functions will not be MT-safe during their first call because
1290                 there is no working 'getpwuid_r' on your system."
1291
1292 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1293                 because there is no 'localtime_r' on your system."
1294
1295 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1296                 crude surrogate will be used. If you happen to know a
1297                 yield function for your system, please inform the GLib
1298                 developers."
1299
1300 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1301                 threads on your system. Thus threads can only have the default
1302                 priority. If you happen to know these main/max
1303                 priorities, please inform the GLib developers."
1304
1305 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1306                 linking threaded applications. As GLib cannot do that
1307                 automatically, you will get an linkg error everytime you are
1308                 not using the right compiler. In that case you have to relink
1309                 with the right compiler. Ususally just '_r' is appended
1310                 to the compiler name."
1311
1312 dnl determination of thread implementation
1313 dnl ***************************************
1314
1315 # have_threads=no   means no thread support
1316 # have_threads=none means no default thread implementation
1317
1318 have_threads=no
1319 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1320         case $host in
1321                 *-*-solaris*)
1322                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1323                 ;;
1324         esac
1325 fi
1326 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1327                                 || test "x$want_threads" = xdce; then
1328         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1329         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1330         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1331         glib_save_CPPFLAGS="$CPPFLAGS"
1332         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1333         if test "x$have_threads" = xno; then
1334                 AC_TRY_COMPILE([#include <pthread.h>],
1335                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1336                         have_threads=posix)
1337         fi
1338         if test "x$have_threads" = xno; then
1339                 AC_TRY_COMPILE([#include <pthread.h>],
1340                         [pthread_mutex_t m;
1341                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1342                         have_threads=dce)
1343         fi
1344         # Tru64Unix requires -pthread to find pthread.h. See #103020
1345         CPPFLAGS="$CPPFLAGS -pthread"
1346         if test "x$have_threads" = xno; then
1347         AC_TRY_COMPILE([#include <pthread.h>],
1348                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1349                        have_threads=posix)
1350         fi
1351         CPPFLAGS="$glib_save_CPPFLAGS"
1352 fi
1353 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1354         case $host in
1355                 *-*-mingw*)
1356                 have_threads=win32
1357                 ;;
1358         esac
1359 fi
1360 if test "x$want_threads" = xnone; then
1361         have_threads=none
1362 fi
1363
1364 AC_MSG_CHECKING(for thread implementation)
1365
1366 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1367         AC_MSG_RESULT(none available)
1368         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1369 else
1370         AC_MSG_RESULT($have_threads)
1371 fi
1372
1373
1374 dnl determination of G_THREAD_CFLAGS
1375 dnl ********************************
1376
1377 G_THREAD_LIBS=
1378 G_THREAD_LIBS_EXTRA=
1379 G_THREAD_CFLAGS=
1380
1381 dnl
1382 dnl Test program for basic POSIX threads functionality
1383 dnl
1384 m4_define([glib_thread_test],[
1385 #include <pthread.h>
1386 int check_me = 0;
1387 void* func(void* data) {check_me = 42; return &check_me;}
1388 int main()
1389  { pthread_t t;
1390    void *ret;
1391    pthread_create (&t, $1, func, 0);
1392    pthread_join (t, &ret);
1393    exit (check_me != 42 || ret != &check_me);
1394 }])
1395
1396 dnl
1397 dnl Test program for sched_get_priority_min()
1398 dnl
1399 m4_define([glib_sched_priority_test],[
1400 #include <sched.h>
1401 #include <errno.h>
1402 int main() {
1403     errno = 0;
1404     return sched_get_priority_min(SCHED_OTHER)==-1
1405            && errno != 0;
1406 }])
1407
1408 if test x"$have_threads" != xno; then
1409
1410   if test x"$have_threads" = xposix; then
1411     # First we test for posix, whether -pthread or -pthreads do the trick as
1412     # both CPPFLAG and LIBS.
1413     # One of them does for most gcc versions and some other platforms/compilers
1414     # too and could be considered as the canonical way to go.
1415     for flag in pthread pthreads; do
1416       glib_save_CFLAGS="$CFLAGS"
1417       CFLAGS="$CFLAGS -$flag"
1418       AC_TRY_RUN(glib_thread_test(0),
1419                  glib_flag_works=yes,
1420                  glib_flag_works=no,
1421                  [AC_LINK_IFELSE(glib_thread_test(0),
1422                                  glib_flag_works=yes,
1423                                  glib_flag_works=no)])
1424       CFLAGS="$glib_save_CFLAGS"
1425       if test $glib_flag_works = yes ; then
1426          G_THREAD_CFLAGS=-$flag
1427          G_THREAD_LIBS=-$flag
1428       fi
1429     done
1430   fi
1431
1432   if test x"$G_THREAD_CFLAGS" = x; then
1433
1434     # The canonical -pthread[s] does not work. Try something different.
1435
1436     case $host in
1437         *-aix*)
1438                 if test x"$GCC" = xyes; then
1439                         # GCC 3.0 and above needs -pthread.
1440                         # Should be coverd by the case above.
1441                         # GCC 2.x and below needs -mthreads
1442                         G_THREAD_CFLAGS="-mthreads"
1443                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1444                 else
1445                         # We are probably using the aix compiler. Normaly a
1446                         # program would have to be compiled with the _r variant
1447                         # of the corresponding compiler, but we as GLib cannot
1448                         # do that: but the good news is that for compiling the
1449                         # only difference is the added -D_THREAD_SAFE compile
1450                         # option. This is according to the "C for AIX User's
1451                         # Guide".
1452                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1453                 fi
1454                 ;;
1455         *-dg-dgux*)  # DG/UX
1456                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1457                 ;;
1458         *-osf*)
1459                 # So we are using dce threads. posix threads are already
1460                 # catched above.
1461                 G_THREAD_CFLAGS="-threads"
1462                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1463                 ;;
1464         *-solaris*)
1465                 if test x"$GCC" = xyes; then
1466                    # We are using solaris threads. posix threads are
1467                    # already catched above.
1468                         G_THREAD_CFLAGS="-threads"
1469                 else
1470                         G_THREAD_CFLAGS="-mt"
1471                 fi
1472                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1473                 ;;
1474         *-sysv5uw7*) # UnixWare 7
1475                 # We are not using gcc with -pthread. Catched above.
1476                 G_THREAD_CFLAGS="-Kthread"
1477                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1478                 ;;
1479         *-mingw*)
1480                 # No flag needed when using MSVCRT.DLL
1481                 G_THREAD_CFLAGS=""
1482                 ;;
1483         *)
1484                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1485                 ;;
1486     esac
1487
1488   fi
1489
1490     # if we are not finding the localtime_r function, then we probably are
1491     # not using the proper multithread flag
1492
1493     glib_save_CPPFLAGS="$CPPFLAGS"
1494     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1495
1496     # First we test, whether localtime_r is declared in time.h
1497     # directly. Then we test whether a macro localtime_r exists, in
1498     # which case localtime_r in the test program is replaced and thus
1499     # if we still find localtime_r in the output, it is not defined as
1500     # a macro.
1501
1502     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1503       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1504                                                            localtime_r(a,b)],
1505                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1506
1507     CPPFLAGS="$glib_save_CPPFLAGS"
1508
1509     AC_MSG_CHECKING(thread related cflags)
1510     AC_MSG_RESULT($G_THREAD_CFLAGS)
1511     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1512 fi
1513
1514 dnl determination of G_THREAD_LIBS
1515 dnl ******************************
1516
1517 mutex_has_default=no
1518 case $have_threads in
1519         posix|dce)
1520           glib_save_CPPFLAGS="$CPPFLAGS"
1521           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1522           if test x"$G_THREAD_LIBS" = x; then
1523             case $host in
1524               *-aix*)
1525                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1526                 # probably using the aix compiler.
1527                 AC_MSG_WARN($AIX_COMPILE_INFO)
1528                 ;;
1529               *)
1530                 G_THREAD_LIBS=error
1531                 glib_save_LIBS="$LIBS"
1532                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1533                         if test x"$thread_lib" = x; then
1534                                 add_thread_lib=""
1535                                 IN=""
1536                         else
1537                                 add_thread_lib="-l$thread_lib"
1538                                 IN=" in -l$thread_lib"
1539                         fi
1540                         if test x"$have_threads" = xposix; then
1541                                 defattr=0
1542                         else
1543                                 defattr=pthread_attr_default
1544                         fi
1545
1546                         LIBS="$add_thread_lib $glib_save_LIBS"
1547
1548                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1549                         AC_TRY_RUN(glib_thread_test($defattr),
1550                                    glib_result=yes,
1551                                    glib_result=no,
1552                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1553                                                    glib_result=yes,
1554                                                    glib_result=no)])
1555                         AC_MSG_RESULT($glib_result)
1556
1557                         if test "$glib_result" = "yes" ; then
1558                           G_THREAD_LIBS="$add_thread_lib"
1559                           break
1560                         fi
1561                 done
1562                 if test "x$G_THREAD_LIBS" = xerror; then
1563                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1564                 fi
1565                 LIBS="$glib_save_LIBS"
1566                 ;;
1567             esac
1568           fi
1569
1570           glib_save_LIBS="$LIBS"
1571           for thread_lib in "" rt rte; do
1572             if test x"$thread_lib" = x; then
1573               add_thread_lib=""
1574               IN=""
1575             else
1576               add_thread_lib="-l$thread_lib"
1577               IN=" in -l$thread_lib"
1578             fi
1579             LIBS="$add_thread_lib $glib_save_LIBS"
1580
1581             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1582             AC_TRY_RUN(glib_sched_priority_test,
1583                        glib_result=yes,
1584                        glib_result=no,
1585                        [AC_LINK_IFELSE(glib_sched_priority_test,
1586                                        glib_result=yes,
1587                                        glib_result=no)])
1588             AC_MSG_RESULT($glib_result)
1589
1590             if test "$glib_result" = "yes" ; then
1591                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1592                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1593                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1594                break
1595             fi
1596           done
1597           LIBS="$glib_save_LIBS"
1598           mutex_has_default=yes
1599           mutex_default_type='pthread_mutex_t'
1600           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1601           mutex_header_file='pthread.h'
1602           if test "x$have_threads" = "xposix"; then
1603             g_threads_impl="POSIX"
1604           else
1605             g_threads_impl="DCE"
1606             have_threads="posix"
1607           fi
1608           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1609           CPPFLAGS="$glib_save_CPPFLAGS"
1610           ;;
1611         solaris)
1612            mutex_has_default=yes
1613            mutex_default_type='mutex_t'
1614            mutex_default_init="DEFAULTMUTEX"
1615            mutex_header_file='thread.h'
1616            g_threads_impl="SOLARIS"
1617            ;;
1618         win32)
1619            g_threads_impl="WIN32"
1620            ;;
1621         none|no)
1622            g_threads_impl="NONE"
1623            ;;
1624         *)
1625            g_threads_impl="NONE"
1626            G_THREAD_LIBS=error
1627            ;;
1628 esac
1629
1630 if test "x$G_THREAD_LIBS" = xerror; then
1631         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1632 fi
1633
1634 case $host in
1635   *-*-beos*)
1636     G_THREAD_LIBS="-lbe -lroot -lglib "
1637     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1638     ;;
1639   *)
1640     ;;
1641 esac
1642
1643 AC_MSG_CHECKING(thread related libraries)
1644 AC_MSG_RESULT($G_THREAD_LIBS)
1645
1646 dnl check for mt safe function variants and some posix functions
1647 dnl ************************************************************
1648
1649 if test x"$have_threads" != xno; then
1650         glib_save_LIBS="$LIBS"
1651         # we are not doing the following for now, as this might require glib
1652         # to always be linked with the thread libs on some platforms.
1653         # LIBS="$LIBS $G_THREAD_LIBS"
1654         AC_CHECK_FUNCS(localtime_r)
1655         if test "$ac_cv_header_pwd_h" = "yes"; then
1656                 AC_CACHE_CHECK([for posix getpwuid_r],
1657                         ac_cv_func_posix_getpwuid_r,
1658                         [AC_TRY_RUN([
1659 #include <errno.h>
1660 #include <pwd.h>
1661 int main () {
1662     char buffer[10000];
1663     struct passwd pwd, *pwptr = &pwd;
1664     int error;
1665     errno = 0;
1666     error = getpwuid_r (0, &pwd, buffer,
1667                         sizeof (buffer), &pwptr);
1668    return (error < 0 && errno == ENOSYS)
1669            || error == ENOSYS;
1670 }                               ],
1671                                 [ac_cv_func_posix_getpwuid_r=yes],
1672                                 [ac_cv_func_posix_getpwuid_r=no])])
1673                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1674                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1675                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1676                                 [Have POSIX function getpwuid_r])
1677                 else
1678                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1679                                 ac_cv_func_nonposix_getpwuid_r,
1680                                 [AC_TRY_LINK([#include <pwd.h>],
1681                                         [char buffer[10000];
1682                                         struct passwd pwd;
1683                                         getpwuid_r (0, &pwd, buffer,
1684                                                         sizeof (buffer));],
1685                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1686                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1687                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1688                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1689                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1690                                         [Have non-POSIX function getpwuid_r])
1691                         fi
1692                 fi
1693         fi
1694         LIBS="$G_THREAD_LIBS $LIBS"
1695         if test x"$have_threads" = xposix; then
1696                 glib_save_CPPFLAGS="$CPPFLAGS"
1697                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1698                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1699                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1700                 # This is not AC_CHECK_FUNC to also work with function
1701                 # name mangling in header files.
1702                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1703                 AC_TRY_LINK([#include <pthread.h>],
1704                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1705                         [AC_MSG_RESULT(yes)
1706                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1707                                   [Have function pthread_attr_setstacksize])],
1708                         [AC_MSG_RESULT(no)])
1709                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1710                 if test x"$posix_priority_min" = x; then
1711                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1712                                 PX_PRIO_MIN],,[
1713                                 posix_priority_min=PX_PRIO_MIN
1714                                 posix_priority_max=PX_PRIO_MAX])
1715                 fi
1716                 if test x"$posix_priority_min" = x; then
1717                         # AIX
1718                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1719                                 PTHREAD_PRIO_MIN],,[
1720                                 posix_priority_min=PTHREAD_PRIO_MIN
1721                                 posix_priority_max=PTHREAD_PRIO_MAX])
1722                 fi
1723                 if test x"$posix_priority_min" = x; then
1724                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1725                                 PRI_OTHER_MIN],,[
1726                                 posix_priority_min=PRI_OTHER_MIN
1727                                 posix_priority_max=PRI_OTHER_MAX])
1728                 fi
1729                 if test x"$posix_priority_min" = x; then
1730                         AC_MSG_RESULT(none found)
1731                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1732                         posix_priority_min=-1
1733                         posix_priority_max=-1
1734                 else
1735                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1736                         AC_MSG_CHECKING(for pthread_setschedparam)
1737                         AC_TRY_LINK([#include <pthread.h>],
1738                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1739                           [AC_MSG_RESULT(yes)
1740                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1741                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1742                           [AC_MSG_RESULT(no)
1743                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1744                 fi
1745                 posix_yield_func=none
1746                 AC_MSG_CHECKING(for posix yield function)
1747                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1748                                                         thr_yield; do
1749                         AC_TRY_LINK([#include <pthread.h>],
1750                                 [$yield_func()],
1751                                 [posix_yield_func="$yield_func"
1752                                 break])
1753                 done
1754                 if test x"$posix_yield_func" = xnone; then
1755                         AC_MSG_RESULT(none found)
1756                         AC_MSG_WARN($POSIX_NO_YIELD)
1757                         posix_yield_func="g_usleep(1000)"
1758                 else
1759                         AC_MSG_RESULT($posix_yield_func)
1760                         posix_yield_func="$posix_yield_func()"
1761                 fi
1762                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1763                 CPPFLAGS="$glib_save_CPPFLAGS"
1764
1765         elif test x"$have_threads" = xwin32; then
1766                 # It's a pointer to a private struct
1767                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1768         elif test x"$have_threads" = xsolaris; then
1769                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1770         fi
1771
1772         LIBS="$glib_save_LIBS"
1773
1774         # now spit out all the warnings.
1775         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1776            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1777                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1778         fi
1779         if test "$ac_cv_func_localtime_r" != "yes"; then
1780                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1781         fi
1782 fi
1783
1784 if test x"$glib_cv_sizeof_system_thread" = x; then
1785    # use a pointer as a fallback.
1786    GLIB_SIZEOF(,void *, system_thread)
1787 fi
1788
1789 #
1790 # Hack to deal with:
1791 #
1792 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1793 #     building shared libraries with linux.
1794 #  b) libtool doesn't recognize -pthread as a library dependency.
1795 #
1796 case $host in
1797   *-*-linux*)
1798     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1799     ;;
1800   *)
1801     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-Wc,-pthread/`"
1802     ;;
1803 esac
1804
1805 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1806                    [Source file containing theread implementation])
1807 AC_SUBST(G_THREAD_CFLAGS)
1808 AC_SUBST(G_THREAD_LIBS)
1809 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1810 AC_SUBST(G_THREAD_LIBS_EXTRA)
1811
1812 dnl **********************************************
1813 dnl *** GDefaultMutex setup and initialization ***
1814 dnl **********************************************
1815 dnl
1816 dnl if mutex_has_default = yes, we also got
1817 dnl mutex_default_type, mutex_default_init and mutex_header_file
1818 if test $mutex_has_default = yes ; then
1819         glib_save_CPPFLAGS="$CPPFLAGS"
1820         glib_save_LIBS="$LIBS"
1821         LIBS="$G_THREAD_LIBS $LIBS"
1822         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1823         GLIB_SIZEOF([#include <$mutex_header_file>],
1824                     $mutex_default_type,
1825                     gmutex)
1826         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1827                            $mutex_default_type,
1828                            gmutex,
1829                            $glib_cv_sizeof_gmutex,
1830                            $mutex_default_init)
1831         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1832                 mutex_has_default=no
1833         fi
1834         CPPFLAGS="$glib_save_CPPFLAGS"
1835         LIBS="$glib_save_LIBS"
1836 fi
1837
1838 dnl ********************************
1839 dnl *** g_atomic_* tests for gcc ***
1840 dnl ********************************
1841
1842 AC_MSG_CHECKING([whether to use inline assembler code for atomic operations])
1843
1844 if test x"$GCC" = xyes; then
1845   case $host_cpu in
1846     i386)
1847       AC_MSG_RESULT([no])
1848       ;;
1849     i?86)
1850       AC_MSG_RESULT([i486])
1851       glib_atomic_inlined_implementation=I486
1852       ;;
1853     sparc*)
1854       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
1855                 when you are using a sparc with v9 instruction set (most
1856                 sparcs nowadays). This will make the code for atomic
1857                 operations much faster. The resulting code will not run
1858                 on very old sparcs though."
1859
1860       AC_LINK_IFELSE([[
1861         main ()
1862         {
1863           int tmp1, tmp2, tmp3;
1864           __asm__ __volatile__("casx [%2], %0, %1"
1865                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
1866         }]],
1867         AC_MSG_RESULT([sparcv9])
1868         glib_atomic_inlined_implementation=SPARCV9,
1869         AC_MSG_RESULT([no])
1870         AC_MSG_WARN([[$SPARCV9_WARNING]]))
1871       ;;
1872     alpha)
1873       AC_MSG_RESULT([alpha])
1874       glib_atomic_inlined_implementation=ALPHA
1875       ;;
1876     x86_64)
1877       AC_MSG_RESULT([x86_64])
1878       glib_atomic_inlined_implementation=X86_64
1879       ;;
1880     powerpc*)
1881       AC_MSG_RESULT([powerpc])
1882       glib_atomic_inlined_implementation=POWERPC
1883       ;;
1884     ia64)
1885       AC_MSG_RESULT([ia64])
1886       glib_atomic_inlined_implementation=IA64
1887       ;;
1888     *)
1889       AC_MSG_RESULT([none])
1890       glib_atomic_inlined_implementation=NONE
1891       ;;
1892   esac
1893 fi
1894
1895 dnl ****************************************
1896 dnl *** GLib POLL* compatibility defines ***
1897 dnl ****************************************
1898
1899 glib_poll_includes=["
1900 #include <sys/types.h>
1901 #include <sys/poll.h>
1902 "]
1903
1904 if test $ac_cv_header_sys_types_h = yes &&
1905    test $ac_cv_header_sys_poll_h = yes ; then
1906   glib_failed=false
1907   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1908   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1909   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
1910   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
1911   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
1912   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
1913   if $glib_failed ; then
1914     AC_MSG_ERROR([Could not determine values for POLL* constants])
1915   fi
1916 else
1917   glib_cv_value_POLLIN=1
1918   glib_cv_value_POLLOUT=4
1919   glib_cv_value_POLLPRI=2
1920   glib_cv_value_POLLERR=8
1921   glib_cv_value_POLLHUP=16
1922   glib_cv_value_POLLNVAL=32
1923 fi
1924
1925 dnl **********************
1926 dnl *** Win32 API libs ***
1927 dnl **********************
1928
1929 case $host in
1930   *-*-cygwin*)
1931         G_LIBS_EXTRA="-luser32 -lkernel32"
1932     ;;
1933   *-*-mingw*)
1934         G_LIBS_EXTRA="-lwsock32"
1935     ;;
1936   *)
1937         G_LIBS_EXTRA=""
1938     ;;
1939 esac
1940 AC_SUBST(G_LIBS_EXTRA)
1941
1942 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1943 dnl since we need it for g_iconv()
1944
1945 AC_MSG_CHECKING([for EILSEQ])
1946 AC_TRY_COMPILE([
1947 #include <errno.h>
1948 ],
1949 [
1950 int error = EILSEQ;
1951 ], have_eilseq=yes, have_eilseq=no);
1952 AC_MSG_RESULT($have_eilseq)
1953
1954 dnl ******************************************************************
1955 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
1956 dnl ******************************************************************
1957
1958 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1959
1960 if test $cross_compiling = yes; then
1961   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
1962   if test x$GLIB_GENMARSHAL = xno; then
1963     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
1964   fi
1965 fi
1966
1967 dnl **************************
1968 dnl *** Checks for gtk-doc ***
1969 dnl **************************
1970
1971 GTK_DOC_CHECK([1.0])
1972
1973 AC_ARG_ENABLE(man,
1974               [AC_HELP_STRING([--enable-man],
1975                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1976               enable_man=no)
1977
1978 if test "${enable_man}" != no; then
1979 dnl
1980 dnl Check for xsltproc
1981 dnl
1982 AC_PATH_PROG([XSLTPROC], [xsltproc])
1983   if test -z "$XSLTPROC"; then
1984     enable_man=no
1985   fi
1986
1987   dnl check for DocBook DTD and stylesheets in the local catalog.
1988   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1989      [DocBook XML DTD V4.1.2],,enable_man=no)
1990   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1991      [DocBook XSL Stylesheets],,enable_man=no)
1992 fi
1993
1994 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1995
1996 dnl ******************************
1997 dnl *** output the whole stuff ***
1998 dnl ******************************
1999
2000 dnl this section will only be run if config.status is invoked with no
2001 dnl arguments, or with "glibconfig.h" as an argument.
2002 AC_CONFIG_COMMANDS([glibconfig.h],
2003 [
2004         outfile=glibconfig.h-tmp
2005         cat > $outfile <<\_______EOF
2006 /* glibconfig.h
2007  *
2008  * This is a generated file.  Please modify 'configure.in'
2009  */
2010
2011 #ifndef __G_LIBCONFIG_H__
2012 #define __G_LIBCONFIG_H__
2013
2014 #include <glib/gmacros.h>
2015
2016 _______EOF
2017
2018         if test x$glib_limits_h = xyes; then
2019           echo '#include <limits.h>' >> $outfile
2020         fi
2021         if test x$glib_float_h = xyes; then
2022           echo '#include <float.h>' >> $outfile
2023         fi
2024         if test x$glib_values_h = xyes; then
2025           echo '#include <values.h>' >> $outfile
2026         fi
2027         if test "$glib_header_alloca_h" = "yes"; then
2028           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2029         fi
2030         if test x$glib_sys_poll_h = xyes; then
2031           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2032         fi
2033
2034         cat >> $outfile <<_______EOF
2035
2036 G_BEGIN_DECLS
2037
2038 #define G_MINFLOAT      $glib_mf
2039 #define G_MAXFLOAT      $glib_Mf
2040 #define G_MINDOUBLE     $glib_md
2041 #define G_MAXDOUBLE     $glib_Md
2042 #define G_MINSHORT      $glib_ms
2043 #define G_MAXSHORT      $glib_Ms
2044 #define G_MAXUSHORT     $glib_Mus
2045 #define G_MININT        $glib_mi
2046 #define G_MAXINT        $glib_Mi
2047 #define G_MAXUINT       $glib_Mui
2048 #define G_MINLONG       $glib_ml
2049 #define G_MAXLONG       $glib_Ml
2050 #define G_MAXULONG      $glib_Mul
2051
2052 _______EOF
2053
2054
2055         ### this should always be true in a modern C/C++ compiler
2056         cat >>$outfile <<_______EOF
2057 typedef signed char gint8;
2058 typedef unsigned char guint8;
2059 _______EOF
2060
2061
2062         if test -n "$gint16"; then
2063           cat >>$outfile <<_______EOF
2064 typedef signed $gint16 gint16;
2065 typedef unsigned $gint16 guint16;
2066 #define G_GINT16_MODIFIER $gint16_modifier
2067 #define G_GINT16_FORMAT $gint16_format
2068 #define G_GUINT16_FORMAT $guint16_format
2069 _______EOF
2070         fi
2071
2072
2073         if test -n "$gint32"; then
2074           cat >>$outfile <<_______EOF
2075 typedef signed $gint32 gint32;
2076 typedef unsigned $gint32 guint32;
2077 #define G_GINT32_MODIFIER $gint32_modifier
2078 #define G_GINT32_FORMAT $gint32_format
2079 #define G_GUINT32_FORMAT $guint32_format
2080 _______EOF
2081         fi
2082
2083         cat >>$outfile <<_______EOF
2084 #define G_HAVE_GINT64 1          /* deprecated, always true */
2085
2086 ${glib_extension}typedef signed $gint64 gint64;
2087 ${glib_extension}typedef unsigned $gint64 guint64;
2088
2089 #define G_GINT64_CONSTANT(val)  $gint64_constant
2090 _______EOF
2091
2092         if test x$gint64_format != x ; then
2093           cat >>$outfile <<_______EOF
2094 #define G_GINT64_MODIFIER $gint64_modifier
2095 #define G_GINT64_FORMAT $gint64_format
2096 #define G_GUINT64_FORMAT $guint64_format
2097 _______EOF
2098         else
2099           cat >>$outfile <<_______EOF
2100 #undef G_GINT64_MODIFIER
2101 #undef G_GINT64_FORMAT
2102 #undef G_GUINT64_FORMAT
2103 _______EOF
2104         fi
2105
2106         cat >>$outfile <<_______EOF
2107
2108 #define GLIB_SIZEOF_VOID_P $glib_void_p
2109 #define GLIB_SIZEOF_LONG   $glib_long
2110 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2111
2112 _______EOF
2113
2114         cat >>$outfile <<_______EOF
2115 typedef signed $glib_size_type_define gssize;
2116 typedef unsigned $glib_size_type_define gsize;
2117 #define G_GSIZE_MODIFIER $gsize_modifier
2118 #define G_GSSIZE_FORMAT $gssize_format
2119 #define G_GSIZE_FORMAT $gsize_format
2120
2121 #define G_MAXSIZE       G_MAXU$glib_msize_type
2122 _______EOF
2123
2124         if test -z "$glib_unknown_void_p"; then
2125           cat >>$outfile <<_______EOF
2126
2127 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2128 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2129
2130 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2131 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2132 _______EOF
2133         else
2134           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2135         fi
2136
2137
2138
2139         cat >>$outfile <<_______EOF
2140 $glib_atexit
2141 $glib_memmove
2142 $glib_defines
2143 $glib_os
2144
2145 $glib_vacopy
2146
2147 #ifdef  __cplusplus
2148 #define G_HAVE_INLINE   1
2149 #else   /* !__cplusplus */
2150 $glib_inline
2151 #endif  /* !__cplusplus */
2152
2153 _______EOF
2154
2155         if test x$g_have_iso_c_varargs = xyes ; then
2156                 cat >>$outfile <<_______EOF
2157 #ifndef __cplusplus
2158 # define G_HAVE_ISO_VARARGS 1
2159 #endif
2160 _______EOF
2161         fi
2162         if test x$g_have_iso_cxx_varargs = xyes ; then
2163                 cat >>$outfile <<_______EOF
2164 #ifdef __cplusplus
2165 # define G_HAVE_ISO_VARARGS 1
2166 #endif
2167 _______EOF
2168         fi
2169         if test x$g_have_gnuc_varargs = xyes ; then
2170                 cat >>$outfile <<_______EOF
2171
2172 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2173  * is passed ISO vararg support is turned off, and there is no work
2174  * around to turn it on, so we unconditionally turn it off.
2175  */
2176 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2177 #  undef G_HAVE_ISO_VARARGS
2178 #endif
2179
2180 #define G_HAVE_GNUC_VARARGS 1
2181 _______EOF
2182         fi
2183
2184         case x$g_stack_grows in
2185         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2186         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2187         esac
2188
2189
2190         echo >>$outfile
2191         if test x$g_have_eilseq = xno; then
2192                 cat >>$outfile <<_______EOF
2193 #ifndef EILSEQ
2194 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2195  * The correspondence between this and the corresponding definition
2196  * in libiconv is essential.
2197  */
2198 #  define EILSEQ ENOENT
2199 #endif
2200 _______EOF
2201
2202         fi
2203
2204         echo >>$outfile
2205         if test x$g_mutex_has_default = xyes; then
2206                 cat >>$outfile <<_______EOF
2207 $g_enable_threads_def G_THREADS_ENABLED
2208 #define G_THREADS_IMPL_$g_threads_impl_def
2209 typedef struct _GStaticMutex GStaticMutex;
2210 struct _GStaticMutex
2211 {
2212   struct _GMutex *runtime_mutex;
2213   union {
2214     char   pad[[$g_mutex_sizeof]];
2215     double dummy_double;
2216     void  *dummy_pointer;
2217     long   dummy_long;
2218   } static_mutex;
2219 };
2220 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2221 #define g_static_mutex_get_mutex(mutex) \\
2222   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \\
2223    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2224 _______EOF
2225         else
2226                 cat >>$outfile <<_______EOF
2227 $g_enable_threads_def G_THREADS_ENABLED
2228 #define G_THREADS_IMPL_$g_threads_impl_def
2229 typedef struct _GMutex* GStaticMutex;
2230 #define G_STATIC_MUTEX_INIT NULL
2231 #define g_static_mutex_get_mutex(mutex) \\
2232   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2233 _______EOF
2234         fi
2235
2236         if test x$g_use_double_checked_locking = xyes; then
2237                 cat >>$outfile <<_______EOF
2238 /* double checked locking can be used on this platform */
2239 #define g_once(once, func, arg) \\
2240   ((once)->status == G_ONCE_STATUS_READY ? (once)->retval : \\
2241    g_once_impl (once, func, arg))
2242 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2243   (*(mutex) ? *(mutex) : g_static_mutex_get_mutex_impl (mutex))
2244 _______EOF
2245         else
2246                 cat >>$outfile <<_______EOF
2247 /* double checked locking is unsafe to use on this platform, do full locking */
2248 #define g_once(once, func, arg) (g_once_impl(once, func, arg))
2249 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2250   (g_static_mutex_get_mutex_impl (mutex))
2251 _______EOF
2252 fi
2253
2254         cat >>$outfile <<_______EOF
2255 /* This represents a system thread as used by the implementation. An
2256  * alien implementaion, as loaded by g_thread_init can only count on
2257  * "sizeof (gpointer)" bytes to store their info. We however need more
2258  * for some of our native implementations. */
2259 typedef union _GSystemThread GSystemThread;
2260 union _GSystemThread
2261 {
2262   char   data[[$g_system_thread_sizeof]];
2263   double dummy_double;
2264   void  *dummy_pointer;
2265   long   dummy_long;
2266 };
2267 _______EOF
2268         if test x"$g_atomic_inlined_implementation" != x; then
2269           echo >>$outfile
2270           echo "#define G_ATOMIC_INLINED_IMPLEMENTATION_$g_atomic_inlined_implementation" >>$outfile
2271         fi
2272
2273         echo >>$outfile
2274         g_bit_sizes="16 32 64"
2275         for bits in $g_bit_sizes; do
2276           cat >>$outfile <<_______EOF
2277 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2278 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2279 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2280 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2281 _______EOF
2282         done
2283
2284         cat >>$outfile <<_______EOF
2285 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2286 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2287 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2288 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2289 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2290 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2291 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2292 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2293 #define G_BYTE_ORDER $g_byte_order
2294
2295 #define GLIB_SYSDEF_POLLIN =$g_pollin
2296 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2297 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2298 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2299 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2300 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2301
2302 #define G_MODULE_SUFFIX "$g_module_suffix"
2303
2304 typedef $g_pid_type GPid;
2305
2306 G_END_DECLS
2307
2308 #endif /* GLIBCONFIG_H */
2309 _______EOF
2310
2311
2312         if cmp -s $outfile glibconfig.h; then
2313           AC_MSG_NOTICE([glibconfig.h is unchanged])
2314           rm -f $outfile
2315         else
2316           mv $outfile glibconfig.h
2317         fi
2318 ],[
2319
2320 # Note that if two cases are the same, case goes with the first one.
2321 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2322 # on variable expansion in case labels.  Look at the generated config.status
2323 # for a hint.
2324
2325 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2326   glib_header_alloca_h="$ac_cv_working_alloca_h"
2327 else
2328   glib_header_alloca_h="$ac_cv_header_alloca_h"
2329 fi
2330
2331 case xyes in
2332 x$ac_cv_header_float_h)
2333   glib_float_h=yes
2334   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2335   glib_md=DBL_MIN glib_Md=DBL_MAX
2336   ;;
2337 x$ac_cv_header_values_h)
2338   glib_values_h=yes
2339   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2340   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2341   ;;
2342 esac
2343
2344 case xyes in
2345 x$ac_cv_header_limits_h)
2346   glib_limits_h=yes
2347   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2348   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2349   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2350   ;;
2351 x$ac_cv_header_values_h)
2352   glib_values_h=yes
2353   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2354   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2355   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2356   ;;
2357 esac
2358
2359 if test x$ac_cv_header_sys_poll_h = xyes ; then
2360   glib_sys_poll_h=yes
2361 fi
2362
2363 case 2 in
2364 $ac_cv_sizeof_short)
2365   gint16=short
2366   gint16_modifier='"h"'
2367   gint16_format='"hi"'
2368   guint16_format='"hu"'
2369   ;;
2370 $ac_cv_sizeof_int)
2371   gint16=int
2372   gint16_modifier='""'
2373   gint16_format='"i"'
2374   guint16_format='"u"'
2375   ;;
2376 esac
2377 case 4 in
2378 $ac_cv_sizeof_short)
2379   gint32=short
2380   gint32_modifier='"h"'
2381   gint32_format='"hi"'
2382   guint32_format='"hu"'
2383   ;;
2384 $ac_cv_sizeof_int)
2385   gint32=int
2386   gint32_modifier='""'
2387   gint32_format='"i"'
2388   guint32_format='"u"'
2389   ;;
2390 $ac_cv_sizeof_long)
2391   gint32=long
2392   gint32_modifier='"l"'
2393   gint32_format='"li"'
2394   guint32_format='"lu"'
2395   ;;
2396 esac
2397 case 8 in
2398 $ac_cv_sizeof_int)
2399   gint64=int
2400   gint64_modifier='""'
2401   gint64_format='"i"'
2402   guint64_format='"u"'
2403   glib_extension=
2404   gint64_constant='(val)'
2405   ;;
2406 $ac_cv_sizeof_long)
2407   gint64=long
2408   gint64_modifier='"l"'
2409   gint64_format='"li"'
2410   guint64_format='"lu"'
2411   glib_extension=
2412   gint64_constant='(val##L)'
2413   ;;
2414 $ac_cv_sizeof_long_long)
2415   gint64='long long'
2416   if test -n "$glib_cv_long_long_format"; then
2417     gint64_modifier='"'$glib_cv_long_long_format'"'
2418     gint64_format='"'$glib_cv_long_long_format'i"'
2419     guint64_format='"'$glib_cv_long_long_format'u"'
2420   fi
2421   glib_extension='G_GNUC_EXTENSION '
2422   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2423   ;;
2424 $ac_cv_sizeof___int64)
2425   gint64='__int64'
2426   if test -n "$glib_cv_long_long_format"; then
2427     gint64_modifier='"'$glib_cv_long_long_format'"'
2428     gint64_format='"'$glib_cv_long_long_format'i"'
2429     guint64_format='"'$glib_cv_long_long_format'u"'
2430   fi
2431   glib_extension=
2432   gint64_constant='(val##i64)'
2433   ;;
2434 esac
2435 glib_size_t=$ac_cv_sizeof_size_t
2436 glib_size_type_define=$glib_size_type
2437 glib_void_p=$ac_cv_sizeof_long
2438 glib_long=$ac_cv_sizeof_void_p
2439
2440 case $glib_size_type in
2441 short)
2442   gsize_modifier='"h"'
2443   gsize_format='"hu"'
2444   gssize_format='"hi"'
2445   glib_msize_type='SHRT'
2446   ;;
2447 int)
2448   gsize_modifier='""'
2449   gsize_format='"u"'
2450   gssize_format='"i"'
2451   glib_msize_type='INT'
2452   ;;
2453 long)
2454   gsize_modifier='"l"'
2455   gsize_format='"lu"'
2456   gssize_format='"li"'
2457   glib_msize_type='LONG'
2458   ;;
2459 esac
2460
2461 gintbits=`expr $ac_cv_sizeof_int \* 8`
2462 glongbits=`expr $ac_cv_sizeof_long \* 8`
2463
2464
2465 case $ac_cv_sizeof_void_p in
2466 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2467 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2468 *)                      glib_unknown_void_p=yes ;;
2469 esac
2470
2471
2472 case xyes in
2473 x$ac_cv_func_atexit)
2474   glib_atexit="
2475 #ifdef NeXT /* @#%@! NeXTStep */
2476 # define g_ATEXIT(proc) (!atexit (proc))
2477 #else
2478 # define g_ATEXIT(proc) (atexit (proc))
2479 #endif"
2480   ;;
2481 x$ac_cv_func_on_exit)
2482   glib_atexit="
2483 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2484   ;;
2485 esac
2486
2487 case xyes in
2488 x$ac_cv_func_memmove)
2489   glib_memmove='
2490 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2491   ;;
2492 x$glib_cv_working_bcopy)
2493   glib_memmove="
2494 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2495 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2496   ;;
2497 *)
2498   glib_memmove="
2499 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2500  * so we have to roll our own copy routine. */
2501 void g_memmove (void* dest, const void * src, unsigned long len);"
2502   ;;
2503 esac
2504
2505 glib_defines="
2506 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2507 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2508 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2509 "
2510
2511 case xyes in
2512 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2513 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2514 *)                      glib_vacopy=''
2515 esac
2516
2517 if test x$glib_cv_va_val_copy = xno; then
2518   glib_vacopy="\$glib_vacopy
2519 #define G_VA_COPY_AS_ARRAY 1"
2520 fi
2521
2522 if test x$glib_cv_hasinline = xyes; then
2523     glib_inline='#define G_HAVE_INLINE 1'
2524 fi
2525 if test x$glib_cv_has__inline = xyes; then
2526     glib_inline="\$glib_inline
2527 #define G_HAVE___INLINE 1"
2528 fi
2529 if test x$glib_cv_has__inline__ = xyes; then
2530     glib_inline="\$glib_inline
2531 #define G_HAVE___INLINE__ 1"
2532 fi
2533
2534 g_have_gnuc_varargs=$g_have_gnuc_varargs
2535 g_have_iso_c_varargs=$g_have_iso_c_varargs
2536 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2537
2538 case xyes in
2539 x$ac_cv_c_bigendian)
2540   g_byte_order=G_BIG_ENDIAN
2541   g_bs_native=BE
2542   g_bs_alien=LE
2543   ;;
2544 *)
2545   g_byte_order=G_LITTLE_ENDIAN
2546   g_bs_native=LE
2547   g_bs_alien=BE
2548   ;;
2549 esac
2550
2551 g_pollin=$glib_cv_value_POLLIN
2552 g_pollout=$glib_cv_value_POLLOUT
2553 g_pollpri=$glib_cv_value_POLLPRI
2554 g_pollhup=$glib_cv_value_POLLHUP
2555 g_pollerr=$glib_cv_value_POLLERR
2556 g_pollnval=$glib_cv_value_POLLNVAL
2557
2558 g_stack_grows=$glib_cv_stack_grows
2559
2560 g_have_eilseq=$have_eilseq
2561
2562 case x$have_threads in
2563 xno)    g_enable_threads_def="#undef";;
2564 *)      g_enable_threads_def="#define";;
2565 esac
2566
2567 g_threads_impl_def=$g_threads_impl
2568 g_use_double_checked_locking=$g_use_double_checked_locking
2569
2570 g_mutex_has_default="$mutex_has_default"
2571 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2572 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2573 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2574
2575 g_atomic_inlined_implementation="$glib_atomic_inlined_implementation"
2576
2577 g_module_suffix="$glib_gmodule_suffix"
2578
2579 g_pid_type="$glib_pid_type"
2580 case $host in
2581   *-*-beos*)
2582     glib_os="#define G_OS_BEOS"
2583     ;;
2584   *-*-cygwin*)
2585     glib_os="#define G_OS_UNIX
2586 #define G_PLATFORM_WIN32
2587 #define G_WITH_CYGWIN"
2588     ;;
2589   *-*-mingw*)
2590     glib_os="#define G_OS_WIN32
2591 #define G_PLATFORM_WIN32"
2592     ;;
2593   *)
2594     glib_os="#define G_OS_UNIX"
2595     ;;
2596 esac
2597 ])
2598
2599 AC_CONFIG_FILES([
2600 glib-2.0.pc
2601 glib-2.0-uninstalled.pc
2602 gmodule-2.0.pc
2603 gmodule-2.0-uninstalled.pc
2604 gthread-2.0.pc
2605 gthread-2.0-uninstalled.pc
2606 gobject-2.0.pc
2607 gobject-2.0-uninstalled.pc
2608 glib-zip
2609 glib-gettextize
2610 Makefile
2611 build/Makefile
2612 build/win32/Makefile
2613 build/win32/dirent/Makefile
2614 glib/Makefile
2615 glib/libcharset/Makefile
2616 glib/gnulib/Makefile
2617 gmodule/Makefile
2618 gmodule/gmoduleconf.h
2619 gobject/Makefile
2620 gobject/glib-mkenums
2621 gthread/Makefile
2622 po/Makefile.in
2623 docs/Makefile
2624 docs/reference/Makefile
2625 docs/reference/glib/Makefile
2626 docs/reference/glib/version.xml
2627 docs/reference/gobject/Makefile
2628 docs/reference/gobject/version.xml
2629 tests/Makefile
2630 tests/gobject/Makefile
2631 m4macros/Makefile
2632 ])
2633
2634 AC_CONFIG_COMMANDS([chmod-scripts],
2635 [chmod 0755 glib-zip
2636 chmod 0755 glib-gettextize
2637 chmod 0755 gobject/glib-mkenums])
2638
2639 # we want to invoke this macro solely so that the config.status script
2640 # and automake generated makefiles know about these generated files.
2641 # They are only needed to distcheck the package
2642 if false; then
2643   AC_CONFIG_FILES([
2644     INSTALL
2645     README
2646     config.h.win32
2647     glibconfig.h.win32
2648     glib/makefile.mingw
2649     glib/makefile.msc
2650     glib/glib.rc
2651     gmodule/makefile.mingw
2652     gmodule/makefile.msc
2653     gmodule/gmodule.rc
2654     gobject/makefile.mingw
2655     gobject/makefile.msc
2656     gobject/gobject.rc
2657     gthread/makefile.mingw
2658     gthread/makefile.msc
2659     gthread/gthread.rc
2660     tests/makefile.mingw
2661     tests/makefile.msc
2662   ])
2663 fi
2664
2665 AC_OUTPUT