configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [1])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [5])
   6 m4_define([folks_micro_version], [1])
   7 m4_define([folks_nano_version], [0])
   8
   9 # If library source has changed since last release, increment revision
  10 # If interfaces have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If interfaces have been added since last release, increment age
  13 # If interfaces have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [24])
  15 m4_define([folks_lt_revision], [0])
  16 m4_define([folks_lt_age], [0])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 # Automatically check the dependencies for the libsocialweb backend
  81 SW_CLIENT_REQUIRED=0.25.15
  82 AC_ARG_ENABLE(libsocialweb-backend,
  83         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
  84                        [build the Libsocialweb backend (default: auto)]),
  85         enable_libsocialweb_backend=$enableval,
  86         enable_libsocialweb_backend=auto )
  87
  88 if test "x$enable_libsocialweb_backend" != "xno"; then
  89   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
  90       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
  91   if test "x$have_libsocialweb_backend" = "xyes"; then
  92     VALA_CHECK_PACKAGES([telepathy-glib
  93                          dbus-glib-1
  94                          gio-2.0
  95                          gee-1.0
  96                          libsocialweb-client],
  97         ,
  98         have_libsocialweb_backend="no")
  99   fi
 100
 101   if test "x$have_libsocialweb_backend" = "xyes"; then
 102     AC_DEFINE(HAVE_TELEPATHY, [], [Define if you have libsocialweb_backend])
 103   fi
 104 else
 105    have_libsocialweb_backend=no
 106 fi
 107
 108 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 109   "x$have_libsocialweb_backend" != "xyes"; then
 110     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 111 fi
 112
 113 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 114         [test "x$have_libsocialweb_backend" = "xyes"])
 115
 116 # -----------------------------------------------------------
 117 # Dependencies
 118 # -----------------------------------------------------------
 119
 120 GLIB_REQUIRED=2.24.0
 121 TP_GLIB_REQUIRED=0.13.1
 122 VALA_REQUIRED=0.12.0
 123 VALADOC_REQUIRED=0.2.1
 124 TRACKER_SPARQL_REQUIRED=0.10
 125 GCONF2_REQUIRED=2.31
 126
 127 PKG_CHECK_MODULES([GLIB],
 128                   [glib-2.0 >= $GLIB_REQUIRED
 129                    gobject-2.0 >= $GLIB_REQUIRED])
 130 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 131 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 132 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 133 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 134
 135 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 136 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7])
 137 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 138
 139 if test x$enable_tracker_backend = xyes; then
 140         PKG_CHECK_MODULES([TRACKER_SPARQL],
 141                           [tracker-sparql-0.10 >= $TRACKER_SPARQL_REQUIRED])
 142 fi
 143
 144 #
 145 # Vala building options -- allows tarball builds without installing Vala
 146 #
 147 AC_ARG_ENABLE([vala],
 148               AS_HELP_STRING([--enable-vala],
 149                              [Enable building from the Vala sources]),
 150               [enable_vala=$enableval],
 151               [enable_vala=no])
 152
 153 # will be re-set as necessary below
 154 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 155 sd=${srcdir}/
 156
 157 # Force Vala for non-release builds
 158 m4_if(folks_released, [1], [],
 159     [
 160         enable_vala=yes
 161         echo "Vala compiler required for non-release builds; requiring Vala..."
 162     ])
 163
 164 # Force Vala if generated source is missing or outdated
 165 if test \
 166         ! -e ${sd}tools/folks_import_vala.stamp -o \
 167         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 168         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 169         ! -e ${sd}tests/folks/field_details_vala.stamp -o \
 170         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 171         ! -e ${sd}tests/lib/folks-test.vapi -o \
 172         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 173         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 174         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 175         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 176         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 177         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 178         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 179         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 180         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 181         ! -e ${sd}backends/key-file/libfolks_backend_key_file_la_vala.stamp -o \
 182         ! -e ${sd}backends/telepathy/libfolks_backend_telepathy_la_vala.stamp \
 183                 -o \
 184         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 185         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 186         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 187         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 188         ! -e ${sd}folks/folks.vapi -o \
 189         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 190         enable_vala=yes
 191         echo "Vala source needs to be re-compiled; requiring Vala..."
 192 fi
 193
 194 if test "x$enable_vala" = "xyes" ; then
 195         AM_PROG_VALAC([$VALA_REQUIRED])
 196         if test "x$VALAC" = "x"; then
 197               AC_MSG_ERROR([Vala requested but valac is not installed])
 198         fi
 199
 200         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 201         if test "x$VAPIGEN" = "x"; then
 202               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 203         fi
 204
 205         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 206         # automatically
 207         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 208         AC_SUBST([VALAFLAGS])
 209         AC_SUBST([VAPIGENFLAGS])
 210         AC_SUBST([VAPIDIR])
 211
 212         VALA_CHECK_PACKAGES([telepathy-glib
 213                              dbus-glib-1
 214                              gio-2.0
 215                              gee-1.0])
 216
 217         if test x$enable_tracker_backend = xyes; then
 218           VALA_CHECK_PACKAGES([tracker-sparql-0.10])
 219         fi
 220
 221 fi
 222
 223 # this will set HAVE_INTROSPECTION
 224 GOBJECT_INTROSPECTION_REQUIRE([0.9.12])
 225
 226 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 227
 228 # Various functions that we need (used in C code generated from Vala)
 229 AC_CHECK_FUNCS([memset])
 230 AC_CHECK_FUNCS([strstr])
 231
 232 # -----------------------------------------------------------
 233 # Backends
 234 # -----------------------------------------------------------
 235
 236 FOLKS_MODULE_VERSION=folks_module_version
 237 AC_SUBST([FOLKS_MODULE_VERSION])
 238 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 239
 240 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 241 AC_SUBST([BACKEND_DIR])
 242
 243 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/libfolks-backend-key-file.so'
 244 AC_SUBST([BACKEND_KF])
 245 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/libfolks-backend-telepathy.so'
 246 AC_SUBST([BACKEND_TP])
 247
 248 if test x$have_libsocialweb_backend = xyes; then
 249   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libfolks-backend-libsocialweb.so'
 250   AC_SUBST([BACKEND_LIBSOCIALWEB])
 251 fi
 252
 253 if test x$enable_tracker_backend = xyes; then
 254   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/libfolks-backend-tracker.so'
 255   AC_SUBST([BACKEND_TRACKER])
 256 fi
 257
 258 # All of the backend libraries in our tree; to be used by the tests
 259 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 260 if test x$have_libsocialweb_backend = xyes; then
 261   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 262   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 263 fi
 264 if test x$enable_tracker_backend = xyes; then
 265   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 266   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 267 fi
 268 AC_SUBST([BACKEND_UNINST_PATH])
 269
 270 # -----------------------------------------------------------
 271 # Tools
 272 # -----------------------------------------------------------
 273
 274 AC_ARG_ENABLE([import-tool],
 275               AS_HELP_STRING([--enable-import-tool],
 276                              [Enable building the meta-contact import tool]),
 277               [enable_import_tool=$enableval with_import_tool=$enableval],
 278               [enable_import_tool=maybe with_import_tool=no])
 279 AS_IF([test "$enable_import_tool" != "no"],
 280       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 281                          [with_import_tool=yes], [with_import_tool=no])])
 282 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 283       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 284 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 285
 286 # Readline's required for the folks-inspect program
 287 AC_ARG_ENABLE([inspect-tool],
 288               AS_HELP_STRING([--enable-inspect-tool],
 289                              [Enable building the data inspection tool]),
 290               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 291               [enable_inspect_tool=maybe with_inspect_tool=no])
 292 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 293       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 294                      using --enable-vala])])
 295 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 296       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 297                       --enable-vala])])
 298 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 299       [AC_CHECK_LIB([readline], [main],
 300                     [with_inspect_tool=yes], [with_inspect_tool=no],
 301                     [-lncurses])])
 302 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 303        "x$enable_vala" = "xyes"],
 304       [VALA_CHECK_PACKAGES([readline])
 305        LIBREADLINE="-lreadline -lncurses"
 306        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 307        AC_SUBST([LIBREADLINE])])
 308 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 309       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 310 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 311
 312 # -----------------------------------------------------------
 313 # Documentation
 314 # -----------------------------------------------------------
 315
 316 AC_ARG_ENABLE([docs],
 317               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 318               [enable_docs=$enableval], [enable_docs=no])
 319 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 320
 321 AS_IF([test "x$enable_docs" != xno],
 322       [PKG_CHECK_MODULES([VALADOC_PC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 323        AC_PATH_PROG([VALADOC], [valadoc], [:])
 324        AS_IF([test "$VALADOC" != :],
 325              have_valadoc=yes)])
 326 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 327
 328 # -----------------------------------------------------------
 329 # Gettext
 330 # -----------------------------------------------------------
 331
 332 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 333 AC_SUBST(GETTEXT_PACKAGE)
 334 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 335 IT_PROG_INTLTOOL([0.35.0])
 336
 337 # -----------------------------------------------------------
 338 # Error flags
 339 # -----------------------------------------------------------
 340
 341 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 342 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 343
 344 AC_ARG_ENABLE([debug],
 345               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 346               [enable_debug=$enableval], [enable_debug=yes])
 347
 348 AC_ARG_ENABLE([Werror],
 349               AS_HELP_STRING([--disable-Werror],
 350                              [compile without -Werror (normally enabled in
 351                               development builds)]),
 352               [werror=$enableval], [werror=yes])
 353
 354 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 355 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 356                  [wno_missing_field_initializers=yes],
 357                  [wno_missing_field_initializers=no])
 358 AS_COMPILER_FLAG([-Wno-unused-parameter],
 359                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 360
 361 m4_if(folks_released, [1], [],
 362     [
 363         if test x$werror = xyes; then
 364             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 365         fi
 366         if test x$wextra = xyes -a \
 367             x$wno_missing_field_initializers = xyes -a \
 368             x$wno_unused_parameter = xyes; then
 369             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 370                 -Wno-missing-field-initializers -Wno-unused-parameter"
 371         fi
 372     ])
 373
 374 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 375 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 376 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 377 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 378                                           -Wmissing-prototypes"])
 379 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 380                                             -Wmissing-declarations"])
 381 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 382                                          -Wstrict-prototypes"])
 383
 384 AC_SUBST([ERROR_CFLAGS])
 385
 386 # Vala-related flags
 387 AS_IF([test "x$enable_vala" = "xyes"],
 388       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 389                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 390        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 391
 392 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 393 AC_SUBST([ERROR_VALAFLAGS])
 394
 395 # -----------------------------------------------------------
 396 # Final output
 397 # -----------------------------------------------------------
 398
 399 AC_CONFIG_FILES([
 400     backends/telepathy/lib/folks-telepathy.pc
 401     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 402     backends/tracker/lib/folks-tracker.pc
 403     backends/tracker/lib/folks-tracker-uninstalled.pc
 404     folks/folks.pc
 405     folks/folks-uninstalled.pc
 406     Makefile
 407     backends/Makefile
 408     backends/key-file/Makefile
 409     backends/libsocialweb/Makefile
 410     backends/libsocialweb/lib/Makefile
 411     backends/libsocialweb/lib/folks-libsocialweb.pc
 412     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 413     backends/telepathy/Makefile
 414     backends/telepathy/lib/Makefile
 415     backends/tracker/Makefile
 416     backends/tracker/lib/Makefile
 417     folks/Makefile
 418     docs/Makefile
 419     po/Makefile.in
 420     tests/Makefile
 421     tests/data/Makefile
 422     tests/data/gconf.path
 423     tests/folks/Makefile
 424     tests/key-file/Makefile
 425     tests/libsocialweb/Makefile
 426     tests/telepathy/Makefile
 427     tests/tracker/Makefile
 428     tests/lib/Makefile
 429     tests/lib/folks-test-uninstalled.pc
 430     tests/lib/key-file/Makefile
 431     tests/lib/libsocialweb/Makefile
 432     tests/lib/libsocialweb/session.conf
 433     tests/lib/telepathy/Makefile
 434     tests/lib/tracker/Makefile
 435     tests/lib/telepathy/contactlist/Makefile
 436     tests/lib/telepathy/contactlist/session.conf
 437     tests/tools/Makefile
 438     tools/Makefile
 439     tools/inspect/Makefile
 440 ])
 441
 442 AC_OUTPUT
 443
 444 echo "
 445 Configure summary:
 446
 447         Vala........................:  ${enable_vala}
 448         Vala Compiler...............:  ${VALAC}
 449         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS}
 450         Prefix......................:  ${prefix}
 451         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 452         Documentation...............:  ${HAVE_VALADOC}
 453         Tests.......................:  ${have_tp_glib_for_tests}
 454         Import tool.................:  ${with_import_tool}
 455         Inspector tool..............:  ${with_inspect_tool}
 456         Tracker backend.............:  ${enable_tracker_backend}
 457         Libsocialweb backend........:  ${have_libsocialweb_backend}
 458
 459
 460 "