configure.bat

   1 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
   2 ::
   3 :: Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 :: Contact: http://www.qt-project.org/
   5 ::
   6 :: This file is part of the tools applications of the Qt Toolkit.
   7 ::
   8 :: $QT_BEGIN_LICENSE:LGPL$
   9 :: GNU Lesser General Public License Usage
  10 :: This file may be used under the terms of the GNU Lesser General Public
  11 :: License version 2.1 as published by the Free Software Foundation and
  12 :: appearing in the file LICENSE.LGPL included in the packaging of this
  13 :: file. Please review the following information to ensure the GNU Lesser
  14 :: General Public License version 2.1 requirements will be met:
  15 :: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 ::
  17 :: In addition, as a special exception, Nokia gives you certain additional
  18 :: rights. These rights are described in the Nokia Qt LGPL Exception
  19 :: version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 ::
  21 :: GNU General Public License Usage
  22 :: Alternatively, this file may be used under the terms of the GNU General
  23 :: Public License version 3.0 as published by the Free Software Foundation
  24 :: and appearing in the file LICENSE.GPL included in the packaging of this
  25 :: file. Please review the following information to ensure the GNU General
  26 :: Public License version 3.0 requirements will be met:
  27 :: http://www.gnu.org/copyleft/gpl.html.
  28 ::
  29 :: Other Usage
  30 :: Alternatively, this file may be used in accordance with the terms and
  31 :: conditions contained in a signed written agreement between you and Nokia.
  32 ::
  33 ::
  34 ::
  35 ::
  36 ::
  37 ::
  38 :: $QT_END_LICENSE$
  39 ::
  40 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  41
  42 @echo off
  43 set QTSRC=%~dp0
  44 set QTDIR=%CD%
  45 if not exist %QTSRC%\.gitignore goto sconf
  46 if exist configure.exe goto conf
  47 echo Please wait while bootstrapping configure ...
  48
  49 for %%C in (cl.exe icl.exe g++.exe perl.exe) do set %%C=%%~$PATH:C
  50
  51 set nosyncqt=
  52 if not exist include (
  53     if "%perl.exe%" == "" (
  54         echo Perl not found in PATH. Aborting. >&2
  55         exit /b 1
  56     )
  57     if not exist mkspecs (
  58         md mkspecs
  59         if errorlevel 1 goto exit
  60     )
  61     perl %QTSRC%bin\syncqt -outdir %QTDIR% %QTSRC%
  62     if errorlevel 1 goto exit
  63     set nosyncqt=-no-syncqt
  64 )
  65
  66 if not exist src\corelib\global\qconfig.h (
  67     if not exist src\corelib\global (
  68         md src\corelib\global
  69         if errorlevel 1 goto exit
  70     )
  71     echo /* Generated by configure.bat - DO NOT EDIT! */ > src\corelib\global\qconfig.h
  72 )
  73
  74 if not exist tools\configure (
  75     md tools\configure
  76     if errorlevel 1 goto exit
  77 )
  78 cd tools\configure
  79 if errorlevel 1 goto exit
  80
  81 echo #### Generated by configure.bat - DO NOT EDIT! ####> Makefile
  82 echo/>> Makefile
  83 for /f "tokens=3 usebackq" %%V in (`findstr QT_VERSION_STR %QTSRC%\src\corelib\global\qglobal.h`) do @echo QTVERSION = %%~V>> Makefile
  84 if not "%cl.exe%" == "" (
  85     echo CXX = cl>>Makefile
  86     echo EXTRA_CXXFLAGS =>>Makefile
  87     rem This must have a trailing space.
  88     echo QTSRC = %QTSRC% >> Makefile
  89     set tmpl=win32
  90     set make=nmake
  91 ) else if not "%icl.exe%" == "" (
  92     echo CXX = icl>>Makefile
  93     echo EXTRA_CXXFLAGS = /Zc:forScope>>Makefile
  94     rem This must have a trailing space.
  95     echo QTSRC = %QTSRC% >> Makefile
  96     set tmpl=win32
  97     set make=nmake
  98 ) else if not "%g++.exe%" == "" (
  99     echo CXX = g++>>Makefile
 100     echo EXTRA_CXXFLAGS =>>Makefile
 101     rem This must NOT have a trailing space.
 102     echo QTSRC = %QTSRC:\=/%>> Makefile
 103     set tmpl=mingw
 104     set make=mingw32-make
 105 ) else (
 106     echo No suitable compiler found in PATH. Aborting. >&2
 107     cd ..\..
 108     exit /b 1
 109 )
 110 echo/>> Makefile
 111 type %QTSRC%tools\configure\Makefile.%tmpl% >> Makefile
 112
 113 %make%
 114 if errorlevel 1 (cd ..\.. & exit /b 1)
 115
 116 cd ..\..
 117
 118 :conf
 119 configure.exe -srcdir %QTSRC% %* %nosyncqt%
 120 goto exit
 121
 122 :sconf
 123 %QTSRC%\configure.exe %*
 124 :exit