configure.ac

   1 ## Process this file with autoconf to produce configure.
   2 ## In general, the safest way to proceed is to run the following:
   3 ##    % aclocal -I . -I `pwd`/../autoconf && autoheader && autoconf && automake
   4
   5 # make sure we're interpreted by some minimal autoconf
   6 AC_PREREQ(2.57)
   7
   8 AC_INIT(glog, 0.1.1, opensource@google.com)
   9 # The argument here is just something that should be in the current directory
  10 # (for sanity checking)
  11 AC_CONFIG_SRCDIR(README)
  12 AM_INIT_AUTOMAKE
  13 AM_CONFIG_HEADER(src/config.h)
  14
  15 # Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18 AC_PROG_CXX
  19 AM_CONDITIONAL(GCC, test "$GCC" = yes)   # let the Makefile know if we're gcc
  20
  21 AC_PROG_LIBTOOL
  22 AC_SUBST(LIBTOOL_DEPS)
  23
  24 # Check whether some low-level functions/files are available
  25 AC_HEADER_STDC
  26
  27 # These are tested for by AC_HEADER_STDC, but I check again to set the var
  28 AC_CHECK_HEADER(stdint.h, ac_cv_have_stdint_h=1, ac_cv_have_stdint_h=0)
  29 AC_CHECK_HEADER(sys/types.h, ac_cv_have_systypes_h=1, ac_cv_have_systypes_h=0)
  30 AC_CHECK_HEADER(inttypes.h, ac_cv_have_inttypes_h=1, ac_cv_have_inttypes_h=0)
  31 AC_CHECK_HEADERS(syscall.h)
  32 AC_CHECK_HEADERS(sys/syscall.h)
  33 # For backtrace with glibc.
  34 AC_CHECK_HEADERS(execinfo.h)
  35 # For backtrace with libunwind.
  36 AC_CHECK_HEADERS(libunwind.h, ac_cv_have_libunwind_h=1, ac_cv_have_libunwind_h=0)
  37 AC_CHECK_HEADERS(ucontext.h)
  38
  39 AC_CHECK_SIZEOF(void *)
  40
  41 # These are the types I need.  We look for them in either stdint.h,
  42 # sys/types.h, or inttypes.h, all of which are part of the default-includes.
  43 AC_CHECK_TYPE(uint16_t, ac_cv_have_uint16_t=1, ac_cv_have_uint16_t=0)
  44 AC_CHECK_TYPE(u_int16_t, ac_cv_have_u_int16_t=1, ac_cv_have_u_int16_t=0)
  45 AC_CHECK_TYPE(__uint16, ac_cv_have___uint16=1, ac_cv_have___uint16=0)
  46
  47 AC_CHECK_FUNC(sigaltstack,
  48               AC_DEFINE(HAVE_SIGALTSTACK, 1,
  49                         [Define if you have the `sigaltstack' function]))
  50 AC_CHECK_FUNC(dladdr,
  51               AC_DEFINE(HAVE_DLADDR, 1,
  52                         [Define if you have the `dladdr' function]))
  53
  54 AX_C___ATTRIBUTE__
  55 # We only care about these two attributes.
  56 if test x"$ac_cv___attribute__" = x"yes"; then
  57   ac_cv___attribute___noreturn="__attribute__ ((noreturn))"
  58   ac_cv___attribute___printf_4_5="__attribute__((__format__ (__printf__, 4, 5)))"
  59 else
  60   ac_cv___attribute___noreturn=
  61   ac_cv___attribute___printf_4_5=
  62 fi
  63
  64 AX_C___BUILTIN_EXPECT
  65 if test x"$ac_cv___builtin_expect" = x"yes"; then
  66   ac_cv_have___builtin_expect=1
  67 else
  68   ac_cv_have___builtin_expect=0
  69 fi
  70
  71 AX_C___SYNC_VAL_COMPARE_AND_SWAP
  72
  73 # On x86_64, instead of libunwind, we can choose to compile with frame-pointers
  74 # (This isn't needed on i386, where -fno-omit-frame-pointer is the default).
  75 AC_ARG_ENABLE(frame_pointers,
  76               AS_HELP_STRING([--enable-frame-pointers],
  77                              [On x86_64 systems, compile with -fno-omit-frame-pointer (see INSTALL)]),
  78               enable_frame_pointers=no)
  79 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [return __x86_64__ == 1 ? 0 : 1])],
  80                   [is_x86_64=yes], [is_x86_64=no])
  81 AM_CONDITIONAL(ENABLE_FRAME_POINTERS, test "$enable_frame_pointers" = yes)
  82 AM_CONDITIONAL(X86_64, test "$is_x86_64" = yes)
  83
  84 # Some of the code in this directory depends on pthreads
  85 ACX_PTHREAD
  86
  87 # Check if there is google-gflags library installed.
  88 AC_CHECK_LIB(gflags, main, ac_cv_have_libgflags=1, ac_cv_have_libgflags=0)
  89 if test x"$ac_cv_have_libgflags" = x"1"; then
  90   GFLAGS_LIBS=-lgflags
  91   AC_DEFINE(HAVE_LIB_GFLAGS, 1, [define if you have google gflags library])
  92 else
  93   GFLAGS_LIBS=
  94 fi
  95
  96 # We want to link in libunwind if it exists
  97 UNWIND_LIBS=
  98 # Unfortunately, we need to check the header file in addition to the
  99 # lib file to check if libunwind is available since libunwind-0.98
 100 # doesn't install all necessary header files.
 101 if test x"$ac_cv_have_libunwind_h" = x"1"; then
 102  AC_CHECK_LIB(unwind, backtrace, UNWIND_LIBS=-lunwind)
 103 fi
 104 AC_SUBST(UNWIND_LIBS)
 105 if test x"$UNWIND_LIBS" != x""; then
 106   AC_DEFINE(HAVE_LIB_UNWIND, 1, [define if you have libunwind])
 107 fi
 108
 109 # We'd like to use read/write locks in several places in the code.
 110 # See if our pthreads support extends to that.  Note: for linux, it
 111 # does as long as you define _XOPEN_SOURCE appropriately.
 112 AC_RWLOCK
 113
 114 # Find out what namespace 'normal' STL code lives in, and also what namespace
 115 # the user wants our classes to be defined in
 116 AC_CXX_STL_NAMESPACE
 117 AC_DEFINE_GOOGLE_NAMESPACE(google)
 118
 119 AC_CXX_USING_OPERATOR
 120
 121 # We want to access the "PC" (Program Counter) register from a struct
 122 # ucontext.  Every system has its own way of doing that.  We try all the
 123 # possibilities we know about.  Note REG_PC should come first (REG_RIP
 124 # is also defined on solaris, but does the wrong thing).
 125 AC_MSG_CHECKING([how to access the program counter from a struct ucontext])
 126 pc_fields="           uc_mcontext.gregs[[REG_PC]]"  # Solaris x86 (32 + 64 bit)
 127 pc_fields="$pc_fields uc_mcontext.gregs[[REG_EIP]]" # Linux (i386)
 128 pc_fields="$pc_fields uc_mcontext.gregs[[REG_RIP]]" # Linux (x86_64)
 129 pc_fields="$pc_fields uc_mcontext.sc_ip"            # Linux (ia64)
 130 pc_fields="$pc_fields uc_mcontext.uc_regs->gregs[[PT_NIP]]" # Linux (ppc)
 131 pc_fields="$pc_fields uc_mcontext.gregs[[R15]]"     # Linux (arm old [untested])
 132 pc_fields="$pc_fields uc_mcontext.arm_pc"           # Linux (arm new [untested])
 133 pc_fields="$pc_fields uc_mcontext.mc_eip"           # FreeBSD (i386)
 134 pc_fields="$pc_fields uc_mcontext.mc_rip"           # FreeBSD (x86_64 [untested])
 135 pc_fields="$pc_fields uc_mcontext->ss.eip"          # OS X (i386, <=10.4)
 136 pc_fields="$pc_fields uc_mcontext->__ss.__eip"      # OS X (i386, >=10.5)
 137 pc_fields="$pc_fields uc_mcontext->ss.rip"          # OS X (x86_64)
 138 pc_fields="$pc_fields uc_mcontext->__ss.__rip"      # OS X (>=10.5 [untested])
 139 pc_fields="$pc_fields uc_mcontext->ss.srr0"         # OS X (ppc, ppc64 [untested])
 140 pc_fields="$pc_fields uc_mcontext->__ss.__srr0"     # OS X (>=10.5 [untested])
 141 pc_field_found=false
 142 for pc_field in $pc_fields; do
 143   if ! $pc_field_found; then
 144     AC_TRY_COMPILE([#define _GNU_SOURCE 1
 145                     #include <ucontext.h>],
 146                    [ucontext_t u; return u.$pc_field == 0;],
 147                    AC_DEFINE_UNQUOTED(PC_FROM_UCONTEXT, $pc_field,
 148                                       How to access the PC from a struct ucontext)
 149                    AC_MSG_RESULT([$pc_field])
 150                  pc_field_found=true)
 151   fi
 152 done
 153 if ! $pc_field_found; then
 154   AC_MSG_WARN(Could not find the PC.  Will not output failed addresses...)
 155 fi
 156
 157 # These are what's needed by logging.h.in and raw_logging.h.in
 158 AC_SUBST(ac_google_start_namespace)
 159 AC_SUBST(ac_google_end_namespace)
 160 AC_SUBST(ac_google_namespace)
 161 AC_SUBST(ac_cv_cxx_using_operator)
 162 AC_SUBST(ac_cv___attribute___noreturn)
 163 AC_SUBST(ac_cv___attribute___printf_4_5)
 164 AC_SUBST(ac_cv_have___builtin_expect)
 165 AC_SUBST(ac_cv_have_stdint_h)
 166 AC_SUBST(ac_cv_have_systypes_h)
 167 AC_SUBST(ac_cv_have_inttypes_h)
 168 AC_SUBST(ac_cv_have_uint16_t)
 169 AC_SUBST(ac_cv_have_u_int16_t)
 170 AC_SUBST(ac_cv_have___uint16)
 171 AC_SUBST(ac_cv_have_libgflags)
 172 AC_SUBST(GFLAGS_LIBS)
 173
 174 # Write generated configuration file
 175 AC_CONFIG_FILES([Makefile src/glog/logging.h src/glog/raw_logging.h src/glog/vlog_is_on.h src/glog/stl_logging.h])
 176 AC_OUTPUT