configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [6])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 if test "$glib_native_win32" = "yes"; then
 516   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 517     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 518   fi
 519   if test x$enable_static = xyes; then
 520     glib_win32_static_compilation=yes
 521     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 522 #define GOBJECT_STATIC_COMPILATION 1"
 523     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 524   fi
 525 fi
 526 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 527
 528 dnl
 529 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 530 dnl
 531 if test $cross_compiling != yes ; then
 532     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 533     glib_save_LIBS=$LIBS
 534     LIBS="$LIBS -lm"
 535     AC_TRY_RUN([#include <math.h>
 536                  int main (void) { return (log(1) != log(1.)); }],
 537          AC_MSG_RESULT(none needed),
 538          glib_save_CFLAGS=$CFLAGS
 539          CFLAGS="$CFLAGS -std1"
 540          AC_TRY_RUN([#include <math.h>
 541                      int main (void) { return (log(1) != log(1.)); }],
 542              AC_MSG_RESULT(-std1),
 543              AC_MSG_RESULT()
 544              CFLAGS=$glib_save_CFLAGS
 545              AC_MSG_WARN(
 546                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 547          )
 548     )
 549     LIBS=$glib_save_LIBS
 550 fi
 551
 552 dnl NeXTStep cc seems to need this
 553 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 554 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 555   AC_MSG_RESULT(none needed),
 556   glib_save_CFLAGS=$CFLAGS
 557   CFLAGS="$CFLAGS -posix"
 558   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 559     AC_MSG_RESULT(-posix),
 560     AC_MSG_RESULT()
 561     CFLAGS=$glib_save_CFLAGS
 562     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 563
 564 # Checks for header files.
 565 AC_HEADER_STDC
 566
 567 # Checks for library functions.
 568 AC_FUNC_VPRINTF
 569 AC_FUNC_ALLOCA
 570 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 571 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 572
 573 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 574 dnl be automatically defined, which we don't want to do
 575 dnl until we have checked this function is actually usable
 576 AC_CHECK_FUNC([qsort_r])
 577
 578 # BSD has a qsort_r with wrong argument order
 579 if test x$ac_cv_func_qsort_r = xyes ; then
 580   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 581   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 582   #define _GNU_SOURCE
 583   #include <stdlib.h>
 584
 585   static int
 586   cmp (const void *a, const void *b, void *c)
 587   {
 588     const int *ia = a;
 589     const int *ib = b;
 590
 591     if (*ia < *ib)
 592       return -1;
 593     else if (*ia > *ib)
 594       return 1;
 595     else
 596       return 0;
 597   }
 598
 599   int
 600   main (int argc, char **argv)
 601   {
 602     int arr[3] = { 1, 2, 0 };
 603     int d = 3;
 604
 605     qsort_r (arr, 3, sizeof (int), cmp, &d);
 606
 607     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 608       return 0;
 609     else
 610       return 1;
 611   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no],[glib_cv_have_qsort_r=no])])
 612 fi
 613
 614 if test x$glib_cv_have_qsort_r = xyes ; then
 615   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 616 fi
 617
 618 AC_CHECK_SIZEOF(char)
 619 AC_CHECK_SIZEOF(short)
 620 AC_CHECK_SIZEOF(long)
 621 AC_CHECK_SIZEOF(int)
 622 AC_CHECK_SIZEOF(void *)
 623 AC_CHECK_SIZEOF(long long)
 624 AC_CHECK_SIZEOF(__int64)
 625
 626 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 627   :
 628 else
 629   AC_MSG_ERROR([
 630 *** GLib requires a 64 bit type. You might want to consider
 631 *** using the GNU C compiler.
 632 ])
 633 fi
 634
 635 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 636         # long long is a 64 bit integer.
 637         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 638         AC_CACHE_VAL(glib_cv_long_long_format,[
 639                 for format in ll q I64; do
 640                   AC_TRY_RUN([#include <stdio.h>
 641                         int main()
 642                         {
 643                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 644                           char buffer[1000];
 645                           sprintf (buffer, "%${format}u", a);
 646                           sscanf (buffer, "%${format}u", &b);
 647                           exit (b!=a);
 648                         }
 649                         ],
 650                         [glib_cv_long_long_format=${format}
 651                         break],
 652                         [],[:])
 653                 done])
 654         if test -n "$glib_cv_long_long_format"; then
 655           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 656           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 657           if test x"$glib_cv_long_long_format" = xI64; then
 658             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 659           fi
 660         else
 661           AC_MSG_RESULT(none)
 662         fi
 663 elif test x$ac_cv_sizeof___int64 = x8; then
 664         # __int64 is a 64 bit integer.
 665         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 666         # We know this is MSVCRT.DLL, and what the formats are
 667         glib_cv_long_long_format=I64
 668         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 669         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 670         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 671 fi
 672
 673 dnl long doubles were not used, and a portability problem
 674 dnl AC_C_LONG_DOUBLE
 675 AC_C_CONST
 676
 677 dnl ok, here we try to check whether the systems prototypes for
 678 dnl malloc and friends actually match the prototypes provided
 679 dnl by gmem.h (keep in sync). i currently only know how to check
 680 dnl this reliably with gcc (-Werror), improvements for other
 681 dnl compilers are apprechiated.
 682 SANE_MALLOC_PROTOS=no
 683 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 684 glib_save_CFLAGS=$CFLAGS
 685 if test "x$GCC" = "xyes"; then
 686   CFLAGS="$CFLAGS -Werror"
 687   AC_TRY_COMPILE([#include <stdlib.h>], [
 688     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 689     void* (*my_malloc_p)  (size_t)         = malloc;
 690     void  (*my_free_p)    (void*)          = free;
 691     void* (*my_realloc_p) (void*, size_t)  = realloc;
 692     my_calloc_p = 0;
 693     my_malloc_p = 0;
 694     my_free_p = 0;
 695     my_realloc_p = 0;
 696   ],
 697     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 698       [Define if you have correct malloc prototypes])
 699     SANE_MALLOC_PROTOS=yes)
 700 fi
 701 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 702 CFLAGS=$glib_save_CFLAGS
 703
 704 dnl
 705 dnl check in which direction the stack grows
 706 dnl
 707 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 708         AC_TRY_RUN([
 709         volatile int *a = 0, *b = 0;
 710         void foo (void);
 711         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 712         void foo (void) { volatile int x = 5; b = &x; }
 713         ],
 714         glib_cv_stack_grows=no
 715         ,
 716         glib_cv_stack_grows=yes
 717         ,)
 718 ])
 719
 720 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 721 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 722 dnl actually supported.
 723 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline=yes
 729         ,
 730         glib_cv_has__inline=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline in
 734 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 735 esac
 736 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         __inline__ int foo () { return 0; }
 739         int main () { return foo (); }
 740         ]])],
 741         glib_cv_has__inline__=yes
 742         ,
 743         glib_cv_has__inline__=no
 744         ,)
 745 ])
 746 case x$glib_cv_has__inline__ in
 747 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 748 esac
 749 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 750         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 751         #undef inline
 752         inline int foo () { return 0; }
 753         int main () { return foo (); }
 754         ]])],
 755         glib_cv_hasinline=yes
 756         ,
 757         glib_cv_hasinline=no
 758         ,)
 759 ])
 760 case x$glib_cv_hasinline in
 761 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 762 esac
 763
 764 # if we can use inline functions in headers
 765 AC_MSG_CHECKING(if inline functions in headers work)
 766 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 767 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 768 #  undef inline
 769 #  define inline __inline__
 770 #elif !defined (G_HAVE_INLINE)
 771 #  undef inline
 772 #  if defined (G_HAVE___INLINE__)
 773 #    define inline __inline__
 774 #  elif defined (G_HAVE___INLINE)
 775 #    define inline __inline
 776 #  endif
 777 #endif
 778
 779 int glib_test_func2 (int);
 780
 781 static inline int
 782 glib_test_func1 (void) {
 783   return glib_test_func2 (1);
 784 }
 785
 786 int
 787 main (void) {
 788   int i = 1;
 789 }]])],[g_can_inline=yes],[g_can_inline=no])
 790 AC_MSG_RESULT($g_can_inline)
 791
 792 dnl *** check for working do while(0) macros ***
 793 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 794         AC_TRY_COMPILE([],[
 795         #define STMT_START do
 796         #define STMT_END while(0)
 797         #define STMT_TEST STMT_START { i = 0; } STMT_END
 798         int main(void) { int i = 1; STMT_TEST; return i; }],
 799         [g_cv_support_dowhile_macros=yes],
 800         [g_cv_support_dowhile_macros=no],
 801         [g_cv_support_dowhile_macros=yes])
 802 ])
 803 if test x$g_cv_support_dowhile_macros = xyes; then
 804   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 805 fi
 806
 807 # check for flavours of varargs macros
 808 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 809 AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 814 AC_MSG_RESULT($g_have_iso_c_varargs)
 815
 816 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 817 if test "$CXX" = ""; then
 818 dnl No C++ compiler
 819   g_have_iso_cxx_varargs=no
 820 else
 821   AC_LANG_CPLUSPLUS
 822   AC_TRY_COMPILE([],[
 823 int a(int p1, int p2, int p3);
 824 #define call_a(...) a(1,__VA_ARGS__)
 825 call_a(2,3);
 826 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 827   AC_LANG_C
 828 fi
 829 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 830
 831 AC_MSG_CHECKING(for GNUC varargs macros)
 832 AC_TRY_COMPILE([],[
 833 int a(int p1, int p2, int p3);
 834 #define call_a(params...) a(1,params)
 835 call_a(2,3);
 836 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 837 AC_MSG_RESULT($g_have_gnuc_varargs)
 838
 839 # check for GNUC visibility support
 840 AC_MSG_CHECKING(for GNUC visibility attribute)
 841 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 842 void
 843 __attribute__ ((visibility ("hidden")))
 844      f_hidden (void)
 845 {
 846 }
 847 void
 848 __attribute__ ((visibility ("internal")))
 849      f_internal (void)
 850 {
 851 }
 852 void
 853 __attribute__ ((visibility ("protected")))
 854      f_protected (void)
 855 {
 856 }
 857 void
 858 __attribute__ ((visibility ("default")))
 859      f_default (void)
 860 {
 861 }
 862 int main (int argc, char **argv)
 863 {
 864         f_hidden();
 865         f_internal();
 866         f_protected();
 867         f_default();
 868         return 0;
 869 }
 870 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 871 AC_MSG_RESULT($g_have_gnuc_visibility)
 872 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 873
 874 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 875 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 876 #else
 877 # include "error: this is not Sun Studio."
 878 #endif
 879 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 880 AC_MSG_RESULT($g_have_sunstudio_visibility)
 881 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 882
 883 # check for bytesex stuff
 884 AC_C_BIGENDIAN
 885 if test x$ac_cv_c_bigendian = xuniversal ; then
 886 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 887 #else
 888 #error Not a big endian.
 889 #endif],
 890     ac_cv_c_bigendian=yes
 891     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 892 #else
 893 #error Not a little endian.
 894 #endif],
 895     ac_cv_c_bigendian=no
 896     ,AC_MSG_WARN([Could not determine endianness.])))
 897 fi
 898
 899
 900 # check for header files
 901 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 902 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 903 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 904 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 905 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 906 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 907 AC_CHECK_HEADERS([linux/magic.h])
 908 AC_CHECK_HEADERS([sys/prctl.h])
 909
 910 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 911 [#if HAVE_SYS_PARAM_H
 912  #include <sys/param.h>
 913  #endif
 914 ])
 915
 916 AC_CHECK_HEADERS([xlocale.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 935 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 936
 937 AC_STRUCT_DIRENT_D_TYPE
 938
 939 # Checks for libcharset
 940 AM_LANGINFO_CODESET
 941 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 942 AC_CHECK_FUNCS(setlocale)
 943
 944 # check additional type sizes
 945 AC_CHECK_SIZEOF(size_t)
 946
 947 dnl Try to figure out whether gsize, gssize should be long or int
 948 AC_MSG_CHECKING([for the appropriate definition for size_t])
 949
 950 case $ac_cv_sizeof_size_t in
 951   $ac_cv_sizeof_short)
 952       glib_size_type=short
 953       ;;
 954   $ac_cv_sizeof_int)
 955       glib_size_type=int
 956       ;;
 957   $ac_cv_sizeof_long)
 958       glib_size_type=long
 959       ;;
 960   $ac_cv_sizeof_long_long)
 961       glib_size_type='long long'
 962       ;;
 963   $ac_cv_sizeof__int64)
 964       glib_size_type='__int64'
 965       ;;
 966   *)  AC_MSG_ERROR([No type matching size_t in size])
 967       ;;
 968 esac
 969
 970 dnl If int/long are the same size, we see which one produces
 971 dnl warnings when used in the location as size_t. (This matters
 972 dnl on AIX with xlc)
 973 dnl
 974 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 975    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 976   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 977 #if defined(_AIX) && !defined(__GNUC__)
 978 #pragma options langlvl=stdc89
 979 #endif
 980 #include <stddef.h>
 981 int main ()
 982 {
 983   size_t s = 1;
 984   unsigned int *size_int = &s;
 985   return (int)*size_int;
 986 }
 987     ]])],glib_size_type=int,
 988       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 989 #if defined(_AIX) && !defined(__GNUC__)
 990 #pragma options langlvl=stdc89
 991 #endif
 992 #include <stddef.h>
 993 int main ()
 994 {
 995    size_t s = 1;
 996    unsigned long *size_long = &s;
 997    return (int)*size_long;
 998 }
 999         ]])],glib_size_type=long)])
