configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [6])
   6 m4_define([folks_micro_version], [1])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If interfaces have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If interfaces have been added since last release, increment age
  13 # If interfaces have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [25])
  15 m4_define([folks_lt_revision], [1])
  16 m4_define([folks_lt_age], [0])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 AC_ARG_ENABLE(eds-backend,
  81         AC_HELP_STRING([--enable-eds-backend],
  82                        [ build the E-D-S backend]),
  83         enable_eds_backend=$enableval,
  84         enable_eds_backend=yes )
  85
  86 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
  87
  88 # Automatically check the dependencies for the libsocialweb backend
  89 SW_CLIENT_REQUIRED=0.25.15
  90 AC_ARG_ENABLE(libsocialweb-backend,
  91         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
  92                        [build the Libsocialweb backend (default: auto)]),
  93         enable_libsocialweb_backend=$enableval,
  94         enable_libsocialweb_backend=auto )
  95
  96 if test "x$enable_libsocialweb_backend" != "xno"; then
  97   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
  98       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
  99   if test "x$have_libsocialweb_backend" = "xyes" -a \
 100           "x$enable_vala" = "xyes"; then
 101     VALA_CHECK_PACKAGES([telepathy-glib
 102                          gio-2.0
 103                          gee-1.0
 104                          libsocialweb-client],
 105         ,
 106         have_libsocialweb_backend="no")
 107   fi
 108
 109   if test "x$have_libsocialweb_backend" = "xyes"; then
 110     AC_DEFINE(HAVE_LIBSOCIALWEB, [],
 111               [Define if you have the libsocialweb backend])
 112   fi
 113 else
 114    have_libsocialweb_backend=no
 115 fi
 116
 117 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 118   "x$have_libsocialweb_backend" != "xyes"; then
 119     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 120 fi
 121
 122 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 123         [test "x$have_libsocialweb_backend" = "xyes"])
 124
 125 # -----------------------------------------------------------
 126 # Dependencies
 127 # -----------------------------------------------------------
 128
 129 GLIB_REQUIRED=2.24.0
 130 TP_GLIB_REQUIRED=0.13.1
 131 VALA_REQUIRED=0.13.3
 132 VALADOC_REQUIRED=0.3.1
 133 TRACKER_SPARQL_REQUIRED=0.10
 134 TRACKER_SPARQL_NEWER_VER=0.10.6
 135 GCONF2_REQUIRED=2.31
 136 EBOOK_REQUIRED=3.1.5
 137 EDATASERVER_REQUIRED=3.1.5
 138
 139 PKG_CHECK_MODULES([GLIB],
 140                   [glib-2.0 >= $GLIB_REQUIRED
 141                    gobject-2.0 >= $GLIB_REQUIRED])
 142 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 143 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 144 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 145 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 146
 147 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 148 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7])
 149 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 150
 151 if test x$enable_tracker_backend = xyes; then
 152         # Starting Tracker 0.10.6, the GLib.SpawnError is exception is thrown
 153         # when calling Tracker.Sparql.Connection.get (). So we need to test
 154         # for the installed version and catch or not the exception, accordingly.
 155         PKG_CHECK_MODULES([TRACKER_SPARQL],
 156                           [tracker-sparql-0.10 >= $TRACKER_SPARQL_NEWER_VER],
 157                           [AM_CONDITIONAL(HAVE_NEW_TRACKER, [ test 1 == 1 ])],
 158                           [PKG_CHECK_MODULES([TRACKER_SPARQL],
 159                                              [tracker-sparql-0.10 >= $TRACKER_SPARQL_REQUIRED],
 160                                              [AM_CONDITIONAL(HAVE_NEW_TRACKER, [ test 0 == 1 ])])]
 161                           )
 162 else
 163         AM_CONDITIONAL(HAVE_NEW_TRACKER, [ test 0 == 1 ])
 164 fi
 165
 166 if test x$enable_eds_backend = xyes; then
 167         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 168         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 169 fi
 170
 171 #
 172 # Vala building options -- allows tarball builds without installing Vala
 173 #
 174 AC_ARG_ENABLE([vala],
 175               AS_HELP_STRING([--enable-vala],
 176                              [Enable building from the Vala sources]),
 177               [enable_vala=$enableval],
 178               [enable_vala=no])
 179
 180 # will be re-set as necessary below
 181 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 182 sd=${srcdir}/
 183
 184 # Force Vala for non-release builds
 185 m4_if(folks_released, [1], [],
 186     [
 187         enable_vala=yes
 188         echo "Vala compiler required for non-release builds; requiring Vala..."
 189     ])
 190
 191 # Force Vala if generated source is missing or outdated
 192 if test \
 193         ! -e ${sd}tools/folks_import_vala.stamp -o \
 194         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 195         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 196         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 197         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 198         ! -e ${sd}tests/lib/folks-test.vapi -o \
 199         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 200         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 201         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 202         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 203         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 204         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 205         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 206         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 207         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 208         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 209         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 210                 -o \
 211         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 212         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 213         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 214         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 215         ! -e ${sd}folks/folks.vapi -o \
 216         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 217         enable_vala=yes
 218         echo "Vala source needs to be re-compiled; requiring Vala..."
 219 fi
 220
 221 if test "x$enable_vala" = "xyes" ; then
 222         AM_PROG_VALAC([$VALA_REQUIRED])
 223         if test "x$VALAC" = "x"; then
 224               AC_MSG_ERROR([Vala requested but valac is not installed])
 225         fi
 226
 227         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 228         if test "x$VAPIGEN" = "x"; then
 229               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 230         fi
 231
 232         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 233         # automatically
 234         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 235         AC_SUBST([VALAFLAGS])
 236         AC_SUBST([VAPIGENFLAGS])
 237         AC_SUBST([VAPIDIR])
 238
 239         VALA_CHECK_PACKAGES([telepathy-glib
 240                              gio-2.0
 241                              gee-1.0])
 242
 243         if test x$enable_tracker_backend = xyes; then
 244           VALA_CHECK_PACKAGES([tracker-sparql-0.10])
 245         fi
 246
 247         if test x$enable_eds_backend = xyes; then
 248           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 249         fi
 250 fi
 251
 252 # this will set HAVE_INTROSPECTION
 253 GOBJECT_INTROSPECTION_REQUIRE([0.9.12])
 254
 255 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 256
 257 # Various functions that we need (used in C code generated from Vala)
 258 AC_CHECK_FUNCS([memset])
 259 AC_CHECK_FUNCS([strstr])
 260
 261 # -----------------------------------------------------------
 262 # Backends
 263 # -----------------------------------------------------------
 264
 265 FOLKS_MODULE_VERSION=folks_module_version
 266 AC_SUBST([FOLKS_MODULE_VERSION])
 267 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 268
 269 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 270 AC_SUBST([BACKEND_DIR])
 271
 272 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 273 AC_SUBST([BACKEND_KF])
 274 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 275 AC_SUBST([BACKEND_TP])
 276 BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 277 AC_SUBST([BACKEND_EDS])
 278
 279 if test x$have_libsocialweb_backend = xyes; then
 280   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 281   AC_SUBST([BACKEND_LIBSOCIALWEB])
 282 fi
 283
 284 if test x$enable_tracker_backend = xyes; then
 285   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 286   AC_SUBST([BACKEND_TRACKER])
 287 fi
 288
 289 if test x$enable_eds_backend = xyes; then
 290   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 291   AC_SUBST([BACKEND_EDS])
 292 fi
 293
 294 # All of the backend libraries in our tree; to be used by the tests
 295 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 296 if test x$have_libsocialweb_backend = xyes; then
 297   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 298   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 299 fi
 300 if test x$enable_tracker_backend = xyes; then
 301   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 302   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 303 fi
 304 if test x$enable_eds_backend = xyes; then
 305   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 306   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 307 fi
 308 AC_SUBST([BACKEND_UNINST_PATH])
 309
 310 # -----------------------------------------------------------
 311 # Tools
 312 # -----------------------------------------------------------
 313
 314 AC_ARG_ENABLE([import-tool],
 315               AS_HELP_STRING([--enable-import-tool],
 316                              [Enable building the meta-contact import tool]),
 317               [enable_import_tool=$enableval with_import_tool=$enableval],
 318               [enable_import_tool=maybe with_import_tool=no])
 319 AS_IF([test "$enable_import_tool" != "no"],
 320       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 321                          [with_import_tool=yes], [with_import_tool=no])])
 322 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 323       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 324 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 325
 326 # Readline's required for the folks-inspect program
 327 AC_ARG_ENABLE([inspect-tool],
 328               AS_HELP_STRING([--enable-inspect-tool],
 329                              [Enable building the data inspection tool]),
 330               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 331               [enable_inspect_tool=maybe with_inspect_tool=no])
 332 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 333       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 334                      using --enable-vala])])
 335 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 336       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 337                       --enable-vala])])
 338 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 339       [AC_CHECK_LIB([readline], [main],
 340                     [with_inspect_tool=yes], [with_inspect_tool=no],
 341                     [-lncurses])])
 342 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 343        "x$enable_vala" = "xyes"],
 344       [VALA_CHECK_PACKAGES([readline])
 345        LIBREADLINE="-lreadline -lncurses"
 346        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 347        AC_SUBST([LIBREADLINE])])
 348 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 349       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 350 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 351
 352 # -----------------------------------------------------------
 353 # Documentation
 354 # -----------------------------------------------------------
 355
 356 AC_ARG_ENABLE([docs],
 357               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 358               [enable_docs=$enableval], [enable_docs=no])
 359 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 360
 361 have_valadoc=no
 362 if test x$enable_docs = xyes; then
 363   # make sure the library is new enough and the program exists
 364   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 365   AC_PATH_PROG([VALADOC], [valadoc], [:])
 366   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 367 fi
 368 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 369
 370 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 371     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 372 fi
 373
 374 # -----------------------------------------------------------
 375 # Gettext
 376 # -----------------------------------------------------------
 377
 378 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 379 AC_SUBST(GETTEXT_PACKAGE)
 380 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 381 IT_PROG_INTLTOOL([0.35.0])
 382
 383 # -----------------------------------------------------------
 384 # Error flags
 385 # -----------------------------------------------------------
 386
 387 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 388 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 389
 390 AC_ARG_ENABLE([debug],
 391               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 392               [enable_debug=$enableval], [enable_debug=yes])
 393
 394 AC_ARG_ENABLE([Werror],
 395               AS_HELP_STRING([--disable-Werror],
 396                              [compile without -Werror (normally enabled in
 397                               development builds)]),
 398               [werror=$enableval], [werror=yes])
 399
 400 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 401 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 402                  [wno_missing_field_initializers=yes],
 403                  [wno_missing_field_initializers=no])
 404 AS_COMPILER_FLAG([-Wno-unused-parameter],
 405                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 406
 407 m4_if(folks_released, [1], [],
 408     [
 409         if test x$werror = xyes; then
 410             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 411         fi
 412         if test x$wextra = xyes -a \
 413             x$wno_missing_field_initializers = xyes -a \
 414             x$wno_unused_parameter = xyes; then
 415             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 416                 -Wno-missing-field-initializers -Wno-unused-parameter"
 417         fi
 418     ])
 419
 420 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 421 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 422 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 423 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 424                                           -Wmissing-prototypes"])
 425 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 426                                             -Wmissing-declarations"])
 427 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 428                                          -Wstrict-prototypes"])
 429
 430 AC_SUBST([ERROR_CFLAGS])
 431
 432 # Vala-related flags
 433 AS_IF([test "x$enable_vala" = "xyes"],
 434       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 435                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 436        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 437
 438 m4_if(folks_released, [1], [],
 439     [
 440         ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 441     ])
 442
 443 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 444 AC_SUBST([ERROR_VALAFLAGS])
 445
 446 # -----------------------------------------------------------
 447 # Final output
 448 # -----------------------------------------------------------
 449
 450 AC_CONFIG_FILES([
 451     backends/telepathy/lib/folks-telepathy.pc
 452     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 453     backends/tracker/lib/folks-tracker.pc
 454     backends/tracker/lib/folks-tracker-uninstalled.pc
 455     backends/eds/lib/folks-eds.pc
 456     backends/eds/lib/folks-eds-uninstalled.pc
 457     folks/folks.pc
 458     folks/folks-uninstalled.pc
 459     Makefile
 460     backends/Makefile
 461     backends/key-file/Makefile
 462     backends/libsocialweb/Makefile
 463     backends/libsocialweb/lib/Makefile
 464     backends/libsocialweb/lib/folks-libsocialweb.pc
 465     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 466     backends/telepathy/Makefile
 467     backends/telepathy/lib/Makefile
 468     backends/tracker/Makefile
 469     backends/tracker/lib/Makefile
 470     backends/eds/Makefile
 471     backends/eds/lib/Makefile
 472     folks/Makefile
 473     docs/Makefile
 474     po/Makefile.in
 475     tests/Makefile
 476     tests/data/Makefile
 477     tests/data/gconf.path
 478     tests/folks/Makefile
 479     tests/key-file/Makefile
 480     tests/libsocialweb/Makefile
 481     tests/telepathy/Makefile
 482     tests/tracker/Makefile
 483     tests/lib/Makefile
 484     tests/lib/folks-test-uninstalled.pc
 485     tests/lib/key-file/Makefile
 486     tests/lib/libsocialweb/Makefile
 487     tests/lib/libsocialweb/session.conf
 488     tests/eds/Makefile
 489     tests/lib/eds/Makefile
 490     tests/lib/telepathy/Makefile
 491     tests/lib/tracker/Makefile
 492     tests/lib/telepathy/contactlist/Makefile
 493     tests/lib/telepathy/contactlist/session.conf
 494     tests/tools/Makefile
 495     tools/Makefile
 496     tools/inspect/Makefile
 497 ])
 498
 499 AC_OUTPUT
 500
 501 echo "
 502 Configure summary:
 503
 504         Vala........................:  ${enable_vala}
 505         Vala Compiler...............:  ${VALAC}
 506         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS}
 507         Prefix......................:  ${prefix}
 508         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 509         Documentation...............:  ${have_valadoc}
 510         Import tool.................:  ${with_import_tool}
 511         Inspector tool..............:  ${with_inspect_tool}
 512         Tracker backend.............:  ${enable_tracker_backend}
 513         Libsocialweb backend........:  ${have_libsocialweb_backend}
 514         E-D-S backend...............:  ${enable_eds_backend}
 515
 516 "