configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 GLIB_REQUIRED=2.31.13
  32 VALA_REQUIRED=0.15.2
  33 VALADOC_REQUIRED=0.2
  34 GSSDP_REQUIRED=0.11.0
  35 GUPNP_REQUIRED=0.17.1
  36 GUPNP_AV_REQUIRED=0.9.0
  37 GUPNP_DLNA_REQUIRED=0.5.0
  38 GUPNP_VALA_REQUIRED=0.10.2
  39 GSTREAMER_REQUIRED=0.10.36
  40 GSTPBU_REQUIRED=0.10.35
  41 GIO_REQUIRED=2.26
  42 GEE_REQUIRED=0.5.2
  43 UUID_REQUIRED=1.41.3
  44 LIBSOUP_REQUIRED=2.34.0
  45 GTK_REQUIRED=2.90.3
  46
  47 dnl Additional requirements for media-export plugin
  48 GSTREAMER_TAG_REQUIRED=0.10.28
  49 GSTREAMER_APP_REQUIRED=0.10.28
  50 LIBSQLITE3_REQUIRED=3.5
  51
  52 PKG_CHECK_MODULES(LIBGLIB, glib-2.0 >= $GLIB_REQUIRED)
  53 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  54
  55 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  56 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  57 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  58 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  59 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  60 PKG_CHECK_MODULES(GSTREAMER_BASE, gstreamer-base-0.10 >= $GSTREAMER_REQUIRED)
  61 PKG_CHECK_MODULES(GST_PBU, gstreamer-pbutils-0.10 >= $GSTPBU_REQUIRED)
  62 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  63 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  64 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  65 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  66
  67 dnl glib-genmarshal
  68 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  69 AC_SUBST(GLIB_GENMARSHAL)
  70
  71 dnl Add plugins
  72 RYGEL_ADD_PLUGIN([test],[Test],[no])
  73 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  74 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  75 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  76 RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
  77 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  78 RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
  79 RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
  80
  81 dnl Explicitly add stamp files for targets that are not plugins
  82 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
  83 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
  84
  85 RYGEL_CHECK_VALA([$VALA_REQUIRED],
  86                  [gupnp-1.0
  87                   gupnp-av-1.0
  88                   gupnp-dlna-1.0
  89                   gstreamer-0.10
  90                   gstreamer-pbutils-0.10
  91                   gio-2.0
  92                   gee-1.0
  93                   posix])
  94
  95 dnl Debugging
  96 AC_ARG_ENABLE(debug,
  97         AS_HELP_STRING([--enable-debug],[enable debugging]),,
  98         enable_debug=no)
  99 if test "x$enable_debug" = "xyes"; then
 100         CFLAGS="$CFLAGS -O0 -g"
 101         RYGEL_DEBUG_VALAFLAGS="-g"
 102 fi
 103
 104 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 105
 106 dnl Strict compiler
 107 AC_ARG_ENABLE(strict-cc,
 108         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 109         enable_strict_cc=no)
 110 if test "x$enable_strict_cc" = "xyes"; then
 111         CFLAGS="$CFLAGS -Wall -Werror"
 112 else
 113         CFLAGS="$CFLAGS -w"
 114 fi
 115
 116 dnl Run uninstalled
 117 AC_ARG_ENABLE(uninstalled,
 118     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 119         enable_uninstalled=no)
 120 if test "x$enable_uninstalled" = "xyes"; then
 121         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 122 fi
 123 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 124
 125 dnl Check wether user wants to build UIs
 126 AC_ARG_WITH( ui,
 127   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 128   try_ui=$withval, try_ui=yes )
 129
 130 HAVE_GTK=no
 131 if test x$try_ui = xyes ; then
 132     dnl check for gtk
 133     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 134       [
 135         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 136       ],
 137       [
 138         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 139         AC_MSG_WARN([UI applications will not be built.])
 140       ])
 141 else
 142     AC_MSG_NOTICE([UI applications disabled.])
 143 fi
 144
 145 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 146
 147 dnl Tests
 148 AC_ARG_ENABLE([tests],
 149               AS_HELP_STRING([--enable-tests],[always build tests]),,
 150               enable_tests=no)
 151 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 152
 153 dnl Generate coverage data
 154 AC_ARG_ENABLE([coverage],
 155   AS_HELP_STRING([--enable-coverage],
 156                  [Generate converage reports for unit tests]),
 157   [],
 158   [enable_coverage=no])
 159 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 160 AS_IF([test "x$enable_coverage" != "xno"],
 161   [
 162     AC_PATH_PROG([LCOV], [lcov])
 163     AC_PATH_PROG([GENHTML], [genhtml])
 164     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 165     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 166     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 167   ]
 168 )
 169
 170 dnl Check additional requirements for MediaExport plugins
 171 if test "x$enable_media_export_plugin" = "xyes";
 172 then
 173     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 174     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 175     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 176     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-0.10 gstreamer-app-0.10])
 177     AC_CHECK_HEADER([unistr.h],
 178                     AC_CHECK_LIB([unistring],
 179                                  [u8_strcoll],
 180                                  [have_unistring=yes],[have_unistring=no]))
 181     if test "x$have_unistring" = "xyes"; then
 182         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 183         COLLATION_CFLAGS=
 184         COLLATION_LIBS=-lunistring
 185         AC_SUBST([COLLATION_CFLAGS])
 186         AC_SUBST([COLLATION_LIBS])
 187     fi
 188 fi
 189
 190 dnl Gettext
 191 GETTEXT_PACKAGE=rygel
 192 AC_SUBST(GETTEXT_PACKAGE)
 193 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 194   [Define the gettext package to be used])
 195
 196 AM_GLIB_GNU_GETTEXT
 197 IT_PROG_INTLTOOL([0.40.0])
 198
 199 dnl Shave the output
 200 AM_SILENT_RULES([yes])
 201
 202 dnl documenation
 203 AC_PATH_PROG([XSLTPROC], [xsltproc])
 204 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 205
 206 dnl Use valadoc for API documentation:
 207 AC_ARG_ENABLE(valadoc,
 208   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 209     [enable_valadoc=auto])
 210
 211 found_valadoc=no
 212 AS_IF([test "x$enable_valadoc" != "xno"], [
 213     AC_PATH_PROG(VALADOC, valadoc, :)
 214     AS_IF([test -x "$VALADOC"], [
 215       found_valadoc=yes
 216       AC_SUBST(VALADOC)
 217     ], [
 218       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 219     ])
 220   ])
 221
 222 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 223
 224
 225 AC_CONFIG_FILES([
 226 Makefile
 227 src/Makefile
 228 src/librygel-core/Makefile
 229 src/librygel-renderer/Makefile
 230 src/rygel/Makefile
 231 src/ui/Makefile
 232 src/plugins/Makefile
 233 data/Makefile
 234 data/xml/Makefile
 235 data/icons/Makefile
 236 data/icons/32x32/Makefile
 237 data/icons/48x48/Makefile
 238 data/icons/120x120/Makefile
 239 data/icons/128x128/Makefile
 240 data/icons/scalable/Makefile
 241 data/rygel.desktop.in
 242 data/rygel-preferences.desktop.in
 243 doc/Makefile
 244 doc/reference/Makefile
 245 doc/reference/librygel-core/Makefile
 246 doc/reference/librygel-renderer/Makefile
 247 po/Makefile.in
 248 rygel-core-1.0.pc
 249 rygel-renderer-1.0.pc
 250 tests/Makefile
 251 examples/Makefile
 252 ])
 253 AC_OUTPUT
 254
 255 echo "
 256
 257                     ${PACKAGE} ${VERSION}
 258                     ============
 259
 260
 261         Prefix:                 ${prefix}
 262         Source code location:   ${srcdir}
 263         Compiler:               ${CC}
 264         CFLAGS:                 ${CFLAGS}
 265         VALAFLAGS:              ${VALAFLAGS}
 266         uninstalled:            ${enable_uninstalled}
 267         preferences ui:         ${HAVE_GTK}
 268     Plugins:
 269         test:                   ${enable_test_plugin}
 270         tracker:                ${enable_tracker_plugin}
 271         mediathek:              ${enable_mediathek_plugin}
 272         media-export            ${enable_media_export_plugin}
 273         external:               ${enable_external_plugin}
 274         MPRIS2:                 ${enable_mpris_plugin}
 275         gst-launch:             ${enable_gst_launch_plugin}
 276         playbin:                ${enable_playbin_plugin}
 277 "