configure.bat

   1 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
   2 ::
   3 :: Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 :: Contact: http://www.qt-project.org/
   5 ::
   6 :: This file is part of the tools applications of the Qt Toolkit.
   7 ::
   8 :: $QT_BEGIN_LICENSE:LGPL$
   9 :: GNU Lesser General Public License Usage
  10 :: This file may be used under the terms of the GNU Lesser General Public
  11 :: License version 2.1 as published by the Free Software Foundation and
  12 :: appearing in the file LICENSE.LGPL included in the packaging of this
  13 :: file. Please review the following information to ensure the GNU Lesser
  14 :: General Public License version 2.1 requirements will be met:
  15 :: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 ::
  17 :: In addition, as a special exception, Nokia gives you certain additional
  18 :: rights. These rights are described in the Nokia Qt LGPL Exception
  19 :: version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 ::
  21 :: GNU General Public License Usage
  22 :: Alternatively, this file may be used under the terms of the GNU General
  23 :: Public License version 3.0 as published by the Free Software Foundation
  24 :: and appearing in the file LICENSE.GPL included in the packaging of this
  25 :: file. Please review the following information to ensure the GNU General
  26 :: Public License version 3.0 requirements will be met:
  27 :: http://www.gnu.org/copyleft/gpl.html.
  28 ::
  29 :: Other Usage
  30 :: Alternatively, this file may be used in accordance with the terms and
  31 :: conditions contained in a signed written agreement between you and Nokia.
  32 ::
  33 ::
  34 ::
  35 ::
  36 ::
  37 ::
  38 :: $QT_END_LICENSE$
  39 ::
  40 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  41
  42 @echo off
  43 set QTSRC=%~dp0
  44 set QTDIR=%CD%
  45 if not exist %QTSRC%\.gitignore goto sconf
  46 if exist configure.exe goto conf
  47 echo Please wait while bootstrapping configure ...
  48
  49 for %%C in (cl.exe icl.exe g++.exe perl.exe) do set %%C=%%~$PATH:C
  50
  51 if not exist include (
  52     if "%perl.exe%" == "" (
  53         echo Perl not found in PATH. Aborting. >&2
  54         exit /b 1
  55     )
  56     if not exist mkspecs (
  57         md mkspecs
  58         if errorlevel 1 goto exit
  59     )
  60     perl %QTSRC%bin\syncqt -minimal -module QtCore -outdir %QTDIR% %QTSRC%
  61     if errorlevel 1 goto exit
  62 )
  63
  64 if not exist tools\configure (
  65     md tools\configure
  66     if errorlevel 1 goto exit
  67 )
  68 cd tools\configure
  69 if errorlevel 1 goto exit
  70
  71 echo #### Generated by configure.bat - DO NOT EDIT! ####> Makefile
  72 echo/>> Makefile
  73 for /f "tokens=3 usebackq" %%V in (`findstr QT_VERSION_STR %QTSRC%\src\corelib\global\qglobal.h`) do @echo QTVERSION = %%~V>> Makefile
  74 if not "%cl.exe%" == "" (
  75     echo CXX = cl>>Makefile
  76     echo EXTRA_CXXFLAGS =>>Makefile
  77     rem This must have a trailing space.
  78     echo QTSRC = %QTSRC% >> Makefile
  79     set tmpl=win32
  80     set make=nmake
  81 ) else if not "%icl.exe%" == "" (
  82     echo CXX = icl>>Makefile
  83     echo EXTRA_CXXFLAGS = /Zc:forScope>>Makefile
  84     rem This must have a trailing space.
  85     echo QTSRC = %QTSRC% >> Makefile
  86     set tmpl=win32
  87     set make=nmake
  88 ) else if not "%g++.exe%" == "" (
  89     echo CXX = g++>>Makefile
  90     echo EXTRA_CXXFLAGS =>>Makefile
  91     rem This must NOT have a trailing space.
  92     echo QTSRC = %QTSRC:\=/%>> Makefile
  93     set tmpl=mingw
  94     set make=mingw32-make
  95 ) else (
  96     echo No suitable compiler found in PATH. Aborting. >&2
  97     cd ..\..
  98     exit /b 1
  99 )
 100 echo/>> Makefile
 101 type %QTSRC%tools\configure\Makefile.%tmpl% >> Makefile
 102
 103 %make%
 104 if errorlevel 1 (cd ..\.. & exit /b 1)
 105
 106 cd ..\..
 107
 108 :conf
 109 configure.exe -srcdir %QTSRC% %*
 110 goto exit
 111
 112 :sconf
 113 %QTSRC%\configure.exe %*
 114 :exit