configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81
  82 dnl Generic infrastructure for drop-in additions to libc.
  83 AC_ARG_ENABLE(add-ons, dnl
  84 [  --enable-add-ons=DIR... configure and build named extra directories],
  85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  86               [add_ons=])
  87 AC_CONFIG_SUBDIRS($add_ons)
  88 add_ons_pfx=
  89 if test x"$add_ons" != x; then
  90   for f in $add_ons; do
  91     add_ons_pfx="$add_ons_pfx $f/"
  92   done
  93 fi
  94
  95 AC_CANONICAL_HOST
  96
  97 # The way shlib-versions is used to generate soversions.mk uses a
  98 # fairly simplistic model for name recognition that can't distinguish
  99 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 100 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 101 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 102 case "$host_os" in
 103 linux*)
 104   ;;
 105 gnu*)
 106   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 107   ;;
 108 esac
 109
 110 # We keep the original values in `$config_*' and never modify them, so we
 111 # can write them unchanged into config.make.  Everything else uses
 112 # $machine, $vendor, and $os, and changes them whenever convenient.
 113 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 114
 115 # Some configurations imply other options.
 116 case "$host_os" in
 117 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 118   # These systems always use GNU tools.
 119   gnu_ld=yes gnu_as=yes ;;
 120 esac
 121 case "$host_os" in
 122 linux*ecoff*)
 123   ;;
 124 gnu* | linux* | sysv4* | solaris2*)
 125   # These systems (almost) always use the ELF format.
 126   elf=yes
 127   ;;
 128 esac
 129
 130 machine=$config_machine
 131 vendor=$config_vendor
 132 os=$config_os
 133
 134 dnl We need to use [ and ] for other purposes for a while now.
 135 changequote(,)dnl
 136 # Expand the configuration machine name into a subdirectory by architecture
 137 # type and particular chip.
 138 case "$machine" in
 139 a29k | am29000) base_machine=a29k machine=a29k ;;
 140 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 141 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 142 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 143 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 144 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 145 m88???)         base_machine=m88k machine=m88k/$machine ;;
 146 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 147 mips*)          base_machine=mips machine=mips/$machine ;;
 148 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 149 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 150 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 151 esac
 152 changequote([,])dnl
 153 AC_SUBST(base_machine)
 154
 155 # Compute the list of sysdep directories for this configuration.
 156 # This can take a while to compute.
 157 sysdep_dir=$srcdir/sysdeps
 158 AC_MSG_CHECKING(sysdep dirs)
 159 dnl We need to use [ and ] for other purposes for a while now.
 160 changequote(,)dnl
 161 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 162 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 163
 164 case "$os" in
 165 gnu*)
 166   base_os=mach/hurd ;;
 167 netbsd* | 386bsd* | freebsd* | bsdi*)
 168   base_os=unix/bsd/bsd4.4 ;;
 169 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 170   base_os=unix/bsd ;;
 171 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 172   base_os=unix/sysv ;;
 173 solaris[2-9]*)
 174   base_os=unix/sysv/sysv4 ;;
 175 none)
 176   base_os=standalone ;;
 177 *)
 178   base_os='' ;;
 179 esac
 180
 181 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 182 tail=$os
 183 ostry=$os
 184 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 185   ostry="$ostry /$o"
 186   tail=$o
 187 done
 188 o=`echo $tail | sed 's/[0-9]*$//'`
 189 if test $o != $tail; then
 190   ostry="$ostry /$o"
 191 fi
 192 # For linux-gnu, try linux-gnu, then linux.
 193 o=`echo $tail | sed 's/-.*$//'`
 194 if test $o != $tail; then
 195   ostry="$ostry /$o"
 196 fi
 197
 198 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 199 base=
 200 tail=$base_os
 201 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 202   set $b
 203   base="$base /$1"
 204   tail="$2"
 205 done
 206
 207 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 208 mach=
 209 tail=$machine
 210 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 211   set $m
 212   # Prepend the machine's FPU directory unless --without-fp.
 213   if test "$with_fp" = yes; then
 214     mach="$mach /$1/fpu"
 215   fi
 216   mach="$mach /$1"
 217   tail="$2"
 218 done
 219
 220 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 221 changequote([,])dnl
 222
 223 # Find what sysdep directories exist.
 224 sysnames=
 225 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 226 for d in $add_ons_pfx ''; do
 227   for b in $base ''; do
 228     for m0 in $mach ''; do
 229       for v in /$vendor ''; do
 230         for o in /$ostry ''; do
 231           for m in $mach ''; do
 232             if test "$m0$b$v$o$m"; then
 233               try="${d}sysdeps$m0$b$v$o$m"
 234               test -n "$enable_debug_configure" &&
 235               echo "$0 [DEBUG]: try $try" >&2
 236               case $try in
 237                 /*) dest=$try ;;
 238                 *)  dest=$srcdir/$try ;;
 239               esac
 240               if test -d $dest; then
 241                 sysnames="$sysnames $try"
 242                 { test -n "$o" || test -n "$b"; } && os_used=t
 243                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 244               fi
 245             fi
 246           done
 247         done
 248       done
 249     done
 250   done
 251 done
 252 IFS="$ac_save_ifs"
 253
 254 if test -z "$os_used" && test "$os" != none; then
 255   AC_MSG_ERROR(Operating system $os is not supported.)
 256 fi
 257 if test -z "$machine_used" && test "$machine" != none; then
 258   AC_MSG_ERROR(The $machine is not supported.)
 259 fi
 260
 261 # We have now validated the configuration.
 262
 263
 264 # If using ELF, look for an `elf' subdirectory of each machine directory.
 265 # We prepend these rather than inserting them whereever the machine appears
 266 # because things specified by the machine's ELF ABI should override
 267 # OS-specific things, and should always be the same for any OS on the
 268 # machine (otherwise what's the point of an ABI?).
 269 if test "$elf" = yes; then
 270   elf_dirs=
 271   for d in $add_ons_pfx ''; do
 272     case $d in
 273       /*) xsrcdir= ;;
 274       *)  xsrcdir=$srcdir/ ;;
 275     esac
 276     for m in $mach; do
 277       if test -d $xsrcdir${d}sysdeps$m/elf; then
 278         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 279       fi
 280     done
 281   done
 282   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 283 fi
 284
 285
 286 # Expand the list of system names into a full list of directories
 287 # from each element's parent name and Implies file (if present).
 288 set $sysnames
 289 names=
 290 while test $# -gt 0; do
 291   name=$1
 292   shift
 293
 294   case " $names " in *" $name "*)
 295     # Already in the list.
 296     continue
 297   esac
 298
 299   # Report each name as we discover it, so there is no long pause in output.
 300   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 301
 302   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 303
 304   case $name in
 305     /*) xsrcdir= ;;
 306     *)  xsrcdir=$srcdir/ ;;
 307   esac
 308   test -n "$enable_debug_configure" &&
 309   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 310
 311   if test -f $xsrcdir$name/Implies; then
 312     # Collect more names from the `Implies' file (removing comments).
 313     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 314     implied=
 315     for x in $implied_candidate; do
 316       if test -d $xsrcdir$name_base/$x; then
 317         implied="$implied $name_base/$x";
 318       else
 319         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 320       fi
 321     done
 322   else
 323     implied=
 324   fi
 325
 326   # Add NAME to the list of names.
 327   names="$names $name"
 328
 329   # Find the parent of NAME, using the empty string if it has none.
 330 changequote(,)dnl
 331   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 332 changequote([,])dnl
 333
 334   # Add the names implied by NAME, and NAME's parent (if it has one), to
 335   # the list of names to be processed (the argument list).  We prepend the
 336   # implied names to the list and append the parent.  We want implied
 337   # directories to come before further directories inferred from the
 338   # configuration components; this ensures that for sysv4, unix/common
 339   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 340   # after sysv4).
 341   sysnames="`echo $implied $* $parent`"
 342   test -n "$sysnames" && set $sysnames
 343 done
 344
 345 # Add the default directories.
 346 sysnames="$names sysdeps/generic sysdeps/stub"
 347 AC_SUBST(sysnames)
 348 # The other names were emitted during the scan.
 349 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 350
 351
 352 ### Locate tools.
 353
 354 AC_PROG_INSTALL
 355 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 356   # The makefiles need to use a different form to find it in $srcdir.
 357   INSTALL='$(..)./install-sh -c'
 358 fi
 359 AC_PROG_LN_S
 360 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 361
 362 AC_CHECK_TOOL(CC, gcc)
 363 if test $host != $build; then
 364   AC_CHECK_PROG(BUILD_CC, gcc cc)
 365 fi
 366 AC_PROG_CPP
 367 AC_CHECK_TOOL(AR, ar)
 368 AC_CHECK_TOOL(RANLIB, ranlib, :)
 369
 370 AC_PATH_PROG(BASH, bash, no)
 371 if test "$BASH" != no &&
 372    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 373   libc_cv_have_bash2=yes
 374 else
 375   libc_cv_have_bash2=no
 376 fi
 377 AC_SUBST(libc_cv_have_bash2)
 378
 379 dnl We need a ksh compatible shell for tzselect.
 380 if test "$BASH" = no; then
 381   AC_PATH_PROG(KSH, ksh, no)
 382   if test "$KSH" = no; then
 383     libc_cv_have_ksh=no
 384   else
 385     libc_cv_have_ksh=yes
 386   fi
 387 else
 388   KSH="$BASH"
 389   AC_SUBST(KSH)
 390   libc_cv_have_ksh=yes
 391 fi
 392 AC_SUBST(libc_cv_have_ksh)
 393
 394 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 395 echo '#include <stddef.h>
 396 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 397 if eval "$ac_cpp conftest.c 2>/dev/null" \
 398 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 399   libc_cv_signed_size_t=no
 400 else
 401   libc_cv_signed_size_t=yes
 402 fi
 403 rm -f conftest*])
 404 if test $libc_cv_signed_size_t = yes; then
 405   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 406   cat >> confdefs.h <<\EOF
 407 #undef __SIZE_TYPE__
 408 #define __SIZE_TYPE__ unsigned
 409 EOF
 410 fi
 411
 412 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 413 AC_TRY_COMPILE(dnl
 414 [#define __need_size_t
 415 #define __need_wchar_t
 416 #include <stddef.h>
 417 #define __need_NULL
 418 #include <stddef.h>], [size_t size; wchar_t wchar;
 419 #ifdef offsetof
 420 #error stddef.h ignored __need_*
 421 #endif
 422 if (&size == NULL || &wchar == NULL) abort ();],
 423                libc_cv_friendly_stddef=yes,
 424                libc_cv_friendly_stddef=no)])
 425 if test $libc_cv_friendly_stddef = yes; then
 426   config_vars="$config_vars
 427 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 428 fi
 429
 430 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 431                libc_cv_need_minus_P, [dnl
 432 cat > conftest.S <<EOF
 433 #include "confdefs.h"
 434 /* Nothing whatsoever.  */
 435 EOF
 436 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 437   libc_cv_need_minus_P=no
 438 else
 439   libc_cv_need_minus_P=yes
 440 fi
 441 rm -f conftest*])
 442 if test $libc_cv_need_minus_P = yes; then
 443   config_vars="$config_vars
 444 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 445 fi
 446
 447 AC_CACHE_CHECK(for assembler global-symbol directive,
 448                libc_cv_asm_global_directive, [dnl
 449 libc_cv_asm_global_directive=UNKNOWN
 450 for ac_globl in .globl .global; do
 451   cat > conftest.s <<EOF
 452 .text
 453 ${ac_globl} foo
 454 foo: .long 0
 455 EOF
 456   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 457     libc_cv_asm_global_directive=${ac_globl}
 458   fi
 459   rm -f conftest*
 460   test $libc_cv_asm_global_directive != UNKNOWN && break
 461 done])
 462 if test $libc_cv_asm_global_directive = UNKNOWN; then
 463   AC_MSG_ERROR(cannot determine asm global directive)
 464 else
 465   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 466 fi
 467
 468 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 469 cat > conftest.s <<EOF
 470 .text
 471 foo: .long 0
 472 .set glibc_conftest_frobozz,foo
 473 $libc_cv_asm_global_directive glibc_conftest_frobozz
 474 EOF
 475 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 476 # (but it doesn't work), so we must do a linking check to be sure.
 477 cat > conftest1.c <<\EOF
 478 extern int glibc_conftest_frobozz;
 479 main () { printf ("%d\n", glibc_conftest_frobozz); }
 480 EOF
 481 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 482             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 483   libc_cv_asm_set_directive=yes
 484 else
 485   libc_cv_asm_set_directive=no
 486 fi
 487 rm -f conftest*])
 488 if test $libc_cv_asm_set_directive = yes; then
 489   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 490 fi
 491
 492 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 493 [cat > conftest.s <<EOF
 494 .text
 495 _sym: ret
 496 .symver _sym,sym@VERS
 497 EOF
 498 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 499   libc_cv_asm_symver_directive=yes
 500 else
 501   libc_cv_asm_symver_directive=no
 502 fi
 503 rm -f conftest*])
 504 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 505 if test $libc_cv_asm_symver_directive = yes; then
 506   cat > conftest.s <<EOF
 507 .text
 508 _sym: ret
 509 .symver _sym,sym@VERS
 510 EOF
 511   cat > conftest.map <<EOF
 512 VERS {
 513         global: sym;
 514 };
 515 EOF
 516   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 517     if AC_TRY_COMMAND([${CC-cc} $CFLAGS --shared -o conftest.so conftest.o
 518                                         -Wl,--version-script,conftest.map]);
 519     then
 520       libc_cv_ld_version_script_option=yes
 521     else
 522       libc_cv_ld_version_script_option=no
 523     fi
 524   else
 525     libc_cv_ld_version_script_option=no
 526   fi
 527 else
 528   libc_cv_ld_version_script_option=no
 529 fi
 530 rm -f conftest*])
 531 if test $libc_cv_asm_symver_directive = yes &&
 532    test $libc_cv_ld_version_script_option = yes; then
 533   VERSIONING=yes
 534   AC_DEFINE(DO_VERSIONING)
 535 else
 536   VERSIONING=no
 537 fi
 538 AC_SUBST(VERSIONING)
 539
 540 if test $elf = yes; then
 541   AC_CACHE_CHECK(for .previous assembler directive,
 542                  libc_cv_asm_previous_directive, [dnl
 543   cat > conftest.s <<EOF
 544 .section foo_section
 545 .previous
 546 EOF
 547   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 548     libc_cv_asm_previous_directive=yes
 549   else
 550     libc_cv_asm_previous_directive=no
 551   fi
 552   rm -f conftest*])
 553   if test $libc_cv_asm_previous_directive = yes; then
 554     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 555   else
 556     AC_CACHE_CHECK(for .popsection assembler directive,
 557                    libc_cv_asm_popsection_directive, [dnl
 558     cat > conftest.s <<EOF
 559 .pushsection foo_section
 560 .popsection
 561 EOF
 562     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 563       libc_cv_asm_popsection_directive=yes
 564     else
 565       libc_cv_asm_popsection_directive=no
 566     fi
 567     rm -f conftest*])
 568     if test $libc_cv_asm_popsection_directive = yes; then
 569       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 570     fi
 571   fi
 572 fi
 573
 574 if test $elf != yes; then
 575   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 576                  [AC_TRY_COMPILE(, [asm (".section .init");
 577                                     asm (".section .fini");
 578                                     asm (".text");],
 579                                  libc_cv_have_initfini=yes,
 580                                  libc_cv_have_initfini=no)])
 581   AC_SUBST(libc_cv_have_initfini)dnl
 582   if test $libc_cv_have_initfini = yes; then
 583     AC_DEFINE(HAVE_INITFINI)
 584   fi
 585 fi
 586
 587 if test $elf = yes; then
 588   libc_cv_asm_underscores=no
 589 else
 590   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 591                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 592                               libc_cv_asm_underscores=yes,
 593                               libc_cv_asm_underscores=no)])
 594 fi
 595 if test $libc_cv_asm_underscores = no; then
 596   AC_DEFINE(NO_UNDERSCORES)
 597 fi
 598
 599 if test $elf = yes; then
 600   libc_cv_weak_symbols=yes
 601   libc_cv_asm_weak_directive=yes
 602   libc_cv_asm_weakext_directive=no
 603 else
 604   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 605                  [dnl
 606 cat > conftest.s <<EOF
 607 .text
 608 ${libc_cv_asm_global_directive} foo
 609 foo: .long 0
 610 .weak foo
 611 .weak bar; bar = foo
 612 EOF
 613   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 614     libc_cv_asm_weak_directive=yes
 615   else
 616     libc_cv_asm_weak_directive=no
 617   fi
 618   rm -f conftest*])
 619
 620 if test $libc_cv_asm_weak_directive = no; then
 621   AC_CACHE_CHECK(for assembler .weakext directive,
 622                  libc_cv_asm_weakext_directive,
 623                  [dnl
 624 cat > conftest.s <<EOF
 625 .text
 626 ${libc_cv_asm_global_directive} foo
 627 foo: .long 0
 628 .weakext foo
 629 .weakext foo, bar
 630 EOF
 631   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 632     libc_cv_asm_weakext_directive=yes
 633   else
 634     libc_cv_asm_weakext_directive=no
 635   fi
 636   rm -f conftest*])
 637
 638   fi # no .weak
 639 fi # not ELF
 640
 641 if test $libc_cv_asm_weak_directive = yes; then
 642   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 643 elif test $libc_cv_asm_weakext_directive = yes; then
 644   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 645 fi
 646
 647 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 648 cat > conftest.c <<\EOF
 649 _start () {}
 650 int __eh_pc;
 651 __throw () {}
 652 EOF
 653 dnl No \ in command here because it ends up inside ''.
 654 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 655                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 656                             -o conftest conftest.c]); then
 657   libc_cv_ld_no_whole_archive=yes
 658 else
 659   libc_cv_ld_no_whole_archive=no
 660 fi
 661 rm -f conftest*])
 662 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 663
 664 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 665 cat > conftest.c <<\EOF
 666 _start () {}
 667 int __eh_pc;
 668 __throw () {}
 669 EOF
 670 dnl No \ in command here because it ends up inside ''.
 671 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 672                             -nostdlib -nostartfiles -fno-exceptions
 673                             -o conftest conftest.c]); then
 674   libc_cv_gcc_no_exceptions=yes
 675 else
 676   libc_cv_gcc_no_exceptions=no
 677 fi
 678 rm -f conftest*])
 679 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 680
 681 ### End of automated tests.
 682 ### Now run sysdeps configure fragments.
 683
 684 # sysdeps configure fragments may set these with files to be linked below.
 685 libc_link_dests=
 686 libc_link_sources=
 687
 688 # Iterate over all the sysdep directories we will use, running their
 689 # configure fragments, and looking for a uname implementation.
 690 uname=
 691 for dir in $sysnames; do
 692   case $dir in
 693     /*) dest=$dir ;;
 694     *)  dest=$srcdir/$dir ;;
 695   esac
 696   if test -r $dest/configure; then
 697     AC_MSG_RESULT(running configure fragment for $dest)
 698     . $dest/configure
 699   fi
 700 [
 701   if test -z "$uname"; then
 702     if test -r $sysdep_dir/$dir/uname.c ||
 703        test -r $sysdep_dir/$dir/uname.S ||
 704        { test -r $sysdep_dir/$dir/syscalls.list &&
 705          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 706       uname=$dir
 707     fi
 708   fi
 709 ]dnl
 710 done
 711
 712 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 713
 714 # If we will use the generic uname implementation, we must figure out what
 715 # it will say by examining the system, and write the results in config-name.h.
 716 if test "$uname" = generic; then
 717
 718 changequote(,)dnl
 719   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 720 changequote([,])dnl
 721   if test $uname_sysname != $config_os; then
 722     config_release=`echo $config_os | sed s/$uname_sysname//`
 723   fi
 724 dnl
 725 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 726     if test -r /vmunix; then
 727       kernel_id=`strings /vmunix | grep UNIX`
 728     elif test -r /dynix; then
 729       kernel_id=`strings /dynix | grep DYNIX`
 730     else
 731       kernel_id=
 732     fi
 733 ])dnl
 734
 735   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 736 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 737 changequote(,)dnl
 738   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 739 changequote([,])dnl
 740   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 741          != x$config_release; then
 742     # The configuration release is a substring of the kernel release.
 743     libc_cv_uname_release=$kernel_release
 744   elif test x$config_release != x; then
 745     libc_cv_uname_release=$config_release
 746   elif test x$kernel_release != x; then
 747     libc_cv_uname_release=$kernel_release
 748   else
 749     libc_cv_uname_release=unknown
 750   fi])
 751   uname_release="$libc_cv_uname_release"
 752
 753   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 754 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 755 changequote(,)dnl
 756   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 757 changequote([,])dnl
 758   if test -n "$kernel_version"; then
 759     libc_cv_uname_version="$kernel_version"
 760   else
 761     libc_cv_uname_version=unknown
 762   fi])
 763   uname_version="$libc_cv_uname_version"
 764
 765 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 766   config_uname=config-name.h:config-name.in
 767 else
 768   # For non-generic uname, we don't need to create config-name.h at all.
 769   config_uname=
 770 fi
 771
 772 AC_MSG_CHECKING(stdio selection)
 773 AC_SUBST(stdio)
 774 case $stdio in
 775 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 776 default) stdio=stdio ;;
 777 esac
 778 AC_MSG_RESULT($stdio)
 779
 780 AC_SUBST(libc_cv_slibdir)
 781 AC_SUBST(libc_cv_sysconfdir)
 782 AC_SUBST(libc_cv_rootsbindir)
 783
 784 AC_SUBST(has_ldconfig)
 785
 786 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 787 if test $gnu_ld = yes; then
 788   AC_DEFINE(HAVE_GNU_LD)
 789 fi
 790 if test $gnu_as = yes; then
 791   AC_DEFINE(HAVE_GNU_AS)
 792 fi
 793 if test $elf = yes; then
 794   AC_DEFINE(HAVE_ELF)
 795 fi
 796
 797 AC_SUBST(shared)
 798 if test $shared = default; then
 799   if test $gnu_ld = yes; then
 800     shared=$elf
 801   else
 802     # For now we do not assume shared libs are available.  In future more
 803     # tests might become available.
 804     shared=no
 805   fi
 806 fi
 807 AC_SUBST(profile)
 808 AC_SUBST(omitfp)
 809 AC_SUBST(bounded)
 810
 811 AC_SUBST(DEFINES)
 812
 813 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 814   config_makefile=
 815 else
 816   config_makefile=Makefile
 817 fi
 818
 819 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 820 AC_SUBST(VERSION)
 821
 822 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 823           [echo '$config_vars' >> config.make])