configure.in

   1 AC_INIT(src/enchant.h)
   2 AC_CANONICAL_HOST
   3
   4 dnl Set release number
   5 dnl This is derived from "Versioning" chapter of info libtool documentation.
   6 PACKAGE=enchant
   7 dnl     4a) Increment when removing or changing interfaces.
   8 ENCHANT_MAJOR_VERSION=1
   9 dnl     4a) 5) Increment when adding interfaces.
  10 dnl     6) Set to zero when removing or changing interfaces.
  11 ENCHANT_MINOR_VERSION=6
  12 dnl     3) Increment when interfaces not changed at all,
  13 dnl               only bug fixes or internal changes made.
  14 dnl     4b) Set to zero when adding, removing or changing interfaces.
  15 ENCHANT_MICRO_VERSION=1
  16 dnl
  17 dnl     Set this too
  18 MAJOR_VERSION_PLUS_MINOR_VERSION=`expr $ENCHANT_MAJOR_VERSION + $ENCHANT_MINOR_VERSION`
  19 dnl
  20 VERSION=$ENCHANT_MAJOR_VERSION.$ENCHANT_MINOR_VERSION.$ENCHANT_MICRO_VERSION
  21 dnl Version info for libraries = CURRENT:REVISION:AGE
  22 VERSION_INFO=$MAJOR_VERSION_PLUS_MINOR_VERSION:$ENCHANT_MICRO_VERSION:$ENCHANT_MINOR_VERSION
  23 AC_SUBST(VERSION_INFO)
  24 AC_SUBST(ENCHANT_MAJOR_VERSION)
  25 AC_SUBST(ENCHANT_MINOR_VERSION)
  26 AC_SUBST(ENCHANT_MICRO_VERSION)
  27
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  29 AM_MAINTAINER_MODE
  30
  31 dnl Checks for programs.
  32 AC_ISC_POSIX
  33 AC_PROG_CC
  34 AC_PROG_CPP
  35 AC_PROG_OBJC
  36 AC_PROG_INSTALL
  37 AC_PROG_LN_S
  38 AC_PROG_MAKE_SET
  39 AC_STDC_HEADERS
  40 AC_LIBTOOL_WIN32_DLL
  41 AM_PROG_LIBTOOL
  42 gt_TYPE_SSIZE_T
  43
  44 AC_C_CONST
  45
  46 AC_CHECK_FUNCS(flock lockf)
  47
  48 have_cxx=yes
  49 AC_PROG_CXX(,have_cxx=no)
  50 AM_CONDITIONAL(WITH_CXX, test "x$have_cxx" = "xyes")
  51
  52 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  53
  54 PKG_CHECK_MODULES(ENCHANT, [glib-2.0 >= 2.6 gmodule-2.0])
  55
  56 dnl ===========================================================================
  57 dnl check compiler flags
  58 AC_DEFUN([ENCHANT_CC_TRY_FLAG], [
  59   AC_MSG_CHECKING([whether $CC supports $1])
  60
  61   enchant_save_CFLAGS="$CFLAGS"
  62   CFLAGS="$CFLAGS $1"
  63
  64   AC_COMPILE_IFELSE([ ], [enchant_cc_flag=yes], [enchant_cc_flag=no])
  65   CFLAGS="$enchant_save_CFLAGS"
  66
  67   if test "x$enchant_cc_flag" = "xyes"; then
  68     ifelse([$2], , :, [$2])
  69   else
  70     ifelse([$3], , :, [$3])
  71   fi
  72   AC_MSG_RESULT([$enchant_cc_flag])
  73 ])
  74
  75 dnl check compiler flags
  76 AC_DEFUN([ENCHANT_CXX_TRY_FLAG], [
  77   AC_MSG_CHECKING([whether $CXX supports $1])
  78
  79   AC_LANG_PUSH(C++)
  80   enchant_save_CXXFLAGS="$CXXFLAGS"
  81   CXXFLAGS="$CXXFLAGS $1"
  82
  83   AC_COMPILE_IFELSE([ ], [enchant_cxx_flag=yes], [enchant_cxx_flag=no])
  84   CXXFLAGS="$enchant_save_CXXFLAGS"
  85
  86   if test "x$enchant_cxx_flag" = "xyes"; then
  87     ifelse([$2], , :, [$2])
  88   else
  89     ifelse([$3], , :, [$3])
  90   fi
  91   AC_MSG_RESULT([$enchant_cxx_flag])
  92   AC_LANG_POP(C++)
  93 ])
  94
  95 dnl Use lots of warning flags with gcc and compatible compilers
  96
  97 dnl Note: if you change the following variable, the cache is automatically
  98 dnl skipped and all flags rechecked.  So there's no need to do anything
  99 dnl else.  If for any reason you need to force a recheck, just change
 100 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 101
 102 CC_MAYBE_WARN="-Wall -Wextra \
 103 -Wsign-compare -Werror-implicit-function-declaration \
 104 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 105 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 106 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 107 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
 108 -Wdeclaration-after-statement -Wold-style-definition \
 109 -Wno-missing-field-initializers -Wno-unused-parameter \
 110 -Wno-attributes -Wno-long-long -Winline -fno-strict-aliasing"
 111
 112 # invalidate cached value if MAYBE_WARN has changed
 113 if test "x$enchant_cv_warn_maybe" != "x$CC_MAYBE_WARN"; then
 114         unset enchant_cv_warn_cflags
 115 fi
 116 AC_CACHE_CHECK([for supported C warning flags], enchant_cv_warn_cflags, [
 117         echo
 118         CC_WARN_CFLAGS=""
 119
 120         # Some warning options are not supported by all versions of
 121         # gcc, so test all desired options against the current
 122         # compiler.
 123         #
 124         # Note that there are some order dependencies
 125         # here. Specifically, an option that disables a warning will
 126         # have no net effect if a later option then enables that
 127         # warnings, (perhaps implicitly). So we put some grouped
 128         # options (-Wall and -Wextra) up front and the -Wno options
 129         # last.
 130
 131         for W in $CC_MAYBE_WARN; do
 132                 ENCHANT_CC_TRY_FLAG([$W], [CC_WARN_CFLAGS="$CC_WARN_CFLAGS $W"])
 133         done
 134
 135         enchant_cv_warn_cflags=$CC_WARN_CFLAGS
 136         enchant_cv_warn_maybe=$CC_MAYBE_WARN
 137
 138         AC_MSG_CHECKING([which C warning flags were supported])])
 139 CC_WARN_CFLAGS="$enchant_cv_warn_cflags"
 140 AC_SUBST(CC_WARN_CFLAGS)
 141
 142 CXX_MAYBE_WARN="-Wall -Wextra \
 143 -Wsign-compare \
 144 -Wpointer-arith -Wwrite-strings \
 145 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 146 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
 147 -Wno-missing-field-initializers -Wno-unused-parameter \
 148 -Wno-attributes -Wno-long-long -Winline -fno-strict-aliasing"
 149
 150 # invalidate cached value if MAYBE_WARN has changed
 151 if test "x$enchant_cxx_cv_warn_maybe" != "x$CXX_MAYBE_WARN"; then
 152         unset enchant_cxx_cv_warn_cflags
 153 fi
 154 AC_CACHE_CHECK([for supported C++ warning flags], enchant_cxx_cv_warn_cflags, [
 155         echo
 156         CXX_WARN_CFLAGS=""
 157
 158         # Some warning options are not supported by all versions of
 159         # gcc, so test all desired options against the current
 160         # compiler.
 161         #
 162         # Note that there are some order dependencies
 163         # here. Specifically, an option that disables a warning will
 164         # have no net effect if a later option then enables that
 165         # warnings, (perhaps implicitly). So we put some grouped
 166         # options (-Wall and -Wextra) up front and the -Wno options
 167         # last.
 168
 169         for W in $CXX_MAYBE_WARN; do
 170                 ENCHANT_CXX_TRY_FLAG([$W], [CXX_WARN_CFLAGS="$CXX_WARN_CFLAGS $W"])
 171         done
 172
 173         enchant_cxx_cv_warn_cflags=$CXX_WARN_CFLAGS
 174         enchant_cxx_cv_warn_maybe=$CXX_MAYBE_WARN
 175
 176         AC_MSG_CHECKING([which C++ warning flags were supported])])
 177 CXX_WARN_CFLAGS="$enchant_cxx_cv_warn_cflags"
 178 AC_SUBST(CXX_WARN_CFLAGS)
 179
 180 ENCHANT_CFLAGS="$ENCHANT_CFLAGS -DENCHANT_PREFIX_DIR='\"$prefix\"'"
 181
 182 AC_SUBST(ENCHANT_CFLAGS)
 183 AC_SUBST(ENCHANT_LIBS)
 184
 185 AC_MSG_CHECKING([for native Win32])
 186 case "$target" in
 187   *-*-mingw*)
 188     native_win32=yes
 189     SOCKET_LIBS='-lws2_32 -ldnsapi'
 190     ENCHANT_WIN32_RESOURCE=enchant-win32res.lo
 191     ;;
 192   *)
 193     native_win32=no
 194     SOCKET_LIBS=''
 195     ENCHANT_WIN32_RESOURCE=
 196     ;;
 197 esac
 198 AC_MSG_RESULT([$native_win32])
 199 AM_CONDITIONAL(OS_WIN32, test "x$native_win32" = "xyes")
 200 AC_SUBST([ENCHANT_WIN32_RESOURCE])
 201
 202 AC_MSG_CHECKING([for OS X])
 203 case ${host_os} in
 204     *darwin*)
 205     check_applespell=yes
 206     ;;
 207     *)
 208     check_applespell=no
 209     ;;
 210 esac
 211 AC_MSG_RESULT([$check_applespell])
 212
 213 AC_SUBST(SOCKET_LIBS)
 214
 215 # Courtesy of Glib: Ensure MSVC-compatible struct packing convention
 216 # is used when compiling for Win32 with gcc.
 217 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 218 # gcc2 uses "-fnative-struct".
 219 if test x"$native_win32" = xyes; then
 220   if test x"$GCC" = xyes; then
 221     msnative_struct=''
 222     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 223     if test -z "$ac_cv_prog_CC"; then
 224       our_gcc="$CC"
 225     else
 226       our_gcc="$ac_cv_prog_CC"
 227     fi
 228     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 229       2.)
 230         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 231           msnative_struct='-fnative-struct'
 232         fi
 233         ;;
 234       *)
 235         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 236           msnative_struct='-mms-bitfields'
 237         fi
 238         ;;
 239     esac
 240     if test x"$msnative_struct" = x ; then
 241       AC_MSG_RESULT([no way])
 242       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 243     else
 244       CFLAGS="$CFLAGS $msnative_struct"
 245       CXXFLAGS="$CXXFLAGS $msnative_struct"
 246       AC_MSG_RESULT([${msnative_struct}])
 247     fi
 248   fi
 249 fi
 250
 251 dnl ===========================================================================
 252
 253 m4_copy([AC_DEFUN],[glib_DEFUN])
 254 glib_DEFUN([GLIB_LC_MESSAGES],
 255   [AC_CHECK_HEADERS([locale.h])
 256     if test $ac_cv_header_locale_h = yes; then
 257     AC_CACHE_CHECK([for LC_MESSAGES], am_cv_val_LC_MESSAGES,
 258       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
 259        am_cv_val_LC_MESSAGES=yes, am_cv_val_LC_MESSAGES=no)])
 260     if test $am_cv_val_LC_MESSAGES = yes; then
 261       AC_DEFINE(HAVE_LC_MESSAGES, 1,
 262         [Define if your <locale.h> file defines LC_MESSAGES.])
 263     fi
 264   fi])
 265
 266 GLIB_LC_MESSAGES
 267
 268 dnl ===========================================================================
 269
 270 dnl binreloc
 271 dnl AM_BINRELOC
 272 AM_CONDITIONAL(WITH_BINRELOC, test "x$br_cv_binreloc" = "xyes")
 273
 274 build_ispell=yes
 275
 276 AC_ARG_ENABLE(ispell, AS_HELP_STRING([--disable-ispell],[enable the ispell backend @<:@default=auto@:>@]), build_ispell="$enableval", build_ispell=yes)
 277
 278 if test "x$have_cxx" = "xno"; then
 279    build_ispell=no
 280 fi
 281 AM_CONDITIONAL(WITH_ISPELL, test "x$build_ispell" = "xyes")
 282
 283 ispell_dir=${datadir}/enchant/ispell
 284 AC_ARG_WITH(ispell-dir, AS_HELP_STRING([--with-ispell-dir=PATH],[path to installed ispell dicts]))
 285
 286 if test "x$with_ispell_dir" != "x" ; then
 287    ispell_dir=$with_ispell_dir
 288 fi
 289
 290 ISPELL_CFLAGS="-DENCHANT_ISPELL_DICT_DIR='\"$ispell_dir\"'"
 291 AC_SUBST(ISPELL_CFLAGS)
 292
 293 build_myspell=yes
 294
 295 AC_ARG_ENABLE(myspell, AS_HELP_STRING([--disable-myspell],[enable the myspell backend @<:@default=auto@:>@]), build_myspell="$enableval", build_myspell=yes)
 296
 297 if test "x$have_cxx" = "xno"; then
 298    build_myspell=no
 299 fi
 300 AM_CONDITIONAL(WITH_MYSPELL, test "x$build_myspell" = "xyes")
 301
 302 myspell_dir=${datadir}/myspell/dicts
 303 AC_ARG_WITH(myspell-dir, AS_HELP_STRING([--with-myspell-dir=PATH],[path to installed myspell dicts]))
 304
 305 if test "x$with_myspell_dir" != "x" ; then
 306    myspell_dir=$with_myspell_dir
 307 fi
 308
 309 MYSPELL_CFLAGS="$MYSPELL_CFLAGS -DENCHANT_MYSPELL_DICT_DIR='\"$myspell_dir\"'"
 310
 311 AC_ARG_WITH(system-myspell, AS_HELP_STRING([--with-system-myspell=yes/no],[use the system myspell/hunspell @<:@default=auto@:>@]))
 312 if test "x$with_system_myspell" != "xno"; then
 313         PKG_CHECK_MODULES(MYSPELL, [hunspell], have_system_myspell=true, have_system_myspell=false)
 314         AC_SUBST(MYSPELL_CFLAGS)
 315         AC_SUBST(MYSPELL_LIBS)
 316 else
 317         have_system_myspell=false;
 318 fi
 319 AM_CONDITIONAL(WITH_SYSTEM_MYSPELL, test "x$have_system_myspell" = "xtrue")
 320
 321 check_aspell=yes
 322 build_aspell=no
 323
 324 AC_ARG_ENABLE(aspell, AS_HELP_STRING([--disable-aspell],[enable the aspell backend @<:@default=auto@:>@]), check_aspell="$enableval", check_aspell=yes)
 325
 326 AC_ARG_WITH(aspell-prefix, AS_HELP_STRING([--with-aspell-prefix=DIR],[specify under which prefix aspell is installed]), aspell_prefix="$withval", )
 327
 328 if test "x$check_aspell" != "xno"; then
 329    saved_LDFLAGS=$LDFLAGS
 330
 331    ASPELL_CFLAGS=
 332    if test "x$aspell_prefix" != "x"; then
 333        LDFLAGS="-L$aspell_prefix/lib "$LDFLAGS
 334        ASPELL_INC="-I$aspell_prefix/include"
 335        ASPELL_LIBS="-L$aspell_prefix/lib -laspell"
 336    else
 337        aspell_prefix=${prefix}
 338        if test "x$prefix" = "xNONE"; then
 339           aspell_prefix="/usr/local"
 340        fi
 341
 342        AC_CHECK_PROG(HAVE_ASPELL, aspell, yes, no)
 343        if test "x$HAVE_ASPELL" = "xyes"; then
 344           AC_MSG_CHECKING([For Aspell >= 0.50.0])
 345           aspell_major=`aspell -v | awk -F. '{print $4;}' | awk -F")" '{print $1;}'`
 346           if test "$aspell_major" -ge "50"; then
 347               aspell_prefix=`aspell config prefix`
 348               LDFLAGS="-L${aspell_prefix}/lib "$LDFLAGS
 349               ASPELL_INC="-I${aspell_prefix}/include"
 350               ASPELL_LIBS="-L${aspell_prefix}/lib -laspell"
 351               AC_MSG_RESULT([yes])
 352           else
 353               AC_MSG_RESULT([unknown])
 354           fi
 355       fi
 356
 357       if test "x$HAVE_ASPELL" != "xyes"; then
 358               AC_MSG_WARN([Didn't find aspell >= 0.50.0 and no explicit path aspell specified. Guessing at $aspell_prefix])
 359               ASPELL_LIBS="-L$aspell_prefix/lib -laspell"
 360       fi
 361    fi
 362
 363    AC_MSG_CHECKING([For aspell headers in $aspell_prefix/include])
 364    if test -f "$aspell_prefix/include/pspell/pspell.h"; then
 365        AC_MSG_RESULT([yes (pspell)])
 366
 367        AC_CHECK_LIB(aspell,new_aspell_config,build_aspell=yes,
 368           [AC_CHECK_LIB(pspell, new_pspell_config, build_aspell=yes, AC_MSG_WARN([Enchant building without the aspell library]))]
 369          ,)
 370        AC_CHECK_LIB(aspell,get_aspell_dict_info_list,ASPELL_CFLAGS="-DASPELL_0_50_0=1",)
 371
 372        ASPELL_CFLAGS+=" -DHAVE_PSPELL_H"
 373    elif test -f "$aspell_prefix/include/aspell.h"; then
 374        AC_MSG_RESULT([yes (aspell)])
 375
 376        AC_CHECK_LIB(aspell,new_aspell_config,build_aspell=yes,
 377           [AC_CHECK_LIB(pspell, new_pspell_config, build_aspell=yes, AC_MSG_WARN([Enchant building without the aspell library]))]
 378          ,)
 379        AC_CHECK_LIB(aspell,get_aspell_dict_info_list,ASPELL_CFLAGS="-DASPELL_0_50_0=1",)
 380    else
 381        AC_MSG_RESULT([no])
 382        if test "x$HAVE_ASPELL" = "xyes"; then
 383            AC_MSG_WARN([Didn't find pspell (aspell) headers])
 384        fi
 385    fi
 386    LDFLAGS=$saved_LDFLAGS
 387
 388    AC_SUBST(ASPELL_INC)
 389    AC_SUBST(ASPELL_LIBS)
 390    AC_SUBST(ASPELL_CFLAGS)
 391 fi
 392
 393 AM_CONDITIONAL(WITH_ASPELL, test "$build_aspell" = yes)
 394
 395 check_voikko=yes
 396 build_voikko=no
 397
 398 AC_ARG_ENABLE(voikko, AS_HELP_STRING([--disable-voikko],[enable the voikko backend @<:@default=auto@:>@]), check_voikko="$enableval", check_voikko=yes)
 399
 400 AC_ARG_WITH(voikko-prefix, AS_HELP_STRING([--with-voikko-prefix=DIR],[specify under which prefix voikko is installed]), voikko_prefix="$withval", )
 401
 402 if test "x$check_voikko" != "xno"; then
 403    saved_LDFLAGS=$LDFLAGS
 404
 405    VOIKKO_INC=
 406    VOIKKO_LIBS="-lvoikko"
 407    if test "x$voikko_prefix" != "x"; then
 408        LDFLAGS="-L$voikko_prefix/lib "$LDFLAGS
 409        VOIKKO_INC="-I$voikko_prefix/include"
 410        VOIKKO_LIBS="-L$voikko_prefix/lib "$VOIKKO_LIBS
 411    fi
 412
 413    AC_CHECK_LIB(voikko,voikko_init,build_voikko=yes)
 414
 415    LDFLAGS=$saved_LDFLAGS
 416
 417    AC_SUBST(VOIKKO_INC)
 418    AC_SUBST(VOIKKO_LIBS)
 419 fi
 420
 421 AM_CONDITIONAL(WITH_VOIKKO, test "$build_voikko" = yes)
 422
 423 build_uspell=no
 424
 425 check_uspell=yes
 426 AC_ARG_ENABLE(uspell, AS_HELP_STRING([--disable-uspell],[enable the uspell backend @<:@default=auto@:>@]), check_uspell="$enableval", check_uspell=yes)
 427
 428 if test "x$have_cxx" = "xno"; then
 429    check_uspell=no
 430 fi
 431
 432 if test "x$check_uspell" != "xno"; then
 433    PKG_CHECK_MODULES(USPELL, [libuspell >= 1.1.0], build_uspell=yes, build_uspell=no)
 434 fi
 435
 436 uspell_dir=${datadir}/uspell
 437 AC_ARG_WITH(uspell-dir, AS_HELP_STRING([--with-uspell-dir=PATH],[path to installed uspell dicts]))
 438
 439 if test "x$with_uspell_dir" != "x" ; then
 440    uspell_dir=$with_uspell_dir
 441 fi
 442
 443 USPELL_CFLAGS="$USPELL_CFLAGS -DENCHANT_USPELL_DICT_DIR='\"$uspell_dir\"'"
 444 AC_SUBST(USPELL_CFLAGS)
 445 AC_SUBST(USPELL_LIBS)
 446
 447 AM_CONDITIONAL(WITH_USPELL, test "$build_uspell" = yes)
 448
 449 build_hspell=no
 450 check_hspell=yes
 451 AC_ARG_ENABLE(hspell, AS_HELP_STRING([--disable-hspell],[enable the hspell backend @<:@default=auto@:>@]), check_hspell="$enableval", check_hspell=yes)
 452
 453 AC_ARG_WITH(hspell-prefix, AS_HELP_STRING([--with-hspell-prefix=DIR],[specify under which prefix hspell is installed]), hspell_prefix="$withval", )
 454
 455 dnl change to pkg-config when hspell provides a hspell.pc file
 456
 457 if test "x$check_hspell" != "xno"; then
 458    saved_LDFLAGS=$LDFLAGS
 459
 460    HSPELL_CFLAGS=
 461    HSPELL_LIBS=" -lhspell -lz"
 462
 463    if test "x$hspell_prefix" != "x"; then
 464        LDFLAGS="-L$hspell_prefix/lib "$LDFLAGS
 465        HSPELL_CFLAGS="-I$hspell_prefix/include"
 466        HSPELL_LIBS="-L$hspell_prefix/lib "$HSPELL_LIBS
 467    fi
 468
 469    AC_CHECK_LIB(hspell, hspell_get_dictionary_path, build_hspell=yes, build_hspell=no, -lz)
 470    LDFLAGS=$saved_LDFLAGS
 471
 472    AC_SUBST(HSPELL_CFLAGS)
 473    AC_SUBST(HSPELL_LIBS)
 474 fi
 475
 476 AM_CONDITIONAL(WITH_HSPELL, test "$build_hspell" = yes)
 477
 478 build_zemberek=no
 479
 480 AC_ARG_ENABLE(zemberek, AS_HELP_STRING([--disable-zemberek],[enable the experimental zemberek (turkish) backend @<:@default=auto@:>@]), build_zemberek="$enableval", build_zemberek=no)
 481
 482 if test "x$have_cxx" = "xno"; then
 483    build_zemberek=no
 484 fi
 485 AC_MSG_CHECKING([For DBus-Glib >= 0.62])
 486 if pkg-config --atleast-version=0.62 dbus-glib-1; then
 487         ZEMBEREK_CFLAGS=`pkg-config --cflags dbus-glib-1`
 488         ZEMBEREK_LIBS=`pkg-config --libs dbus-glib-1`
 489 else
 490         build_zemberek=no
 491 fi
 492
 493 AC_SUBST(ZEMBEREK_CFLAGS)
 494 AC_SUBST(ZEMBEREK_LIBS)
 495
 496 AM_CONDITIONAL(WITH_ZEMBEREK, test "x$build_zemberek" = "xyes")
 497
 498 zemberek_dir=${datadir}/enchant/zemberek
 499
 500 APPLESPELL_CFLAGS=""
 501 APPLESPELL_LIBS=""
 502 APPLESPELL_LDFLAGS=""
 503
 504 build_applespell=no
 505 if test "x$check_applespell" = "xyes"; then
 506
 507     AC_ARG_ENABLE(applespell, AS_HELP_STRING([--disable-applespell],[enable the applespell backend @<:@default=no@:>@]), build_applespell="$enableval", build_applespell=no)
 508
 509     if test "x$build_applespell" != "xno"; then
 510         APPLESPELL_CFLAGS+=" -DXP_TARGET_COCOA -xobjective-c"
 511         APPLESPELL_LIBS+=" -lobjc"
 512         APPLESPELL_LDFLAGS+=" -framework Cocoa"
 513     fi
 514
 515 fi
 516
 517 AC_SUBST(APPLESPELL_CFLAGS)
 518 AC_SUBST(APPLESPELL_LIBS)
 519 AC_SUBST(APPLESPELL_LDFLAGS)
 520
 521 AM_CONDITIONAL(WITH_APPLESPELL, test "x$build_applespell" = "xyes")
 522
 523 dnl =======================================================================================
 524
 525 AC_OUTPUT([
 526 Makefile
 527 enchant.pc
 528 enchant-uninstalled.pc
 529 enchant.spec
 530 src/libenchant.rc
 531 src/Makefile
 532 src/aspell/Makefile
 533 src/ispell/Makefile
 534 src/uspell/Makefile
 535 src/myspell/Makefile
 536 src/hspell/Makefile
 537 src/applespell/Makefile
 538 src/voikko/Makefile
 539 src/zemberek/Makefile
 540 tests/Makefile
 541 tests/ispell
 542 doc/Makefile
 543 data/Makefile
 544 autopackage/default.apspec
 545 ])
 546
 547 dnl ===========================================================================================
 548
 549 relocatable_library="no"
 550 if test "x$native_win32" = "xyes" || test "x$br_cv_binreloc" = "xyes"; then
 551    relocatable_library="yes"
 552 fi
 553
 554 echo "
 555 $PACKAGE-$VERSION
 556
 557     prefix:                                 ${prefix}
 558     compiler:                               ${CC}
 559
 560     Build Aspell backend:                   ${build_aspell}
 561     Build Ispell backend:                   ${build_ispell}
 562     Build Uspell backend:                   ${build_uspell}
 563     Build Hspell backend:                   ${build_hspell}
 564     Build Myspell/Hunspell backend:         ${build_myspell}
 565     Build Voikko backend (Linux only):      ${build_voikko}
 566     Build Zemberek backend:                 ${build_zemberek}
 567     Build Apple Spell backend (OS X only):  ${build_applespell}
 568     Build a relocatable library:            ${relocatable_library}"
 569
 570 if test "x$build_zemberek" = "xyes"; then
 571    echo "
 572 The Zemberek Turkish spell-checking plugin is enabled. It is known
 573 to cause crashes with WebKit. Use at your own discretion."
 574 fi