configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(glist.c)
   3
   4 # Save this value here, since automake will set cflags later
   5 cflags_set=${CFLAGS+set}
   6
   7 # The following version number definitions apply to GLib and GModule
   8 # as a whole, so if changes occoured in either of them, they are both
   9 # treated with the same interface and binary age.
  10 #
  11 # Making releases:
  12 #   GLIB_MICRO_VERSION += 1;
  13 #   GLIB_INTERFACE_AGE += 1;
  14 #   GLIB_BINARY_AGE += 1;
  15 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  16 # if backwards compatibility has been broken,
  17 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  18 #
  19 GLIB_MAJOR_VERSION=1
  20 GLIB_MINOR_VERSION=1
  21 GLIB_MICRO_VERSION=7
  22 GLIB_INTERFACE_AGE=1
  23 GLIB_BINARY_AGE=1
  24 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  25 AC_SUBST(GLIB_VERSION)
  26
  27 # libtool versioning
  28 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  29 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  30 LT_REVISION=$GLIB_INTERFACE_AGE
  31 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  32 AC_SUBST(LT_RELEASE)
  33 AC_SUBST(LT_CURRENT)
  34 AC_SUBST(LT_REVISION)
  35 AC_SUBST(LT_AGE)
  36
  37 VERSION=$GLIB_VERSION
  38 PACKAGE=glib
  39
  40 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  41
  42 # Specify a configuration file
  43 AM_CONFIG_HEADER(config.h)
  44
  45 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  46 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  47 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  48 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  49 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  50
  51 dnl Initialize libtool
  52 AM_PROG_LIBTOOL
  53
  54 dnl Initialize maintainer mode
  55 AM_MAINTAINER_MODE
  56
  57 AC_CANONICAL_HOST
  58
  59 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  60 AC_ARG_ENABLE(mem_check, [  --enable-mem-check=[no/yes] turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  61 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile=[no/yes] turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  62
  63 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  64                     , enable_ansi=no)
  65
  66 AC_MSG_CHECKING(whether to enable memory checking)
  67 if test "x$enable_mem_check" = "xyes"; then
  68   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  69   AC_SUBST(ENABLE_MEM_CHECK)
  70   AC_MSG_RESULT(yes)
  71 else
  72   AC_MSG_RESULT(no)
  73 fi
  74
  75 AC_MSG_CHECKING(whether to enable memory profiling)
  76 if test "x$enable_mem_profile" = "xyes"; then
  77   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  78   AC_SUBST(ENABLE_MEM_PROFILE)
  79   AC_MSG_RESULT(yes)
  80 else
  81   AC_MSG_RESULT(no)
  82 fi
  83
  84 if test "x$enable_debug" = "xyes"; then
  85   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  86   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
  87 else
  88   if test "x$enable_debug" = "xno"; then
  89     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
  90   fi
  91 fi
  92
  93 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
  94
  95 # Checks for programs.
  96 AC_PROG_CC
  97 AM_PROG_CC_STDC
  98 AC_PROG_INSTALL
  99
 100 changequote(,)dnl
 101 if test "x$GCC" = "xyes"; then
 102   case " $CFLAGS " in
 103   *[\ \ ]-Wall[\ \      ]*) ;;
 104   *) CFLAGS="$CFLAGS -Wall" ;;
 105   esac
 106
 107   if test "x$enable_ansi" = "xyes"; then
 108     case " $CFLAGS " in
 109     *[\ \       ]-ansi[\ \      ]*) ;;
 110     *) CFLAGS="$CFLAGS -ansi" ;;
 111     esac
 112
 113     case " $CFLAGS " in
 114     *[\ \       ]-pedantic[\ \  ]*) ;;
 115     *) CFLAGS="$CFLAGS -pedantic" ;;
 116     esac
 117   fi
 118 fi
 119 changequote([,])dnl
 120
 121 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 122 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 123 glib_save_LIBS=$LIBS
 124 LIBS="$LIBS -lm"
 125 AC_TRY_RUN([#include <math.h>
 126              int main (void) { return (log(1) != log(1.)); }],
 127      AC_MSG_RESULT(none needed),
 128      glib_save_CFLAGS=$CFLAGS
 129      CFLAGS="$CFLAGS -std1"
 130      AC_TRY_RUN([#include <math.h>
 131                  int main (void) { return (log(1) != log(1.)); }],
 132          AC_MSG_RESULT(-std1),
 133          AC_MSG_RESULT()
 134          CFLAGS=$glib_save_CFLAGS
 135          AC_MSG_WARN(
 136                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 137      )
 138 )
 139 LIBS=$glib_save_LIBS
 140
 141 dnl NeXTStep cc seems to need this
 142 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 143 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 144   AC_MSG_RESULT(none needed),
 145   glib_save_CFLAGS=$CFLAGS
 146   CFLAGS="$CFLAGS -posix"
 147   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 148     AC_MSG_RESULT(-posix),
 149     AC_MSG_RESULT()
 150     CFLAGS=$glib_save_CFLAGS
 151     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 152
 153 # Checks for header files.
 154 AC_HEADER_STDC
 155
 156 # Checks for library functions.
 157 AC_FUNC_VPRINTF
 158
 159 AC_CHECK_FUNCS(atexit on_exit)
 160
 161 AC_CHECK_SIZEOF(char)
 162 AC_CHECK_SIZEOF(short)
 163 AC_CHECK_SIZEOF(long)
 164 AC_CHECK_SIZEOF(int)
 165 AC_CHECK_SIZEOF(void *)
 166 AC_CHECK_SIZEOF(long long)
 167
 168 dnl long doubles were not used, and a portability problem
 169 dnl AC_C_LONG_DOUBLE
 170 AC_C_CONST
 171
 172 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 173 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 174 dnl actually supported.
 175 AC_MSG_CHECKING(for __inline)
 176 AC_CACHE_VAL(glib_cv_has__inline,[
 177         AC_TRY_RUN([
 178         __inline int foo () { return 0; }
 179         int main () { return foo (); }
 180         ],
 181         glib_cv_has__inline=yes
 182         ,
 183         glib_cv_has__inline=no
 184         ,)
 185 ])
 186 AC_MSG_RESULT($glib_cv_has__inline)
 187 case x$glib_cv_has__inline in
 188 xyes) AC_DEFINE(G_HAVE___INLINE)
 189 esac
 190 AC_MSG_CHECKING(for __inline__)
 191 AC_CACHE_VAL(glib_cv_has__inline__,[
 192         AC_TRY_RUN([
 193         __inline__ int foo () { return 0; }
 194         int main () { return foo (); }
 195         ],
 196         glib_cv_has__inline__=yes
 197         ,
 198         glib_cv_has__inline__=no
 199         ,)
 200 ])
 201 AC_MSG_RESULT($glib_cv_has__inline__)
 202 case x$glib_cv_has__inline__ in
 203 xyes) AC_DEFINE(G_HAVE___INLINE__)
 204 esac
 205 AC_MSG_CHECKING(for inline)
 206 AC_CACHE_VAL(glib_cv_hasinline,[
 207         AC_TRY_RUN([
 208         inline int foo () { return 0; }
 209         int main () { return foo (); }
 210         ],
 211         glib_cv_hasinline=yes
 212         ,
 213         glib_cv_hasinline=no
 214         ,)
 215 ])
 216 AC_MSG_RESULT($glib_cv_hasinline)
 217 case x$glib_cv_hasinline in
 218 xyes) AC_DEFINE(G_HAVE_INLINE)
 219 esac
 220
 221 dnl for bytesex stuff
 222 AC_C_BIGENDIAN
 223
 224 dnl header file checks
 225 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 226 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 227 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 228 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 229 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 230 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 231 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 232 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 233 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 234 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 235
 236 # Check for some functions
 237 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 238
 239 # Check for sys_errlist
 240 AC_MSG_CHECKING(for sys_errlist)
 241 AC_TRY_LINK(, [
 242 extern char *sys_errlist[];
 243 extern int sys_nerr;
 244 sys_errlist[sys_nerr-1][0] = 0;
 245 ], glib_ok=yes, glib_ok=no)
 246 AC_MSG_RESULT($glib_ok)
 247 if test $glib_ok = no; then
 248     AC_DEFINE(NO_SYS_ERRLIST)
 249 fi
 250
 251 # Check for sys_siglist
 252 AC_MSG_CHECKING(for sys_siglist)
 253 AC_TRY_LINK(, [
 254 extern char *sys_siglist[];
 255 sys_siglist[1][0] = 0;
 256 ], glib_ok=yes, glib_ok=no)
 257 AC_MSG_RESULT($glib_ok)
 258 if test $glib_ok = no; then
 259     AC_DEFINE(NO_SYS_SIGLIST)
 260 fi
 261
 262 # Check if <sys/select.h> needs to be included for fd_set
 263 AC_MSG_CHECKING([for fd_set])
 264 AC_TRY_COMPILE([#include <sys/types.h>],
 265         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 266 if test $gtk_ok = yes; then
 267     AC_MSG_RESULT([yes, found in sys/types.h])
 268 else
 269     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 270     if test $gtk_ok = yes; then
 271         AC_DEFINE(HAVE_SYS_SELECT_H)
 272         AC_MSG_RESULT([yes, found in sys/select.h])
 273     else
 274         AC_DEFINE(NO_FD_SET)
 275         AC_MSG_RESULT(no)
 276     fi
 277 fi
 278
 279 # These are used only in GDK (gdki18n.h)
 280 # This stuff is here only so that we can define these
 281 # things in glibconfig.h. If gtk+ started using an installed
 282 # gdkconfig.h file, then the definitions would belong there.
 283
 284 # Check for wchar.h
 285
 286 AC_MSG_CHECKING(for wchar.h)
 287 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 288 if test $glib_wchar_h = yes; then
 289    AC_DEFINE(HAVE_WCHAR_H)
 290 fi
 291 AC_MSG_RESULT($glib_wchar_h)
 292
 293 # Check for wctype.h (for iswalnum)
 294
 295 AC_MSG_CHECKING(for wctype.h)
 296 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 297 if test $glib_wctype_h = yes; then
 298    AC_DEFINE(HAVE_WCTYPE_H)
 299 fi
 300 AC_MSG_RESULT($glib_wctype_h)
 301
 302 oLIBS="$LIBS"
 303 # in Solaris 2.5, `iswalnum' is in -lw
 304 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 305
 306 # The following is necessary for Linux libc-5.4.38
 307 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 308 AC_TRY_LINK([#include <stdlib.h>],[
 309 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 310 #  ifdef HAVE_WCTYPE_H
 311 #    include <wctype.h>
 312 #  else
 313 #    ifdef HAVE_WCHAR_H
 314 #      include <wchar.h>
 315 #    endif
 316 #  endif
 317 #else
 318 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 319 #endif
 320 iswalnum((wchar_t) 0);
 321 ], glib_working_wctype=yes, glib_working_wctype=no)
 322 LIBS="$oLIBS"
 323
 324 if test $glib_working_wctype = no; then
 325    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 326 fi
 327 AC_MSG_RESULT($glib_working_wctype)
 328
 329
 330 dnl **********************
 331 dnl *** va_copy checks ***
 332 dnl **********************
 333 dnl we currently check for all three va_copy possibilities, so we get
 334 dnl all results in config.log for bug reports.
 335 AC_MSG_CHECKING(for an implementation of va_copy())
 336 AC_CACHE_VAL(glib_cv_va_copy,[
 337         AC_TRY_RUN([
 338         #include <stdarg.h>
 339         void f (int i, ...) {
 340         va_list args1, args2;
 341         va_start (args1, i);
 342         va_copy (args2, args1);
 343         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 344           exit (1);
 345         va_end (args1); va_end (args2);
 346         }
 347         int main() {
 348           f (0, 42);
 349           return 0;
 350         }],
 351         glib_cv_va_copy=yes
 352         ,
 353         glib_cv_va_copy=no
 354         ,)
 355 ])
 356 AC_MSG_RESULT($glib_cv_va_copy)
 357 AC_MSG_CHECKING(for an implementation of __va_copy())
 358 AC_CACHE_VAL(glib_cv___va_copy,[
 359         AC_TRY_RUN([
 360         #include <stdarg.h>
 361         void f (int i, ...) {
 362         va_list args1, args2;
 363         va_start (args1, i);
 364         __va_copy (args2, args1);
 365         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 366           exit (1);
 367         va_end (args1); va_end (args2);
 368         }
 369         int main() {
 370           f (0, 42);
 371           return 0;
 372         }],
 373         glib_cv___va_copy=yes
 374         ,
 375         glib_cv___va_copy=no
 376         ,)
 377 ])
 378 AC_MSG_RESULT($glib_cv___va_copy)
 379 AC_MSG_CHECKING(whether va_lists can be copied by value)
 380 AC_CACHE_VAL(glib_cv_va_val_copy,[
 381         AC_TRY_RUN([
 382         #include <stdarg.h>
 383         void f (int i, ...) {
 384         va_list args1, args2;
 385         va_start (args1, i);
 386         args2 = args1;
 387         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 388           exit (1);
 389         va_end (args1); va_end (args2);
 390         }
 391         int main() {
 392           f (0, 42);
 393           return 0;
 394         }],
 395         glib_cv_va_val_copy=yes
 396         ,
 397         glib_cv_va_val_copy=no
 398         ,)
 399 ])
 400 if test "x$glib_cv_va_copy" = "xyes"; then
 401   AC_DEFINE(G_VA_COPY, va_copy)
 402 else if test "x$glib_cv___va_copy" = "xyes"; then
 403   AC_DEFINE(G_VA_COPY, __va_copy)
 404 fi
 405 fi
 406 if test "x$glib_cv_va_val_copy" = "xno"; then
 407   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 408 fi
 409 AC_MSG_RESULT($glib_cv_va_val_copy)
 410
 411
 412 dnl ***********************
 413 dnl *** g_module checks ***
 414 dnl ***********************
 415 G_MODULE_LIBS=
 416 G_MODULE_LDFLAGS=
 417 G_MODULE_IMPL=
 418 G_MODULE_NEED_USCORE=0
 419 G_MODULE_HAVE_DLERROR=0
 420 dnl *** dlopen() in system libraries
 421 if test -z "$G_MODULE_IMPL"; then
 422         AC_CHECK_FUNC(dlopen,
 423                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 424         ,)
 425 fi
 426 dnl *** dlopen() in libdl
 427 if test -z "$G_MODULE_IMPL"; then
 428         AC_CHECK_LIB(dl, dlopen,
 429                 G_MODULE_LIBS=-ldl
 430                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 431         ,)
 432 fi
 433 dnl *** shl_load() in libdld (HP-UX)
 434 if test -z "$G_MODULE_IMPL"; then
 435         AC_MSG_CHECKING(how to export all symbols)
 436         SAVED_LDFLAGS=$LDFLAGS
 437         LDFLAGS="$LDFLAGS -Wl,-E"
 438         AC_TRY_LINK(,[ return 0; ],
 439                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 440                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 441                 AC_TRY_LINK(,[ return 0; ],
 442                         G_MODULE_LDFLAGS="-bexpall",
 443                         G_MODULE_LDFLAGS="none"
 444                 )
 445         ])
 446         LDFLAGS=$SAVED_LDFLAGS
 447         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 448         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 449                 G_MODULE_LDFLAGS=
 450         fi
 451         AC_CHECK_LIB(dld, shl_load,
 452                 G_MODULE_LIBS=-ldld
 453                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 454         ,)
 455 fi
 456 dnl *** additional checks for G_MODULE_IMPL_DL
 457 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 458         case "$host_os" in
 459           linux*)
 460             G_MODULE_LDFLAGS='-rdynamic'
 461             ;;
 462         esac
 463         LIBS_orig="$LIBS"
 464         LDFLAGS_orig="$LDFLAGS"
 465         LIBS="$LIBS $G_MODULE_LIBS"
 466         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 467 dnl *** check whether we need preceeding underscores
 468         AC_MSG_CHECKING(for preceeding underscore in symbols)
 469         AC_CACHE_VAL(glib_cv_uscore,[
 470                 AC_TRY_RUN([
 471                 #include <dlfcn.h>
 472                 int glib_underscore_test (void) { return 42; }
 473                 int main() {
 474                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 475                   handle = dlopen ((void*)0, 0);
 476                   if (handle) {
 477                     f1 = dlsym (handle, "glib_underscore_test");
 478                     f2 = dlsym (handle, "_glib_underscore_test");
 479                   } return (!f2 || f1);
 480                 }],
 481                         glib_cv_uscore=yes,
 482                         glib_cv_uscore=no,
 483                 )
 484                 rm -f plugin.c plugin.o plugin.lo
 485         ])
 486         AC_MSG_RESULT($glib_cv_uscore)
 487         if test "x$glib_cv_uscore" = "xyes"; then
 488                 G_MODULE_NEED_USCORE=1
 489         else
 490                 G_MODULE_NEED_USCORE=0
 491         fi
 492
 493         LDFLAGS="$LDFLAGS_orig"
 494 dnl *** check for having dlerror()
 495         AC_CHECK_FUNC(dlerror,
 496                 G_MODULE_HAVE_DLERROR=1,
 497                 G_MODULE_HAVE_DLERROR=0)
 498         LIBS="$LIBS_orig"
 499 fi
 500 dnl *** done, have e got an implementation?
 501 if test -z "$G_MODULE_IMPL"; then
 502         G_MODULE_IMPL=0
 503 fi
 504 AC_SUBST(G_MODULE_IMPL)
 505 AC_SUBST(G_MODULE_LIBS)
 506 AC_SUBST(G_MODULE_LDFLAGS)
 507 AC_SUBST(G_MODULE_HAVE_DLERROR)
 508 AC_SUBST(G_MODULE_NEED_USCORE)
 509 AC_SUBST(GLIB_DEBUG_FLAGS)
 510
 511 AC_OUTPUT_COMMANDS([
 512
 513 ## Generate `glibconfig.h' in two cases
 514 ## 1. `config.status' is run either explicitly, or via configure.
 515 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 516 ##     config.h
 517 ## 2. CONFIG_OTHER is set explicitly
 518 ##
 519 ## Case 1 is difficult.  We know that `automake' sets one of
 520 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 521 ## only when AM_CONFIG_HEADER is set, however.
 522
 523 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 524   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 525   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 526 fi
 527 case "$CONFIG_OTHER" in
 528 *glibconfig.h*)
 529   echo creating glibconfig.h
 530   outfile=glibconfig.h-tmp
 531   cat > $outfile <<\outfile_EOF
 532 /* glibconfig.h */
 533 /* This is a generated file.  Please modify `configure.in' */
 534
 535 #ifndef GLIBCONFIG_H
 536 #define GLIBCONFIG_H
 537
 538 #ifdef __cplusplus
 539 extern "C" {
 540 #endif /* __cplusplus */
 541
 542 outfile_EOF
 543
 544   if test x$glib_limits_h = xyes; then
 545     echo '#include <limits.h>' >> $outfile
 546   fi
 547   if test x$glib_float_h = xyes; then
 548     echo '#include <float.h>' >> $outfile
 549   fi
 550   if test x$glib_values_h = xyes; then
 551     echo '#include <values.h>' >> $outfile
 552   fi
 553   if test x$glib_sys_poll_h = xyes; then
 554     echo '#include <sys/types.h>' >> $outfile
 555     echo '#include <sys/poll.h>' >> $outfile
 556   fi
 557
 558   cat >> $outfile <<outfile_EOF
 559
 560 #define G_MINFLOAT $glib_mf
 561 #define G_MAXFLOAT $glib_Mf
 562 #define G_MINDOUBLE $glib_md
 563 #define G_MAXDOUBLE $glib_Md
 564 #define G_MINSHORT $glib_ms
 565 #define G_MAXSHORT $glib_Ms
 566 #define G_MININT $glib_mi
 567 #define G_MAXINT $glib_Mi
 568 #define G_MINLONG $glib_ml
 569 #define G_MAXLONG $glib_Ml
 570
 571 outfile_EOF
 572
 573   ## this should always be true in a modern C/C++ compiler
 574   cat >>$outfile <<outfile_EOF
 575 typedef signed char gint8;
 576 typedef unsigned char guint8;
 577 outfile_EOF
 578
 579   if test -n "$gint16"; then
 580     cat >>$outfile <<outfile_EOF
 581 typedef signed $gint16 gint16;
 582 typedef unsigned $gint16 guint16;
 583 outfile_EOF
 584   fi
 585   if test -n "$gint32"; then
 586     cat >>$outfile <<outfile_EOF
 587 typedef signed $gint32 gint32;
 588 typedef unsigned $gint32 guint32;
 589 outfile_EOF
 590   fi
 591   if test -n "$gint64"; then
 592     cat >>$outfile <<outfile_EOF
 593 ${glib_warning_guard}#define G_HAVE_GINT64 1
 594
 595 ${glib_extension}typedef signed $gint64 gint64;
 596 ${glib_extension}typedef unsigned $gint64 guint64;
 597
 598 #define G_GINT64_CONSTANT(val)  $gint64_constant
 599 outfile_EOF
 600   fi
 601
 602   if test -z "$glib_unknown_void_p"; then
 603     cat >>$outfile <<outfile_EOF
 604
 605 #define GPOINTER_TO_INT(p)      ((gint)${glib_gpi_cast}(p))
 606 #define GPOINTER_TO_UINT(p)     ((guint)${glib_gpui_cast}(p))
 607
 608 #define GINT_TO_POINTER(i)      ((gpointer)${glib_gpi_cast}(i))
 609 #define GUINT_TO_POINTER(u)     ((gpointer)${glib_gpui_cast}(u))
 610 outfile_EOF
 611   else
 612     echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 613   fi
 614
 615   cat >>$outfile <<outfile_EOF
 616 $glib_atexit
 617 $glib_memmove
 618 $glib_defines
 619
 620 $glib_vacopy
 621
 622 #ifdef  __cplusplus
 623 #define G_HAVE_INLINE   1
 624 #else   /* !__cplusplus */
 625 $glib_inline
 626 #endif  /* !__cplusplus */
 627
 628 #define G_BYTE_ORDER $g_byte_order
 629 outfile_EOF
 630
 631   g_bit_sizes="16 32"
 632   if test -n "$gint64"; then
 633     g_bit_sizes="$g_bit_sizes 64"
 634   fi
 635
 636   for bits in $g_bit_sizes; do
 637     cat >>$outfile <<outfile_EOF
 638
 639 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 640 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 641 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 642 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 643 outfile_EOF
 644 done
 645
 646   cat >>$outfile <<outfile_EOF
 647
 648 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 649 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 650 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 651 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 652
 653 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 654 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 655 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 656 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 657 $glib_wc
 658
 659 #ifdef __cplusplus
 660 }
 661 #endif /* __cplusplus */
 662
 663 #endif /* GLIBCONFIG_H */
 664
 665 outfile_EOF
 666
 667   if cmp -s $outfile glibconfig.h; then
 668     echo glibconfig.h is unchanged
 669     rm -f $outfile
 670   else
 671     mv $outfile glibconfig.h
 672   fi ;;
 673 esac
 674 ],[
 675
 676 # Note that if two cases are the same, case goes with the first one.
 677 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
 678 # on variable expansion in case labels.  Look at the generated config.status
 679 # for a hint.
 680
 681 case xyes in
 682 x$ac_cv_header_float_h)
 683   glib_float_h=yes
 684   glib_mf=FLT_MIN glib_Mf=FLT_MAX
 685   glib_md=DBL_MIN glib_Md=DBL_MAX
 686   ;;
 687 x$ac_cv_header_values_h)
 688   glib_values_h=yes
 689   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
 690   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
 691   ;;
 692 esac
 693
 694 case xyes in
 695 x$ac_cv_header_limits_h)
 696   glib_limits_h=yes
 697   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
 698   glib_mi=INT_MIN  glib_Mi=INT_MAX
 699   glib_ml=LONG_MIN glib_Ml=LONG_MAX
 700   ;;
 701 x$ac_cv_header_values_h)
 702   glib_values_h=yes
 703   glib_ms=MINSHORT glib_Ms=MAXSHORT
 704   glib_mi=MININT   glib_Mi=MAXINT
 705   glib_ml=MINLONG  glib_Ml=MAXLONG
 706   ;;
 707 esac
 708
 709 if test x$ac_cv_header_sys_poll_h = xyes ; then
 710   glib_sys_poll_h=yes
 711 fi
 712
 713 case 2 in
 714 $ac_cv_sizeof_short)            gint16=short;;
 715 $ac_cv_sizeof_int)              gint16=int;;
 716 esac
 717 case 4 in
 718 $ac_cv_sizeof_short)            gint32=short;;
 719 $ac_cv_sizeof_int)              gint32=int;;
 720 $ac_cv_sizeof_long)             gint32=long;;
 721 esac
 722 case 8 in
 723 $ac_cv_sizeof_int)
 724   gint64=int
 725   glib_extension=
 726   glib_warning_guard=
 727   gint64_constant='(val)'
 728   ;;
 729 $ac_cv_sizeof_long)
 730   gint64=long
 731   glib_extension=
 732   glib_warning_guard=
 733   gint64_constant='(val##L)'
 734   ;;
 735 $ac_cv_sizeof_long_long)
 736   gint64='long long'
 737   glib_extension='GLIB_WARNINGS_MAKE_PEOPLE_CRY '
 738   glib_warning_guard="
 739 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
 740 #  define GLIB_WARNINGS_MAKE_PEOPLE_CRY __extension__
 741 #else
 742 #  define GLIB_WARNINGS_MAKE_PEOPLE_CRY
 743 #endif
 744
 745 "
 746   gint64_constant='(GLIB_WARNINGS_MAKE_PEOPLE_CRY (val##LL))'
 747   ;;
 748 esac
 749
 750 gintbits=`expr $ac_cv_sizeof_int \* 8`
 751 glongbits=`expr $ac_cv_sizeof_long \* 8`
 752
 753
 754 case $ac_cv_sizeof_void_p in
 755 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
 756 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
 757 *)                      glib_unknown_void_p=yes ;;
 758 esac
 759
 760
 761 case xyes in
 762 x$ac_cv_func_atexit)
 763   glib_atexit="
 764 #ifdef NeXT /* @#%@! NeXTStep */
 765 # define g_ATEXIT(proc) (!atexit (proc))
 766 #else
 767 # define g_ATEXIT(proc) (atexit (proc))
 768 #endif"
 769   ;;
 770 x$ac_cv_func_on_exit)
 771   glib_atexit="
 772 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
 773   ;;
 774 esac
 775
 776 case xyes in
 777 x$ac_cv_func_memmove)
 778   glib_memmove='
 779 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
 780   ;;
 781 *)
 782   glib_memmove="
 783 /* We make the assumption that if memmove isn't available, then
 784  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
 785  * necessarily handle overlapping copies) */
 786 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
 787   ;;
 788 esac
 789
 790 glib_defines="
 791 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
 792 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
 793 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
 794 "
 795
 796 case xyes in
 797 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
 798 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
 799 *)                      glib_vacopy=''
 800 esac
 801
 802 if test x$glib_cv_va_val_copy = xno; then
 803   glib_vacopy="\$glib_vacopy
 804 #define G_VA_COPY_AS_ARRAY 1"
 805 fi
 806
 807 if test x$glib_cv_hasinline = xyes; then
 808     glib_inline='#define G_HAVE_INLINE 1'
 809 fi
 810 if test x$glib_cv_has__inline = xyes; then
 811     glib_inline="\$glib_inline
 812 #define G_HAVE___INLINE 1"
 813 fi
 814 if test x$glib_cv_has__inline__ = xyes; then
 815     glib_inline="\$glib_inline
 816 #define G_HAVE___INLINE__ 1"
 817 fi
 818
 819 case xyes in
 820 x$ac_cv_c_bigendian)
 821   g_byte_order=G_BIG_ENDIAN
 822   g_bs_native=BE
 823   g_bs_alien=LE
 824   ;;
 825 *)
 826   g_byte_order=G_LITTLE_ENDIAN
 827   g_bs_native=LE
 828   g_bs_alien=BE
 829   ;;
 830 esac
 831
 832 if test x$glib_wchar_h = xyes; then
 833   glib_wc='
 834 #define G_HAVE_WCHAR_H 1'
 835 fi
 836 if test x$glib_wctype_h = xyes; then
 837   glib_wc="\$glib_wc
 838 #define G_HAVE_WCTYPE_H 1"
 839 fi
 840 if test x$glib_working_wctype = xno; then
 841   glib_wc="\$glib_wc
 842 #define G_HAVE_BROKEN_WCTYPE 1"
 843 fi
 844 ])
 845
 846 AC_OUTPUT([
 847 Makefile
 848 glib-config
 849 gmodule/gmoduleconf.h
 850 gmodule/Makefile
 851 docs/Makefile
 852 ],[case "$CONFIG_FILES" in
 853 *glib-config*)chmod +x glib-config;;
 854 esac])