configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memprofstat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 else
 182   if test "$minimum_kernel" = current; then
 183     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 184   fi
 185 fi
 186
 187 AC_CANONICAL_HOST
 188
 189 # The way shlib-versions is used to generate soversions.mk uses a
 190 # fairly simplistic model for name recognition that can't distinguish
 191 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 192 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 193 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 194 case "$host_os" in
 195 linux*)
 196   ;;
 197 gnu*)
 198   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 199   ;;
 200 esac
 201
 202 # We keep the original values in `$config_*' and never modify them, so we
 203 # can write them unchanged into config.make.  Everything else uses
 204 # $machine, $vendor, and $os, and changes them whenever convenient.
 205 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 206
 207 # Some configurations imply other options.
 208 case "$host_os" in
 209 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 210   # These systems always use GNU tools.
 211   gnu_ld=yes gnu_as=yes ;;
 212 esac
 213 case "$host_os" in
 214 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 215 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 216   ;;
 217 gnu* | linux* | sysv4* | solaris2* | irix6*)
 218   # These systems (almost) always use the ELF format.
 219   elf=yes
 220   ;;
 221 esac
 222
 223 machine=$config_machine
 224 vendor=$config_vendor
 225 os=$config_os
 226
 227 ###
 228 ### I put this here to prevent those annoying emails from people who cannot
 229 ### read and try to compile glibc on unsupported platforms.  --drepper
 230 ###
 231 ### By using the undocumented --enable-hacker-mode option for configure
 232 ### one can skip this test to make the configuration not fail for unsupported
 233 ### platforms.
 234 ###
 235 if test -z "$enable_hacker_mode"; then
 236   case "$machine-$host_os" in
 237   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 238     ;;
 239   *)
 240     echo "*** The GNU C library is currently not available for this platform."
 241     echo "*** So far nobody cared to port it and if there is no volunteer it"
 242     echo "*** might never happen.  So, if you have interest to see glibc on"
 243     echo "*** this platform visit"
 244     echo "***   http://www.gnu.org/software/libc/porting.html"
 245     echo "*** and join the group of porters"
 246     exit 1
 247     ;;
 248   esac
 249 fi
 250
 251 dnl We need to use [ and ] for other purposes for a while now.
 252 changequote(,)dnl
 253 # Expand the configuration machine name into a subdirectory by architecture
 254 # type and particular chip.
 255 case "$machine" in
 256 a29k | am29000) base_machine=a29k machine=a29k ;;
 257 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 258 arm*)           base_machine=arm machine=arm/$machine ;;
 259 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 260 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 261 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 262 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 263 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 264 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 265 m88???)         base_machine=m88k machine=m88k/$machine ;;
 266 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 267 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 268 mips*)          base_machine=mips
 269                 case "`uname -m`" in
 270                 IP22) machine=mips/mips3 ;;
 271                 *)    machine=mips/$machine ;;
 272                 esac ;;
 273 sparc | sparcv[67])
 274                 base_machine=sparc machine=sparc/sparc32 ;;
 275 sparcv8 | supersparc | hypersparc)
 276                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 277 sparcv8plus | sparcv8plusa | sparcv9)
 278                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 279 sparc64 | ultrasparc)
 280                 base_machine=sparc machine=sparc/sparc64 ;;
 281 esac
 282 changequote([,])dnl
 283 AC_SUBST(base_machine)
 284
 285 if test "$base_machine" = "i386"; then
 286   AC_DEFINE(USE_REGPARMS)
 287 fi
 288
 289 # Compute the list of sysdep directories for this configuration.
 290 # This can take a while to compute.
 291 sysdep_dir=$srcdir/sysdeps
 292 AC_MSG_CHECKING(sysdep dirs)
 293 dnl We need to use [ and ] for other purposes for a while now.
 294 changequote(,)dnl
 295 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 296 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 297
 298 case "$os" in
 299 gnu*)
 300   base_os=mach/hurd ;;
 301 netbsd* | 386bsd* | freebsd* | bsdi*)
 302   base_os=unix/bsd/bsd4.4 ;;
 303 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 304   base_os=unix/bsd ;;
 305 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 306   base_os=unix/sysv ;;
 307 irix6*)
 308   base_os=unix/sysv/irix6/$os ;;
 309 solaris[2-9]*)
 310   base_os=unix/sysv/sysv4 ;;
 311 hpux*)
 312   base_os=unix/sysv/hpux/$os ;;
 313 aix4.3*)
 314   base_os=unix/sysv/aix/aix4.3 ;;
 315 none)
 316   base_os=standalone ;;
 317 *)
 318   base_os='' ;;
 319 esac
 320
 321 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 322 tail=$os
 323 ostry=$os
 324 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 325   ostry="$ostry /$o"
 326   tail=$o
 327 done
 328 o=`echo $tail | sed 's/[0-9]*$//'`
 329 if test $o != $tail; then
 330   ostry="$ostry /$o"
 331 fi
 332 # For linux-gnu, try linux-gnu, then linux.
 333 o=`echo $tail | sed 's/-.*$//'`
 334 if test $o != $tail; then
 335   ostry="$ostry /$o"
 336 fi
 337
 338 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 339 base=
 340 tail=$base_os
 341 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 342   set $b
 343   base="$base /$1"
 344   tail="$2"
 345 done
 346
 347 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 348 mach=
 349 tail=$machine
 350 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 351   set $m
 352   # Prepend the machine's FPU directory unless --without-fp.
 353   if test "$with_fp" = yes; then
 354     mach="$mach /$1/fpu"
 355   fi
 356   mach="$mach /$1"
 357   tail="$2"
 358 done
 359
 360 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 361 changequote([,])dnl
 362
 363 # Find what sysdep directories exist.
 364 sysnames=
 365 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 366 for d in $add_ons_pfx ''; do
 367   for b in $base ''; do
 368     for m0 in $mach ''; do
 369       for v in /$vendor ''; do
 370         test "$v" = / && continue
 371         for o in /$ostry ''; do
 372           test "$o" = / && continue
 373           for m in $mach ''; do
 374             if test "$m0$b$v$o$m"; then
 375               try="${d}sysdeps$m0$b$v$o$m"
 376               test -n "$enable_debug_configure" &&
 377               echo "$0 [DEBUG]: try $try" >&2
 378               if test -d $srcdir/$try; then
 379                 sysnames="$sysnames $try"
 380                 { test -n "$o" || test -n "$b"; } && os_used=t
 381                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 382               fi
 383             fi
 384           done
 385         done
 386       done
 387     done
 388   done
 389 done
 390 IFS="$ac_save_ifs"
 391
 392 if test -z "$os_used" && test "$os" != none; then
 393   AC_MSG_ERROR(Operating system $os is not supported.)
 394 fi
 395 if test -z "$machine_used" && test "$machine" != none; then
 396   AC_MSG_ERROR(The $machine is not supported.)
 397 fi
 398
 399 # We have now validated the configuration.
 400
 401
 402 # If using ELF, look for an `elf' subdirectory of each machine directory.
 403 # We prepend these rather than inserting them whereever the machine appears
 404 # because things specified by the machine's ELF ABI should override
 405 # OS-specific things, and should always be the same for any OS on the
 406 # machine (otherwise what's the point of an ABI?).
 407 if test "$elf" = yes; then
 408   elf_dirs=
 409   for d in $add_ons_pfx ''; do
 410     for m in $mach; do
 411       if test -d $srcdir/${d}sysdeps$m/elf; then
 412         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 413       fi
 414     done
 415   done
 416   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 417 fi
 418
 419
 420 # Expand the list of system names into a full list of directories
 421 # from each element's parent name and Implies file (if present).
 422 set $sysnames
 423 names=
 424 while test $# -gt 0; do
 425   name=$1
 426   shift
 427
 428   case " $names " in *" $name "*)
 429     # Already in the list.
 430     continue
 431   esac
 432
 433   # Report each name as we discover it, so there is no long pause in output.
 434   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 435
 436   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 437
 438   case $name in
 439     /*) xsrcdir= ;;
 440     *)  xsrcdir=$srcdir/ ;;
 441   esac
 442   test -n "$enable_debug_configure" &&
 443   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 444
 445   if test -f $xsrcdir$name/Implies; then
 446     # Collect more names from the `Implies' file (removing comments).
 447     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 448     implied=
 449     for x in $implied_candidate; do
 450       if test -d $xsrcdir$name_base/$x; then
 451         implied="$implied $name_base/$x";
 452       else
 453         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 454       fi
 455     done
 456   else
 457     implied=
 458   fi
 459
 460   # Add NAME to the list of names.
 461   names="$names $name"
 462
 463   # Find the parent of NAME, using the empty string if it has none.
 464 changequote(,)dnl
 465   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 466 changequote([,])dnl
 467
 468   # Add the names implied by NAME, and NAME's parent (if it has one), to
 469   # the list of names to be processed (the argument list).  We prepend the
 470   # implied names to the list and append the parent.  We want implied
 471   # directories to come before further directories inferred from the
 472   # configuration components; this ensures that for sysv4, unix/common
 473   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 474   # after sysv4).
 475   sysnames="`echo $implied $* $parent`"
 476   test -n "$sysnames" && set $sysnames
 477 done
 478
 479 # Add the default directories.
 480 default_sysnames=sysdeps/generic
 481 if test "$elf" = yes; then
 482   default_sysnames="sysdeps/generic/elf $default_sysnames"
 483 fi
 484 sysnames="$names $default_sysnames"
 485 AC_SUBST(sysnames)
 486 # The other names were emitted during the scan.
 487 AC_MSG_RESULT($default_sysnames)
 488
 489
 490 ### Locate tools.
 491
 492 AC_PROG_INSTALL
 493 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 494   # The makefiles need to use a different form to find it in $srcdir.
 495   INSTALL='\$(..)./scripts/install-sh -c'
 496 fi
 497 AC_PROG_LN_S
 498
 499 # These programs are version sensitive.
 500 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 501 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 502   [version \([egcygnustp-]*[0-9.]*\)],
 503   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
 504   critic_missing=t)
 505 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 506   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 507   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 508
 509 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 510   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 511   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 512 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 513   [GNU texinfo.* \([0-9][0-9.]*\)],
 514   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 515 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 516   [GNU sed version \([0-9]*\.[0-9.]*\)],
 517   [3.0[2-9]|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 518
 519 if test -n "$critic_missing"; then
 520 AC_MSG_ERROR([
 521 *** Some critical program is missing or too old.
 522 *** Check the INSTALL file for required versions.])
 523 fi
 524
 525 test -n "$aux_missing" && AC_MSG_WARN([
 526 *** An auxiliary program is missing or too old;
 527 *** some features will be disabled.
 528 *** Check the INSTALL file for required versions.])
 529
 530 # glibcbug.in wants to know the compiler version.
 531 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 532 AC_SUBST(CCVERSION)
 533
 534 AC_PROG_CC_LOCAL
 535 AC_CANONICAL_BUILD
 536 if test $host != $build; then
 537   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 538 fi
 539 AC_SUBST(cross_compiling)
 540 AC_PROG_CPP
 541 LIBC_PROG_BINUTILS
 542 AC_CHECK_TOOL(MIG, mig)
 543
 544 # if using special system headers, find out the compiler's sekrit
 545 # header directory and add that to the list.  NOTE: Only does the right
 546 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 547 if test -n "$sysheaders"; then
 548   ccheaders=`$CC -print-file-name=include`
 549   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 550 fi
 551 AC_SUBST(SYSINCLUDES)
 552
 553 # check if ranlib is necessary
 554 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 555 cat > conftest.c <<EOF
 556 int a;
 557 char b;
 558 void c(void) {}
 559 EOF
 560 $CC $CFLAGS -c conftest.c
 561 $AR cr conftest.a conftest.c
 562 cp conftest.a conftest2.a
 563 $RANLIB conftest.a
 564 if cmp -s conftest.a conftest2.a; then
 565   libc_cv_ranlib_necessary=no
 566 else
 567   libc_cv_ranlib_necessary=yes
 568 fi
 569 rm -rf conftest*])
 570 if test "$libc_cv_ranlib_necessary" = no; then
 571  RANLIB=:
 572 fi
 573
 574 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 575 # since this would lead to problems installing/building glibc.
 576 # LD_LIBRARY_PATH contains the current directory if one of the following
 577 # is true:
 578 # - one of the terminals (":" and ";") is the first or last sign
 579 # - two terminals occur directly after each other
 580 # - the path contains an element with a dot in it
 581 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 582 changequote(,)dnl
 583 case ${LD_LIBRARY_PATH} in
 584   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 585     ld_library_path_setting="contains current directory"
 586     ;;
 587   *)
 588     ld_library_path_setting="ok"
 589     ;;
 590 esac
 591 changequote([,])dnl
 592 AC_MSG_RESULT($ld_library_path_setting)
 593 if test "$ld_library_path_setting" != "ok"; then
 594 AC_MSG_ERROR([
 595 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 596 *** building glibc. Please change the environment variable
 597 *** and run configure again.])
 598 fi
 599
 600 AC_PATH_PROG(BASH, bash, no)
 601 if test "$BASH" != no &&
 602    $BASH -c 'test "$BASH_VERSINFO" \
 603              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 604   libc_cv_have_bash2=yes
 605 else
 606   libc_cv_have_bash2=no
 607 fi
 608 AC_SUBST(libc_cv_have_bash2)
 609
 610 dnl We need a ksh compatible shell for tzselect.
 611 if test "$BASH" = no; then
 612   AC_PATH_PROG(KSH, ksh, no)
 613   if test "$KSH" = no; then
 614     libc_cv_have_ksh=no
 615   else
 616     libc_cv_have_ksh=yes
 617   fi
 618 else
 619   KSH="$BASH"
 620   AC_SUBST(KSH)
 621   libc_cv_have_ksh=yes
 622 fi
 623 AC_SUBST(libc_cv_have_ksh)
 624
 625 AC_PROG_AWK
 626 AC_PATH_PROG(PERL, perl, no)
 627 AC_SUBST(PERL)
 628 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 629              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 630 AC_SUBST(INSTALL_INFO)
 631 if test "$INSTALL_INFO" != "no"; then
 632 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 633  [mkdir conftest.d
 634   # There is a hard ^_ on the next line.  I am open to better ideas.
 635   (echo '\1f'
 636   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 637   echo '* Menu:') >conftest.d/dir
 638   (echo 'INFO-DIR-SECTION i-d-s works'
 639   echo 'START-INFO-DIR-ENTRY'
 640   echo '* Prog: (prog).   Program.'
 641   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 642   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 643   then
 644     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 645     then libc_cv_old_debian_install_info=no
 646     else libc_cv_old_debian_install_info=yes
 647     fi
 648   else libc_cv_old_debian_install_info=no testfailed=t
 649   fi
 650   rm -fr conftest.d])
 651 if test -n "$testfailed"
 652 then AC_MSG_WARN([install-info errored out, check config.log])
 653 fi
 654 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 655 fi
 656 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 657
 658 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 659 echo '#include <stddef.h>
 660 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 661 if eval "$ac_cpp conftest.c 2>/dev/null" \
 662 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 663   libc_cv_signed_size_t=no
 664 else
 665   libc_cv_signed_size_t=yes
 666 fi
 667 rm -f conftest*])
 668 if test $libc_cv_signed_size_t = yes; then
 669   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 670   cat >> confdefs.h <<\EOF
 671 #undef __SIZE_TYPE__
 672 #define __SIZE_TYPE__ unsigned
 673 EOF
 674 fi
 675
 676 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 677 AC_TRY_COMPILE(dnl
 678 [#define __need_size_t
 679 #define __need_wchar_t
 680 #include <stddef.h>
 681 #define __need_NULL
 682 #include <stddef.h>], [size_t size; wchar_t wchar;
 683 #ifdef offsetof
 684 #error stddef.h ignored __need_*
 685 #endif
 686 if (&size == NULL || &wchar == NULL) abort ();],
 687                libc_cv_friendly_stddef=yes,
 688                libc_cv_friendly_stddef=no)])
 689 if test $libc_cv_friendly_stddef = yes; then
 690   config_vars="$config_vars
 691 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 692 fi
 693
 694 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 695                libc_cv_need_minus_P, [dnl
 696 cat > conftest.S <<EOF
 697 #include "confdefs.h"
 698 /* Nothing whatsoever.  */
 699 EOF
 700 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 701   libc_cv_need_minus_P=no
 702 else
 703   libc_cv_need_minus_P=yes
 704 fi
 705 rm -f conftest*])
 706 if test $libc_cv_need_minus_P = yes; then
 707   config_vars="$config_vars
 708 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 709 fi
 710
 711 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 712 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 713 cat > conftest.s <<EOF
 714 .text
 715 EOF
 716 libc_cv_dot_text=
 717 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 718   libc_cv_dot_text=.text
 719 fi
 720 rm -f conftest*])
 721 if test -z "$libc_cv_dot_text"; then
 722   AC_MSG_RESULT(no)
 723 else
 724   AC_MSG_RESULT(yes)
 725 fi
 726
 727 AC_CACHE_CHECK(for assembler global-symbol directive,
 728                libc_cv_asm_global_directive, [dnl
 729 libc_cv_asm_global_directive=UNKNOWN
 730 for ac_globl in .globl .global .EXPORT; do
 731   cat > conftest.s <<EOF
 732         ${libc_cv_dot_text}
 733         ${ac_globl} foo
 734 foo:
 735 EOF
 736   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 737     libc_cv_asm_global_directive=${ac_globl}
 738   fi
 739   rm -f conftest*
 740   test $libc_cv_asm_global_directive != UNKNOWN && break
 741 done])
 742 if test $libc_cv_asm_global_directive = UNKNOWN; then
 743   AC_MSG_ERROR(cannot determine asm global directive)
 744 else
 745   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 746 fi
 747
 748 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 749 cat > conftest.s <<EOF
 750 ${libc_cv_dot_text}
 751 foo:
 752 .set glibc_conftest_frobozz,foo
 753 $libc_cv_asm_global_directive glibc_conftest_frobozz
 754 EOF
 755 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 756 # (but it doesn't work), so we must do a linking check to be sure.
 757 cat > conftest1.c <<\EOF
 758 extern int glibc_conftest_frobozz;
 759 main () { printf ("%d\n", glibc_conftest_frobozz); }
 760 EOF
 761 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 762             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 763   libc_cv_asm_set_directive=yes
 764 else
 765   libc_cv_asm_set_directive=no
 766 fi
 767 rm -f conftest*])
 768 if test $libc_cv_asm_set_directive = yes; then
 769   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 770 fi
 771
 772 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 773 [cat > conftest.s <<EOF
 774 ${libc_cv_dot_text}
 775 _sym:
 776 .symver _sym,sym@VERS
 777 EOF
 778 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 779   libc_cv_asm_symver_directive=yes
 780 else
 781   libc_cv_asm_symver_directive=no
 782 fi
 783 rm -f conftest*])
 784 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 785 if test $libc_cv_asm_symver_directive = yes; then
 786   cat > conftest.s <<EOF
 787 ${libc_cv_dot_text}
 788 _sym:
 789 .symver _sym,sym@VERS
 790 EOF
 791   cat > conftest.map <<EOF
 792 VERS_1 {
 793         global: sym;
 794 };
 795
 796 VERS_2 {
 797         global: sym;
 798 } VERS_1;
 799 EOF
 800   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 801     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 802                                         -nostartfiles -nostdlib
 803                                         -Wl,--version-script,conftest.map
 804                        1>&AC_FD_CC]);
 805     then
 806       libc_cv_ld_version_script_option=yes
 807     else
 808       libc_cv_ld_version_script_option=no
 809     fi
 810   else
 811     libc_cv_ld_version_script_option=no
 812   fi
 813 else
 814   libc_cv_ld_version_script_option=no
 815 fi
 816 rm -f conftest*])
 817 if test $libc_cv_asm_symver_directive = yes &&
 818    test $libc_cv_ld_version_script_option = yes &&
 819    test $enable_versioning = yes; then
 820   VERSIONING=yes
 821   AC_DEFINE(DO_VERSIONING)
 822 else
 823   VERSIONING=no
 824 fi
 825 AC_SUBST(VERSIONING)
 826
 827 if test $VERSIONING = no; then
 828   echo "\
 829 *** WARNING: You should not compile GNU libc without versioning. Not using
 830 *** versioning will introduce incompatibilities so that old binaries
 831 *** will not run anymore.
 832 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 833 fi
 834 if test $elf = yes; then
 835   AC_CACHE_CHECK(for .previous assembler directive,
 836                  libc_cv_asm_previous_directive, [dnl
 837   cat > conftest.s <<EOF
 838 .section foo_section
 839 .previous
 840 EOF
 841   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 842     libc_cv_asm_previous_directive=yes
 843   else
 844     libc_cv_asm_previous_directive=no
 845   fi
 846   rm -f conftest*])
 847   if test $libc_cv_asm_previous_directive = yes; then
 848     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 849   else
 850     AC_CACHE_CHECK(for .popsection assembler directive,
 851                    libc_cv_asm_popsection_directive, [dnl
 852     cat > conftest.s <<EOF
 853 .pushsection foo_section
 854 .popsection
 855 EOF
 856     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 857       libc_cv_asm_popsection_directive=yes
 858     else
 859       libc_cv_asm_popsection_directive=no
 860     fi
 861     rm -f conftest*])
 862     if test $libc_cv_asm_popsection_directive = yes; then
 863       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 864     fi
 865   fi
 866 fi
 867
 868 if test $elf != yes; then
 869   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 870                  [AC_TRY_COMPILE(, [asm (".section .init");
 871                                     asm (".section .fini");
 872                                     asm ("${libc_cv_dot_text}");],
 873                                  libc_cv_have_initfini=yes,
 874                                  libc_cv_have_initfini=no)])
 875   AC_SUBST(libc_cv_have_initfini)dnl
 876   if test $libc_cv_have_initfini = yes; then
 877     AC_DEFINE(HAVE_INITFINI)
 878   fi
 879 fi
 880
 881 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 882 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 883 [cat > conftest.$ac_ext <<EOF
 884 dnl This sometimes fails to find confdefs.h, for some reason.
 885 dnl [#]line __oline__ "[$]0"
 886 [#]line __oline__ "configure"
 887 #include "confdefs.h"
 888 void underscore_test(void) {
 889 return; }
 890 EOF
 891 if AC_TRY_EVAL(ac_compile); then
 892   if grep _underscore_test conftest* >/dev/null; then
 893     ifelse([$1], , :, [rm -f conftest*
 894     $1])
 895   else
 896     ifelse([$2], , , [rm -f conftest*
 897     $2])
 898   fi
 899 else
 900   echo "configure: failed program was:" >&AC_FD_CC
 901   cat conftest.$ac_ext >&AC_FD_CC
 902   ifelse([$2], , , [rm -f conftest*
 903   $2])
 904 fi
 905 rm -f conftest*])
 906
 907 if test $elf = yes; then
 908   libc_cv_asm_underscores=no
 909 else
 910   if test $ac_cv_prog_cc_works = yes; then
 911     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 912                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 913                                 libc_cv_asm_underscores=yes,
 914                                 libc_cv_asm_underscores=no)])
 915   else
 916     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 917                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 918                                             libc_cv_asm_underscores=no)])
 919   fi
 920 fi
 921 if test $libc_cv_asm_underscores = no; then
 922   AC_DEFINE(NO_UNDERSCORES)
 923 fi
 924
 925 if test $elf = yes; then
 926   libc_cv_weak_symbols=yes
 927 fi
 928
 929 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 930                [dnl
 931 cat > conftest.s <<EOF
 932 ${libc_cv_dot_text}
 933 ${libc_cv_asm_global_directive} foo
 934 foo:
 935 .weak foo
 936 .weak bar; bar = foo
 937 EOF
 938 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 939   libc_cv_asm_weak_directive=yes
 940 else
 941   libc_cv_asm_weak_directive=no
 942 fi
 943 rm -f conftest*])
 944
 945 if test $libc_cv_asm_weak_directive = no; then
 946   AC_CACHE_CHECK(for assembler .weakext directive,
 947                  libc_cv_asm_weakext_directive,
 948                  [dnl
 949 cat > conftest.s <<EOF
 950 ${libc_cv_dot_text}
 951 ${libc_cv_asm_global_directive} foo
 952 foo:
 953 .weakext bar foo
 954 .weakext baz
 955 ${libc_cv_asm_global_directive} baz
 956 baz:
 957 EOF
 958   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 959     libc_cv_asm_weakext_directive=yes
 960   else
 961     libc_cv_asm_weakext_directive=no
 962   fi
 963   rm -f conftest*])
 964
 965 fi # no .weak
 966
 967 if test $libc_cv_asm_weak_directive = yes; then
 968   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 969 elif test $libc_cv_asm_weakext_directive = yes; then
 970   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 971 fi
 972
 973 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 974 cat > conftest.c <<\EOF
 975 _start () {}
 976 int __eh_pc;
 977 __throw () {}
 978 EOF
 979 dnl No \ in command here because it ends up inside ''.
 980 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 981                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 982                             -o conftest conftest.c 1>&AC_FD_CC]); then
 983   libc_cv_ld_no_whole_archive=yes
 984 else
 985   libc_cv_ld_no_whole_archive=no
 986 fi
 987 rm -f conftest*])
 988 if test $libc_cv_ld_no_whole_archive = yes; then
 989   no_whole_archive=-Wl,--no-whole-archive
 990 fi
 991 AC_SUBST(no_whole_archive)dnl
 992
 993 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 994 cat > conftest.c <<\EOF
 995 _start () {}
 996 int __eh_pc;
 997 __throw () {}
 998 EOF
 999 dnl No \ in command here because it ends up inside ''.
