configure.bat

   1 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
   2 ::
   3 :: Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 :: Contact: http://www.qt-project.org/
   5 ::
   6 :: This file is part of the tools applications of the Qt Toolkit.
   7 ::
   8 :: $QT_BEGIN_LICENSE:LGPL$
   9 :: GNU Lesser General Public License Usage
  10 :: This file may be used under the terms of the GNU Lesser General Public
  11 :: License version 2.1 as published by the Free Software Foundation and
  12 :: appearing in the file LICENSE.LGPL included in the packaging of this
  13 :: file. Please review the following information to ensure the GNU Lesser
  14 :: General Public License version 2.1 requirements will be met:
  15 :: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 ::
  17 :: In addition, as a special exception, Nokia gives you certain additional
  18 :: rights. These rights are described in the Nokia Qt LGPL Exception
  19 :: version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 ::
  21 :: GNU General Public License Usage
  22 :: Alternatively, this file may be used under the terms of the GNU General
  23 :: Public License version 3.0 as published by the Free Software Foundation
  24 :: and appearing in the file LICENSE.GPL included in the packaging of this
  25 :: file. Please review the following information to ensure the GNU General
  26 :: Public License version 3.0 requirements will be met:
  27 :: http://www.gnu.org/copyleft/gpl.html.
  28 ::
  29 :: Other Usage
  30 :: Alternatively, this file may be used in accordance with the terms and
  31 :: conditions contained in a signed written agreement between you and Nokia.
  32 ::
  33 ::
  34 ::
  35 ::
  36 ::
  37 ::
  38 :: $QT_END_LICENSE$
  39 ::
  40 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  41
  42 @echo off
  43 set QTSRC=%~dp0
  44 set QTDIR=%CD%
  45 if exist configure.exe goto conf
  46 echo Please wait while bootstrapping configure ...
  47
  48 for %%C in (cl.exe icl.exe g++.exe perl.exe) do set %%C=%%~$PATH:C
  49
  50 set nosyncqt=
  51 if not exist include (
  52     if "%perl.exe%" == "" (
  53         echo Perl not found in PATH. Aborting. >&2
  54         exit /b 1
  55     )
  56     if not exist mkspecs (
  57         md mkspecs
  58         if errorlevel 1 goto exit
  59     )
  60     perl %QTSRC%bin\syncqt -outdir %QTDIR% %QTSRC%
  61     if errorlevel 1 goto exit
  62     set nosyncqt=-no-syncqt
  63 )
  64
  65 if not exist src\corelib\global\qconfig.h (
  66     if not exist src\corelib\global (
  67         md src\corelib\global
  68         if errorlevel 1 goto exit
  69     )
  70     echo #define Q_BIG_ENDIAN 4321 > src\corelib\global\qconfig.h
  71     echo #define Q_LITTLE_ENDIAN 1234 >> src\corelib\global\qconfig.h
  72     echo #define Q_BYTE_ORDER Q_LITTLE_ENDIAN >> src\corelib\global\qconfig.h
  73 )
  74
  75 if not exist tools\configure (
  76     md tools\configure
  77     if errorlevel 1 goto exit
  78 )
  79 cd tools\configure
  80 if errorlevel 1 goto exit
  81
  82 echo #### Generated by configure.bat - DO NOT EDIT! ####> Makefile
  83 echo/>> Makefile
  84 for /f "tokens=3 usebackq" %%V in (`findstr QT_VERSION_STR %QTSRC%\src\corelib\global\qglobal.h`) do @echo QTVERSION = %%~V>> Makefile
  85 if not "%cl.exe%" == "" (
  86     echo CXX = cl>>Makefile
  87     echo EXTRA_CXXFLAGS =>>Makefile
  88     rem This must have a trailing space.
  89     echo QTSRC = %QTSRC% >> Makefile
  90     set tmpl=win32
  91     set make=nmake
  92 ) else if not "%icl.exe%" == "" (
  93     echo CXX = icl>>Makefile
  94     echo EXTRA_CXXFLAGS = /Zc:forScope>>Makefile
  95     rem This must have a trailing space.
  96     echo QTSRC = %QTSRC% >> Makefile
  97     set tmpl=win32
  98     set make=nmake
  99 ) else if not "%g++.exe%" == "" (
 100     echo CXX = g++>>Makefile
 101     echo EXTRA_CXXFLAGS =>>Makefile
 102     rem This must NOT have a trailing space.
 103     echo QTSRC = %QTSRC:\=/%>> Makefile
 104     set tmpl=mingw
 105     set make=mingw32-make
 106 ) else (
 107     echo No suitable compiler found in PATH. Aborting. >&2
 108     cd ..\..
 109     exit /b 1
 110 )
 111 echo/>> Makefile
 112 type %QTSRC%tools\configure\Makefile.%tmpl% >> Makefile
 113
 114 %make%
 115 if errorlevel 1 (cd ..\.. & exit /b 1)
 116
 117 cd ..\..
 118
 119 :conf
 120 configure.exe -srcdir %QTSRC% %nosyncqt% %*
 121 :exit