configure.in

   1 dnl configure.in for RPM
   2 dnl
   3 dnl Don't add checks for things we can't work around, unless those checks
   4 dnl failing causes the script to bomb out with a message. If we can't fix
   5 dnl it, why check it?
   6
   7 AC_INIT(rpm.c)
   8 AC_CANONICAL_SYSTEM
   9
  10 AM_INIT_AUTOMAKE(rpm, 4.1)
  11 AM_CONFIG_HEADER(config.h)
  12
  13 AC_PREREQ(2.12)         dnl Minimum Autoconf version required.
  14
  15 dnl XXX AM_MAINTAINER_MODE
  16
  17 dnl Set of available languages.
  18 ALL_LINGUAS="cs da de en_RN es eu_ES fi fr gl hu id is it ja ko no pl pt pt_BR ro ru sk sl sr sv tr uk wa zh zh_CN.GB2312"
  19
  20 LIBOBJS=
  21
  22 dnl Checks for programs.
  23 AC_ARG_PROGRAM
  24 AC_PROG_CC
  25 if test "$ac_cv_prog_gcc" = yes; then
  26     CFLAGS="$CFLAGS -D_GNU_SOURCE -Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wno-char-subscripts"
  27 fi
  28 export CFLAGS
  29
  30 AC_PROG_CPP
  31 AC_PROG_GCC_TRADITIONAL
  32
  33 RPMUSER=rpm
  34 RPMUID=37
  35 RPMGROUP=rpm
  36 RPMGID=37
  37 export RPMUSER RPMUID RPMGROUP RPMGID
  38 AC_SUBST(RPMUSER)
  39 AC_SUBST(RPMUID)
  40 AC_SUBST(RPMGROUP)
  41 AC_SUBST(RPMGID)
  42
  43 AC_PATH_PROG(CTAGS, ctags, /bin/true)
  44 AC_PATH_PROG(CSCOPE, cscope, /bin/true)
  45
  46 dnl
  47 dnl This now uses libtool. Put
  48 dnl     LDFLAGS_STATIC="-all"
  49 dnl to attempt static executables using libtool. Otherwise
  50 dnl     LDFLAGS_STATIC=""
  51 dnl
  52 AC_MSG_CHECKING(flag used by libtool to link rpm)
  53 if test X"$GCC" = Xyes ; then
  54         case "$target" in
  55                 *-*-solaris*)   LDFLAGS_STATIC="-static";;
  56                 *-*-hpux*)      LDFLAGS_STATIC="-static";;
  57                 *-*-sysv5uw*)   LDFLAGS_STATUS="-static";; # Unixware has no shared libthread.
  58                 *-*-*)          LDFLAGS_STATIC="-all-static";;
  59         esac
  60 elif test X"$CC" = Xcc ; then
  61         case "$target" in
  62                 *-*-linux*)     LDFLAGS_STATIC="-all-static";;
  63                 *-*-freebsd*)   LDFLAGS_STATIC="-all-static";;
  64                 *-*-osf*)       LDFLAGS_STATIC="";; # OSF5 has no shared pthreads libs
  65                 *-*-aix*)       LDFLAGS_STATIC="-static";;  # -Wl,-bnso doesn't seem to work...
  66                 *-*-hpux*)      LDFLAGS_STATIC="-static";;
  67                 *-*-solaris*)   LDFLAGS_STATIC="-static";;
  68                 *-*-irix*)      LDFLAGS_STATIC="-static";;  #should be -non_shared, but can't
  69                                                                                         # link because of crt1.o then.
  70                 *-*-ultrix*)    LDFLAGS_STATIC="-all-static";;  #ultrix doesn't have shared libs.
  71                 *-*-*)          LDFLAGS_STATIC="-static"
  72 AC_MSG_WARN([
  73
  74 Unable to guess what option to pass to $CC to generate a static
  75 executable.  You will need to set the LDFLAGS_STATIC macro in Makefile.inc to
  76 the appropriate argument(s) if you want to build a static rpm executable.
  77
  78 ])
  79                 ;;
  80         esac
  81 else
  82         # just link it dynamically
  83         LDFLAGS_STATIC=""
  84 fi
  85 LDFLAGS_STATIC="${LDFLAGS} ${LDFLAGS_STATIC}"   # libtool format
  86 AC_MSG_RESULT($LDFLAGS_STATIC)
  87 AC_SUBST(LDFLAGS_STATIC)
  88
  89 dnl
  90 dnl look for POSIX chmod attributes
  91 dnl
  92 AC_MSG_CHECKING(POSIX chmod)
  93 touch foo.chmodtest
  94 chmod 744 foo.chmodtest
  95 chmod +X foo.chmodtest 2>/dev/null
  96 a=`ls -l foo.chmodtest | awk '{print $1}'`
  97 rm -f foo.chmodtest
  98 if test "$a" = "-rwxr-xr-x"; then
  99     AC_MSG_RESULT(yes)
 100     FIXPERMS=a+rX,g-w,o-w
 101 else
 102     AC_MSG_RESULT(no (tell your OS vendor about GNU fileutils))
 103     FIXPERMS=a+r,g-w,o-w
 104 fi
 105 AC_SUBST(FIXPERMS)
 106
 107 dnl
 108 dnl see if we have a mkdir that supports `-p'.
 109 dnl
 110 AC_PATH_PROGS(MKDIR, mkdir, mkdir)
 111 AC_MSG_CHECKING(if $MKDIR supports -p)
 112 rm -rf conftest
 113 $MKDIR -p conftest/a 2>/dev/null
 114 if test $? = 0 ; then
 115         rmdir conftest/a 2>/dev/null
 116         if test $? = 0  ; then
 117                 :
 118         else
 119                 MKDIR_P=0
 120         fi
 121
 122         rmdir conftest 2>/dev/null
 123         if test $? = 0 ; then
 124                 MKDIR_P="$MKDIR -p"
 125         else
 126                 MKDIR_P=0
 127         fi
 128 else
 129         MKDIR_P=0
 130 fi
 131
 132 if test X"$MKDIR_P" = X0 ; then
 133         AC_MSG_RESULT(no)
 134         MKDIR_P="`echo ${prefix}/lib/rpm/mkinstalldirs`"
 135 else
 136         AC_MSG_RESULT(yes)
 137 fi
 138 dnl
 139 dnl substitute this into config.h, so the C source picks it up.
 140 dnl
 141 AC_DEFINE_UNQUOTED(MKDIR_P, "${MKDIR_P}")
 142 AC_SUBST(MKDIR_P)
 143
 144 AC_AIX
 145 AC_MINIX
 146 AC_ISC_POSIX
 147
 148 dnl This test must precede tests of compiler characteristics like
 149 dnl that for the inline keyword, since it may change the degree to
 150 dnl which the compiler supports such features.
 151 AM_C_PROTOTYPES
 152
 153 AC_PROG_AWK
 154 AC_PROG_LN_S
 155 AC_PROG_MAKE_SET
 156
 157 dnl AM_DISABLE_SHARED
 158 AM_PROG_LIBTOOL
 159
 160 AC_CHECK_TOOL(AR, ar, :)
 161
 162 if test "$cross_compiling" != "yes"; then
 163 dnl
 164 dnl Set search path for common programs
 165 dnl
 166     MYPATH="/bin:/usr/bin:/usr/local/bin:$PATH:/sbin:/usr/sbin:/usr/local/sbin:/opt/gnu/bin"
 167
 168 dnl
 169 dnl Find some common programs
 170 dnl
 171     AC_PATH_PROG(BZIP2BIN, bzip2, /usr/bin/bzip2, $MYPATH)
 172     AC_PATH_PROG(__CAT, cat, /bin/cat, $MYPATH)
 173     AC_PATH_PROG(__CHGRP, chgrp, /bin/chgrp, $MYPATH)
 174     AC_PATH_PROG(__CHMOD, chmod, /bin/chmod, $MYPATH)
 175     AC_PATH_PROG(__CHOWN, chown, /bin/chown, $MYPATH)
 176     AC_PATH_PROG(__CP, cp, /bin/cp, $MYPATH)
 177     AC_PATH_PROG(__CPIO, cpio, /bin/cpio, $MYPATH)
 178     AC_PATH_PROG(GZIPBIN, gzip, /bin/gzip, $MYPATH)
 179     AC_PATH_PROG(__GREP, grep, /bin/grep, $MYPATH)
 180     AC_PATH_PROG(UNZIPBIN, unzip, /usr/bin/unzip, $MYPATH)
 181
 182     AC_PATH_PROG(__ID, id, /usr/bin/id, $MYPATH)
 183     AC_MSG_CHECKING(checking whether id supports -u)
 184     if `${__ID} -u 2>&1 > /dev/null` ; then
 185         __ID_U="%{__id} -u"
 186         AC_MSG_RESULT(yes)
 187     else
 188 dnl XXX Watchout for square brackets fed to m4.
 189         __ID_U="%{__id} | %{__sed} 's/[[^=]]*=\\\\([[0-9]][[0-9]]*\\\\).*$/\\\\1/'"
 190         AC_MSG_RESULT(no)
 191     fi
 192     AC_SUBST(__ID_U)
 193
 194     AC_PATH_PROG(__INSTALL, install, /usr/bin/install, $MYPATH)
 195     AC_PATH_PROG(__MAKE, make, /usr/bin/make, $MYPATH)
 196     AC_PATH_PROG(__MKDIR, mkdir, /bin/mkdir, $MYPATH)
 197     AC_PATH_PROG(__MV, mv, /bin/mv, $MYPATH)
 198     AC_PATH_PROG(__PATCH, patch, /usr/bin/patch, $MYPATH)
 199     AC_MSG_CHECKING(old version of patch)
 200     PATCHVERSION=`patch --version 2>&1`
 201
 202     if test "$PATCHVERSION" = "Patch version 2.1"; then
 203         AC_DEFINE(HAVE_OLDPATCH_21)
 204         AC_MSG_RESULT(patch older then 2.2 found)
 205     else
 206         AC_MSG_RESULT(patch later then 2.2 found)
 207     fi
 208
 209     AC_PATH_PROG(__PERL, perl, /usr/bin/perl, $MYPATH)
 210     AC_PATH_PROG(PGPBIN, pgp, /usr/bin/pgp, $MYPATH)
 211     AC_PATH_PROG(__PYTHON, python, /usr/bin/python, $MYPATH)
 212     AC_PATH_PROG(__RM, rm, /bin/rm, $MYPATH)
 213     AC_PATH_PROG(__RSH, rsh, /usr/bin/rsh, $MYPATH)
 214     AC_PATH_PROG(__SED, sed, /bin/sed, $MYPATH)
 215     AC_PATH_PROG(__SSH, ssh, /usr/bin/ssh, $MYPATH)
 216     AC_PATH_PROG(__TAR, tar, /bin/tar, $MYPATH)
 217
 218     AC_PATH_PROG(__LD, ld, /usr/bin/ld, $MYPATH)
 219     AC_PATH_PROG(__NM, nm, /usr/bin/nm, $MYPATH)
 220     AC_PATH_PROG(__OBJCOPY, objcopy, /usr/bin/objcopy, $MYPATH)
 221     AC_PATH_PROG(__OBJDUMP, objdump, /usr/bin/objdump, $MYPATH)
 222     AC_PATH_PROG(__STRIP, strip, /usr/bin/strip, $MYPATH)
 223 fi
 224
 225 addlib() {
 226   l=$1
 227   shift
 228   case "$target" in
 229     *-*-solaris*)       LIBS="$LIBS -L$l -R$l $*";;
 230     *)          LIBS="$LIBS -L$l $*";;
 231   esac
 232 }
 233
 234 localdone=
 235 for dir in $prefix /usr/local
 236 do
 237         case $dir in
 238         NONE|/usr)      continue;;
 239         /usr/local)
 240                 if test X$localdone != X ; then continue; fi
 241                 localdone="$dir"
 242                 ;;
 243         esac
 244
 245         AC_MSG_CHECKING(for $dir/lib in LIBS)
 246         if test -d $dir/lib ; then
 247                 addlib $dir/lib
 248                 AC_MSG_RESULT(yes)
 249         else
 250                 AC_MSG_RESULT(no)
 251         fi
 252
 253         AC_MSG_CHECKING(for $dir/include in INCPATH)
 254         if test -d $dir/include ; then
 255                 INCPATH="$INCPATH -I$dir/include"
 256                 AC_MSG_RESULT(yes)
 257         else
 258                 AC_MSG_RESULT(no)
 259         fi
 260 done
 261
 262 AC_MSG_CHECKING(for /usr/ucblib in LIBS)
 263 if test -d /usr/ucblib ; then
 264         if test "$build" = "mips-sni-sysv4" ; then
 265                 addlib /usr/ccs/lib -lc
 266         fi
 267
 268         addlib /usr/ucblib
 269
 270         AC_MSG_RESULT(yes)
 271 else
 272         AC_MSG_RESULT(no)
 273 fi
 274
 275 dnl
 276 dnl Check for features
 277 dnl
 278
 279 dnl ### use option --enable-v5-packages to turn on support for rpm-5.x packages
 280 dnl AC_MSG_CHECKING(if you want experimental rpm-5.0 packages)
 281 dnl AC_ARG_ENABLE(v5-packages,
 282 dnl         [  --enable-v5-packages[=no]    [experimental] support for rpm-5.x packages],
 283 dnl         [with_v5_packages=$enableval],
 284 dnl         [with_v5_packages=no])
 285 dnl AC_MSG_RESULT($with_v5_packages)
 286 dnl test "$with_v5_packages" = yes && AC_DEFINE(ENABLE_V5_PACKAGES)
 287
 288 dnl Checks for libraries.
 289
 290 AC_CHECK_FUNC(setreuid, [], [
 291     AC_CHECK_LIB(ucb, setreuid, [if echo $LIBS | grep -- -lucb >/dev/null ;then :; else LIBS="$LIBS -lc -lucb" USEUCB=y;fi])
 292 ])
 293
 294 AC_CHECK_FUNC(rand, [], [
 295     AC_CHECK_LIB(rand, rand, [LIBS="$LIBS -lm"])
 296 ])
 297
 298 AC_CHECK_FUNC(getdomainname, [], [
 299     AC_CHECK_LIB(nsl, getdomainname, [LIBS="$LIBS -lnsl"])
 300 ])
 301 AC_CHECK_FUNC(socket, [], [
 302     AC_CHECK_LIB(socket, socket, [LIBS="$LIBS -lsocket"])
 303 ])
 304
 305 dnl Better not use fchmod at all.
 306 AC_CHECK_FUNC(fchmod)
 307
 308 AC_CHECK_FUNCS(vsnprintf snprintf)
 309
 310 dnl Temporary hack for MiNT.  Some functions (writev, snprintf) are
 311 dnl not in the libc but in libport (for political reasons).  This check
 312 dnl can hopefully be removed soon.  Please use the default action
 313 dnl for this macro (not LIBS=...), otherwise the check for dbopen
 314 dnl will fail.
 315 AC_CHECK_LIB(port, writev)
 316
 317 libthread=""
 318 AC_CHECK_LIB(pthread, pthread_mutex_trylock, [libthread="-lpthread"], [
 319   dnl OSF 5.0 has the the symbols prefixed with __ in libpthread.
 320   AC_CHECK_LIB(pthread, __pthread_mutex_trylock, [libthread="-lpthread"])
 321 ])
 322
 323 if test "x$libthread" = "x"; then
 324         # Try in libthread too.
 325         AC_CHECK_LIB(thread, mutex_lock, [libthread="-lthread"])
 326 fi
 327
 328 WITH_DB_SUBDIR=
 329 WITH_INTERNAL_DB=0
 330 DBLIBSRCS=""
 331 libdb3=""
 332 libdb3a=""
 333
 334 dnl
 335 dnl Detect whether internal Berkeley DB should be built.
 336 dnl
 337 withval=yes
 338 AC_ARG_WITH(db, [  --without-db            do not use internal Berkeley db])
 339
 340 if test $withval = no ; then
 341 dnl ------------------ without internal db
 342
 343 AC_CHECK_HEADERS(db3/db.h)
 344
 345 dnl Check for Berkeley db3 API.
 346 AC_CHECK_FUNC(db_create, [DBLIBSRCS="$DBLIBSRCS db3.c"],
 347   AC_CHECK_LIB(db-3.2, db_create, [DBLIBSRCS="$DBLIBSRCS db3.c"; libdb3="-ldb-3.2"],
 348     AC_CHECK_LIB(db-3.1, db_create, [DBLIBSRCS="$DBLIBSRCS db3.c"; libdb3="-ldb-3.1"],
 349       AC_CHECK_LIB(db-3.0, db_create, [DBLIBSRCS="$DBLIBSRCS db3.c"; libdb3="-ldb-3.0"],
 350         AC_CHECK_LIB(db, db_create, [DBLIBSRCS="$DBLIBSRCS db3.c"; libdb3="-ldb"],
 351         ,$libthread)
 352       ,$libthread)
 353     ,$libthread)
 354   ,$libthread)
 355 )
 356
 357 if test X"$DBLIBSRCS" = X; then
 358     AC_MSG_ERROR([sorry rpm requires libdb-3.x.a (from the Berkeley db package)])
 359 fi
 360
 361 if test -n "$libdb3" -a -n "$libthread" ; then
 362    AC_MSG_CHECKING(whether $libdb3 needs $libthread)
 363    saveLIBS="$LIBS"
 364    LIBS="$LIBS $libdb3"
 365    AC_TRY_LINK_FUNC(db_create, AC_MSG_RESULT(no),
 366         [libdb3="$libdb3 $libthread"; AC_MSG_RESULT(yes)])
 367    LIBS="$saveLIBS"
 368 fi
 369
 370 else
 371 dnl ------------------ with    internal db
 372   AC_DEFINE(HAVE_DB3_DB_H)
 373   WITH_DB_SUBDIR=db3
 374   WITH_INTERNAL_DB=1
 375   DBLIBSRCS="db3.c"
 376   libdb3="# \$(top_builddir)/db3/libdb.la"
 377   libdb3a="\$(top_builddir)/db3/libdb.a"
 378 dnl  INCPATH="-I\$(top_builddir)/$(WITH_DB_SUBDIR) $INCPATH"
 379 fi
 380
 381 AC_SUBST(WITH_DB_SUBDIR)
 382 AC_SUBST(WITH_INTERNAL_DB)
 383
 384 DBLIBSRCS="$DBLIBSRCS db1.c falloc.c"
 385 DBLIBOBJS=`echo $DBLIBSRCS | sed -e "s/\.c/\.lo/g"`
 386
 387 AC_SUBST(DBLIBSRCS)
 388 AC_SUBST(DBLIBOBJS)
 389 AC_SUBST(libdb3)
 390 AC_SUBST(libdb3a)
 391
 392 for dbi in $DBLIBSRCS; do
 393   case $dbi in
 394   db3.c) AC_DEFINE(USE_DB3) ;;
 395   db1.c) AC_DEFINE(USE_DB1) ;;
 396   esac
 397 done
 398
 399 AC_CHECK_FUNC(fork, [], [echo "using vfork() instead of fork()";
 400         LIBOBJS=fakefork.o])
 401
 402 dnl AmigaOS and IXEmul have a fork() dummy
 403     case "$target" in
 404         m68k-*-amigaos )
 405                 echo "Building for AmigaOS: using vfork() instead of fork()";
 406                 CFLAGS="$CFLAGS -Dfork=vfork"
 407                 ;;
 408 esac
 409
 410
 411 for zlib in z gz ; do
 412    AC_CHECK_LIB(${zlib}, gzread,
 413         [LIBS="$LIBS -l${zlib}"; break],
 414         [if test ${zlib} = gz; then
 415             AC_MSG_ERROR([sorry rpm requires libz.a or libgz.a (from the zlib package)])
 416          fi]
 417                )
 418 done
 419
 420 dnl zlib-1.0.4 has not gzseek
 421 AC_CHECK_LIB(${zlib}, gzseek, [AC_DEFINE(HAVE_GZSEEK)])
 422
 423 AC_CHECK_LIB(bz2, bzread, [LIBS="$LIBS -lbz2"],
 424    AC_CHECK_LIB(bz2, BZ2_bzread, [
 425      WITH_BZIP2=1
 426      LIBS="$LIBS -lbz2"
 427      AC_DEFINE(HAVE_BZ2_1_0) ],
 428      WITH_BZIP2=0))
 429 AC_SUBST(WITH_BZIP2)
 430
 431 dnl Red Hat 4.x has not personality
 432 AC_CHECK_FUNCS(personality)
 433
 434 dnl XXX these are needed only by rpmgettext right now
 435 AM_FUNC_ERROR_AT_LINE
 436
 437 dnl ==> AM_GNU_GETTEXT does this (and more)
 438 dnl AC_CHECK_HEADERS(unistd.h limits.h locale.h malloc.h string.h sys/param.h)
 439
 440 AM_GNU_GETTEXT
 441 dnl TVM:
 442 dnl horrible *temporary* hack to make sure that if we found gettext() in
 443 dnl -lintl that we add -lintl *back* to $LIBS.
 444 dnl
 445 if test X$gt_cv_func_gettext_libintl = Xyes ; then
 446     LIBS="-lintl $LIBS"
 447 fi
 448
 449 dnl Checks for header files we can live without.
 450 AC_HEADER_STDC
 451 AC_HEADER_MAJOR
 452 AC_HEADER_DIRENT
 453 AC_HEADER_TIME
 454
 455 AC_CHECK_HEADERS(fcntl.h getopt.h grp.h memory.h netdb.h pwd.h utime.h)
 456
 457 AC_CHECK_HEADERS(sys/ipc.h sys/socket.h sys/select.h)
 458 AC_CHECK_HEADERS(sys/types.h sys/stdtypes.h)
 459 AC_CHECK_HEADERS(sys/mman.h sys/resource.h sys/utsname.h sys/wait.h)
 460
 461 AC_CHECK_HEADERS(netinet/in_systm.h)
 462 AC_CHECK_HEADERS(machine/types.h)
 463 AC_CHECK_HEADERS(mntent.h sys/mnttab.h sys/systemcfg.h)
 464 AC_CHECK_HEADERS(sys/mount.h sys/mntctl.h sys/param.h sys/vmount.h)
 465 AC_CHECK_HEADERS(bzlib.h libio.h zlib.h)
 466 AC_CHECK_HEADERS(err.h mcheck.h)
 467
 468 dnl popt w float/double needs.
 469 AC_CHECK_HEADERS(float.h)
 470
 471 dnl whether or not we should try to build rpmgettext/rpmputtext.
 472 if test X"$USE_NLS" = Xyes; then
 473     BUILD_RPMNLSTOOLS="rpmgettext rpmputtext"
 474     if test X"$USE_INCLUDED_LIBINTL" = Xyes; then
 475         INCPATH="-I\$(top_builddir)/intl $INCPATH"
 476     fi
 477 else
 478     BUILD_RPMNLSTOOLS=
 479 fi
 480 AC_SUBST(BUILD_RPMNLSTOOLS)
 481
 482 AC_CHECK_HEADERS(glob.h)
 483
 484 dnl statfs portability fiddles.
 485 dnl
 486 dnl We should really emulate/steal sections of the statfs and struct statfs
 487 dnl checks from GNU fileutils.
 488 dnl
 489 AC_MSG_CHECKING(for struct statfs)
 490 dnl
 491 dnl this is easier than nesting AC_TRY_COMPILEs...
 492 dnl
 493 found_struct_statfs=no
 494
 495 if test X$found_struct_statfs = Xno ; then
 496 dnl Solaris 2.6+ wants to use statvfs
 497 AC_TRY_COMPILE([
 498 #ifdef HAVE_SYS_TYPES_H
 499 #include <sys/types.h>
 500 #endif
 501 #include <sys/statvfs.h> ],
 502         [struct statvfs sfs;],
 503         [AC_MSG_RESULT(in sys/statvfs.h)
 504         AC_DEFINE(STATFS_IN_SYS_STATVFS)
 505         found_struct_statfs=yes],
 506 )
 507 fi
 508
 509 if test X$found_struct_statfs = Xno ; then
 510 dnl first try including sys/vfs.h
 511 AC_TRY_COMPILE([
 512 #ifdef HAVE_SYS_TYPES_H
 513 #include <sys/types.h>
 514 #endif
 515 #include <sys/vfs.h> ],
 516         [struct statfs sfs;],
 517         [AC_MSG_RESULT(in sys/vfs.h)
 518         AC_DEFINE(STATFS_IN_SYS_VFS)
 519         found_struct_statfs=yes],
 520 )
 521 fi
 522
 523 if test X$found_struct_statfs = Xno ; then
 524 dnl ...next try including sys/mount.h
 525 AC_TRY_COMPILE([
 526 #ifdef HAVE_SYS_TYPES_H
 527 #include <sys/types.h>
 528 #endif
 529 #ifdef HAVE_SYS_PARAM_H
 530 #include <sys/param.h>
 531 #endif
 532 #include <sys/mount.h> ],
 533         [struct statfs sfs;],
 534         [AC_MSG_RESULT(in sys/mount.h)
 535         AC_DEFINE(STATFS_IN_SYS_MOUNT)
 536         found_struct_statfs=yes],
 537 )
 538 fi
 539
 540 if test X$found_struct_statfs = Xno ; then
 541 dnl ...still no joy.  Try sys/statfs.h
 542 AC_TRY_COMPILE([
 543 #ifdef HAVE_SYS_TYPES_H
 544 #include <sys/types.h>
 545 #endif
 546 #include <sys/statfs.h> ],
 547         [struct statfs sfs;],
 548         [AC_MSG_RESULT(in sys/statfs.h)
 549         AC_DEFINE(STATFS_IN_SYS_STATFS)
 550         found_struct_statfs=yes],
 551 )
 552 fi
 553
 554 if test X$found_struct_statfs = Xno ; then
 555 dnl ...no luck.  Warn the user of impending doom.
 556 AC_MSG_WARN(not found)
 557 fi
 558
 559 dnl
 560 dnl if we found the struct, see if it has the f_bavail member.  Some OSes
 561 dnl don't, including IRIX 6.5+
 562 dnl
 563 if test X$found_struct_statfs = Xyes ; then
 564 AC_MSG_CHECKING(for f_bavail member in struct statfs)
 565 AC_TRY_COMPILE([
 566 #ifdef HAVE_SYS_TYPES_H
 567 #include <sys/types.h>
 568 #endif
 569 #if STATFS_IN_SYS_STATVFS
 570 # include <sys/statvfs.h>
 571   typedef struct statvfs STATFS_t;
 572 #else
 573   typedef struct statfs STATFS_t;
 574 # if STATFS_IN_SYS_VFS
 575 #  include <sys/vfs.h>
 576 # elif STATFS_IN_SYS_MOUNT
 577 #  include <sys/mouht.h>
 578 # elif STATFS_IN_SYS_STATFS
 579 #  include <sys/statfs.h>
 580 # endif
 581 #endif ],
 582         [STATFS_t sfs;
 583         sfs.f_bavail = 0;],
 584         [AC_MSG_RESULT(yes)
 585         AC_DEFINE(STATFS_HAS_F_BAVAIL)],
 586         [AC_MSG_RESULT(no)]
 587 )
 588 fi
 589
 590 if test X$found_struct_statfs = Xyes ; then
 591 dnl
 592 dnl now check to see if we have the 4-argument variant of statfs()
 593 dnl this pretty much requires AC_TRY_RUN
 594 dnl
 595 AC_MSG_CHECKING([if statfs() requires 4 arguments])
 596 AC_TRY_RUN([
 597 #ifdef HAVE_SYS_TYPES_H
 598 #include <sys/types.h>
 599 #endif
 600 #ifdef STATFS_IN_SYS_VFS
 601 #include <sys/vfs.h>
 602 #elif STATFS_IN_SYS_MOUNT
 603 #include <sys/mouht.h>
 604 #elif STATFS_IN_SYS_STATFS
 605 #include <sys/statfs.h>
 606 #endif
 607 main() {
 608         struct statfs sfs;
 609         exit (statfs(".", &sfs, sizeof(sfs), 0));
 610 }
 611 ],
 612         [AC_MSG_RESULT(yes)
 613         AC_DEFINE(STAT_STATFS4)],
 614         [AC_MSG_RESULT(no)],
 615         [AC_MSG_RESULT(no)]
 616 )
 617 fi
 618
 619 AC_C_INLINE
 620
 621 dnl look for libc features
 622 PROVIDES_ERRNO=no
 623 AC_MSG_CHECKING(if <netdb.h> defines h_errno)
 624 AC_TRY_LINK([#include <netdb.h>],printf("%d",h_errno),PROVIDES_ERRNO=yes)
 625 AC_MSG_RESULT($PROVIDES_ERRNO)
 626 if test $PROVIDES_ERRNO = yes; then
 627         AC_DEFINE(HAVE_HERRNO)
 628 fi
 629
 630 dnl If a system doesn't have S_IFSOCK, define it as 0 which will
 631 dnl make S_ISSOCK always return false (nice, eh?)
 632 AC_MSG_CHECKING(if <sys/stat.h> defines S_IFSOCK)
 633 AC_TRY_LINK([#include <sys/stat.h>],printf("%d", S_IFSOCK),
 634         HAS_S_IFSOCK=yes,HAS_S_IFSOCK=no)
 635 AC_MSG_RESULT($HAS_S_IFSOCK)
 636 if test $HAS_S_IFSOCK = yes; then
 637         AC_DEFINE(HAVE_S_IFSOCK)
 638 fi
 639
 640 dnl Some Unix's are missing S_ISLNK, S_ISSOCK
 641 AC_MSG_CHECKING(if <sys/stat.h> defines S_ISLNK)
 642 AC_TRY_LINK([#include <sys/stat.h>],printf("%d", S_ISLNK(0755)),
 643         HAS_S_ISLNK=yes,HAS_S_ISLNK=no)
 644 AC_MSG_RESULT($HAS_S_ISLNK)
 645 if test $HAS_S_ISLNK = yes; then
 646         AC_DEFINE(HAVE_S_ISLNK)
 647 fi
 648
 649 AC_MSG_CHECKING(if <sys/stat.h> defines S_ISSOCK)
 650 AC_TRY_LINK([#include <sys/stat.h>],printf("%d", S_ISSOCK(0755)),
 651         HAS_S_ISSOCK=yes,HAS_S_ISSOCK=no)
 652 AC_MSG_RESULT($HAS_S_ISSOCK)
 653 if test $HAS_S_ISSOCK = yes; then
 654         AC_DEFINE(HAVE_S_ISSOCK)
 655 fi
 656
 657 AC_MSG_CHECKING(if timezone is defined)
 658 AC_TRY_LINK([#include <time.h>],printf("%ld", timezone),
 659       HAS_TIMEZONE=yes,HAS_TIMEZONE=no)
 660 AC_MSG_RESULT($HAS_TIMEZONE)
 661
 662 dnl Check for missing typedefs
 663 AC_TYPE_MODE_T
 664 AC_TYPE_PID_T
 665
 666 dnl Checks for library functions.
 667 AC_FUNC_ALLOCA
 668 AC_FUNC_VPRINTF
 669
 670 AC_FUNC_FNMATCH
 671 if test $ac_cv_func_fnmatch_works = no; then
 672    LIBOBJS="$LIBOBJS fnmatch.o"
 673    AC_DEFINE_UNQUOTED(fnmatch, rpl_fnmatch)
 674 fi
 675
 676 dnl XXX AC_FUNC_MEMCMP
 677 dnl XXX AC_FUNC_MMAP
 678 dnl XXX AC_TYPE_SIGNAL
 679 dnl XXX AC_FUNC_STRCOLL
 680 dnl XXX AC_FUNC_STRFTIME
 681 dnl XXX AC_FUNC_UTIME_NULL
 682 dnl XXX AC_FUNC_VFORK
 683 dnl XXX AC_CHECK_FUNCS(gethostname mkdir mkfifo rmdir select uname)
 684
 685 AC_CHECK_FUNCS(basename getcwd getwd inet_aton mtrace putenv realpath setenv)
 686 AC_CHECK_FUNCS(stpcpy stpncpy strcspn)
 687 AC_CHECK_FUNCS(strdup strerror strtol strtoul strspn strstr)
 688
 689 AC_CHECK_FUNCS(regcomp)
 690
 691 AC_CHECK_FUNCS(ftok)
 692
 693 dnl
 694 dnl XXX Regex replacement isn't known to be needed yet.
 695 dnl
 696 dnl AC_ARG_WITH(regex, [  --with-regex            use the GNU regex library ],
 697 dnl     [rpm_cv_regex=yes],
 698 dnl     [AC_CHECK_FUNCS(regcomp, rpm_cv_regex=no, rpm_cv_regex=yes)])
 699 dnl
 700 dnl if test $rpm_cv_regex = no ; then
 701 dnl     AC_MSG_CHECKING(whether the regexp library is broken)
 702 dnl     AC_TRY_RUN([
 703 dnl #include <unistd.h>
 704 dnl #include <regex.h>
 705 dnl main() { regex_t blah ; exit(regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0)); }],
 706 dnl     rpm_cv_regex_broken=no, rpm_cv_regex_broken=yes, rpm_cv_regex_broken=yes)
 707 dnl     AC_MSG_RESULT([$rpm_cv_regex_broken])
 708 dnl     if test $rpm_cv_regex_broken = yes ; then
 709 dnl         echo "   --> using the included GNU regex instead." >&AC_FD_MSG
 710 dnl         rpm_cv_regex=yes
 711 dnl     fi
 712 dnl fi
 713 dnl
 714 dnl if test $rpm_cv_regex = yes; then
 715 dnl     AC_DEFINE(USE_GNU_REGEX)
 716 dnl     LIBOBJS="$LIBOBJS regex.o"
 717 dnl fi
 718
 719 dnl
 720 dnl XXX Glob *is* broken on linux with libc5, solaris and possibly aix when
 721 dnl %files gets something like
 722 dnl     /usr/*/locale/*/LC_MESSAGES/*.mo
 723 dnl (Note: more than one asterisk in glob pattern.)
 724 dnl
 725 AC_ARG_WITH(glob, [  --with-glob             use the internal GNU glob ],
 726     [rpm_cv_glob=yes],
 727     [AC_CHECK_FUNCS(glob, rpm_cv_glob=no, rpm_cv_glob=yes)])
 728
 729 if test $rpm_cv_glob = no ; then
 730     AC_MSG_CHECKING(for GNU extensions to glob)
 731     rm -f t
 732     mkdir t
 733     mkdir t/p
 734     touch t/p/foo.8
 735     AC_TRY_RUN([
 736 #include <unistd.h>
 737 #include <sys/stat.h>
 738 #include <glob.h>
 739 main() {
 740   glob_t gl ;
 741   gl.gl_stat = stat;
 742   exit(glob("t/*/*.8", GLOB_PERIOD, NULL, &gl) || gl.gl_pathc < 1);
 743 } ],
 744     rpm_cv_glob_ext=yes, rpm_cv_glob_ext=no, rpm_cv_glob_ext=no)
 745     rm -r t
 746     AC_MSG_RESULT([$rpm_cv_glob_ext])
 747     if test $rpm_cv_glob_ext = no ; then
 748             echo "    --> using the included GNU glob instead." >&AC_FD_MSG
 749             rpm_cv_glob=yes
 750     fi
 751 fi
 752
 753 if test $rpm_cv_glob = yes; then
 754     AC_DEFINE(USE_GNU_GLOB)
 755     LIBOBJS="$LIBOBJS glob.o fnmatch.o"
 756 fi
 757
 758 dnl
 759 dnl Auto-detect whether python bindings should be built.
 760 dnl
 761 withval=auto
 762 AC_ARG_WITH(python, [  --with-python           build rpm python bindings ])
 763
 764 if test $withval = auto ; then
 765   AC_MSG_CHECKING(for python 1.5.2)
 766   AC_TRY_RUN([
 767 #include <python1.5/Python.h>
 768 main() {
 769   exit(strcmp("1.5.2", PY_VERSION));
 770 } ],
 771   withval=yes, withval=no, withval=no)
 772   AC_MSG_RESULT($withval)
 773 fi
 774
 775 if test $withval = yes ; then
 776   WITH_PYTHON_SUBDIR=python
 777   WITH_PYTHON_SUBPACKAGE=1
 778 else
 779   WITH_PYTHON_SUBDIR=
 780   WITH_PYTHON_SUBPACKAGE=0
 781 fi
 782 AC_SUBST(WITH_PYTHON_SUBDIR)
 783 AC_SUBST(WITH_PYTHON_SUBPACKAGE)
 784
 785 AC_PATH_PROG(__DOXYGEN, doxygen, no, $PATH)
 786 dnl
 787 dnl Auto-detect whether doxygen generated API docs should be included.
 788 dnl
 789 withval=auto
 790 AC_ARG_WITH(apidocs, [  --with-apidocs          build rpm API docs ])
 791
 792 if test $withval = auto -a $__DOXYGEN != no ; then
 793   withval=yes
 794 elif test $withval = yes -a $__DOXYGEN = no ; then
 795   AC_MSG_ERROR(--> rpm API docs needs doxygen in PATH)
 796 fi
 797
 798 if test $withval = yes; then
 799   WITH_APIDOCS_TARGET=apidocs
 800   WITH_APIDOCS=1
 801 else
 802   WITH_APIDOCS=0
 803 fi
 804 AC_SUBST(WITH_APIDOCS_TARGET)
 805 AC_SUBST(WITH_APIDOCS)
 806
 807 withval=no
 808 AC_ARG_WITH(dmalloc, [  --with-dmalloc          build with dmalloc debugging support ])
 809 if test $withval = yes ; then
 810   AC_DEFINE(DMALLOC)
 811   LIBS="$LIBS -ldmalloc"
 812 fi
 813
 814 AC_CHECK_FUNCS(setlocale)
 815
 816 dnl XXX Solaris <= 2.6 only permits 8 chars in password.
 817 AC_CHECK_FUNCS(getpassphrase)
 818
 819 AC_CHECK_FUNC(getmntent, AC_DEFINE(HAVE_GETMNTENT), [
 820   AC_CHECK_FUNC(mntctl, AC_DEFINE(HAVE_MNTCTL),[
 821     AC_CHECK_FUNC(getmntinfo_r, AC_DEFINE(HAVE_GETMNTINFO_R), [
 822       AC_CHECK_LIB(c_r, getmntinfo_r, [LIBS="$LIBS -lc_r";
 823                                         AC_DEFINE(HAVE_GETMNTINFO_R)], [
 824                  AC_DEFINE([USE_GETMNTENT], 1, [Defined if getmntent replacement is used])
 825                  LIBOBJS="$LIBOBJS getmntent.o"])])])])
 826
 827 AC_CHECK_FUNC(lchown,
 828    [__CHOWN_RHF="%{__chown} -Rhf"
 829     __CHGRP_RHF="%{__chgrp} -Rhf"
 830     AC_DEFINE(HAVE_LCHOWN)],
 831    [__CHOWN_RHF="%{__chown} -Rf"
 832     __CHGRP_RHF="%{__chgrp} -Rf"
 833     dnl Does chown() follow symlinks? This should be a good enough test.
 834     AC_MSG_CHECKING(whether chown() follows symlinks)
 835     AC_ARG_ENABLE([broken-chown],
 836     [  --enable-broken-chown   this system's chown follows symbolic links],
 837             result=$enableval, result=unknown)
 838     if echo "$build" | egrep "(aix)|(hpux)|(linux)" > /dev/null ; then
 839         result=yes
 840     elif echo "$build" | egrep "(nextstep)" > /dev/null ; then
 841         result=no
 842     fi
 843     if test $result = unknown; then
 844         if test `${__ID} | cut -f2 -d\= | cut -f1 -d\(` = 0; then
 845             rm -f foo bar
 846             touch foo
 847             ln -s foo bar
 848             ${__CHOWN} 10 bar
 849             if test `ls -l foo | awk '{print $3}'` != "root"; then
 850                 result=yes
 851             else
 852                 result=no
 853             fi
 854             ${__RM} -f foo bar
 855         else
 856             AC_MSG_CHECKING((cannot check by non-root user))
 857             result=no
 858         fi
 859     fi
 860
 861     AC_MSG_RESULT($result)
 862     if test $result = yes; then
 863             AC_DEFINE(CHOWN_FOLLOWS_SYMLINK)
 864     fi])
 865 AC_SUBST(__CHOWN_RHF)
 866 AC_SUBST(__CHGRP_RHF)
 867
 868 dnl
 869 dnl figure out what root's primary group is
 870 dnl
 871 AC_MSG_CHECKING(root's primary group)
 872 AC_TRY_RUN([#include <stdio.h>
 873 #include <sys/types.h>
 874 #include <pwd.h>
 875 #include <grp.h>
 876
 877 int main()
 878 {
 879         struct passwd *root = NULL;
 880         struct group *roots_group = NULL;
 881         FILE * tempfile = NULL;
 882
 883         root = getpwuid( (uid_t) 0 );
 884         if (root != NULL) {
 885                 roots_group = getgrgid(root->pw_gid);
 886                 if (roots_group != NULL) {
 887                         tempfile = fopen("conftest_rootg", "w");
 888                         if (tempfile != NULL) {
 889                                 fprintf(tempfile, "%s\n", roots_group->gr_name);
 890                                 fclose(tempfile);
 891                                 exit(0);
 892                         }
 893                 }
 894         }
 895
 896         exit(1);
 897 }], ROOT_GROUP=`cat conftest_rootg`,
 898         ROOT_GROUP="root",ROOT_GROUP="root"
 899 )
 900 AC_MSG_RESULT($ROOT_GROUP)
 901 AC_SUBST(ROOT_GROUP)
 902
 903 if test "x$varprefix" = "x"; then
 904     # For /usr and /usr/local, we want the 'var' directory to go
 905     # in /var and /var/local respectively. For everything else,
 906     # just put the 'var' directory in prefix/var.
 907     case $prefix in
 908         /usr | /usr/local )
 909             varprefix=`echo $prefix | sed 's/usr/var/'` ;;
 910         NONE)
 911             varprefix=`echo $ac_default_prefix | sed 's/usr/var/'` ;;
 912         *)
 913             varprefix=$prefix/var ;;
 914     esac
 915 fi
 916 AC_SUBST(varprefix)
 917
 918 if test "x$tmpdir" = "x"; then
 919     if test -d $varprefix/tmp; then
 920         tmpdir=$varprefix/tmp
 921     else
 922         if test -d /var/tmp; then
 923             tmpdir=/var/tmp
 924         else
 925             tmpdir=/tmp
 926         fi
 927     fi
 928 fi
 929 AC_SUBST(tmpdir)
 930
 931 if echo "$build_os" | grep sco > /dev/null; then
 932         echo "hacking things up for sco"
 933         AC_DEFINE(NEED_STRINGS_H)
 934         AC_DEFINE(HAVE_STRUCT_MNTTAB)
 935 elif echo "$build_os" | grep sunos > /dev/null; then
 936         echo "hacking things up for sunos"
 937         CFLAGS="$CFLAGS -D__USE_FIXED_PROTOTYPES__"
 938         AC_DEFINE(NEED_STRINGS_H)
 939         AC_DEFINE(NEED_MYREALLOC)
 940         LIBOBJS="$LIBOBJS myrealloc.o"
 941 fi
 942
 943 #
 944 # get rid of the 4-th tuple, if config.guess returned "linux-gnu" for build_os
 945 #
 946 if echo "$build_os" | grep '.*-gnulibc1' > /dev/null ; then
 947         build_os=`echo "${build_os}" | sed 's/-gnulibc1$//'`
 948 fi
 949 if echo "$build_os" | grep '.*-gnu' > /dev/null ; then
 950         build_os=`echo "${build_os}" | sed 's/-gnu$//'`
 951 fi
 952
 953 changequote(<, >)
 954 build_os_exact="${build_os}"
 955 build_os_major=`echo "${build_os}" | sed 's/\..*$//'`
 956 build_os_noversion=`echo "${build_os}" | sed 's/[0-9]*\..*$//'`
 957 changequote([, ])
 958
 959 rm -f ./find-provides
 960 if test -f ${srcdir}/autodeps/${build_cpu}-${build_os_exact}.prov ; then
 961         echo "using ${srcdir}/autodeps/${build_cpu}-${build_os_exact}.prov for automatic provides generation"
 962     ln -s ${srcdir}/autodeps/${build_cpu}-${build_os_exact}.prov ./find-provides
 963 elif test -f ${srcdir}/autodeps/${build_os_exact}.prov ; then
 964         echo "using ${srcdir}/autodeps/${build_os_exact}.prov for automatic provides generation"
 965     ln -s ${srcdir}/autodeps/${build_os_exact}.prov ./find-provides
 966 elif test -f ${srcdir}/autodeps/${build_os_major}.prov ; then
 967         echo "using ${srcdir}/autodeps/${build_os_major}.prov for automatic provides generation"
 968     ln -s ${srcdir}/autodeps/${build_os_major}.prov ./find-provides
 969 elif test -f ${srcdir}/autodeps/${build_os_noversion}.prov ; then
 970         echo "using ${srcdir}/autodeps/${build_os_noversion}.prov for automatic provides generation"
 971     ln -s ${srcdir}/autodeps/${build_os_noversion}.prov ./find-provides
 972 else
 973     echo "*** no default provides information is available for ${build_os_noversion}"
 974     ln -s ${srcdir}/autodeps/none ./find-provides
 975 fi
 976
 977 rm -f ./find-requires
 978 if test -f ${srcdir}/autodeps/${build_cpu}-${build_os_exact}.req ; then
 979         echo "using ${srcdir}/autodeps/${build_cpu}-${build_os_exact}.req for automatic requires generation"
 980     ln -s ${srcdir}/autodeps/${build_cpu}-${build_os_exact}.req ./find-requires
 981 elif test -f ${srcdir}/autodeps/${build_os_exact}.req ; then
 982         echo "using ${srcdir}/autodeps/${build_os_exact}.req for automatic requires generation"
 983     ln -s ${srcdir}/autodeps/${build_os_exact}.req ./find-requires
 984 elif test -f ${srcdir}/autodeps/${build_os_major}.req ; then
 985         echo "using ${srcdir}/autodeps/${build_os_major}.req for automatic requires generation"
 986     ln -s ${srcdir}/autodeps/${build_os_major}.req ./find-requires
 987 elif test -f ${srcdir}/autodeps/${build_os_noversion}.req ; then
 988         echo "using ${srcdir}/autodeps/${build_os_noversion}.req for automatic requires generation"
 989     ln -s ${srcdir}/autodeps/${build_os_noversion}.req ./find-requires
 990 else
 991     echo "*** no default requires information is available for ${build_os_noversion}"
 992     ln -s ${srcdir}/autodeps/none ./find-requires
 993 fi
 994
 995 dnl Determine the canonical arch-vendor-os for the build machine
 996 case "${build_cpu}" in
 997 *86)            RPMCANONARCH=i386 ;;
 998 alpha*)         RPMCANONARCH=alpha ;;
 999 sparc*)         RPMCANONARCH=sparc ;;
1000 ia64*)          RPMCANONARCH=ia64 ;;
1001 s390*)          RPMCANONARCH=s390 ;;
1002 powerpc*)       RPMCANONARCH=ppc ;;
1003 armv3l*)        RPMCANONARCH=armv3l ;;
1004 armv4l*)        RPMCANONARCH=armv4l ;;
1005 armv4b*)        RPMCANONARCH=armv4b ;;
1006 arm*)           RPMCANONARCH="${build_cpu}" ;;
1007 m68k*)          RPMCANONARCH=m68k ;;
1008 *)              RPMCANONARCH=unknown ;;
1009 esac
1010 case "${build_os_noversion}" in
1011 mint)           RPMCANONARCH=m68kmint ;;
1012 esac
1013 RPMCANONVENDOR="$build_vendor"
1014 case "${build_vendor}" in
1015 unknown|pc|redhat|pld|mandrake|conectiva)
1016         test -f /etc/redhat-release &&          RPMCANONVENDOR=redhat
1017         test -f /etc/pld-release &&             RPMCANONVENDOR=pld
1018         test -f /etc/mandrake-release &&        RPMCANONVENDOR=mandrake
1019         test -f /etc/conectiva-release &&       RPMCANONVENDOR=conectiva
1020         ;;
1021 esac
1022 RPMCANONOS="$build_os_noversion"
1023 AC_SUBST(RPMCANONARCH)
1024 AC_SUBST(RPMCANONVENDOR)
1025 AC_SUBST(RPMCANONOS)
1026
1027 if test -n "$LIBOBJS" ; then
1028     LIBMISC='$(top_builddir)/misc/libmisc.a'
1029 fi
1030 AC_SUBST(LIBOBJS)
1031 AC_SUBST(LIBMISC)
1032
1033 if test X"$prefix" = XNONE ; then
1034     usrprefix="$ac_default_prefix"
1035 else
1036     usrprefix=$prefix
1037 fi
1038 LOCALEDIR="`echo ${usrprefix}/share/locale`"
1039 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR")
1040 AC_SUBST(LOCALEDIR)
1041 LIBDIR="`echo $libdir | sed 's-/lib$-/%{_lib}-'`"
1042 AC_SUBST(LIBDIR)
1043 RPMCONFIGDIR="`echo ${usrprefix}/lib/rpm`"
1044 AC_DEFINE_UNQUOTED(RPMCONFIGDIR, "$RPMCONFIGDIR")
1045 AC_SUBST(RPMCONFIGDIR)
1046
1047 SYSCONFIGDIR="`echo /etc/rpm`"
1048 AC_DEFINE_UNQUOTED(SYSCONFIGDIR, "$SYSCONFIGDIR")
1049 AC_SUBST(SYSCONFIGDIR)
1050
1051 MACROFILES="${RPMCONFIGDIR}/macros:${RPMCONFIGDIR}/%{_target_platform}/macros:${SYSCONFIGDIR}/macros:${SYSCONFIGDIR}/macros.specspo:${SYSCONFIGDIR}/macros.db1:${SYSCONFIGDIR}/%{_target_platform}/macros:~/.rpmmacros"
1052 AC_DEFINE_UNQUOTED(MACROFILES, "$MACROFILES")
1053 AC_SUBST(MACROFILES)
1054
1055 LIBRPMRC_FILENAME="${RPMCONFIGDIR}/rpmrc"
1056 AC_DEFINE_UNQUOTED(LIBRPMRC_FILENAME, "$LIBRPMRC_FILENAME")
1057 AC_SUBST(LIBRPMRC_FILENAME)
1058
1059 LIBRPMALIAS_FILENAME="${RPMCONFIGDIR}/rpmpopt-${VERSION}"
1060 AC_DEFINE_UNQUOTED(LIBRPMALIAS_FILENAME, "$LIBRPMALIAS_FILENAME")
1061 AC_SUBST(LIBRPMALIAS_FILENAME)
1062 FINDREQUIRES="${RPMCONFIGDIR}/find-requires"
1063 AC_DEFINE_UNQUOTED(FINDREQUIRES, "$FINDREQUIRES")
1064 AC_SUBST(FINDREQUIRES)
1065 FINDPROVIDES="${RPMCONFIGDIR}/find-provides"
1066 AC_DEFINE_UNQUOTED(FINDPROVIDES, "$FINDPROVIDES")
1067 AC_SUBST(FINDPROVIDES)
1068
1069 testdir="`pwd`/tests"
1070 dnl AC_DEFINE_UNQUOTED(testdir, "$testdir")
1071 AC_SUBST(testdir)
1072
1073 if test -n "$LIBOBJS"; then
1074     INCPATH="-I\$(top_builddir)/misc $INCPATH"
1075 fi
1076 AC_SUBST(INCPATH)
1077
1078 AC_SUBST(LIBS)
1079
1080 AC_SUBST(RPM)
1081
1082 AC_SUBST(OBJDUMP)
1083
1084 dnl XXX this causes popt to depend on zlib et al
1085 dnl # XXX Propagate -lucb to popt ...
1086 dnl export LIBS INCPATH CONFIG_SITE
1087
1088 AC_CONFIG_SUBDIRS(popt $WITH_DB_SUBDIR)
1089
1090 AC_OUTPUT([ Doxyfile Makefile rpmrc macros platform rpmpopt rpm.spec
1091         rpmio/Makefile rpmdb/Makefile lib/Makefile build/Makefile
1092         scripts/Makefile scripts/brp-redhat tools/Makefile
1093         tests/Makefile tests/rpmrc tests/macros tests/hello-test/Makefile
1094         misc/Makefile po/Makefile.in intl/Makefile
1095         doc/Makefile doc/manual/Makefile
1096         doc/ja/Makefile doc/pl/Makefile doc/ru/Makefile doc/sk/Makefile
1097         python/Makefile perl/Makefile perl/Makefile.PL ],
1098   [     echo timestamp > popt/stamp-h.in
1099         echo timestamp > stamp-h.in
1100   ]
1101 )