configure.bat

   1 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
   2 ::
   3 :: Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 :: Contact: http://www.qt-project.org/
   5 ::
   6 :: This file is part of the tools applications of the Qt Toolkit.
   7 ::
   8 :: $QT_BEGIN_LICENSE:LGPL$
   9 :: GNU Lesser General Public License Usage
  10 :: This file may be used under the terms of the GNU Lesser General Public
  11 :: License version 2.1 as published by the Free Software Foundation and
  12 :: appearing in the file LICENSE.LGPL included in the packaging of this
  13 :: file. Please review the following information to ensure the GNU Lesser
  14 :: General Public License version 2.1 requirements will be met:
  15 :: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 ::
  17 :: In addition, as a special exception, Nokia gives you certain additional
  18 :: rights. These rights are described in the Nokia Qt LGPL Exception
  19 :: version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 ::
  21 :: GNU General Public License Usage
  22 :: Alternatively, this file may be used under the terms of the GNU General
  23 :: Public License version 3.0 as published by the Free Software Foundation
  24 :: and appearing in the file LICENSE.GPL included in the packaging of this
  25 :: file. Please review the following information to ensure the GNU General
  26 :: Public License version 3.0 requirements will be met:
  27 :: http://www.gnu.org/copyleft/gpl.html.
  28 ::
  29 :: Other Usage
  30 :: Alternatively, this file may be used in accordance with the terms and
  31 :: conditions contained in a signed written agreement between you and Nokia.
  32 ::
  33 ::
  34 ::
  35 ::
  36 ::
  37 ::
  38 :: $QT_END_LICENSE$
  39 ::
  40 :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  41
  42 @echo off
  43 set QTSRC=%~dp0
  44 set QTDIR=%CD%
  45 if not exist %QTSRC%\.gitignore goto sconf
  46 if exist configure.exe goto conf
  47 echo Please wait while bootstrapping configure ...
  48
  49 for %%C in (cl.exe icl.exe g++.exe perl.exe) do set %%C=%%~$PATH:C
  50
  51 if not exist include (
  52     if "%perl.exe%" == "" (
  53         echo Perl not found in PATH. Aborting. >&2
  54         exit /b 1
  55     )
  56     if not exist mkspecs (
  57         md mkspecs
  58         if errorlevel 1 goto exit
  59     )
  60     perl %QTSRC%bin\syncqt -minimal -outdir %QTDIR% %QTSRC%
  61     if errorlevel 1 goto exit
  62 )
  63
  64 if not exist src\corelib\global\qconfig.h (
  65     if not exist src\corelib\global (
  66         md src\corelib\global
  67         if errorlevel 1 goto exit
  68     )
  69     echo /* Generated by configure.bat - DO NOT EDIT! */ > src\corelib\global\qconfig.h
  70 )
  71
  72 if not exist tools\configure (
  73     md tools\configure
  74     if errorlevel 1 goto exit
  75 )
  76 cd tools\configure
  77 if errorlevel 1 goto exit
  78
  79 echo #### Generated by configure.bat - DO NOT EDIT! ####> Makefile
  80 echo/>> Makefile
  81 for /f "tokens=3 usebackq" %%V in (`findstr QT_VERSION_STR %QTSRC%\src\corelib\global\qglobal.h`) do @echo QTVERSION = %%~V>> Makefile
  82 if not "%cl.exe%" == "" (
  83     echo CXX = cl>>Makefile
  84     echo EXTRA_CXXFLAGS =>>Makefile
  85     rem This must have a trailing space.
  86     echo QTSRC = %QTSRC% >> Makefile
  87     set tmpl=win32
  88     set make=nmake
  89 ) else if not "%icl.exe%" == "" (
  90     echo CXX = icl>>Makefile
  91     echo EXTRA_CXXFLAGS = /Zc:forScope>>Makefile
  92     rem This must have a trailing space.
  93     echo QTSRC = %QTSRC% >> Makefile
  94     set tmpl=win32
  95     set make=nmake
  96 ) else if not "%g++.exe%" == "" (
  97     echo CXX = g++>>Makefile
  98     echo EXTRA_CXXFLAGS =>>Makefile
  99     rem This must NOT have a trailing space.
 100     echo QTSRC = %QTSRC:\=/%>> Makefile
 101     set tmpl=mingw
 102     set make=mingw32-make
 103 ) else (
 104     echo No suitable compiler found in PATH. Aborting. >&2
 105     cd ..\..
 106     exit /b 1
 107 )
 108 echo/>> Makefile
 109 type %QTSRC%tools\configure\Makefile.%tmpl% >> Makefile
 110
 111 %make%
 112 if errorlevel 1 (cd ..\.. & exit /b 1)
 113
 114 cd ..\..
 115
 116 :conf
 117 configure.exe -srcdir %QTSRC% %*
 118 goto exit
 119
 120 :sconf
 121 %QTSRC%\configure.exe %*
 122 :exit