1000 fi
1001
1002 AC_MSG_RESULT(unsigned $glib_size_type)
1003
1004 # Check for some functions
1005 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1006 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1007 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1008 # Check for high-resolution sleep functions
1009 AC_CHECK_FUNCS(splice)
1010 AC_CHECK_FUNCS(prlimit)
1011
1012 # To avoid finding a compatibility unusable statfs, which typically
1013 # successfully compiles, but warns to use the newer statvfs interface:
1014 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1015 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1016
1017 AC_MSG_CHECKING([whether to use statfs or statvfs])
1018 # Some systems have both statfs and statvfs, pick the most "native" for these
1019 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1020    [
1021    # on solaris and irix, statfs doesn't even have the f_bavail field
1022    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1023       [ac_cv_func_statfs=no],
1024    # else, at least on linux, statfs is the actual syscall
1025       [ac_cv_func_statvfs=no])
1026    ])
1027
1028 AS_IF([test x$ac_cv_func_statfs = xyes],
1029       [
1030          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1031          AC_MSG_RESULT([statfs])
1032       ],
1033       [test x$ac_cv_func_statvfs = xyes],
1034       [
1035          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1036          AC_MSG_RESULT([statvfs])
1037       ],
1038       [  AC_MSG_RESULT([neither])])
1039
1040 AC_CHECK_HEADERS(crt_externs.h)
1041 AC_CHECK_FUNCS(_NSGetEnviron)
1042
1043 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1044
1045 AC_FUNC_VSNPRINTF_C99
1046 AC_FUNC_PRINTF_UNIX98
1047
1048 # Internet address families
1049 if test $glib_native_win32 = yes; then
1050   glib_inet_includes=["
1051 #include <winsock2.h>
1052   "]
1053 else
1054   glib_inet_includes=["
1055 #include <sys/types.h>
1056 #include <sys/socket.h>
1057   "]
1058 fi
1059
1060 glib_failed=false
1061 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1062 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1063 # winsock defines this even though it doesn't support it
1064 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1065 if $glib_failed ; then
1066   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1067 fi
1068
1069 glib_failed=false
1070 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1071 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1072 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1073 if $glib_failed ; then
1074   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1075 fi
1076
1077 AC_CHECK_FUNCS(getprotobyname_r endservent)
1078 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1079
1080 if test $glib_native_win32 = no; then
1081   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1082   NETWORK_LIBS=""
1083   AC_MSG_CHECKING([for res_query])
1084   AC_TRY_LINK([#include <sys/types.h>
1085                #include <netinet/in.h>
1086                #include <arpa/nameser.h>
1087                #include <resolv.h>
1088               ],[
1089                res_query("test", 0, 0, (void *)0, 0);
1090               ],[AC_MSG_RESULT([yes])],
1091               [save_libs="$LIBS"
1092                LIBS="-lresolv $LIBS"
1093                AC_TRY_LINK([#include <sys/types.h>
1094                             #include <netinet/in.h>
1095                             #include <arpa/nameser.h>
1096                             #include <resolv.h>
1097                            ],[
1098                             res_query("test", 0, 0, (void *)0, 0);
1099                            ],[AC_MSG_RESULT([in -lresolv])
1100                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1101                            [LIBS="-lbind $save_libs"
1102                             AC_TRY_LINK([#include <resolv.h>],
1103                                         [res_query("test", 0, 0, (void *)0, 0);],
1104                                         [AC_MSG_RESULT([in -lbind])
1105                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1106                                         [AC_MSG_ERROR(not found)])])
1107                LIBS="$save_libs"])
1108   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1109                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1110                                         [AC_MSG_ERROR(Could not find socket())]))
1111 fi
1112 AC_SUBST(NETWORK_LIBS)
1113
1114 AC_CHECK_HEADER([linux/netlink.h],
1115                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1116                 [#include <sys/socket.h>])
1117 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1118
1119 case $host in
1120   *-*-solaris* )
1121      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1122      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1123      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1124      ;;
1125 esac
1126
1127 dnl
1128 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1129 dnl
1130 if test "$ac_cv_func_statfs" = yes ; then
1131   AC_MSG_CHECKING([number of arguments to statfs()])
1132   AC_TRY_COMPILE([#include <unistd.h>
1133   #ifdef HAVE_SYS_PARAM_H
1134   #include <sys/param.h>
1135   #endif
1136   #ifdef HAVE_SYS_VFS_H
1137   #include <sys/vfs.h>
1138   #endif
1139   #ifdef HAVE_SYS_MOUNT_H
1140   #include <sys/mount.h>
1141   #endif
1142   #ifdef HAVE_SYS_STATFS_H
1143   #include <sys/statfs.h>
1144   #endif], [struct statfs st;
1145   statfs(NULL, &st);],[
1146     AC_MSG_RESULT([2])
1147     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1148     AC_TRY_COMPILE([#include <unistd.h>
1149   #ifdef HAVE_SYS_PARAM_H
1150   #include <sys/param.h>
1151   #endif
1152   #ifdef HAVE_SYS_VFS_H
1153   #include <sys/vfs.h>
1154   #endif
1155   #ifdef HAVE_SYS_MOUNT_H
1156   #include <sys/mount.h>
1157   #endif
1158   #ifdef HAVE_SYS_STATFS_H
1159   #include <sys/statfs.h>
1160   #endif], [struct statfs st;
1161   statfs(NULL, &st, sizeof (st), 0);],[
1162       AC_MSG_RESULT([4])
1163       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1164       AC_MSG_RESULT(unknown)
1165       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1166 fi
1167
1168 #
1169 # Check whether to use an included printf
1170 #
1171
1172 AC_ARG_ENABLE(included-printf,
1173               [AC_HELP_STRING([--enable-included-printf],
1174                               [use included printf [default=auto]])],
1175               enable_included_printf="$enableval")
1176
1177 need_included_printf=no
1178 if test "x$enable_included_printf" = "xyes" ; then
1179   need_included_printf=yes
1180 fi
1181 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1182   need_included_printf=yes
1183 fi
1184 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1185   need_included_printf=yes
1186 fi
1187 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1188    test -z "$glib_cv_long_long_format" ; then
1189   need_included_printf=yes
1190 fi
1191
1192 if test "x$enable_included_printf" = "xno" &&
1193    test "x$need_included_printf" = "xyes" ; then
1194   AC_MSG_ERROR([
1195 *** Your C library's printf doesn't appear to have the features that
1196 *** GLib needs, but you specified --enable-included-printf=no.])
1197 fi
1198
1199 enable_included_printf=$need_included_printf
1200
1201 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1202 if test "$enable_included_printf" != "yes" ; then
1203   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1204 else
1205   if test -z "$glib_cv_long_long_format" ; then
1206     glib_cv_long_long_format="ll"
1207   fi
1208   AC_DEFINE(HAVE_VASPRINTF,1)
1209 fi
1210
1211 # Checks needed for gnulib vasnprintf
1212 bh_C_SIGNED
1213 jm_AC_TYPE_LONG_LONG
1214 gt_TYPE_LONGDOUBLE
1215 gt_TYPE_WCHAR_T
1216 gt_TYPE_WINT_T
1217 AC_TYPE_SIZE_T
1218 AC_CHECK_TYPES(ptrdiff_t)
1219 jm_AC_TYPE_INTMAX_T
1220 AC_CHECK_FUNCS([snprintf wcslen])
1221 AC_FUNC_SNPRINTF_C99
1222
1223 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1224 # The check is borrowed from the PERL Configure script.
1225 if test "$ac_cv_func_memmove" != "yes"; then
1226   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1227     glib_cv_working_bcopy,[AC_TRY_RUN([
1228       int main() {
1229         char buf[128], abc[128], *b;
1230         int len, off, align;
1231         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1232         for (align = 7; align >= 0; align--) {
1233           for (len = 36; len; len--) {
1234             b = buf+align; bcopy(abc, b, len);
1235             for (off = 1; off <= len; off++) {
1236               bcopy(b, b+off, len); bcopy(b+off, b, len);
1237                 if (bcmp(b, abc, len)) return(1);
1238             }
1239           }
1240         }
1241         return(0);
1242       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1243
1244   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1245   if test "$glib_cv_working_bcopy" = "yes"; then
1246     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1247   fi
1248 fi
1249
1250 # Check if <sys/select.h> needs to be included for fd_set
1251 AC_MSG_CHECKING([for fd_set])
1252 AC_TRY_COMPILE([#include <sys/types.h>],
1253         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1254 if test "$gtk_ok" = "yes"; then
1255     AC_MSG_RESULT([yes, found in sys/types.h])
1256 else
1257     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1258     if test "$gtk_ok" = "yes"; then
1259         # *** FIXME: give it a different name
1260         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1261         AC_MSG_RESULT([yes, found in sys/select.h])
1262     else
1263         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1264         AC_MSG_RESULT(no)
1265     fi
1266 fi
1267
1268 dnl *** check for sane realloc() ***
1269 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1270         AC_TRY_RUN([#include <stdlib.h>
1271         int main() {
1272           return realloc (0, sizeof (int)) == 0;
1273         }],
1274         [glib_cv_sane_realloc=yes],
1275         [glib_cv_sane_realloc=no],
1276         [glib_cv_sane_realloc=yes])
1277 ])
1278 if test x$glib_cv_sane_realloc = xyes; then
1279   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1280 fi
1281
1282 dnl Check for nl_langinfo and CODESET
1283 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1284         AC_TRY_COMPILE([#include <langinfo.h>],
1285                 [char *codeset = nl_langinfo (CODESET);],
1286                 [glib_cv_langinfo_codeset=yes],
1287                 [glib_cv_langinfo_codeset=no])])
1288 if test x$glib_cv_langinfo_codeset = xyes; then
1289   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1290 fi
1291
1292 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1293 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1294         AC_TRY_COMPILE([#include <langinfo.h>],
1295                 [char *str;
1296                  str = nl_langinfo (PM_STR);
1297                  str = nl_langinfo (D_T_FMT);
1298                  str = nl_langinfo (D_FMT);
1299                  str = nl_langinfo (T_FMT);
1300                  str = nl_langinfo (T_FMT_AMPM);
1301                  str = nl_langinfo (MON_1);
1302                  str = nl_langinfo (ABMON_12);
1303                  str = nl_langinfo (DAY_1);
1304                  str = nl_langinfo (ABDAY_7);],
1305                 [glib_cv_langinfo_time=yes],
1306                 [glib_cv_langinfo_time=no])])
1307 if test x$glib_cv_langinfo_time = xyes; then
1308   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1309 fi
1310
1311 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1312 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1313         AC_TRY_COMPILE([#include <langinfo.h>],
1314                 [char *str;
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1318                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1319                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1320                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1321                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1322                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1323                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1324                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1325                 [glib_cv_langinfo_outdigit=yes],
1326                 [glib_cv_langinfo_outdigit=no])])
1327 if test x$glib_cv_langinfo_outdigit = xyes; then
1328   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1329 fi
1330
1331 dnl ****************************************
1332 dnl *** posix_memalign                   ***
1333 dnl ****************************************
1334 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1335 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1336     glib_cv_compliant_posix_memalign=0
1337     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1338         AC_TRY_RUN([
1339                 #define _XOPEN_SOURCE 600
1340                 #include <stdlib.h> /* posix_memalign() should be defined here */
1341                 /* some systems break if #include <malloc.h> used */
1342                 static void test_memalign (size_t boundary, size_t size) {
1343                     void *mem = 0;
1344                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1345                         exit (1);
1346                     else
1347                       free (mem);
1348                 }
1349                 int main() {
1350                     test_memalign (  128,   128 - 2 * sizeof (void*));
1351                     test_memalign (  256,   256 - 2 * sizeof (void*));
1352                     test_memalign (  512,   512 - 2 * sizeof (void*));
1353                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1354                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1355                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1356                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1357                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1358                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1359                     exit (0); /* success */
1360                 }
1361                 ],
1362             [glib_cv_compliant_posix_memalign=1], [], [:])
1363       :
1364     fi
1365     ])
1366 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1367     AC_MSG_RESULT(yes)
1368     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1369 else
1370     AC_MSG_RESULT(no)
1371 fi
1372
1373
1374 dnl ****************************************
1375 dnl *** strlcpy/strlcat                  ***
1376 dnl ****************************************
1377 # Check for strlcpy
1378 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1379 AC_TRY_RUN([#include <stdlib.h>
1380 #include <string.h>
1381 int main() {
1382   char p[10];
1383   (void) strlcpy (p, "hi", 10);
1384   if (strlcat (p, "bye", 0) != 3)
1385     return 1;
1386   return 0;
1387 }], glib_cv_have_strlcpy=yes,
1388     glib_cv_have_strlcpy=no,
1389     glib_cv_have_strlcpy=no)])
1390 if test "$glib_cv_have_strlcpy" = "yes"; then
1391     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1392 fi
1393
1394
1395 dnl **********************
1396 dnl *** va_copy checks ***
1397 dnl **********************
1398 dnl we currently check for all three va_copy possibilities, so we get
1399 dnl all results in config.log for bug reports.
1400 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1401         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1402 #include <stdlib.h>
1403         void f (int i, ...) {
1404         va_list args1, args2;
1405         va_start (args1, i);
1406         va_copy (args2, args1);
1407         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1408           exit (1);
1409         va_end (args1); va_end (args2);
1410         }
1411         int main() {
1412           f (0, 42);
1413           return 0;
1414         }]])],
1415         [glib_cv_va_copy=yes],
1416         [glib_cv_va_copy=no])
1417 ])
1418 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1419         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1420 #include <stdlib.h>
1421         void f (int i, ...) {
1422         va_list args1, args2;
1423         va_start (args1, i);
1424         __va_copy (args2, args1);
1425         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1426           exit (1);
1427         va_end (args1); va_end (args2);
1428         }
1429         int main() {
1430           f (0, 42);
1431           return 0;
1432         }]])],
1433         [glib_cv___va_copy=yes],
1434         [glib_cv___va_copy=no])
1435 ])
1436
1437 if test "x$glib_cv_va_copy" = "xyes"; then
1438   g_va_copy_func=va_copy
1439 else if test "x$glib_cv___va_copy" = "xyes"; then
1440   g_va_copy_func=__va_copy
1441 fi
1442 fi
1443
1444 if test -n "$g_va_copy_func"; then
1445   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1446 fi
1447
1448 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1449         AC_TRY_RUN([#include <stdarg.h>
1450 #include <stdlib.h>
1451         void f (int i, ...) {
1452         va_list args1, args2;
1453         va_start (args1, i);
1454         args2 = args1;
1455         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1456           exit (1);
1457         va_end (args1); va_end (args2);
1458         }
1459         int main() {
1460           f (0, 42);
1461           return 0;
1462         }],
1463         [glib_cv_va_val_copy=yes],
1464         [glib_cv_va_val_copy=no],
1465         [glib_cv_va_val_copy=yes])
1466 ])
1467
1468 if test "x$glib_cv_va_val_copy" = "xno"; then
1469   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1470 fi
1471
1472 dnl ***********************
1473 dnl *** g_module checks ***
1474 dnl ***********************
1475 G_MODULE_LIBS=
1476 G_MODULE_LIBS_EXTRA=
1477 G_MODULE_PLUGIN_LIBS=
1478 if test x"$glib_native_win32" = xyes; then
1479   dnl No use for this on Win32
1480   G_MODULE_LDFLAGS=
1481 else
1482   export SED
1483   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1484 fi
1485 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1486 G_MODULE_NEED_USCORE=0
1487 G_MODULE_BROKEN_RTLD_GLOBAL=0
1488 G_MODULE_HAVE_DLERROR=0
1489 dnl *** force native WIN32 shared lib loader
1490 if test -z "$G_MODULE_IMPL"; then
1491   case "$host" in
1492   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1493   esac
1494 fi
1495 dnl *** force native AIX library loader
1496 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1497 if test -z "$G_MODULE_IMPL"; then
1498   case "$host" in
1499   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1500   esac
1501 fi
1502 dnl *** dlopen() and dlsym() in system libraries
1503 if test -z "$G_MODULE_IMPL"; then
1504         AC_CHECK_FUNC(dlopen,
1505                       [AC_CHECK_FUNC(dlsym,
1506                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1507                       [])
1508 fi
1509 dnl *** load_image (BeOS)
1510 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1511   AC_CHECK_LIB(root, load_image,
1512       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1513       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1514       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1515       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1516       [])
1517 fi
1518 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1519 if test -z "$G_MODULE_IMPL"; then
1520         AC_CHECK_FUNC(NSLinkModule,
1521                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1522                        G_MODULE_NEED_USCORE=1],
1523                       [])
1524 fi
1525 dnl *** dlopen() and dlsym() in libdl
1526 if test -z "$G_MODULE_IMPL"; then
1527         AC_CHECK_LIB(dl, dlopen,
1528                      [AC_CHECK_LIB(dl, dlsym,
1529                                    [G_MODULE_LIBS=-ldl
1530                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1531                      [])
1532 fi
1533 dnl *** shl_load() in libdld (HP-UX)
1534 if test -z "$G_MODULE_IMPL"; then
1535         AC_CHECK_LIB(dld, shl_load,
1536                 [G_MODULE_LIBS=-ldld
1537                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1538                 [])
1539 fi
1540 dnl *** additional checks for G_MODULE_IMPL_DL
1541 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1542         LIBS_orig="$LIBS"
1543         LDFLAGS_orig="$LDFLAGS"
1544         LIBS="$G_MODULE_LIBS $LIBS"
1545         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1546 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1547         echo "void glib_plugin_test(void) { }" > plugin.c
1548         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1549                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1550         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1551                 glib_cv_rtldglobal_broken,[
1552                 AC_TRY_RUN([
1553 #include <dlfcn.h>
1554 #ifndef RTLD_GLOBAL
1555 #  define RTLD_GLOBAL 0
1556 #endif
1557 #ifndef RTLD_LAZY
1558 #  define RTLD_LAZY 0
1559 #endif
1560 int glib_plugin_test;
1561 int main () {
1562     void *handle, *global, *local;
1563     global = &glib_plugin_test;
1564     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1565     if (!handle) return 0;
1566     local = dlsym (handle, "glib_plugin_test");
1567     return global == local;
1568 }                       ],
1569                         [glib_cv_rtldglobal_broken=no],
1570                         [glib_cv_rtldglobal_broken=yes],
1571                         [glib_cv_rtldglobal_broken=no])
1572                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1573                 rmdir .libs 2>/dev/null
1574         ])
1575         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1576                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1577         else
1578                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1579         fi
1580 dnl *** check whether we need preceeding underscores
1581         AC_CACHE_CHECK([for preceeding underscore in symbols],
1582                 glib_cv_uscore,[
1583                 AC_TRY_RUN([#include <dlfcn.h>
1584                 int glib_underscore_test (void) { return 42; }
1585                 int main() {
1586                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1587                   handle = dlopen ((void*)0, 0);
1588                   if (handle) {
1589                     f1 = dlsym (handle, "glib_underscore_test");
1590                     f2 = dlsym (handle, "_glib_underscore_test");
1591                   } return (!f2 || f1);
1592                 }],
1593                         [glib_cv_uscore=yes],
1594                         [glib_cv_uscore=no],
1595                         [])
1596                 rm -f plugin.c plugin.$ac_objext plugin.lo
1597         ])
1598         GLIB_ASSERT_SET(glib_cv_uscore)
1599         if test "x$glib_cv_uscore" = "xyes"; then
1600                 G_MODULE_NEED_USCORE=1
1601         else
1602                 G_MODULE_NEED_USCORE=0
1603         fi
1604
1605         LDFLAGS="$LDFLAGS_orig"
1606 dnl *** check for having dlerror()
1607         AC_CHECK_FUNC(dlerror,
1608                 [G_MODULE_HAVE_DLERROR=1],
1609                 [G_MODULE_HAVE_DLERROR=0])
1610         LIBS="$LIBS_orig"
1611 fi
1612 dnl *** done, have we got an implementation?
1613 if test -z "$G_MODULE_IMPL"; then
1614         G_MODULE_IMPL=0
1615         G_MODULE_SUPPORTED=false
1616 else
1617         G_MODULE_SUPPORTED=true
1618 fi
1619
1620 AC_MSG_CHECKING(for the suffix of module shared libraries)
1621 export SED
1622 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1623 eval $shrext_cmds
1624 module=yes eval std_shrext=$shrext_cmds
1625 # chop the initial dot
1626 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1627 AC_MSG_RESULT(.$glib_gmodule_suffix)
1628 # any reason it may fail?
1629 if test "x$glib_gmodule_suffix" = x; then
1630         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1631 fi
1632
1633 AC_SUBST(G_MODULE_SUPPORTED)
1634 AC_SUBST(G_MODULE_IMPL)
1635 AC_SUBST(G_MODULE_LIBS)
1636 AC_SUBST(G_MODULE_LIBS_EXTRA)
1637 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1638 AC_SUBST(G_MODULE_LDFLAGS)
1639 AC_SUBST(G_MODULE_HAVE_DLERROR)
1640 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1641 AC_SUBST(G_MODULE_NEED_USCORE)
1642 AC_SUBST(GLIB_DEBUG_FLAGS)
1643
1644 dnl **********************
1645 dnl *** g_spawn checks ***
1646 dnl **********************
1647
1648 AC_MSG_CHECKING(for gspawn implementation)
1649 case "$host" in
1650   *-*-mingw*)
1651     GSPAWN=gspawn-win32.lo
1652     ;;
1653   *)
1654     GSPAWN=gspawn.lo
1655     ;;
1656 esac
1657 AC_MSG_RESULT($GSPAWN)
1658 AC_SUBST(GSPAWN)
1659
1660 dnl *************************
1661 dnl *** GIOChannel checks ***
1662 dnl *************************
1663
1664 AC_MSG_CHECKING(for GIOChannel implementation)
1665 case "$host" in
1666   *-*-mingw*)
1667     GIO=giowin32.lo
1668     ;;
1669   *)
1670     GIO=giounix.lo
1671     ;;
1672 esac
1673 AC_MSG_RESULT($GIO)
1674 AC_SUBST(GIO)
1675
1676 dnl *********************************
1677 dnl *** Directory for GIO modules ***
1678 dnl *********************************
1679
1680 AC_ARG_WITH(gio-module-dir,
1681            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1682                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1683            [],
1684            [with_gio_module_dir='${libdir}/gio/modules'])
1685 GIO_MODULE_DIR=$with_gio_module_dir
1686 AC_SUBST(GIO_MODULE_DIR)
1687
1688 dnl **********************************
1689 dnl *** Check for libselinux (GIO) ***
1690 dnl **********************************
1691 AC_ARG_ENABLE(selinux,
1692               AC_HELP_STRING([--disable-selinux],
1693                              [build without selinux support]))
1694 msg_selinux=no
1695 SELINUX_LIBS=
1696 if test "x$enable_selinux" != "xno"; then
1697
1698  AC_CHECK_LIB(selinux, is_selinux_enabled,
1699    [AC_CHECK_HEADERS(selinux/selinux.h,
1700      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1701        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1702         SELINUX_LIBS="-lselinux"
1703         msg_selinux=yes])
1704      ])
1705    ])
1706 fi
1707 AC_SUBST(SELINUX_LIBS)
1708
1709 dnl *****************************
1710 dnl ** Check for inotify (GIO) **
1711 dnl *****************************
1712 inotify_support=no
1713 AC_CHECK_HEADERS([sys/inotify.h],
1714 [
1715         inotify_support=yes
1716         AC_CHECK_FUNCS(inotify_init1)
1717 ])
1718
1719 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1720
1721 dnl *********************************
1722 dnl ** Check for Solaris FEN (GIO) **
1723 dnl *********************************
1724 fen_support=no
1725 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1726 #include <port.h>
1727 #ifndef PORT_SOURCE_FILE
1728 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1729 #endif
1730 int main() { return 0; } ]])],
1731 [
1732         fen_support=yes
1733 ],)
1734
1735 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1736
1737 dnl ****************************
1738 dnl *** Checks for FAM (GIO) ***
1739 dnl ****************************
1740
1741 should_disable_fam=no
1742
1743 AC_ARG_ENABLE(fam,
1744               AC_HELP_STRING([--disable-fam],
1745                              [don't use fam for file system monitoring]),
1746                          [
1747                                 if test "x$enable_fam" = "xno"; then
1748                                         should_disable_fam=yes
1749                                 fi
1750                          ]
1751                          )
1752 fam_support=no
1753 FAM_LIBS=
1754 if test "x$should_disable_fam" = "xno"; then
1755 AC_CHECK_LIB(fam, FAMOpen,
1756   [AC_CHECK_HEADERS(fam.h,
1757     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1758      AC_CHECK_LIB(fam, FAMNoExists,
1759                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1760      FAM_LIBS="-lfam"]
1761      fam_support=yes,
1762     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1763   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1764 AC_SUBST(FAM_LIBS)
1765 fi
1766 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1767
1768
1769 dnl *****************************
1770 dnl *** Check for xattr (GIO) ***
1771 dnl *****************************
1772 AC_ARG_ENABLE(xattr,
1773               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1774 msg_xattr=no
1775 XATTR_LIBS=
1776 if test "x$enable_xattr" != "xno"; then
1777
1778 dnl either glibc or libattr can provide xattr support
1779
1780 dnl for both of them, we check for getxattr being in
1781 dnl the library and a valid xattr header.
1782
1783 dnl try glibc
1784  AC_CHECK_LIB(c, getxattr,
1785    [AC_CHECK_HEADERS(sys/xattr.h,
1786      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1787       msg_xattr=yes])
1788    ])
1789
1790   if test "x$msg_xattr" != "xyes"; then
1791 dnl   failure. try libattr
1792    AC_CHECK_LIB(attr, getxattr,
1793       [AC_CHECK_HEADERS(attr/xattr.h,
1794        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1795         XATTR_LIBS="-lattr"
1796         msg_xattr=yes])
1797       ])
1798   fi
1799
1800   if test "x$msg_xattr" = "xyes"; then
1801     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1802     AC_TRY_COMPILE([
1803       #include <stdio.h>
1804       #ifdef HAVE_SYS_TYPES_H
1805       #include <sys/types.h>
1806       #endif
1807       #ifdef HAVE_SYS_XATTR_H
1808       #include <sys/xattr.h>
1809       #elif HAVE_ATTR_XATTR_H
1810       #include <attr/xattr.h>
1811       #endif
1812     ],
1813     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1814     [
1815       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1816       AC_MSG_RESULT([yes])
1817     ],
1818     [AC_MSG_RESULT([no])]
1819     )
1820   fi
1821
1822 fi
1823 AC_SUBST(XATTR_LIBS)
1824
1825 dnl ****************************************
1826 dnl *** platform dependent source checks ***
1827 dnl ****************************************
1828
1829 AC_MSG_CHECKING(for platform-dependent source)
1830 case "$host" in
1831   *-*-cygwin*|*-*-mingw*)
1832     PLATFORMDEP=gwin32.lo
1833     ;;
1834   *)
1835     PLATFORMDEP=
1836     ;;
1837 esac
1838 AC_MSG_RESULT($PLATFORMDEP)
1839 AC_SUBST(PLATFORMDEP)
1840
1841 AC_MSG_CHECKING([whether to compile timeloop])
1842 case "$host" in
1843   *-*-cygwin*|*-*-mingw*|*-*-minix)
1844     enable_timeloop=no
1845     ;;
1846   *)
1847     enable_timeloop=yes
1848     ;;
1849 esac
1850 AC_MSG_RESULT($enable_timeloop)
1851 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1852
1853 AC_MSG_CHECKING([if building for some Win32 platform])
1854 case "$host" in
1855   *-*-mingw*|*-*-cygwin*)
1856     platform_win32=yes
1857     ;;
1858   *)
1859     platform_win32=no
1860     ;;
1861 esac
1862 AC_MSG_RESULT($platform_win32)
1863 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1864
1865 dnl ***********************
1866 dnl *** g_thread checks ***
1867 dnl ***********************
1868
1869 AC_ARG_WITH(threads,
1870            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1871                            [specify a thread implementation to use])],
1872            [if test "x$with_threads" = x; then
1873                 want_threads=yes
1874             else
1875                 want_threads=$with_threads
1876             fi],
1877            [want_threads=yes])
1878
1879 dnl error and warning message
1880 dnl *************************
1881
1882 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1883                 computer."
1884
1885 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1886                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1887                 compilation now, but then your programs might not work.
1888                 Please provide information on how it is done on your system."
1889
1890 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1891                 "
1892
1893 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1894                 provide information on your thread implementation."
1895
1896 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1897                 functions will not be MT-safe during their first call because
1898                 there is no working 'getpwuid_r' on your system."
1899
1900 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1901                 because there is no 'localtime_r' on your system."
1902
1903 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1904                 crude surrogate will be used. If you happen to know a
1905                 yield function for your system, please inform the GLib
1906                 developers."
1907
1908 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1909                 threads on your system. Thus threads can only have the default
1910                 priority. If you happen to know these main/max
1911                 priorities, please inform the GLib developers."
1912
1913 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1914                 linking threaded applications. As GLib cannot do that
1915                 automatically, you will get an linkg error everytime you are
1916                 not using the right compiler. In that case you have to relink
1917                 with the right compiler. Ususally just '_r' is appended
1918                 to the compiler name."
1919
1920 dnl determination of thread implementation
1921 dnl ***************************************
1922
1923 have_threads=no
1924 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1925                                 || test "x$want_threads" = xdce; then
1926         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1927         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1928         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1929         glib_save_CPPFLAGS="$CPPFLAGS"
1930         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1931         if test "x$have_threads" = xno; then
1932                 AC_TRY_COMPILE([#include <pthread.h>],
1933                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1934                         have_threads=posix)
1935         fi
1936         # Tru64Unix requires -pthread to find pthread.h. See #103020
1937         CPPFLAGS="$CPPFLAGS -pthread"
1938         if test "x$have_threads" = xno; then
1939         AC_TRY_COMPILE([#include <pthread.h>],
1940                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1941                        have_threads=posix)
1942         fi
1943         CPPFLAGS="$glib_save_CPPFLAGS"
1944 fi
1945 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1946         case $host in
1947                 *-*-mingw*)
1948                 have_threads=win32
1949                 ;;
1950         esac
1951 fi
1952
1953 AC_MSG_CHECKING(for thread implementation)
1954
1955 if test "x$have_threads" = xno; then
1956         AC_MSG_RESULT(none available)
1957         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1958 else
1959         AC_MSG_RESULT($have_threads)
1960 fi
1961
1962
1963 dnl determination of G_THREAD_CFLAGS
1964 dnl ********************************
1965
1966 G_THREAD_LIBS=
1967 G_THREAD_LIBS_EXTRA=
1968 G_THREAD_CFLAGS=
1969
1970 dnl
1971 dnl Test program for basic POSIX threads functionality
1972 dnl
1973 m4_define([glib_thread_test],[
1974 #include <pthread.h>
1975 int check_me = 0;
1976 void* func(void* data) {check_me = 42; return &check_me;}
1977 int main()
1978  { pthread_t t;
1979    void *ret;
1980    pthread_create (&t, $1, func, 0);
1981    pthread_join (t, &ret);
1982    return (check_me != 42 || ret != &check_me);
1983 }])
1984
1985 dnl
1986 dnl Test program for sched_get_priority_min()
1987 dnl
1988 m4_define([glib_sched_priority_test],[
1989 #include <sched.h>
1990 #include <errno.h>
1991 int main() {
1992     errno = 0;
1993     return sched_get_priority_min(SCHED_OTHER)==-1
1994            && errno != 0;
1995 }])
1996
1997 if test x"$have_threads" = xposix; then
1998   # First we test for posix, whether -pthread or -pthreads do the trick as
1999   # both CPPFLAG and LIBS.
2000   # One of them does for most gcc versions and some other platforms/compilers
2001   # too and could be considered as the canonical way to go.
2002   case $host in
2003     *-*-cygwin*|*-*-darwin*)
2004        # skip cygwin and darwin -pthread or -pthreads test
2005        ;;
2006     *-solaris*)
2007       # These compiler/linker flags work with both Sun Studio and gcc
2008       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2009       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2010       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2011       G_THREAD_LIBS="-lpthread -lthread"
2012       ;;
2013     *)
2014       for flag in pthread pthreads mt; do
2015         glib_save_CFLAGS="$CFLAGS"
2016         CFLAGS="$CFLAGS -$flag"
2017         AC_TRY_RUN(glib_thread_test(0),
2018                    glib_flag_works=yes,
2019                    glib_flag_works=no,
2020                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2021                                    glib_flag_works=yes,
2022                                    glib_flag_works=no)])
2023         CFLAGS="$glib_save_CFLAGS"
2024         if test $glib_flag_works = yes ; then
2025            G_THREAD_CFLAGS=-$flag
2026         G_THREAD_LIBS=-$flag
2027         break;
2028         fi
2029       done
2030        ;;
2031   esac
2032 fi
2033
2034 if test x"$G_THREAD_CFLAGS" = x; then
2035
2036   # The canonical -pthread[s] does not work. Try something different.
2037
2038   case $host in
2039         *-aix*)
2040                 if test x"$GCC" = xyes; then
2041                         # GCC 3.0 and above needs -pthread.
2042                         # Should be coverd by the case above.
2043                         # GCC 2.x and below needs -mthreads
2044                         G_THREAD_CFLAGS="-mthreads"
2045                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2046                 else
2047                         # We are probably using the aix compiler. Normaly a
2048                         # program would have to be compiled with the _r variant
2049                         # of the corresponding compiler, but we as GLib cannot
2050                         # do that: but the good news is that for compiling the
2051                         # only difference is the added -D_THREAD_SAFE compile
2052                         # option. This is according to the "C for AIX User's
2053                         # Guide".
2054                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2055                 fi
2056                 ;;
2057         *-dg-dgux*)  # DG/UX
2058                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2059                 ;;
2060         *-sysv5uw7*) # UnixWare 7
2061                 # We are not using gcc with -pthread. Catched above.
2062                 G_THREAD_CFLAGS="-Kthread"
2063                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2064                 ;;
2065         *-mingw*)
2066                 # No flag needed when using MSVCRT.DLL
2067                 G_THREAD_CFLAGS=""
2068                 ;;
2069         *)
2070                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2071                 ;;
2072   esac
2073
2074 fi
2075
2076 # if we are not finding the localtime_r function, then we probably are
2077 # not using the proper multithread flag
2078
2079 glib_save_CPPFLAGS="$CPPFLAGS"
2080 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2081
2082 # First we test, whether localtime_r is declared in time.h
2083 # directly. Then we test whether a macro localtime_r exists, in
2084 # which case localtime_r in the test program is replaced and thus
2085 # if we still find localtime_r in the output, it is not defined as
2086 # a macro.
2087
2088 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2089   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2090                                                            localtime_r(a,b)],
2091                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2092
2093 CPPFLAGS="$glib_save_CPPFLAGS"
2094
2095 AC_MSG_CHECKING(thread related cflags)
2096 AC_MSG_RESULT($G_THREAD_CFLAGS)
2097 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2098
2099 dnl determination of G_THREAD_LIBS
2100 dnl ******************************
2101
2102 case $have_threads in
2103         posix)
2104           glib_save_CPPFLAGS="$CPPFLAGS"
2105           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2106           if test x"$G_THREAD_LIBS" = x; then
2107             case $host in
2108               *-aix*)
2109                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2110                 # probably using the aix compiler.
2111                 AC_MSG_WARN($AIX_COMPILE_INFO)
2112                 ;;
2113               *)
2114                 G_THREAD_LIBS=error
2115                 glib_save_LIBS="$LIBS"
2116                 for thread_lib in "" pthread pthread32 pthreads thread; do
2117                         if test x"$thread_lib" = x; then
2118                                 add_thread_lib=""
2119                                 IN=""
2120                         else
2121                                 add_thread_lib="-l$thread_lib"
2122                                 IN=" in -l$thread_lib"
2123                         fi
2124                         if test x"$have_threads" = xposix; then
2125                                 defattr=0
2126                         else
2127                                 defattr=pthread_attr_default
2128                         fi
2129
2130                         LIBS="$add_thread_lib $glib_save_LIBS"
2131
2132                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2133                         AC_TRY_RUN(glib_thread_test($defattr),
2134                                    glib_result=yes,
2135                                    glib_result=no,
2136                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2137                                                    glib_result=yes,
2138                                                    glib_result=no)])
2139                         AC_MSG_RESULT($glib_result)
2140
2141                         if test "$glib_result" = "yes" ; then
2142                           G_THREAD_LIBS="$add_thread_lib"
2143                           break
2144                         fi
2145                 done
2146                 if test "x$G_THREAD_LIBS" = xerror; then
2147                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2148                 fi
2149                 LIBS="$glib_save_LIBS"
2150                 ;;
2151             esac
2152           fi
2153
2154           glib_save_LIBS="$LIBS"
2155           for thread_lib in "" rt rte; do
2156             if test x"$thread_lib" = x; then
2157               add_thread_lib=""
2158               IN=""
2159             else
2160               add_thread_lib="-l$thread_lib"
2161               IN=" in -l$thread_lib"
2162             fi
2163             LIBS="$add_thread_lib $glib_save_LIBS"
2164
2165             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2166             AC_TRY_RUN(glib_sched_priority_test,
2167                        glib_result=yes,
2168                        glib_result=no,
2169                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2170                                        glib_result=yes,
2171                                        glib_result=no)])
2172             AC_MSG_RESULT($glib_result)
2173
2174             if test "$glib_result" = "yes" ; then
2175                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2176                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2177                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2178                break
2179             fi
2180           done
2181           LIBS="$glib_save_LIBS"
2182           g_threads_impl="POSIX"
2183           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2184           CPPFLAGS="$glib_save_CPPFLAGS"
2185           ;;
2186         win32)
2187            g_threads_impl="WIN32"
2188            ;;
2189         *)
2190            g_threads_impl="NONE"
2191            G_THREAD_LIBS=error
2192            ;;
2193 esac
2194
2195 if test "x$G_THREAD_LIBS" = xerror; then
2196         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2197 fi
2198
2199 case $host in
2200   *-*-beos*)
2201     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2202     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2203     ;;
2204   *)
2205     ;;
2206 esac
2207
2208 AC_MSG_CHECKING(thread related libraries)
2209 AC_MSG_RESULT($G_THREAD_LIBS)
2210
2211 dnl check for mt safe function variants and some posix functions
2212 dnl ************************************************************
2213
2214 glib_save_LIBS="$LIBS"
2215 # we are not doing the following for now, as this might require glib
2216 # to always be linked with the thread libs on some platforms.
2217 # LIBS="$LIBS $G_THREAD_LIBS"
2218 AC_CHECK_FUNCS(localtime_r gmtime_r)
2219 if test "$ac_cv_header_pwd_h" = "yes"; then
2220         AC_CACHE_CHECK([for posix getpwuid_r],
2221                 ac_cv_func_posix_getpwuid_r,
2222                 [AC_TRY_RUN([
2223 #include <errno.h>
2224 #include <pwd.h>
2225 int main () {
2226     char buffer[10000];
2227     struct passwd pwd, *pwptr = &pwd;
2228     int error;
2229     errno = 0;
2230     error = getpwuid_r (0, &pwd, buffer,
2231                         sizeof (buffer), &pwptr);
2232    return (error < 0 && errno == ENOSYS)
2233            || error == ENOSYS;
2234 }                               ],
2235                         [ac_cv_func_posix_getpwuid_r=yes],
2236                         [ac_cv_func_posix_getpwuid_r=no])])
2237         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2238         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2239                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2240                         [Have POSIX function getpwuid_r])
2241         else
2242                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2243                         ac_cv_func_nonposix_getpwuid_r,
2244                         [AC_TRY_LINK([#include <pwd.h>],
2245                                 [char buffer[10000];
2246                                 struct passwd pwd;
2247                                 getpwuid_r (0, &pwd, buffer,
2248                                                 sizeof (buffer));],
2249                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2250                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2251                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2252                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2253                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2254                                 [Have non-POSIX function getpwuid_r])
2255                 fi
2256         fi
2257 fi
2258 if test "$ac_cv_header_grp_h" = "yes"; then
2259         AC_CACHE_CHECK([for posix getgrgid_r],
2260                 ac_cv_func_posix_getgrgid_r,
2261                 [AC_TRY_RUN([
2262 #include <errno.h>
2263 #include <grp.h>
2264 int main () {
2265     char buffer[10000];
2266     struct group grp, *grpptr = &grp;
2267     int error;
2268     errno = 0;
2269     error = getgrgid_r (0, &grp, buffer,
2270                         sizeof (buffer), &grpptr);
2271    return (error < 0 && errno == ENOSYS)
2272            || error == ENOSYS;
2273 }                              ],
2274                        [ac_cv_func_posix_getgrgid_r=yes],
2275                        [ac_cv_func_posix_getgrgid_r=no])])
2276         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2277         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2278                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2279                         [Have POSIX function getgrgid_r])
2280         else
2281                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2282                         ac_cv_func_nonposix_getgrgid_r,
2283                         [AC_TRY_LINK([#include <grp.h>],
2284                                 [char buffer[10000];
2285                                 struct group grp;
2286                                 getgrgid_r (0, &grp, buffer,
2287                                 sizeof (buffer));],
2288                         [ac_cv_func_nonposix_getgrgid_r=yes],
2289                         [ac_cv_func_nonposix_getgrgid_r=no])])
2290                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2291                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2292                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2293                                 [Have non-POSIX function getgrgid_r])
2294                 fi
2295         fi
2296 fi
2297 LIBS="$G_THREAD_LIBS $LIBS"
2298 if test x"$have_threads" = xposix; then
2299         glib_save_CPPFLAGS="$CPPFLAGS"
2300         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2301         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2302         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2303         # This is not AC_CHECK_FUNC to also work with function
2304         # name mangling in header files.
2305         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2306         AC_TRY_LINK([#include <pthread.h>],
2307                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2308                 [AC_MSG_RESULT(yes)
2309                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2310                           [Have function pthread_attr_setstacksize])],
2311                 [AC_MSG_RESULT(no)])
2312         AC_MSG_CHECKING(for minimal/maximal thread priority)
2313         if test x"$posix_priority_min" = x; then
2314                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2315                         PX_PRIO_MIN],,[
2316                         posix_priority_min=PX_PRIO_MIN
2317                         posix_priority_max=PX_PRIO_MAX])
2318         fi
2319         if test x"$posix_priority_min" = x; then
2320                 # AIX
2321                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2322                         PTHREAD_PRIO_MIN],,[
2323                         posix_priority_min=PTHREAD_PRIO_MIN
2324                         posix_priority_max=PTHREAD_PRIO_MAX])
2325         fi
2326         if test x"$posix_priority_min" = x; then
2327                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2328                         PRI_OTHER_MIN],,[
2329                         posix_priority_min=PRI_OTHER_MIN
2330                         posix_priority_max=PRI_OTHER_MAX])
2331         fi
2332         if test x"$posix_priority_min" = x; then
2333                 AC_MSG_RESULT(none found)
2334                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2335                 posix_priority_min=-1
2336                 posix_priority_max=-1
2337         else
2338                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2339                 AC_MSG_CHECKING(for pthread_setschedparam)
2340                 AC_TRY_LINK([#include <pthread.h>],
2341                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2342                   [AC_MSG_RESULT(yes)
2343                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2344                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2345                   [AC_MSG_RESULT(no)
2346                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2347         fi
2348         posix_yield_func=none
2349         AC_MSG_CHECKING(for posix yield function)
2350         for yield_func in sched_yield pthread_yield_np pthread_yield \
2351                                                 thr_yield; do
2352                 AC_TRY_LINK([#include <pthread.h>],
2353                         [$yield_func()],
2354                         [posix_yield_func="$yield_func"
2355                         break])
2356         done
2357         if test x"$posix_yield_func" = xnone; then
2358                 AC_MSG_RESULT(none found)
2359                 AC_MSG_WARN($POSIX_NO_YIELD)
2360                 posix_yield_func="g_usleep(1000)"
2361         else
2362                 AC_MSG_RESULT($posix_yield_func)
2363                 posix_yield_func="$posix_yield_func()"
2364         fi
2365         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2366         CPPFLAGS="$glib_save_CPPFLAGS"
2367
2368 elif test x"$have_threads" = xwin32; then
2369         # It's a pointer to a private struct
2370         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2371 fi
2372
2373 LIBS="$glib_save_LIBS"
2374
2375 # now spit out all the warnings.
2376 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2377    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2378         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2379 fi
2380 if test "$ac_cv_func_localtime_r" != "yes"; then
2381         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2382 fi
2383
2384 if test x"$glib_cv_sizeof_system_thread" = x; then
2385    # use a pointer as a fallback.
2386    GLIB_SIZEOF(,void *, system_thread)
2387 fi
2388
2389 #
2390 # Hack to deal with:
2391 #
2392 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2393 #     building shared libraries with linux.
2394 #  b) FreeBSD doesn't do this either.
2395 #
2396 case $host in
2397   *-*-freebsd*|*-*-linux*)
2398     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2399     ;;
2400   *-*-openbsd*)
2401     LDFLAGS="$LDFLAGS -pthread"
2402     ;;
2403   *)
2404     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2405     ;;
2406 esac
2407
2408 AC_SUBST(G_THREAD_CFLAGS)
2409 AC_SUBST(G_THREAD_LIBS)
2410 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2411 AC_SUBST(G_THREAD_LIBS_EXTRA)
2412
2413 AC_CHECK_FUNCS(clock_gettime, [], [
2414   AC_CHECK_LIB(rt, clock_gettime, [
2415     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2416     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2417     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2418     GLIB_RT_LIBS="-lrt"
2419   ])
2420 ])
2421 AC_SUBST(GLIB_RT_LIBS)
2422
2423
2424 dnl ************************
2425 dnl *** g_atomic_* tests ***
2426 dnl ************************
2427
2428 dnl We need to decide at configure time if GLib will use real atomic
2429 dnl operations ("lock free") or emulated ones with a mutex.  This is
2430 dnl because we must put this information in glibconfig.h so we know if
2431 dnl it is safe or not to inline using compiler intrinsics directly from
2432 dnl the header.
2433 dnl
2434 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2435 dnl user is interested in knowing if they can use the atomic ops across
2436 dnl processes.
2437 dnl
2438 dnl We can currently support the atomic ops natively when building GLib
2439 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2440 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2441 dnl we are using GCC.
2442 dnl
2443 dnl Note that the atomic ops are only available with GCC on x86 when
2444 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2445 dnl not available but would be available given the right flags, we want
2446 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2447 dnl that then to silently fall back on emulated atomic ops just because
2448 dnl the user had the wrong build environment.
2449
2450 dnl We may add other compilers here in the future...
2451 AC_MSG_CHECKING([for lock-free atomic intrinsics])
2452 AC_TRY_COMPILE([],
2453                [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2454                [glib_cv_g_atomic_lock_free=yes],
2455                [glib_cv_g_atomic_lock_free=no])
2456 AC_MSG_RESULT($glib_cv_g_atomic_lock_free)
2457
2458 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2459   SAVE_CFLAGS="${CFLAGS}"
2460   CFLAGS="-march=i486"
2461   AC_TRY_COMPILE([],
2462                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2463                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2464                  [])
2465   CFLAGS="${SAVE_CFLAGS}"
2466 fi
2467
2468 dnl We need a more robust approach here...
2469 case $host_cpu in
2470   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2471     glib_memory_barrier_needed=no
2472     ;;
2473   sparc*|alpha*|powerpc*|ia64)
2474     glib_memory_barrier_needed=yes
2475     ;;
2476   *)
2477     glib_memory_barrier_needed=yes
2478     ;;
2479 esac
2480
2481 dnl ************************
2482 dnl ** Check for futex(2) **
2483 dnl ************************
2484 AC_CACHE_CHECK(for futex(2) system call,
2485     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2486 #include <linux/futex.h>
2487 #include <sys/syscall.h>
2488 #include <unistd.h>
2489 ],[
2490 int
2491 main (void)
2492 {
2493   /* it is not like this actually runs or anything... */
2494   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2495   return 0;
2496 }
2497 ])],glib_cv_futex=yes,glib_cv_futex=no))
2498 if test x"$glib_cv_futex" = xyes; then
2499   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2500 fi
2501
2502 AC_CACHE_CHECK(for eventfd(2) system call,
2503     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2504 #include <sys/eventfd.h>
2505 #include <unistd.h>
2506 ],[
2507 int
2508 main (void)
2509 {
2510   eventfd (0, EFD_CLOEXEC);
2511   return 0;
2512 }
2513 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2514 if test x"$glib_cv_eventfd" = x"yes"; then
2515   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2516 fi
2517 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2518
2519 dnl ****************************************
2520 dnl *** GLib POLL* compatibility defines ***
2521 dnl ****************************************
2522
2523 glib_poll_includes=["
2524 #include <sys/types.h>
2525 #include <sys/poll.h>
2526 "]
2527
2528 if test $ac_cv_header_sys_types_h = yes &&
2529    test $ac_cv_header_sys_poll_h = yes ; then
2530   glib_failed=false
2531   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2532   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2533   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2534   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2535   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2536   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2537   if $glib_failed ; then
2538     AC_MSG_ERROR([Could not determine values for POLL* constants])
2539   fi
2540 else
2541   glib_cv_value_POLLIN=1
2542   glib_cv_value_POLLOUT=4
2543   glib_cv_value_POLLPRI=2
2544   glib_cv_value_POLLERR=8
2545   glib_cv_value_POLLHUP=16
2546   glib_cv_value_POLLNVAL=32
2547 fi
2548
2549 AC_MSG_CHECKING([for broken poll])
2550 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2551         #include <stdlib.h>
2552         #include <fcntl.h>
2553         #include <poll.h>
2554         #ifdef HAVE_SYS_POLL_H
2555         #include <sys/poll.h>
2556         #endif
2557         int main(void) {
2558           struct pollfd fds[1];
2559           int fd;
2560           fd = open("/dev/null", 1);
2561           fds[0].fd = fd;
2562           fds[0].events = POLLIN;
2563           fds[0].revents = 0;
2564           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2565                 exit(1);  /* Does not work for devices -- fail */
2566           }
2567           exit(0);
2568         }]])],
2569   [broken_poll=no],
2570   [broken_poll=yes
2571    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2572   [broken_poll="no (cross compiling)"])
2573 AC_MSG_RESULT($broken_poll)
2574
2575 dnl *********************
2576 dnl *** GRegex checks ***
2577 dnl *********************
2578 PCRE_REQUIRED_VERSION=8.11
2579
2580 # Check if we should compile GRegex
2581 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2582                                     [disable the compilation of GRegex]),
2583 [case "${enableval}" in
2584   yes) enable_regex=true ;;
2585   no)  enable_regex=false ;;
2586   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2587 esac],
2588 [enable_regex=true])
2589
2590 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2591
2592 if test x$enable_regex = xtrue; then
2593   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2594   # Check if we should use the internal or the system-supplied pcre
2595   AC_ARG_WITH(pcre,
2596              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2597                              [whether to use system PCRE [default=internal]])])
2598
2599   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2600
2601   if test "x$with_pcre" = xsystem; then
2602     PKG_CHECK_MODULES(PCRE,
2603                       libpcre >= $PCRE_REQUIRED_VERSION)
2604     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2605                    glib_save_CFLAGS="$CFLAGS"
2606                    glib_save_LIBS="$LIBS"
2607                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2608                    AC_TRY_RUN([#include <pcre.h>
2609                                int main () {
2610                                  int support;
2611                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2612                                  if (!support)
2613                                    return 1;
2614                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2615                                  if (!support)
2616                                    return 1;
2617                                  return 0;
2618                                }],
2619                    glib_cv_pcre_has_unicode=yes,
2620                    glib_cv_pcre_has_unicode=no,
2621                    glib_cv_pcre_has_unicode=yes)
2622                    CFLAGS="$glib_save_CFLAGS"
2623                    LIBS="$glib_save_LIBS"
2624         ])
2625     if test "$glib_cv_pcre_has_unicode" = "no"; then
2626       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2627     fi
2628     AC_SUBST(PCRE_CFLAGS)
2629     AC_SUBST(PCRE_LIBS)
2630     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2631     PCRE_REQUIRES=libpcre
2632     AC_SUBST(PCRE_REQUIRES)
2633   else
2634     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2635     if test x"$GCC" = xyes; then
2636       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2637       save_CFLAGS="$CFLAGS"
2638       CFLAGS="$CFLAGS -Wno-pointer-sign"
2639       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2640                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2641       CFLAGS="$save_CFLAGS"
2642     fi
2643   fi
2644   AC_SUBST(PCRE_WARN_CFLAGS)
2645 else
2646   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2647 fi
2648
2649 dnl **********************
2650 dnl *** Win32 API libs ***
2651 dnl **********************
2652
2653 case $host in
2654   *-*-cygwin*)
2655         G_LIBS_EXTRA="-luser32 -lkernel32"
2656     ;;
2657   *-*-mingw*)
2658         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm"
2659     ;;
2660   *)
2661         G_LIBS_EXTRA=""
2662     ;;
2663 esac
2664 AC_SUBST(G_LIBS_EXTRA)
2665
2666 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2667 dnl since we need it for g_iconv()
2668
2669 AC_MSG_CHECKING([for EILSEQ])
2670 AC_TRY_COMPILE([
2671 #include <errno.h>
2672 ],
2673 [
2674 int error = EILSEQ;
2675 ], have_eilseq=yes, have_eilseq=no);
2676 AC_MSG_RESULT($have_eilseq)
2677
2678 dnl ******************************************************************
2679 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2680 dnl *** glib-compile-schemas in PATH                               ***
2681 dnl ******************************************************************
2682
2683 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2684
2685 if test $cross_compiling = yes; then
2686   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2687   if test x$GLIB_GENMARSHAL = xno; then
2688     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2689   fi
2690
2691   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2692   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2693     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2694   fi
2695 fi
2696
2697 dnl **************************
2698 dnl *** Checks for gtk-doc ***
2699 dnl **************************
2700
2701 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2702
2703 AC_ARG_ENABLE(man,
2704               [AC_HELP_STRING([--enable-man],
2705                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2706               enable_man=no)
2707
2708 if test "${enable_man}" != no; then
2709 dnl
2710 dnl Check for xsltproc
2711 dnl
2712 AC_PATH_PROG([XSLTPROC], [xsltproc])
2713   if test -z "$XSLTPROC"; then
2714     enable_man=no
2715   fi
2716
2717   dnl check for DocBook DTD and stylesheets in the local catalog.
2718   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2719      [DocBook XML DTD V4.1.2],,enable_man=no)
2720   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2721      [DocBook XSL Stylesheets],,enable_man=no)
2722 fi
2723
2724 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2725
2726 dnl
2727 dnl Tracing
2728 dnl
2729
2730 AC_ARG_ENABLE([dtrace],
2731              [AS_HELP_STRING([--enable-dtrace],
2732                               [include tracing support for dtrace])])
2733 have_dtrace=no
2734 AC_MSG_CHECKING([whether to include dtrace tracing support])
2735 if test "x$enable_dtrace" != xno; then
2736   if test x$glib_have_carbon = xyes; then
2737     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2738   else
2739     AC_MSG_RESULT([yes])
2740     AC_CHECK_PROGS(DTRACE, dtrace)
2741     if test -z "$DTRACE"; then
2742       if test "x$enable_dtrace" = xyes; then
2743         AC_MSG_ERROR([dtrace not found])
2744       fi
2745     else
2746       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2747                       [if test "x$enable_dtrace" = xyes; then
2748                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2749                        fi])
2750     fi
2751   fi
2752 else
2753   AC_MSG_RESULT([no])
2754 fi
2755 if test "x$have_dtrace" = xyes; then
2756   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2757 fi
2758 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2759
2760 AC_MSG_CHECKING([whether to include systemtap tracing support])
2761 AC_ARG_ENABLE([systemtap],
2762              [AS_HELP_STRING([--enable-systemtap],
2763                               [include tracing support for systemtap])])
2764 have_systemtap=no
2765 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2766   have_systemtap=yes
2767 fi
2768 AC_MSG_RESULT(${have_systemtap})
2769
2770 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2771
2772 AC_ARG_WITH([tapset-install-dir],
2773             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2774                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2775             [if test "x${withval}" = x; then
2776                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2777              else
2778                ABS_TAPSET_DIR="${withval}"
2779               fi],
2780             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2781 AC_SUBST(ABS_TAPSET_DIR)
2782
2783 dnl ************************************
2784 dnl *** Enable lcov coverage reports ***
2785 dnl ************************************
2786
2787 AC_ARG_ENABLE(gcov,
2788   AS_HELP_STRING([--enable-gcov],
2789                  [enable coverage testing with gcov]),
2790   [use_gcov=$enableval], [use_gcov=no])
2791
2792 if test "x$use_gcov" = "xyes"; then
2793   dnl we need gcc:
2794   if test "$GCC" != "yes"; then
2795     AC_MSG_ERROR([GCC is required for --enable-gcov])
2796   fi
2797
2798   dnl Check if ccache is being used
2799   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2800   case `$SHTOOL path $CC` in
2801     *ccache*[)] gcc_ccache=yes;;
2802     *[)] gcc_ccache=no;;
2803   esac
2804
2805   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2806     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2807   fi
2808
2809   ltp_version_list="1.6 1.7 1.8 1.9"
2810   AC_CHECK_PROG(LTP, lcov, lcov)
2811   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2812
2813   if test "$LTP"; then
2814     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2815       glib_cv_ltp_version=invalid
2816       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2817       for ltp_check_version in $ltp_version_list; do
2818         if test "$ltp_version" = "$ltp_check_version"; then
2819           glib_cv_ltp_version="$ltp_check_version (ok)"
2820         fi
2821       done
2822     ])
2823   else
2824     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2825     AC_MSG_ERROR([$ltp_msg])
2826   fi
2827
2828   case $glib_cv_ltp_version in
2829     ""|invalid[)]
2830       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2831       AC_MSG_ERROR([$ltp_msg])
2832       LTP="exit 0;"
2833       ;;
2834   esac
2835
2836   if test -z "$LTP_GENHTML"; then
2837     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2838   fi
2839
2840   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2841
2842   dnl Remove all optimization flags from CFLAGS
2843   changequote({,})
2844   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2845   changequote([,])
2846
2847   dnl Add the special gcc flags
2848   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2849   LDFLAGS="$LDFLAGS -lgcov"
2850 fi
2851
2852 dnl ******************************
2853 dnl *** output the whole stuff ***
2854 dnl ******************************
2855
2856 dnl this section will only be run if config.status is invoked with no
2857 dnl arguments, or with "glib/glibconfig.h" as an argument.
2858 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2859 [
2860         outfile=glib/glibconfig.h-tmp
2861         cat > $outfile <<\_______EOF
2862 /* glibconfig.h
2863  *
2864  * This is a generated file.  Please modify 'configure.ac'
2865  */
2866
2867 #ifndef __G_LIBCONFIG_H__
2868 #define __G_LIBCONFIG_H__
2869
2870 #include <glib/gmacros.h>
2871
2872 _______EOF
2873
2874         if test x$glib_limits_h = xyes; then
2875           echo '#include <limits.h>' >> $outfile
2876         fi
2877         if test x$glib_float_h = xyes; then
2878           echo '#include <float.h>' >> $outfile
2879         fi
2880         if test x$glib_values_h = xyes; then
2881           echo '#include <values.h>' >> $outfile
2882         fi
2883         if test "$glib_header_alloca_h" = "yes"; then
2884           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2885         fi
2886         if test x$glib_sys_poll_h = xyes; then
2887           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2888         fi
2889         if test x$glib_included_printf != xyes; then
2890           echo "
2891 /* Specifies that GLib's g_print*() functions wrap the
2892  * system printf functions.  This is useful to know, for example,
2893  * when using glibc's register_printf_function().
2894  */" >> $outfile
2895           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2896         fi
2897
2898         cat >> $outfile <<_______EOF
2899
2900 G_BEGIN_DECLS
2901
2902 #define G_MINFLOAT      $glib_mf
2903 #define G_MAXFLOAT      $glib_Mf
2904 #define G_MINDOUBLE     $glib_md
2905 #define G_MAXDOUBLE     $glib_Md
2906 #define G_MINSHORT      $glib_ms
2907 #define G_MAXSHORT      $glib_Ms
2908 #define G_MAXUSHORT     $glib_Mus
2909 #define G_MININT        $glib_mi
2910 #define G_MAXINT        $glib_Mi
2911 #define G_MAXUINT       $glib_Mui
2912 #define G_MINLONG       $glib_ml
2913 #define G_MAXLONG       $glib_Ml
2914 #define G_MAXULONG      $glib_Mul
2915
2916 _______EOF
2917
2918
2919         ### this should always be true in a modern C/C++ compiler
2920         cat >>$outfile <<_______EOF
2921 typedef signed char gint8;
2922 typedef unsigned char guint8;
2923 _______EOF
2924
2925
2926         if test -n "$gint16"; then
2927           cat >>$outfile <<_______EOF
2928 typedef signed $gint16 gint16;
2929 typedef unsigned $gint16 guint16;
2930 #define G_GINT16_MODIFIER $gint16_modifier
2931 #define G_GINT16_FORMAT $gint16_format
2932 #define G_GUINT16_FORMAT $guint16_format
2933 _______EOF
2934         fi
2935
2936
2937         if test -n "$gint32"; then
2938           cat >>$outfile <<_______EOF
2939 typedef signed $gint32 gint32;
2940 typedef unsigned $gint32 guint32;
2941 #define G_GINT32_MODIFIER $gint32_modifier
2942 #define G_GINT32_FORMAT $gint32_format
2943 #define G_GUINT32_FORMAT $guint32_format
2944 _______EOF
2945         fi
2946
2947         cat >>$outfile <<_______EOF
2948 #define G_HAVE_GINT64 1          /* deprecated, always true */
2949
2950 ${glib_extension}typedef signed $gint64 gint64;
2951 ${glib_extension}typedef unsigned $gint64 guint64;
2952
2953 #define G_GINT64_CONSTANT(val)  $gint64_constant
2954 #define G_GUINT64_CONSTANT(val) $guint64_constant
2955 _______EOF
2956
2957         if test x$gint64_format != x ; then
2958           cat >>$outfile <<_______EOF
2959 #define G_GINT64_MODIFIER $gint64_modifier
2960 #define G_GINT64_FORMAT $gint64_format
2961 #define G_GUINT64_FORMAT $guint64_format
2962 _______EOF
2963         else
2964           cat >>$outfile <<_______EOF
2965 #undef G_GINT64_MODIFIER
2966 #undef G_GINT64_FORMAT
2967 #undef G_GUINT64_FORMAT
2968 _______EOF
2969         fi
2970
2971         cat >>$outfile <<_______EOF
2972
2973 #define GLIB_SIZEOF_VOID_P $glib_void_p
2974 #define GLIB_SIZEOF_LONG   $glib_long
2975 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2976
2977 _______EOF
2978
2979         cat >>$outfile <<_______EOF
2980 typedef signed $glib_size_type_define gssize;
2981 typedef unsigned $glib_size_type_define gsize;
2982 #define G_GSIZE_MODIFIER $gsize_modifier
2983 #define G_GSSIZE_FORMAT $gssize_format
2984 #define G_GSIZE_FORMAT $gsize_format
2985
2986 #define G_MAXSIZE       G_MAXU$glib_msize_type
2987 #define G_MINSSIZE      G_MIN$glib_msize_type
2988 #define G_MAXSSIZE      G_MAX$glib_msize_type
2989
2990 typedef gint64 goffset;
2991 #define G_MINOFFSET     G_MININT64
2992 #define G_MAXOFFSET     G_MAXINT64
2993
2994 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2995 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2996 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2997
2998 _______EOF
2999
3000         if test -z "$glib_unknown_void_p"; then
3001           cat >>$outfile <<_______EOF
3002
3003 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3004 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3005
3006 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3007 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3008
3009 typedef signed $glib_intptr_type_define gintptr;
3010 typedef unsigned $glib_intptr_type_define guintptr;
3011
3012 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3013 #define G_GINTPTR_FORMAT        $gintptr_format
3014 #define G_GUINTPTR_FORMAT       $guintptr_format
3015 _______EOF
3016         else
3017           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3018         fi
3019
3020
3021
3022         cat >>$outfile <<_______EOF
3023 $glib_atexit
3024 $glib_memmove
3025 $glib_defines
3026 $glib_os
3027 $glib_static_compilation
3028
3029 $glib_vacopy
3030
3031 #ifdef  __cplusplus
3032 #define G_HAVE_INLINE   1
3033 #else   /* !__cplusplus */
3034 $glib_inline
3035 #endif  /* !__cplusplus */
3036
3037 #ifdef  __cplusplus
3038 #define G_CAN_INLINE    1
3039 _______EOF
3040
3041         if test x$g_can_inline = xyes ; then
3042                 cat >>$outfile <<_______EOF
3043 #else   /* !__cplusplus */
3044 #define G_CAN_INLINE    1
3045 _______EOF
3046         fi
3047
3048         cat >>$outfile <<_______EOF
3049 #endif
3050
3051 _______EOF
3052
3053         if test x$g_have_iso_c_varargs = xyes ; then
3054                 cat >>$outfile <<_______EOF
3055 #ifndef __cplusplus
3056 # define G_HAVE_ISO_VARARGS 1
3057 #endif
3058 _______EOF
3059         fi
3060         if test x$g_have_iso_cxx_varargs = xyes ; then
3061                 cat >>$outfile <<_______EOF
3062 #ifdef __cplusplus
3063 # define G_HAVE_ISO_VARARGS 1
3064 #endif
3065 _______EOF
3066         fi
3067         if test x$g_have_gnuc_varargs = xyes ; then
3068                 cat >>$outfile <<_______EOF
3069
3070 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3071  * is passed ISO vararg support is turned off, and there is no work
3072  * around to turn it on, so we unconditionally turn it off.
3073  */
3074 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3075 #  undef G_HAVE_ISO_VARARGS
3076 #endif
3077
3078 #define G_HAVE_GNUC_VARARGS 1
3079 _______EOF
3080         fi
3081
3082         case x$g_stack_grows in
3083         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3084         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3085         esac
3086
3087
3088         echo >>$outfile
3089         if test x$g_have_eilseq = xno; then
3090                 cat >>$outfile <<_______EOF
3091 #ifndef EILSEQ
3092 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3093  * The correspondence between this and the corresponding definition
3094  * in libiconv is essential.
3095  */
3096 #  define EILSEQ ENOENT
3097 #endif
3098 _______EOF
3099
3100         fi
3101
3102         if test x$g_have_gnuc_visibility = xyes; then
3103                 cat >>$outfile <<_______EOF
3104 #define G_HAVE_GNUC_VISIBILITY 1
3105 _______EOF
3106         fi
3107                 cat >>$outfile <<_______EOF
3108 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3109 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3110 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3111 #define G_GNUC_INTERNAL __hidden
3112 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3113 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3114 #else
3115 #define G_GNUC_INTERNAL
3116 #endif
3117 _______EOF
3118
3119         echo >>$outfile
3120         cat >>$outfile <<_______EOF
3121 #define G_THREADS_ENABLED
3122 #define G_THREADS_IMPL_$g_threads_impl_def
3123 _______EOF
3124
3125         if test x"$g_memory_barrier_needed" != xno; then
3126           echo >>$outfile
3127           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3128         fi
3129         if test x"$g_atomic_lock_free" = xyes; then
3130           echo >>$outfile
3131           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3132         fi
3133         echo >>$outfile
3134         g_bit_sizes="16 32 64"
3135         for bits in $g_bit_sizes; do
3136           cat >>$outfile <<_______EOF
3137 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3138 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3139 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3140 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3141 _______EOF
3142         done
3143
3144         cat >>$outfile <<_______EOF
3145 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3146 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3147 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3148 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3149 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3150 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3151 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3152 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3153 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3154 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3155 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3156 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3157 #define G_BYTE_ORDER $g_byte_order
3158
3159 #define GLIB_SYSDEF_POLLIN =$g_pollin
3160 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3161 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3162 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3163 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3164 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3165
3166 #define G_MODULE_SUFFIX "$g_module_suffix"
3167
3168 /* A GPid is an abstraction for a process "handle". It is *not* an
3169  * abstraction for a process identifier in general. GPid is used in
3170  * GLib only for descendant processes spawned with the g_spawn*
3171  * functions. On POSIX there is no "process handle" concept as such,
3172  * but on Windows a GPid is a handle to a process, a kind of pointer,
3173  * not a process identifier.
3174  */
3175 typedef $g_pid_type GPid;
3176
3177 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3178 #define GLIB_SYSDEF_AF_INET $g_af_inet
3179 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3180
3181 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3182 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3183 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3184
3185 G_END_DECLS
3186
3187 #endif /* GLIBCONFIG_H */
3188 _______EOF
3189
3190
3191         if cmp -s $outfile glib/glibconfig.h; then
3192           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3193           rm -f $outfile
3194         else
3195           mv $outfile glib/glibconfig.h
3196         fi
3197 ],[
3198
3199 # Note that if two cases are the same, case goes with the first one.
3200 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3201 # on variable expansion in case labels.  Look at the generated config.status
3202 # for a hint.
3203
3204 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3205   glib_header_alloca_h="$ac_cv_working_alloca_h"
3206 else
3207   glib_header_alloca_h="$ac_cv_header_alloca_h"
3208 fi
3209
3210 case xyes in
3211 x$ac_cv_header_float_h)
3212   glib_float_h=yes
3213   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3214   glib_md=DBL_MIN glib_Md=DBL_MAX
3215   ;;
3216 x$ac_cv_header_values_h)
3217   glib_values_h=yes
3218   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3219   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3220   ;;
3221 esac
3222
3223 case xyes in
3224 x$ac_cv_header_limits_h)
3225   glib_limits_h=yes
3226   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3227   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3228   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3229   ;;
3230 x$ac_cv_header_values_h)
3231   glib_values_h=yes
3232   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3233   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3234   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3235   ;;
3236 esac
3237
3238 if test x$ac_cv_header_sys_poll_h = xyes ; then
3239   glib_sys_poll_h=yes
3240 fi
3241
3242 if test x$enable_included_printf = xyes ; then
3243   glib_included_printf=yes
3244 fi
3245
3246 case 2 in
3247 $ac_cv_sizeof_short)
3248   gint16=short
3249   gint16_modifier='"h"'
3250   gint16_format='"hi"'
3251   guint16_format='"hu"'
3252   ;;
3253 $ac_cv_sizeof_int)
3254   gint16=int
3255   gint16_modifier='""'
3256   gint16_format='"i"'
3257   guint16_format='"u"'
3258   ;;
3259 esac
3260 case 4 in
3261 $ac_cv_sizeof_short)
3262   gint32=short
3263   gint32_modifier='"h"'
3264   gint32_format='"hi"'
3265   guint32_format='"hu"'
3266   ;;
3267 $ac_cv_sizeof_int)
3268   gint32=int
3269   gint32_modifier='""'
3270   gint32_format='"i"'
3271   guint32_format='"u"'
3272   ;;
3273 $ac_cv_sizeof_long)
3274   gint32=long
3275   gint32_modifier='"l"'
3276   gint32_format='"li"'
3277   guint32_format='"lu"'
3278   ;;
3279 esac
3280 case 8 in
3281 $ac_cv_sizeof_int)
3282   gint64=int
3283   gint64_modifier='""'
3284   gint64_format='"i"'
3285   guint64_format='"u"'
3286   glib_extension=
3287   gint64_constant='(val)'
3288   guint64_constant='(val)'
3289   ;;
3290 $ac_cv_sizeof_long)
3291   gint64=long
3292   gint64_modifier='"l"'
3293   gint64_format='"li"'
3294   guint64_format='"lu"'
3295   glib_extension=
3296   gint64_constant='(val##L)'
3297   guint64_constant='(val##UL)'
3298   ;;
3299 $ac_cv_sizeof_long_long)
3300   gint64='long long'
3301   if test -n "$glib_cv_long_long_format"; then
3302     gint64_modifier='"'$glib_cv_long_long_format'"'
3303     gint64_format='"'$glib_cv_long_long_format'i"'
3304     guint64_format='"'$glib_cv_long_long_format'u"'
3305   fi
3306   glib_extension='G_GNUC_EXTENSION '
3307   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3308   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3309   ;;
3310 $ac_cv_sizeof___int64)
3311   gint64='__int64'
3312   if test -n "$glib_cv_long_long_format"; then
3313     gint64_modifier='"'$glib_cv_long_long_format'"'
3314     gint64_format='"'$glib_cv_long_long_format'i"'
3315     guint64_format='"'$glib_cv_long_long_format'u"'
3316   fi
3317   glib_extension=
3318   gint64_constant='(val##i64)'
3319   guint64_constant='(val##ui64)'
3320   ;;
3321 esac
3322 glib_size_t=$ac_cv_sizeof_size_t
3323 glib_size_type_define="$glib_size_type"
3324 glib_void_p=$ac_cv_sizeof_void_p
3325 glib_long=$ac_cv_sizeof_long
3326
3327 case "$glib_size_type" in
3328 short)
3329   gsize_modifier='"h"'
3330   gsize_format='"hu"'
3331   gssize_format='"hi"'
3332   glib_msize_type='SHRT'
3333   ;;
3334 int)
3335   gsize_modifier='""'
3336   gsize_format='"u"'
3337   gssize_format='"i"'
3338   glib_msize_type='INT'
3339   ;;
3340 long)
3341   gsize_modifier='"l"'
3342   gsize_format='"lu"'
3343   gssize_format='"li"'
3344   glib_msize_type='LONG'
3345   ;;
3346 "long long"|__int64)
3347   gsize_modifier='"I64"'
3348   gsize_format='"I64u"'
3349   gssize_format='"I64i"'
3350   glib_msize_type='INT64'
3351   ;;
3352 esac
3353
3354 gintbits=`expr $ac_cv_sizeof_int \* 8`
3355 glongbits=`expr $ac_cv_sizeof_long \* 8`
3356 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3357
3358 case $ac_cv_sizeof_void_p in
3359 $ac_cv_sizeof_int)
3360   glib_intptr_type_define=int
3361   gintptr_modifier='""'
3362   gintptr_format='"i"'
3363   guintptr_format='"u"'
3364   glib_gpi_cast='(gint)'
3365   glib_gpui_cast='(guint)'
3366   ;;
3367 $ac_cv_sizeof_long)
3368   glib_intptr_type_define=long
3369   gintptr_modifier='"l"'
3370   gintptr_format='"li"'
3371   guintptr_format='"lu"'
3372   glib_gpi_cast='(glong)'
3373   glib_gpui_cast='(gulong)'
3374   ;;
3375 $ac_cv_sizeof_long_long)
3376   glib_intptr_type_define='long long'
3377   gintptr_modifier='"I64"'
3378   gintptr_format='"I64i"'
3379   guintptr_format='"I64u"'
3380   glib_gpi_cast='(gint64)'
3381   glib_gpui_cast='(guint64)'
3382   ;;
3383 $ac_cv_sizeof___int64)
3384   glib_intptr_type_define=__int64
3385   gintptr_modifier='"I64"'
3386   gintptr_format='"I64i"'
3387   guintptr_format='"I64u"'
3388   glib_gpi_cast='(gint64)'
3389   glib_gpui_cast='(guint64)'
3390   ;;
3391 *)
3392   glib_unknown_void_p=yes
3393   ;;
3394 esac
3395
3396
3397 case xyes in
3398 x$ac_cv_func_atexit)
3399   glib_atexit="
3400 #ifdef NeXT /* @#%@! NeXTStep */
3401 # define g_ATEXIT(proc) (!atexit (proc))
3402 #else
3403 # define g_ATEXIT(proc) (atexit (proc))
3404 #endif"
3405   ;;
3406 x$ac_cv_func_on_exit)
3407   glib_atexit="
3408 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3409   ;;
3410 esac
3411
3412 case xyes in
3413 x$ac_cv_func_memmove)
3414   glib_memmove='
3415 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3416   ;;
3417 x$glib_cv_working_bcopy)
3418   glib_memmove="
3419 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3420 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3421   ;;
3422 *)
3423   glib_memmove="
3424 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3425  * so we have to roll our own copy routine. */
3426 void g_memmove (void* dest, const void * src, unsigned long len);"
3427   ;;
3428 esac
3429
3430 glib_defines="
3431 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3432 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3433 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3434 "
3435
3436 case xyes in
3437 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3438 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3439 *)                      glib_vacopy=''
3440 esac
3441
3442 if test x$glib_cv_va_val_copy = xno; then
3443   glib_vacopy="\$glib_vacopy
3444 #define G_VA_COPY_AS_ARRAY 1"
3445 fi
3446
3447 if test x$glib_cv_hasinline = xyes; then
3448     glib_inline='#define G_HAVE_INLINE 1'
3449 fi
3450 if test x$glib_cv_has__inline = xyes; then
3451     glib_inline="\$glib_inline
3452 #define G_HAVE___INLINE 1"
3453 fi
3454 if test x$glib_cv_has__inline__ = xyes; then
3455     glib_inline="\$glib_inline
3456 #define G_HAVE___INLINE__ 1"
3457 fi
3458
3459 g_have_gnuc_varargs=$g_have_gnuc_varargs
3460 g_have_iso_c_varargs=$g_have_iso_c_varargs
3461 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3462
3463 g_can_inline=$g_can_inline
3464 g_have_gnuc_visibility=$g_have_gnuc_visibility
3465 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3466
3467 if test x$ac_cv_c_bigendian = xyes; then
3468   g_byte_order=G_BIG_ENDIAN
3469   g_bs_native=BE
3470   g_bs_alien=LE
3471 else
3472   g_byte_order=G_LITTLE_ENDIAN
3473   g_bs_native=LE
3474   g_bs_alien=BE
3475 fi
3476
3477 g_pollin=$glib_cv_value_POLLIN
3478 g_pollout=$glib_cv_value_POLLOUT
3479 g_pollpri=$glib_cv_value_POLLPRI
3480 g_pollhup=$glib_cv_value_POLLHUP
3481 g_pollerr=$glib_cv_value_POLLERR
3482 g_pollnval=$glib_cv_value_POLLNVAL
3483
3484 g_af_unix=$glib_cv_value_AF_UNIX
3485 g_af_inet=$glib_cv_value_AF_INET
3486 g_af_inet6=$glib_cv_value_AF_INET6
3487
3488 g_msg_peek=$glib_cv_value_MSG_PEEK
3489 g_msg_oob=$glib_cv_value_MSG_OOB
3490 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3491
3492 g_stack_grows=$glib_cv_stack_grows
3493
3494 g_have_eilseq=$have_eilseq
3495
3496 g_threads_impl_def=$g_threads_impl
3497
3498 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3499
3500 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3501 g_memory_barrier_needed="$glib_memory_barrier_needed"
3502 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3503
3504 g_module_suffix="$glib_gmodule_suffix"
3505
3506 g_pid_type="$glib_pid_type"
3507 case $host in
3508   *-*-beos*)
3509     glib_os="#define G_OS_BEOS"
3510     ;;
3511   *-*-cygwin*)
3512     glib_os="#define G_OS_UNIX
3513 #define G_PLATFORM_WIN32
3514 #define G_WITH_CYGWIN"
3515     ;;
3516   *-*-mingw*)
3517     glib_os="#define G_OS_WIN32
3518 #define G_PLATFORM_WIN32"
3519     ;;
3520   *)
3521     glib_os="#define G_OS_UNIX"
3522     ;;
3523 esac
3524 glib_static_compilation=""
3525 if test x$glib_win32_static_compilation = xyes; then
3526   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3527 #define GOBJECT_STATIC_COMPILATION 1"
3528 fi
3529 ])
3530
3531 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3532 #
3533 # 1.2.14 required for dbus_message_set_serial
3534 PKG_CHECK_MODULES(DBUS1,
3535                   dbus-1 >= 1.2.14,
3536                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3537                   have_dbus1=no)
3538 AC_SUBST(DBUS1_CFLAGS)
3539 AC_SUBST(DBUS1_LIBS)
3540 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3541
3542 dnl
3543 dnl Check for -Bsymbolic-functions linker flag used to avoid
3544 dnl intra-library PLT jumps, if available.
3545 dnl
3546
3547 AC_ARG_ENABLE(Bsymbolic,
3548               [AC_HELP_STRING([--disable-Bsymbolic],
3549                               [avoid linking with -Bsymbolic])],,
3550               [SAVED_LDFLAGS="${LDFLAGS}"
3551                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3552                LDFLAGS=-Wl,-Bsymbolic-functions
3553                AC_TRY_LINK([], [int main (void) { return 0; }],
3554                            AC_MSG_RESULT(yes)
3555                            enable_Bsymbolic=yes,
3556                            AC_MSG_RESULT(no)
3557                            enable_Bsymbolic=no)
3558                LDFLAGS="${SAVED_LDFLAGS}"])
3559
3560 if test "x${enable_Bsymbolic}" == "xyes"; then
3561   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3562 fi
3563
3564 AC_SUBST(GLIB_LINK_FLAGS)
3565
3566 #
3567 # Define variables corresponding to the correct include paths to use for
3568 # in-tree building.
3569 #
3570
3571 # for config.h:
3572 config_h_INCLUDES='-I$(top_builddir)'
3573 AC_SUBST(config_h_INCLUDES)
3574
3575 # glib:
3576 #   config.h
3577 #   $(top_builddir)/glib: for glibconfig.h
3578 #   $(top_srcdir)/glib:   for glib.h
3579 #   $(top_srcdir):        for everything
3580 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3581 AC_SUBST(glib_INCLUDES)
3582
3583 # gthread:
3584 #   same as glib
3585 gthread_INCLUDES='$(glib_INCLUDES)'
3586 AC_SUBST(gthread_INCLUDES)
3587
3588 # gobject:
3589 #   same as gthread
3590 gobject_INCLUDES='$(gthread_INCLUDES)'
3591 AC_SUBST(gobject_INCLUDES)
3592
3593 # gmodule:
3594 #   glib includes
3595 #   $(top_srcdir)/gmodule: for gmodule.h
3596 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3597 AC_SUBST(gmodule_INCLUDES)
3598
3599 # gio:
3600 #   same as gmodule
3601 gio_INCLUDES='$(gmodule_INCLUDES)'
3602 AC_SUBST(gio_INCLUDES)
3603
3604
3605 AC_CONFIG_FILES([
3606 glib-2.0.pc
3607 gmodule-2.0.pc
3608 gmodule-export-2.0.pc
3609 gmodule-no-export-2.0.pc
3610 gthread-2.0.pc
3611 gobject-2.0.pc
3612 gio-2.0.pc
3613 gio-unix-2.0.pc
3614 gio-windows-2.0.pc
3615 glib-zip
3616 glib-gettextize
3617 Makefile
3618 build/Makefile
3619 build/win32/Makefile
3620 build/win32/dirent/Makefile
3621 build/win32/vs9/Makefile
3622 build/win32/vs10/Makefile
3623 glib/Makefile
3624 glib/glib.stp
3625 glib/libcharset/Makefile
3626 glib/gnulib/Makefile
3627 glib/pcre/Makefile
3628 glib/update-pcre/Makefile
3629 glib/tests/Makefile
3630 gmodule/Makefile
3631 gmodule/gmoduleconf.h
3632 gobject/Makefile
3633 gobject/gobject.stp
3634 gobject/glib-mkenums
3635 gobject/tests/Makefile
3636 gthread/Makefile
3637 gio/Makefile
3638 gio/gdbus-2.0/codegen/Makefile
3639 gio/gdbus-2.0/codegen/config.py
3640 gio/xdgmime/Makefile
3641 gio/inotify/Makefile
3642 gio/fen/Makefile
3643 gio/fam/Makefile
3644 gio/win32/Makefile
3645 gio/tests/Makefile
3646 gio/tests/gdbus-object-manager-example/Makefile
3647 po/Makefile.in
3648 docs/Makefile
3649 docs/reference/Makefile
3650 docs/reference/glib/Makefile
3651 docs/reference/glib/version.xml
3652 docs/reference/gobject/Makefile
3653 docs/reference/gobject/version.xml
3654 docs/reference/gio/Makefile
3655 docs/reference/gio/gdbus-object-manager-example/Makefile
3656 docs/reference/gio/version.xml
3657 tests/Makefile
3658 tests/gobject/Makefile
3659 tests/refcount/Makefile
3660 m4macros/Makefile
3661 ])
3662
3663 AC_CONFIG_COMMANDS([chmod-scripts],
3664 [chmod 0755 glib-zip
3665 chmod 0755 glib-gettextize
3666 chmod 0755 gobject/glib-mkenums])
3667
3668 # we want to invoke this macro solely so that the config.status script
3669 # and automake generated makefiles know about these generated files.
3670 # They are only needed to distcheck the package
3671 if false; then
3672   AC_CONFIG_FILES([
3673     INSTALL
3674     README
3675     config.h.win32
3676     glib/glibconfig.h.win32
3677     glib/makefile.msc
3678     glib/glib.rc
3679     gmodule/makefile.msc
3680     gmodule/gmodule.rc
3681     gobject/makefile.msc
3682     gobject/gobject.rc
3683     gthread/makefile.msc
3684     gthread/gthread.rc
3685     gio/gio.rc
3686     tests/makefile.msc
3687   ])
3688 fi
3689
3690 AC_OUTPUT