configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.9.2.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 902, 0, 902)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.9.2.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl used in gst/tcp
 183 AC_CHECK_HEADERS([sys/socket.h],
 184   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 185 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 186
 187 dnl used in gst-libs/gst/rtsp
 188 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 189 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 190 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 191   WIN32_LIBS="-lws2_32"
 192   AC_SUBST(WIN32_LIBS)
 193 fi
 194
 195 dnl used in gst-libs/gst/pbutils and associated unit test
 196 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 197
 198 dnl checks for ARM NEON support
 199 dnl this instruction set is used by the speex resampler code
 200 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 201 AC_LINK_IFELSE([
 202 AC_LANG_PROGRAM([[
 203   #include <arm_neon.h>
 204   int32x4_t testfunc(int16_t *a, int16_t *b) {
 205       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 206       return vmull_s16(vld1_s16(a), vld1_s16(b));
 207   }
 208 ]])],
 209 [
 210   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 211   AC_MSG_RESULT(yes)
 212 ],
 213 [
 214   AC_MSG_RESULT(no)
 215 ])
 216
 217 dnl also, Windows does not have long long
 218 AX_CREATE_STDINT_H
 219
 220 dnl *** checks for functions ***
 221 AC_CHECK_FUNCS([localtime_r gmtime_r])
 222
 223 dnl *** checks for math functions ***
 224 LIBS_SAVE=$LIBS
 225 LIBS="$LIBS $LIBM"
 226 AC_CHECK_FUNCS(log2)
 227 LIBS=$LIBS_SAVE
 228
 229 dnl *** checks for types/defines ***
 230
 231 dnl *** checks for structures ***
 232
 233 dnl *** checks for compiler characteristics ***
 234
 235 dnl *** checks for library functions ***
 236
 237 dnl check for fseeko()
 238 AC_FUNC_FSEEKO
 239
 240 dnl Check for fast float to int casting as defined in C99
 241 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 242 save_libs=$LIBS
 243 LIBS="$LIBS $LIBM"
 244 AC_C99_FUNC_LRINT
 245 AC_C99_FUNC_LRINTF
 246 LIBS=$save_libs
 247
 248 dnl Check for a way to display the function name in debug output
 249 AG_GST_CHECK_FUNCTION
 250
 251 dnl *** checks for dependency libraries ***
 252
 253 dnl GLib
 254 GLIB_REQ=2.40.0
 255 AG_GST_GLIB_CHECK([$GLIB_REQ])
 256
 257 ORC_CHECK([0.4.24])
 258
 259 dnl checks for gstreamer
 260 dnl uninstalled is selected preferentially -- see pkg-config(1)
 261 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 262 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 263 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 265 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 266 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 267
 268 dnl Check for documentation xrefs
 269 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 270 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 271 AC_SUBST(GLIB_PREFIX)
 272 AC_SUBST(GST_PREFIX)
 273
 274 dnl GTK is optional and only used in examples
 275 HAVE_GTK=no
 276 HAVE_GTK_X11=no
 277 GTK_REQ=3.10
 278 if test "x$BUILD_EXAMPLES" = "xyes"; then
 279   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 280   dnl some examples need gtk+-x11
 281   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 282   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 283   AC_SUBST(GTK_LIBS)
 284   AC_SUBST(GTK_CFLAGS)
 285 fi
 286 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 287 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 288 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 289
 290 HAVE_QT=no
 291 HAVE_QT_MOC=no
 292 dnl QT is optional and only used in examples
 293 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 294   HAVE_QT=yes
 295 ], [
 296   HAVE_QT=no
 297 ])
 298 if test "x$HAVE_QT" = "xyes"; then
 299   AC_CHECK_TOOL(QT_MOC, moc)
 300   AC_MSG_CHECKING([for Qt5 moc])
 301   mocversion=`$QT_MOC -v 2>&1`
 302   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 303   if test x"$mocversiongrep" != x"$mocversion"; then
 304     AC_MSG_RESULT([no])
 305     # moc was not the qt5 one, try with moc-qt5
 306     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 307     AC_MSG_CHECKING([for Qt5 moc-qt5])
 308     mocversion=`$QT_MOC -v 2>&1`
 309     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 310     if test x"$mocversiongrep" != x"$mocversion"; then
 311       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 312       AC_MSG_CHECKING([for qtchooser])
 313       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 314       mocversion=`$qt5tooldir/moc -v 2>&1`
 315       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 316       if test x"$mocversiongrep" != x"$mocversion"; then
 317         # no valid moc found
 318         QT_MOC="no"
 319       else
 320         QT_MOC=$qt5tooldir/moc
 321       fi
 322     else
 323       QT_MOC=$QT_MOC
 324     fi
 325   fi
 326   AC_SUBST(QT_MOC)
 327   AC_MSG_RESULT([$QT_MOC])
 328 fi
 329 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 330 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 331
 332 dnl chck for linux headers needed by the joystick seek example
 333 AC_COMPILE_IFELSE(
 334 [
 335   AC_LANG_PROGRAM([
 336     #include <linux/input.h>
 337     #include <linux/joystick.h>
 338   ],[
 339     struct js_event js;
 340     js.type = JS_EVENT_AXIS;
 341   ])
 342 ], [
 343   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 344 ], [
 345   HAVE_LINUX_JOYSTICK_HEADERS="no"
 346 ])
 347 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 348
 349 dnl Check for -Bsymbolic-functions linker flag used to avoid
 350 dnl intra-library PLT jumps, if available.
 351 AC_ARG_ENABLE(Bsymbolic,
 352               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 353               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 354                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 355                LDFLAGS=-Wl,-Bsymbolic-functions
 356                LIBS=
 357                AC_TRY_LINK([], [return 0],
 358                            AC_MSG_RESULT(yes)
 359                            enable_Bsymbolic=yes,
 360                            AC_MSG_RESULT(no)
 361                            enable_Bsymbolic=no)
 362                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 363
 364
 365 dnl *** set variables based on configure arguments ***
 366
 367 dnl set license and copyright notice
 368 GST_LICENSE="LGPL"
 369 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 370 AC_SUBST(GST_LICENSE)
 371
 372 dnl set location of plugin directory
 373 AG_GST_SET_PLUGINDIR
 374
 375 dnl set release date/time
 376 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 377   ["${srcdir}/gst-plugins-base.doap"],
 378   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 379
 380 dnl build static plugins or not
 381 AC_MSG_CHECKING([whether to build static plugins or not])
 382 AC_ARG_ENABLE(
 383   static-plugins,
 384   AC_HELP_STRING(
 385     [--enable-static-plugins],
 386     [build static plugins @<:@default=no@:>@]),
 387   [AS_CASE(
 388     [$enableval], [no], [], [yes], [],
 389     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 390   [enable_static_plugins=no])
 391 AC_MSG_RESULT([$enable_static_plugins])
 392 if test "x$enable_static_plugins" = xyes; then
 393   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 394     [Define if static plugins should be built])
 395   GST_PLUGIN_LIBTOOLFLAGS=""
 396 else
 397   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 398 fi
 399 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 400 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 401
 402 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 403 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 404 if test x$enable_static = xyes -a x$enable_shared = xno; then
 405   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 406 fi
 407
 408 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 409 dnl make sure it doesn't complain about unused variables if debugging is disabled
 410 NO_WARNINGS=""
 411 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 412
 413 dnl define an ERROR_CFLAGS Makefile variable
 414 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 415 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 416     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 417     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 418     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 419     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 420
 421 dnl define an ERROR_CXXFLAGS Makefile variable
 422 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 423     -Wmissing-declarations -Wredundant-decls -Wundef
 424     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 425     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 426     -Wno-multichar $NO_WARNINGS])
 427
 428 dnl define correct level for debugging messages
 429 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 430
 431 dnl used in examples
 432 AG_GST_DEFAULT_ELEMENTS
 433
 434 dnl needed for encoding-target
 435 GST_DATADIR="$GST_PREFIX/share"
 436 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 437 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 438
 439 dnl behaviour of speex based audio resampler
 440 AC_MSG_CHECKING(which audio resample format to use for integer)
 441 AC_ARG_WITH([audioresample_format],
 442         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 443         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 444 AC_MSG_RESULT($ac_cv_audioresample_format)
 445 case $ac_cv_audioresample_format in
 446   int)
 447     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 448     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 449   ;;
 450   float)
 451     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 452     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 453   ;;
 454   auto)
 455     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 456     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 457 esac
 458
 459 dnl Check for mmap (needed by allocators library)
 460 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 461
 462 dnl *** plug-ins to include ***
 463
 464 dnl these are all the gst plug-ins, compilable without additional libs
 465 AG_GST_CHECK_PLUGIN(adder)
 466 AG_GST_CHECK_PLUGIN(app)
 467 AG_GST_CHECK_PLUGIN(audioconvert)
 468 AG_GST_CHECK_PLUGIN(audiorate)
 469 AG_GST_CHECK_PLUGIN(audiotestsrc)
 470 AG_GST_CHECK_PLUGIN(encoding)
 471 AG_GST_CHECK_PLUGIN(videoconvert)
 472 AG_GST_CHECK_PLUGIN(gio)
 473 AG_GST_CHECK_PLUGIN(playback)
 474 AG_GST_CHECK_PLUGIN(audioresample)
 475 AG_GST_CHECK_PLUGIN(subparse)
 476 AG_GST_CHECK_PLUGIN(tcp)
 477 AG_GST_CHECK_PLUGIN(typefind)
 478 AG_GST_CHECK_PLUGIN(videotestsrc)
 479 AG_GST_CHECK_PLUGIN(videorate)
 480 AG_GST_CHECK_PLUGIN(videoscale)
 481 AG_GST_CHECK_PLUGIN(volume)
 482
 483 dnl iso-codes is optional, used by libgsttag
 484 AC_ARG_ENABLE(iso-codes,
 485 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 486 [case "${enableval}" in
 487   yes) enable_iso_codes=yes ;;
 488   no)  enable_iso_codes=no ;;
 489   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 490 esac
 491 ],
 492 [enable_iso_codes=yes]) dnl Default value
 493
 494 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 495 if test "x$enable_iso_codes" = "xyes"; then
 496   AC_MSG_RESULT([yes])
 497   have_iso_codes=no
 498   AC_MSG_CHECKING([whether iso-codes are available on this system])
 499   if $PKG_CONFIG iso-codes; then
 500     AC_MSG_RESULT([yes])
 501     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 502     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 503       AC_MSG_RESULT([yes])
 504       AC_MSG_CHECKING([for iso-codes prefix])
 505       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 506       if test -d "$ISO_CODES_PREFIX"; then
 507         AC_MSG_RESULT([yes])
 508         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 509         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 510         ISO_639_DOMAIN="iso_639"
 511         AC_MSG_CHECKING([ISO_639_DOMAIN])
 512         AC_MSG_RESULT([$ISO_639_DOMAIN])
 513         have_iso_codes=yes
 514         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 515         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 516         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 517         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 518       else
 519         AC_MSG_RESULT([no])
 520       fi
 521     else
 522       AC_MSG_RESULT([no])
 523     fi
 524   else
 525     AC_MSG_RESULT([no])
 526   fi
 527   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 528 else
 529   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 530   AM_CONDITIONAL(USE_ISO_CODES, false)
 531 fi
 532
 533 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 534 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 535 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 536   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 537       HAVE_ZLIB="yes"
 538     ], [
 539       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 540         HAVE_ZLIB="yes"
 541         ZLIB_LIBS="-lz"
 542         AC_SUBST(ZLIB_LIBS)
 543       ])
 544     ])
 545 ])
 546
 547 dnl *** sys plug-ins ***
 548
 549 echo
 550 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 551 echo
 552
 553 dnl *** X11 ***
 554 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 555 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 556                   [ximagesink], [
 557   AG_GST_PKG_CHECK_MODULES(X, x11)
 558 ])
 559
 560 dnl Check for Xv extension
 561 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 562 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 563                   [xvimagesink], [
 564   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 565 ])
 566
 567 dnl check for X Shm
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 569 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 570   if test x$HAVE_X = xyes; then
 571     PKG_CHECK_MODULES(XSHM, xext, [
 572       AC_CHECK_LIB(Xext, XShmAttach, [
 573         HAVE_XSHM="yes"
 574       ], [
 575         HAVE_XSHM="no"
 576         XSHM_LIBS=""
 577       ], [ $X_LIBS ])
 578     ], [
 579       HAVE_XSHM="no"
 580     ])
 581   fi
 582 ], , [
 583   AC_SUBST(HAVE_XSHM)
 584   AC_SUBST(XSHM_LIBS)
 585 ])
 586
 587 dnl *** ext plug-ins ***
 588 dnl keep this list sorted alphabetically !
 589
 590 if test "x$BUILD_EXTERNAL" = "xyes"; then
 591
 592 echo
 593 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 594 echo
 595
 596 dnl *** alsa ***
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 598 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 599   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 600     HAVE_ALSA="yes"
 601     AC_SUBST(ALSA_CFLAGS)
 602     AC_SUBST(ALSA_LIBS)
 603   ], [
 604     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 605   ])
 606 ])
 607
 608 dnl *** CDParanoia ***
 609 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 610 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 611 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 612   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 613     HAVE_CDPARANOIA="yes"
 614   ], [
 615     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 616                         cdda_open, -lm,
 617                         cdda_interface.h,
 618                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 619                         HEADER_DIR="no"
 620                         FOUND_CDPARANOIA="yes")
 621     if test "x$FOUND_CDPARANOIA" != "xyes";
 622     then
 623       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 624                           cdda_open, -lm,
 625                           cdda/cdda_interface.h,
 626                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 627                           HEADER_DIR="yes"
 628                           FOUND_CDPARANOIA="yes")
 629     fi
 630     if test "x$HEADER_DIR" = "xyes";
 631     then
 632       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 633                          defined if cdda headers are in a cdda/ directory)
 634     fi
 635     if test "x$FOUND_CDPARANOIA" = "xyes";
 636     then
 637       AC_CHECK_LIB(cdda_paranoia,
 638                    paranoia_cachemodel_size,
 639                    : ,
 640                    HAVE_CDPARANOIA=no,
 641                  [-lcdda_interface])
 642     fi
 643
 644     AC_SUBST(CDPARANOIA_LIBS)
 645   ])
 646 ])
 647 dnl FIXME : add second check somehow if that is necessary
 648 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 649 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 650
 651 dnl *** ivorbis ***
 652 dnl AM_PATH_IVORBIS only takes two options
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 654 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 655   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 656   if test $HAVE_IVORBIS = no
 657   then
 658     IVORBIS_LIBS=
 659     IVORBIS_CFLAGS=
 660     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 661       [IVORBIS_LIBS=-lvorbisidec
 662       HAVE_IVORBIS=yes
 663       case $host in
 664       arm-*-*)
 665         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 666       esac
 667       ],
 668       HAVE_IVORBIS=no)
 669     AC_SUBST(IVORBIS_LIBS)
 670     AC_SUBST(IVORBIS_CFLAGS)
 671   else
 672     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 673       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 674       USE_TREMOLO=no)
 675   fi
 676 ])
 677
 678 dnl *** libvisual ***
 679 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 680 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 681   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 682   if test x$HAVE_LIBVISUAL = xyes; then
 683     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 684   fi
 685   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 686   if test x$LIBVIS_PLUGINSDIR != x; then
 687     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 688         "$LIBVIS_PLUGINSDIR",
 689         [directory in which the detected libvisual's plugins are located])
 690   fi
 691 ])
 692
 693 dnl *** ogg ***
 694 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 695 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 696   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 697 ])
 698
 699 dnl *** Opus ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 701 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 702   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 703           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 704           HAVE_OPUS="yes"
 705   ], [
 706           HAVE_OPUS="no"
 707   ])
 708   AC_SUBST(OPUS_CFLAGS)
 709   AC_SUBST(OPUS_LIBS)
 710 ])
 711
 712 dnl *** pango ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 714 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 715   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 716 ])
 717
 718 dnl *** theora ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 720 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 721   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 722 ])
 723
 724 dnl *** vorbis ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 726 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 727   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 728 ])
 729
 730 if test "x$HAVE_VORBIS" = "xyes"; then
 731   ac_cflags_save="$CFLAGS"
 732   AC_COMPILE_IFELSE([
 733     AC_LANG_PROGRAM([[
 734 #include <vorbis/codec.h>
 735                      ]],[[
 736 vorbis_dsp_state *v;
 737
 738 vorbis_synthesis_restart (v);
 739                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 740   if test "x$HAVE_VSR" = "xyes"; then
 741     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 742                        [defined if vorbis_synthesis_restart is present])
 743   fi
 744   CFLAGS="$ac_cflags_save"
 745 fi
 746
 747 else
 748
 749 dnl not building plugins with external dependencies,
 750 dnl but we still need to set the conditionals
 751 AM_CONDITIONAL(USE_ALSA, false)
 752 AM_CONDITIONAL(USE_CDPARANOIA, false)
 753 AM_CONDITIONAL(USE_IVORBIS, false)
 754 AM_CONDITIONAL(USE_LIBVISUAL, false)
 755 AM_CONDITIONAL(USE_OGG, false)
 756 AM_CONDITIONAL(USE_OPUS, false)
 757 AM_CONDITIONAL(USE_PANGO, false)
 758 AM_CONDITIONAL(USE_THEORA, false)
 759 AM_CONDITIONAL(USE_VORBIS, false)
 760
 761 fi dnl of EXT plugins
 762
 763 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 764 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 765     HAVE_GIO_UNIX_2_0="yes",
 766     HAVE_GIO_UNIX_2_0="no")
 767 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 768
 769 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 770
 771 dnl Overview:
 772 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 773 dnl GST_*:              flags shared by built objects to link against GStreamer
 774 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 775 dnl                          (compare to other modules) or for i18n
 776 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 777 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 778 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 779 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 780
 781 dnl GST_OPTION_CFLAGS
 782 if test "x$USE_DEBUG" = xyes; then
 783    PROFILE_CFLAGS="-g"
 784 fi
 785 AC_SUBST(PROFILE_CFLAGS)
 786
 787 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 788   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 789   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 790 else
 791   DEPRECATED_CFLAGS=""
 792 fi
 793 AC_SUBST(DEPRECATED_CFLAGS)
 794
 795 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 796 dnl at make time with e.g. make ERROR_CFLAGS=""
 797 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 798 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 799 AC_SUBST(GST_OPTION_CFLAGS)
 800 AC_SUBST(GST_OPTION_CXXFLAGS)
 801
 802 dnl our libraries need to be versioned correctly
 803 AC_SUBST(GST_LT_LDFLAGS)
 804
 805 dnl GST_PLUGINS_BASE_CFLAGS
 806 dnl prefer internal headers to already installed ones
 807 dnl also add builddir include for enumtypes and marshal
 808 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 809 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 810
 811 dnl FIXME: do we want to rename to GST_ALL_* ?
 812 dnl add GST_OPTION_CFLAGS, but overridable
 813 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 814 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 815 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 816 AC_SUBST(GST_CFLAGS)
 817 AC_SUBST(GST_CXXFLAGS)
 818 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 819 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 820 AC_SUBST(GST_LIBS)
 821
 822 dnl LDFLAGS really should only contain flags, not libs - they get added before
 823 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 824 GST_ALL_LDFLAGS="-no-undefined"
 825 if test "x${enable_Bsymbolic}" = "xyes"; then
 826   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 827 fi
 828 AC_SUBST(GST_ALL_LDFLAGS)
 829
 830 dnl GST_LIB_LDFLAGS
 831 dnl linker flags shared by all libraries
 832 dnl LDFLAGS modifier defining exported symbols from built libraries
 833 dnl (export _gst_foo but not __gst_foo)
 834 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 835 AC_SUBST(GST_LIB_LDFLAGS)
 836
 837 dnl this really should only contain flags, not libs - they get added before
 838 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 839 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 840 AC_SUBST(GST_PLUGIN_LDFLAGS)
 841
 842 dnl *** output files ***
 843
 844 $MKDIR_P tests/check/orc
 845
 846 AC_CONFIG_FILES(
 847 Makefile
 848 gst-plugins-base.spec
 849 gst/Makefile
 850 gst/adder/Makefile
 851 gst/app/Makefile
 852 gst/audioconvert/Makefile
 853 gst/audiorate/Makefile
 854 gst/audiotestsrc/Makefile
 855 gst/encoding/Makefile
 856 gst/videoconvert/Makefile
 857 gst/gio/Makefile
 858 gst/playback/Makefile
 859 gst/audioresample/Makefile
 860 gst/subparse/Makefile
 861 gst/tcp/Makefile
 862 gst/typefind/Makefile
 863 gst/videotestsrc/Makefile
 864 gst/videorate/Makefile
 865 gst/videoscale/Makefile
 866 gst/volume/Makefile
 867 sys/Makefile
 868 sys/ximage/Makefile
 869 sys/xvimage/Makefile
 870 ext/Makefile
 871 ext/alsa/Makefile
 872 ext/cdparanoia/Makefile
 873 ext/libvisual/Makefile
 874 ext/ogg/Makefile
 875 ext/opus/Makefile
 876 ext/pango/Makefile
 877 ext/theora/Makefile
 878 ext/vorbis/Makefile
 879 gst-libs/Makefile
 880 gst-libs/gst/Makefile
 881 gst-libs/gst/allocators/Makefile
 882 gst-libs/gst/audio/Makefile
 883 gst-libs/gst/app/Makefile
 884 gst-libs/gst/fft/Makefile
 885 gst-libs/gst/riff/Makefile
 886 gst-libs/gst/rtp/Makefile
 887 gst-libs/gst/rtsp/Makefile
 888 gst-libs/gst/sdp/Makefile
 889 gst-libs/gst/tag/Makefile
 890 gst-libs/gst/pbutils/Makefile
 891 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 892 gst-libs/gst/video/Makefile
 893 tools/Makefile
 894 pkgconfig/Makefile
 895 pkgconfig/gstreamer-allocators.pc
 896 pkgconfig/gstreamer-allocators-uninstalled.pc
 897 pkgconfig/gstreamer-audio.pc
 898 pkgconfig/gstreamer-audio-uninstalled.pc
 899 pkgconfig/gstreamer-app.pc
 900 pkgconfig/gstreamer-app-uninstalled.pc
 901 pkgconfig/gstreamer-fft.pc
 902 pkgconfig/gstreamer-fft-uninstalled.pc
 903 pkgconfig/gstreamer-pbutils.pc
 904 pkgconfig/gstreamer-pbutils-uninstalled.pc
 905 pkgconfig/gstreamer-riff.pc
 906 pkgconfig/gstreamer-riff-uninstalled.pc
 907 pkgconfig/gstreamer-rtp.pc
 908 pkgconfig/gstreamer-rtp-uninstalled.pc
 909 pkgconfig/gstreamer-rtsp.pc
 910 pkgconfig/gstreamer-rtsp-uninstalled.pc
 911 pkgconfig/gstreamer-sdp.pc
 912 pkgconfig/gstreamer-sdp-uninstalled.pc
 913 pkgconfig/gstreamer-tag.pc
 914 pkgconfig/gstreamer-tag-uninstalled.pc
 915 pkgconfig/gstreamer-video.pc
 916 pkgconfig/gstreamer-video-uninstalled.pc
 917 pkgconfig/gstreamer-plugins-base.pc
 918 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 919 tests/Makefile
 920 tests/check/Makefile
 921 tests/examples/Makefile
 922 tests/examples/app/Makefile
 923 tests/examples/audio/Makefile
 924 tests/examples/decodebin_next/Makefile
 925 tests/examples/dynamic/Makefile
 926 tests/examples/encoding/Makefile
 927 tests/examples/fft/Makefile
 928 tests/examples/gio/Makefile
 929 tests/examples/overlay/Makefile
 930 tests/examples/seek/Makefile
 931 tests/examples/snapshot/Makefile
 932 tests/examples/playback/Makefile
 933 tests/examples/playrec/Makefile
 934 tests/files/Makefile
 935 tests/icles/Makefile
 936 tests/icles/playback/Makefile
 937 docs/Makefile
 938 docs/design/Makefile
 939 docs/libs/Makefile
 940 docs/plugins/Makefile
 941 docs/version.entities
 942 po/Makefile.in
 943 common/Makefile
 944 common/m4/Makefile
 945 m4/Makefile
 946 )
 947
 948 dnl Create the config.h file for Visual Studio builds
 949 dnl Beware of spaces and /'s in some of the shell variable contents.
 950 sed \
 951     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 952     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 953     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 954     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 955     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 956     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 957     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 958     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 959     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 960     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 961     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 962     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 963     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 964     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 965     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 966     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 967     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 968     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 969     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 970     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 971     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 972     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 973     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 974     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 975     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 976     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 977     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 978     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 979     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 980     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 981     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 982     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 983     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 984     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 985     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 986     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 987     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 988     config.h.in >win32/common/config.h-new
 989
 990
 991
 992 AC_OUTPUT
 993
 994 AG_GST_OUTPUT_PLUGINS
 995 ORC_OUTPUT
 996