configure.ac

   1 AC_PREREQ(2.53)
   2 AC_INIT([rygel],
   3         m4_esyscmd([GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version]),
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel])
   5 AC_CONFIG_AUX_DIR([build-aux])
   6
   7 # require automake-1.11 for vala support
   8 AM_INIT_AUTOMAKE([1.11])
   9 AC_CONFIG_SRCDIR([src/rygel/rygel-root-device.vala])
  10 AM_CONFIG_HEADER([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12 AM_MAINTAINER_MODE
  13
  14 # Disable generation of static libraries
  15 AC_DISABLE_STATIC
  16
  17 AC_ISC_POSIX
  18 AC_PROG_CC
  19 AC_STDC_HEADERS
  20 AC_PROG_LIBTOOL
  21 AC_FUNC_MMAP
  22
  23 VALA_REQUIRED=0.9.5
  24 GUPNP_REQUIRED=0.13.4
  25 GUPNP_AV_REQUIRED=0.5.9
  26 GUPNP_DLNA_REQUIRED=0.3.0
  27 GUPNP_VALA_REQUIRED=0.6.11
  28 DBUS_GLIB_REQUIRED=0.74
  29 GSTREAMER_REQUIRED=0.10.23
  30 GSTREAMER_TAG_REQUIRED=0.10.28
  31 GSTREAMER_APP_REQUIRED=0.10.28
  32 GIO_REQUIRED=2.16
  33 GEE_REQUIRED=0.5.2
  34 UUID_REQUIRED=1.41.3
  35 LIBSOUP_REQUIRED=2.26.0
  36 LIBSQLITE3_REQUIRED=3.5
  37
  38 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  39 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  40 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  41 PKG_CHECK_MODULES(LIBDBUS_GLIB, dbus-glib-1 >= $DBUS_GLIB_REQUIRED)
  42 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  43 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  44 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  45 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  46 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  47
  48 # glib-genmarshal
  49 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  50 AC_SUBST(GLIB_GENMARSHAL)
  51
  52 AC_ARG_ENABLE(vala,
  53         [  --enable-vala          enable checks for vala],,
  54         enable_vala=no)
  55 AC_ARG_ENABLE(sql-debugging,
  56               [  --enable-sql-debugging         enable SQL statement debugging],,
  57                  enable_sql_debugging=no)
  58
  59 if test x$enable_sql_debugging = xyes ; then
  60     VALAFLAGS="$VALAFLAGS -D RYGEL_DEBUG_SQL"
  61 fi
  62
  63 # Enable check for Vala even if not asked to do so if stamp files are absent.
  64 if test ! -e src/rygel/rygel_vala.stamp -o \
  65         ! -e src/rygel/librygel_configuration_a_vala.stamp -o \
  66         ! -e src/ui/rygel_preferences_vala.stamp -o \
  67         ! -e src/plugins/playbin/librygel_playbin_la_vala.stamp -o \
  68         ! -e src/plugins/tracker/librygel_media_tracker_la_vala.stamp -o \
  69         ! -e src/plugins/test/librygel_test_la_vala.stamp -o \
  70         ! -e src/plugins/media-export/librygel_media_export_la_vala.stamp -o \
  71         ! -e src/plugins/mediathek/librygel_mediathek_la_vala.stamp -o \
  72         ! -e src/plugins/gst-launch/librygel_gst_launch_la_vala.stamp -o \
  73         ! -e src/plugins/external/librygel_external_la_vala.stamp ; then
  74     enable_vala=yes
  75 fi
  76
  77 # Vala
  78 if test x$enable_vala = xyes ; then
  79     # check for vala
  80     AM_PROG_VALAC([$VALA_REQUIRED])
  81
  82     if test "x$VALAC" = "x"; then
  83         AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])
  84     fi
  85
  86     PKG_CHECK_MODULES(GUPNP_VALA, gupnp-vala-1.0 >= $GUPNP_VALA_REQUIRED)
  87
  88     VALA_CHECK_PACKAGES([gupnp-1.0
  89                          gupnp-av-1.0
  90                          gupnp-dlna-1.0
  91                          dbus-glib-1
  92                          gstreamer-0.10
  93                          gstreamer-discoverer-gupnp-dlna-0.10
  94                          gio-2.0
  95                          gee-1.0
  96                          posix])
  97 else
  98     VAPIDIR=`echo ${datadir}/vala/vapi`
  99 fi
 100
 101 AC_SUBST(VAPIDIR)
 102
 103 # Maemo support
 104 AC_ARG_ENABLE(maemo,
 105         [  --enable-maemo          enable maemo support],,
 106         enable_maemo=no)
 107
 108 # Debugging
 109 AC_ARG_ENABLE(debug,
 110         [  --enable-debug          enable debugging],,
 111         enable_debug=no)
 112 if test "x$enable_debug" = "xyes"; then
 113         CFLAGS="$CFLAGS -O0 -g"
 114 fi
 115
 116 # Strict compiler
 117 AC_ARG_ENABLE(strict-cc,
 118         [  --enable-strict-cc          enable strict C compiler],,
 119         enable_strict_cc=no)
 120 if test "x$enable_strict_cc" = "xyes"; then
 121         CFLAGS="$CFLAGS -Wall -Werror"
 122 else
 123         CFLAGS="$CFLAGS -w"
 124 fi
 125
 126 # Run uninstalled
 127 AC_ARG_ENABLE(uninstalled,
 128         [  --enable-uninstalled          run uninstalled],,
 129         enable_uninstalled=no)
 130 if test "x$enable_uninstalled" = "xyes"; then
 131         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 132 fi
 133
 134 AC_MSG_CHECKING([which gtk+ version to compile against])
 135 AC_ARG_WITH([gtk],
 136   [AS_HELP_STRING([--with-gtk=2.0|3.0],[which gtk+ version to compile against (default: 2.0)])],
 137   [case "$with_gtk" in
 138      2.0|3.0) ;;
 139      *) AC_MSG_ERROR([invalid gtk version specified]) ;;
 140    esac],
 141   [with_gtk=2.0])
 142 AC_MSG_RESULT([$with_gtk])
 143
 144 case "$with_gtk" in
 145   2.0) GTK_VAPI_VERSION=2.0
 146        GTK_REQUIRED=2.20.0
 147        ;;
 148   3.0) GTK_VAPI_VERSION=3.0
 149        GTK_REQUIRED=2.90.3
 150        ;;
 151 esac
 152
 153 # Check wether user wants to build UIs
 154 AC_ARG_WITH( ui,
 155   AC_HELP_STRING([--without-ui],[Do not build UI applications]),
 156   try_ui=$withval, try_ui=yes )
 157
 158 HAVE_GTK=no
 159 if test x$try_ui = xyes ; then
 160     dnl check for gtk
 161     PKG_CHECK_MODULES(GTK, gtk+-$GTK_VAPI_VERSION >= $GTK_REQUIRED ,
 162       [
 163         AC_SUBST(GTK_CFLAGS)
 164         AC_SUBST(GTK_LIBS)
 165         if test x$enable_vala = xyes ; then
 166                 VALA_CHECK_PACKAGES([gtk+-$GTK_VAPI_VERSION], [HAVE_GTK=yes])
 167         else
 168                 HAVE_GTK=yes
 169         fi
 170       ],
 171       [
 172         HAVE_GTK=no
 173         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 174         AC_MSG_WARN([UI applications will not be built.])
 175       ])
 176 else
 177     AC_MSG_NOTICE([UI applications disabled.])
 178 fi
 179
 180 if test x$HAVE_GTK = xno; then
 181   BUILD_UI=no
 182   with_gtk="n/a"
 183 else
 184   BUILD_UI=yes
 185   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 186 fi
 187
 188 AC_SUBST(HAVE_GTK)
 189 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 190
 191 # Build test plugin
 192 AC_ARG_ENABLE(test-plugin,
 193         [  --enable-test-plugin          build test plugin],,
 194         enable_test_plugin=no)
 195
 196 # Build Tracker plugin
 197 AC_ARG_ENABLE(tracker-plugin,
 198         [  --enable-tracker-plugin      build tracker plugin],,
 199         enable_tracker_plugin=yes)
 200
 201 # Build MediaExport plugin
 202 AC_ARG_ENABLE(media-export-plugin,
 203         [  --enable-media-export-plugin          build MediaExport plugin],,
 204         enable_media_export_plugin=yes)
 205
 206 # Build External plugin
 207 AC_ARG_ENABLE(external-plugin,
 208         [  --enable-external-plugin          build External plugin],,
 209         enable_external_plugin=yes)
 210
 211 # Build GstRenderer plugin
 212 AC_ARG_ENABLE(playbin-plugin,
 213         [  --enable-playbin_plugin          build Gstreamer Playbin plugin],,
 214         enable_playbin_plugin=yes)
 215
 216 # Build Mediathek plugin
 217 AC_ARG_ENABLE(mediathek-plugin,
 218         [  --enable-mediathek-plugin          build Mediathek plugin],,
 219         enable_mediathek_plugin=no)
 220
 221 # Build GstLaunch plugin
 222 AC_ARG_ENABLE(gst-launch-plugin,
 223         [  --enable-gst-launch-plugin          build Gstreamer launchline plugin],,
 224         enable_gst_launch_plugin=no)
 225
 226
 227 AC_SUBST(abs_top_builddir)
 228
 229 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 230 AM_CONDITIONAL([ENABLE_MAEMO], [test "x$enable_maemo" = "xyes"])
 231 AM_CONDITIONAL([BUILD_TEST_PLUGIN], [test "x$enable_test_plugin" = "xyes"])
 232 AM_CONDITIONAL([BUILD_TRACKER_PLUGIN],
 233                [test "x$enable_tracker_plugin" = "xyes"])
 234 AM_CONDITIONAL([BUILD_MEDIATHEK_PLUGIN], [test "x$enable_mediathek_plugin" = "xyes"])
 235 AM_CONDITIONAL([BUILD_MEDIA_EXPORT_PLUGIN], [test "x$enable_media_export_plugin" = "xyes"])
 236 AM_CONDITIONAL([BUILD_EXTERNAL_PLUGIN], [test "x$enable_external_plugin" = "xyes"])
 237 AM_CONDITIONAL([BUILD_PLAYBIN_PLUGIN], [test "x$enable_playbin_plugin" = "xyes"])
 238 AM_CONDITIONAL([BUILD_GST_LAUNCH_PLUGIN], [test "x$enable_gst_launch_plugin" = "xyes"])
 239
 240 if test "x$enable_media_export_plugin" = "xyes";
 241 then
 242     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 243     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 244     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 245     if test x$enable_vala = xyes ; then
 246         VALA_CHECK_PACKAGES([sqlite3
 247                              gstreamer-tag-0.10
 248                              gstreamer-app-0.10])
 249     fi
 250 fi
 251
 252 # Gettext
 253 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 254 AC_SUBST(GETTEXT_PACKAGE)
 255 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 256   [Define the gettext package to be used])
 257
 258 AM_GLIB_GNU_GETTEXT
 259 IT_PROG_INTLTOOL([0.35.0])
 260
 261 AC_SUBST(VALAFLAGS)
 262
 263 dnl Shave the output
 264 AM_SILENT_RULES([yes])
 265
 266 dnl documenation
 267 AC_PATH_PROG([XSLTPROC], [xsltproc])
 268 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 269
 270 AC_OUTPUT([
 271 Makefile
 272 src/Makefile
 273 src/rygel/Makefile
 274 src/ui/Makefile
 275 src/plugins/Makefile
 276 src/plugins/media-export/Makefile
 277 src/plugins/external/Makefile
 278 src/plugins/gst-launch/Makefile
 279 src/plugins/mediathek/Makefile
 280 src/plugins/tracker/Makefile
 281 src/plugins/playbin/Makefile
 282 src/plugins/test/Makefile
 283 data/Makefile
 284 data/xml/Makefile
 285 data/icons/Makefile
 286 data/icons/32x32/Makefile
 287 data/icons/48x48/Makefile
 288 data/icons/120x120/Makefile
 289 data/icons/scalable/Makefile
 290 doc/Makefile
 291 po/Makefile.in
 292 rygel-1.0.pc
 293 tests/Makefile
 294 ])
 295
 296 echo "
 297
 298                     ${PACKAGE} ${VERSION}
 299                     ============
 300
 301
 302         Prefix:                 ${prefix}
 303         Source code location:   ${srcdir}
 304         Compiler:               ${CC}
 305         CFLAGS:                 ${CFLAGS}
 306         uninstalled:            ${enable_uninstalled}
 307         maemo support:          ${enable_maemo}
 308         preferences ui:         ${BUILD_UI}
 309         GTK+ version:           ${with_gtk}
 310         SQL debugging:          ${enable_sql_debugging}
 311     Plugins:
 312         test:                   ${enable_test_plugin}
 313         tracker:                ${enable_tracker_plugin}
 314         mediathek:              ${enable_mediathek_plugin}
 315         media-export            ${enable_media_export_plugin}
 316         external:               ${enable_external_plugin}
 317         gst-launch:             ${enable_gst_launch_plugin}
 318         playbin:                ${enable_playbin_plugin}
 319 "