configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT().
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb], LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AM_CONFIG_HEADER([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 AC_PROG_LIBTOOL
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48 case $host in
  49 *-linux*)
  50         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  51         AC_SUBST(OS_LINUX)
  52         AC_MSG_RESULT([Linux])
  53         backend="linux"
  54         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  55         threads="posix"
  56         THREAD_CFLAGS="-pthread"
  57         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  58         AC_CHECK_HEADERS([poll.h])
  59         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  60         ;;
  61 *-darwin*)
  62         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
  63         AC_SUBST(OS_DARWIN)
  64         AC_MSG_RESULT([Darwin/Mac OS X])
  65         backend="darwin"
  66         threads="posix"
  67         LIBS="${LIBS} -lobjc"
  68         PC_LIBS_PRIVATE="-Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
  69         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
  70         AC_CHECK_HEADERS([poll.h])
  71         AC_CHECK_TYPE([nfds_t],
  72                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
  73                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
  74                 [#include <poll.h>])
  75         ;;
  76 *-mingw*)
  77         AC_MSG_RESULT([Windows])
  78         backend="windows"
  79         ;;
  80 *-cygwin*)
  81         AC_MSG_RESULT([Cygwin (using Windows backend)])
  82         backend="windows"
  83         threads="posix"
  84         ;;
  85 *)
  86         AC_MSG_ERROR([unsupported operating system])
  87 esac
  88 if test "$backend" = windows; then
  89         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
  90         AC_SUBST(OS_WINDOWS)
  91         PC_LIBS_PRIVATE=""
  92         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
  93         AC_CHECK_TOOL(RC, windres, no)
  94         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  95 fi
  96 AC_SUBST(THREAD_CFLAGS)
  97 AC_SUBST(PC_LIBS_PRIVATE)
  98 LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  99
 100 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 101 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 102 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 103 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 104 if test "$threads" = posix; then
 105         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 106 fi
 107
 108 # timerfd
 109 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 110 AC_ARG_ENABLE([timerfd],
 111         [AS_HELP_STRING([--enable-timerfd],
 112                 [use timerfd for timing (default auto)])],
 113         [use_timerfd=$enableval], [use_timerfd='auto'])
 114
 115 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 116         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 117 fi
 118
 119 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 120 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 121         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 122 fi
 123
 124 AC_MSG_CHECKING([whether to use timerfd for timing])
 125 if test "x$use_timerfd" = "xno"; then
 126         AC_MSG_RESULT([no (disabled by user)])
 127 else
 128         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 129                 AC_MSG_RESULT([yes])
 130                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 131         else
 132                 AC_MSG_RESULT([no (header not available)])
 133         fi
 134 fi
 135
 136 AC_CHECK_TYPES(struct timespec)
 137
 138 # Message logging
 139 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 140         [log_enabled=$enableval],
 141         [log_enabled='yes'])
 142 if test "x$log_enabled" != "xno"; then
 143         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 144 fi
 145
 146 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 147         [enable debug logging (default n)])],
 148         [debug_log_enabled=$enableval],
 149         [debug_log_enabled='no'])
 150 if test "x$debug_log_enabled" != "xno"; then
 151         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 152 fi
 153
 154 # Examples build
 155 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 156         [build example applications (default n)])],
 157         [build_examples=$enableval],
 158         [build_examples='no'])
 159 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 160
 161 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 162 saved_cflags="$CFLAGS"
 163 # -Werror required for cygwin
 164 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 165 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 166         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 167          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 168         [ VISIBILITY_CFLAGS=""
 169          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 170         ])
 171 CFLAGS="$saved_cflags"
 172
 173 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 174 saved_cflags="$CFLAGS"
 175 CFLAGS="$CFLAGS -Wno-pointer-sign"
 176 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 177         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 178 CFLAGS="$saved_cflags"
 179
 180 # sigaction not available on MinGW
 181 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 182 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 183
 184 # headers not available on all platforms but required on others
 185 AC_CHECK_HEADERS([sys/time.h])
 186
 187 AM_CFLAGS="-std=gnu99 -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 188
 189 AC_SUBST(VISIBILITY_CFLAGS)
 190 AC_SUBST(AM_CFLAGS)
 191 AC_SUBST(LTLDFLAGS)
 192
 193 AC_CONFIG_FILES([libusb-1.0.pc])
 194 AC_CONFIG_FILES([Makefile])
 195 AC_CONFIG_FILES([libusb/Makefile])
 196 AC_CONFIG_FILES([examples/Makefile])
 197 AC_CONFIG_FILES([doc/Makefile])
 198 AC_CONFIG_FILES([doc/doxygen.cfg])
 199 AC_OUTPUT