configure.bat

   1 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
   2 ::
   3 :: Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 :: Contact: http://www.qt-project.org/
   5 ::
   6 :: This file is part of the tools applications of the Qt Toolkit.
   7 ::
   8 :: $QT_BEGIN_LICENSE:LGPL$
   9 :: GNU Lesser General Public License Usage
  10 :: This file may be used under the terms of the GNU Lesser General Public
  11 :: License version 2.1 as published by the Free Software Foundation and
  12 :: appearing in the file LICENSE.LGPL included in the packaging of this
  13 :: file. Please review the following information to ensure the GNU Lesser
  14 :: General Public License version 2.1 requirements will be met:
  15 :: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 ::
  17 :: In addition, as a special exception, Nokia gives you certain additional
  18 :: rights. These rights are described in the Nokia Qt LGPL Exception
  19 :: version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 ::
  21 :: GNU General Public License Usage
  22 :: Alternatively, this file may be used under the terms of the GNU General
  23 :: Public License version 3.0 as published by the Free Software Foundation
  24 :: and appearing in the file LICENSE.GPL included in the packaging of this
  25 :: file. Please review the following information to ensure the GNU General
  26 :: Public License version 3.0 requirements will be met:
  27 :: http://www.gnu.org/copyleft/gpl.html.
  28 ::
  29 :: Other Usage
  30 :: Alternatively, this file may be used in accordance with the terms and
  31 :: conditions contained in a signed written agreement between you and Nokia.
  32 ::
  33 ::
  34 ::
  35 ::
  36 ::
  37 ::
  38 :: $QT_END_LICENSE$
  39 ::
  40 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  41
  42 @echo off
  43 set QTSRC=%~dp0
  44 set QTDIR=%CD%
  45 if not exist %QTSRC%\.gitignore goto sconf
  46 if exist configure.exe goto conf
  47 echo Please wait while bootstrapping configure ...
  48
  49 for %%C in (cl.exe icl.exe g++.exe perl.exe) do set %%C=%%~$PATH:C
  50
  51 if "%perl.exe%" == "" (
  52     echo Perl not found in PATH. Aborting. >&2
  53     exit /b 1
  54 )
  55 if not exist mkspecs (
  56     md mkspecs
  57     if errorlevel 1 goto exit
  58 )
  59 perl %QTSRC%bin\syncqt -minimal -module QtCore -outdir %QTDIR% %QTSRC%
  60 if errorlevel 1 goto exit
  61
  62 if not exist tools\configure (
  63     md tools\configure
  64     if errorlevel 1 goto exit
  65 )
  66 cd tools\configure
  67 if errorlevel 1 goto exit
  68
  69 echo #### Generated by configure.bat - DO NOT EDIT! ####> Makefile
  70 echo/>> Makefile
  71 for /f "tokens=3 usebackq" %%V in (`findstr QT_VERSION_STR %QTSRC%\src\corelib\global\qglobal.h`) do @echo QTVERSION = %%~V>> Makefile
  72 if not "%cl.exe%" == "" (
  73     echo CXX = cl>>Makefile
  74     echo EXTRA_CXXFLAGS =>>Makefile
  75     rem This must have a trailing space.
  76     echo QTSRC = %QTSRC% >> Makefile
  77     set tmpl=win32
  78     set make=nmake
  79 ) else if not "%icl.exe%" == "" (
  80     echo CXX = icl>>Makefile
  81     echo EXTRA_CXXFLAGS = /Zc:forScope>>Makefile
  82     rem This must have a trailing space.
  83     echo QTSRC = %QTSRC% >> Makefile
  84     set tmpl=win32
  85     set make=nmake
  86 ) else if not "%g++.exe%" == "" (
  87     echo CXX = g++>>Makefile
  88     echo EXTRA_CXXFLAGS =>>Makefile
  89     rem This must NOT have a trailing space.
  90     echo QTSRC = %QTSRC:\=/%>> Makefile
  91     set tmpl=mingw
  92     set make=mingw32-make
  93 ) else (
  94     echo No suitable compiler found in PATH. Aborting. >&2
  95     cd ..\..
  96     exit /b 1
  97 )
  98 echo/>> Makefile
  99 type %QTSRC%tools\configure\Makefile.%tmpl% >> Makefile
 100
 101 %make%
 102 if errorlevel 1 (cd ..\.. & exit /b 1)
 103
 104 cd ..\..
 105
 106 :conf
 107 configure.exe -srcdir %QTSRC% %*
 108 goto exit
 109
 110 :sconf
 111 %QTSRC%\configure.exe %*
 112 :exit