1000 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1001                             -nostdlib -nostartfiles -fexceptions
1002                             -o conftest conftest.c 1>&AC_FD_CC]); then
1003   libc_cv_gcc_exceptions=yes
1004 else
1005   libc_cv_gcc_exceptions=no
1006 fi
1007 rm -f conftest*])
1008 if test $libc_cv_gcc_exceptions = yes; then
1009   exceptions=-fexceptions
1010 fi
1011 AC_SUBST(exceptions)dnl
1012
1013 if test "$base_machine" = alpha ; then
1014 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1015 cat > conftest.c <<\EOF
1016 foo () { }
1017 EOF
1018 dnl
1019 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1020 then
1021   libc_cv_gcc_alpha_ng_prefix=yes
1022 else
1023   libc_cv_gcc_alpha_ng_prefix=no
1024 fi
1025 rm -f conftest* ])
1026 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1027   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1028 else
1029   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1030 fi
1031 fi
1032
1033 if test "$host_cpu" = powerpc ; then
1034 # Check for a bug present in at least versions 2.8.x of GCC
1035 # and versions 1.0.x of EGCS.
1036 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1037 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1038                libc_cv_c_asmcr0_bug='no',
1039                libc_cv_c_asmcr0_bug='yes')])
1040 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1041   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1042 fi
1043 fi
1044
1045 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1046 [cat > conftest.c <<EOF
1047 #line __oline__ "configure"
1048 static char __EH_FRAME_BEGIN__[];
1049 _start ()
1050 {
1051 #ifdef CHECK__register_frame
1052   __register_frame (__EH_FRAME_BEGIN__);
1053   __deregister_frame (__EH_FRAME_BEGIN__);
1054 #endif
1055 #ifdef CHECK__register_frame_info
1056   __register_frame_info (__EH_FRAME_BEGIN__);
1057   __deregister_frame_info (__EH_FRAME_BEGIN__);
1058 #endif
1059 }
1060 int __eh_pc;
1061 __throw () {}
1062 /* FIXME: this is fragile.  */
1063 malloc () {}
1064 strcmp () {}
1065 strlen () {}
1066 memcpy () {}
1067 memset () {}
1068 free () {}
1069 abort () {}
1070 __bzero () {}
1071 EOF
1072 dnl No \ in command here because it ends up inside ''.
1073 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1074                             -nostdlib -nostartfiles
1075                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1076   libc_cv_gcc_dwarf2_unwind_info=static
1077 else
1078   libc_cv_gcc_dwarf2_unwind_info=no
1079 fi
1080 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1081   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1082                               -nostdlib -nostartfiles
1083                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1084     libc_cv_gcc_dwarf2_unwind_info=yes
1085   else
1086     libc_cv_gcc_dwarf2_unwind_info=no
1087   fi
1088 fi
1089 rm -f conftest*])
1090 case $libc_cv_gcc_dwarf2_unwind_info in
1091 yes)
1092   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1093   ;;
1094 static)
1095   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1096   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1097   ;;
1098 esac
1099
1100 dnl Check whether compiler understands __builtin_expect.
1101 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1102 [cat > conftest.c <<EOF
1103 #line __oline__ "configure"
1104 int foo (int a)
1105 {
1106   a = __builtin_expect (a, 10);
1107   return a == 10 ? 0 : 1;
1108 }
1109 EOF
1110 dnl No \ in command here because it ends up inside ''.
1111 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1112                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1113   libc_cv_gcc_builtin_expect=yes
1114 else
1115   libc_cv_gcc_builtin_expect=no
1116 fi
1117 rm -f conftest*])
1118 if test "$libc_cv_gcc_builtin_expect" = yes; then
1119   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1120 fi
1121
1122 dnl Check whether the compiler supports subtraction of local labels.
1123 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1124 [cat > conftest.c <<EOF
1125 changequote(,)dnl
1126 #line __oline__ "configure"
1127 int foo (int a)
1128 {
1129   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1130   void *p = &&l1 + ar[a];
1131   goto *p;
1132  l1:
1133   return 1;
1134  l2:
1135   return 2;
1136 }
1137 changequote([,])dnl
1138 EOF
1139 dnl No \ in command here because it ends up inside ''.
1140 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1141                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1142   libc_cv_gcc_subtract_local_labels=yes
1143 else
1144   libc_cv_gcc_subtract_local_labels=no
1145 fi
1146 rm -f conftest*])
1147 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1148   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1149 fi
1150
1151 dnl Check whether we have the gd library available.
1152 AC_MSG_CHECKING(for libgd)
1153 old_CFLAGS="$CFLAGS"
1154 CFLAGS="$CFLAGS $libgd_include"
1155 old_LDFLAGS="$LDFLAGS"
1156 LDFLAGS="$LDFLAGS $libgd_ldflags"
1157 old_LIBS="$LIBS"
1158 LIBS="$LIBS -lgd -lpng -lz"
1159 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1160 CFLAGS="$old_CFLAGS"
1161 LDFLAGS="$old_LDFLAGS"
1162 LIBS="$old_LIBS"
1163 AC_MSG_RESULT($LIBGD)
1164 AC_SUBST(LIBGD)
1165
1166 ### End of automated tests.
1167 ### Now run sysdeps configure fragments.
1168
1169 # sysdeps configure fragments may set these with files to be linked below.
1170 libc_link_dests=
1171 libc_link_sources=
1172
1173 # They also can set these variables.
1174 use_ldconfig=no
1175 ldd_rewrite_script=no
1176
1177 # Iterate over all the sysdep directories we will use, running their
1178 # configure fragments, and looking for a uname implementation.
1179 uname=
1180 for dir in $sysnames; do
1181   case $dir in
1182     /*) dest=$dir ;;
1183     *)  dest=$srcdir/$dir ;;
1184   esac
1185   if test -r $dest/configure; then
1186     AC_MSG_RESULT(running configure fragment for $dest)
1187     . $dest/configure
1188   fi
1189 [
1190   if test -z "$uname"; then
1191     if test -r $dest/uname.c ||
1192        test -r $dest/uname.S ||
1193        { test -r $dest/syscalls.list &&
1194          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1195       uname=$dir
1196     fi
1197   fi
1198 ]dnl
1199 done
1200
1201 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1202
1203 # If we will use the generic uname implementation, we must figure out what
1204 # it will say by examining the system, and write the results in config-name.h.
1205 if test "$uname" = "sysdeps/generic"; then
1206
1207 changequote(,)dnl
1208   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1209 changequote([,])dnl
1210   if test $uname_sysname != $config_os; then
1211     config_release=`echo $config_os | sed s/$uname_sysname//`
1212   fi
1213 dnl
1214 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1215     if test -r /vmunix; then
1216       kernel_id=`strings /vmunix | grep UNIX`
1217     elif test -r /dynix; then
1218       kernel_id=`strings /dynix | grep DYNIX`
1219     else
1220       kernel_id=
1221     fi
1222 ])dnl
1223
1224   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1225 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1226 changequote(,)dnl
1227   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1228 changequote([,])dnl
1229   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1230          != x$config_release; then
1231     # The configuration release is a substring of the kernel release.
1232     libc_cv_uname_release=$kernel_release
1233   elif test x$config_release != x; then
1234     libc_cv_uname_release=$config_release
1235   elif test x$kernel_release != x; then
1236     libc_cv_uname_release=$kernel_release
1237   else
1238     libc_cv_uname_release=unknown
1239   fi])
1240   uname_release="$libc_cv_uname_release"
1241
1242   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1243 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1244 changequote(,)dnl
1245   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1246 changequote([,])dnl
1247   if test -n "$kernel_version"; then
1248     libc_cv_uname_version="$kernel_version"
1249   else
1250     libc_cv_uname_version=unknown
1251   fi])
1252   uname_version="$libc_cv_uname_version"
1253
1254 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1255   config_uname=config-name.h:config-name.in
1256 else
1257   # For non-generic uname, we don't need to create config-name.h at all.
1258   config_uname=
1259 fi
1260
1261 AC_MSG_CHECKING(stdio selection)
1262 AC_SUBST(stdio)
1263 case $stdio in
1264 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1265 default) stdio=stdio ;;
1266 esac
1267 AC_MSG_RESULT($stdio)
1268
1269 # Test for old glibc 2.0.x headers so that they can be removed properly
1270 # Search only in includedir.
1271 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1272 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1273 then
1274   old_glibc_headers=yes
1275 else
1276   old_glibc_headers=no
1277 fi
1278 AC_MSG_RESULT($old_glibc_headers)
1279 if test ${old_glibc_headers} = yes; then
1280   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1281   AC_MSG_WARN(*** be removed.)
1282 fi
1283 AC_SUBST(old_glibc_headers)
1284
1285 AC_SUBST(libc_cv_slibdir)
1286 AC_SUBST(libc_cv_localedir)
1287 AC_SUBST(libc_cv_sysconfdir)
1288 AC_SUBST(libc_cv_rootsbindir)
1289
1290 AC_SUBST(use_ldconfig)
1291 AC_SUBST(ldd_rewrite_script)
1292
1293 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1294 if test $gnu_ld = yes; then
1295   AC_DEFINE(HAVE_GNU_LD)
1296 fi
1297 if test $gnu_as = yes; then
1298   AC_DEFINE(HAVE_GNU_AS)
1299 fi
1300 if test $elf = yes; then
1301   AC_DEFINE(HAVE_ELF)
1302 fi
1303
1304 AC_SUBST(static)
1305 AC_SUBST(shared)
1306 if test $shared = default; then
1307   if test $gnu_ld = yes; then
1308     shared=$elf
1309   else
1310     # For now we do not assume shared libs are available.  In future more
1311     # tests might become available.
1312     shared=no
1313   fi
1314 fi
1315
1316 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1317 [pic_default=yes
1318 cat > conftest.c <<EOF
1319 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1320 # error PIC is default.
1321 #endif
1322 EOF
1323 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1324   pic_default=no
1325 fi
1326 rm -f conftest.*])
1327 AC_SUBST(pic_default)
1328
1329 AC_SUBST(profile)
1330 AC_SUBST(omitfp)
1331 AC_SUBST(bounded)
1332 AC_SUBST(static_nss)
1333 AC_SUBST(nopic_initfini)
1334
1335 AC_SUBST(DEFINES)
1336
1337 case "$add_ons" in
1338   *door*) linux_doors=yes ;;
1339   *) linux_doors=no ;;
1340 esac
1341 AC_SUBST(linux_doors)
1342
1343 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1344   config_makefile=
1345 else
1346   config_makefile=Makefile
1347 fi
1348
1349 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1350 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1351 AC_SUBST(VERSION)
1352 AC_SUBST(RELEASE)
1353
1354 echo '*** Do NOT install this release on any production system!'
1355 echo '*** It is known to be broken and will be so for quite some time.'
1356 echo '*** Use the latest released version instead.'
1357
1358 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1359 case $CONFIG_FILES in *config.make*)
1360 echo "$config_vars" >> config.make;;
1361 esac
1362 test -d bits || mkdir bits], [config_vars='$config_vars'])