configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [2])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 AC_LIBTOOL_WIN32_DLL
  42 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  43 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  44 AC_PROG_LIBTOOL
  45
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  49 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  50 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  51 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  52 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  53 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  54 version_info="lt_cur:lt_rev:lt_age"
  55 release_info="v_rel"
  56 AC_SUBST(version_info)
  57 AC_SUBST(release_info)
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 VMAJ=v_maj
  61 AC_SUBST(VMAJ)
  62
  63
  64 ### Needed information
  65
  66 AC_CANONICAL_BUILD
  67 AC_CANONICAL_HOST
  68
  69 requirements_pc_eina=""
  70
  71 have_wince="no"
  72 have_win32="no"
  73 case "$host_os" in
  74    mingw32ce*)
  75       have_win32="yes"
  76       have_wince="yes"
  77       MODULE_ARCH="$host_os-$host_cpu"
  78       MODULE_EXT=".dll"
  79       ;;
  80    mingw*)
  81       have_win32="yes"
  82       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  83       MODULE_EXT=".dll"
  84       ;;
  85    *)
  86       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  87       MODULE_EXT=".so"
  88       ;;
  89 esac
  90 AM_CONDITIONAL([EINA_HAVE_WINCE], [test "x$have_wince" = "xyes"])
  91 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
  92 AC_SUBST([MODULE_ARCH])
  93 AC_DEFINE_UNQUOTED([MODULE_ARCH], ["${MODULE_ARCH}"], ["Module architecture"])
  94 AC_DEFINE_UNQUOTED([SHARED_LIB_SUFFIX], ["${MODULE_EXT}"], [Suffix for shared objects])
  95
  96 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  97 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  98 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  99 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
 100
 101 EFL_CHECK_THREADS
 102
 103 if ! test "x${efl_have_threads}" = "xno" ; then
 104    EINA_CONFIGURE_HAVE_THREADS="#define EINA_HAVE_THREADS"
 105 fi
 106 AC_SUBST(EINA_CONFIGURE_HAVE_THREADS)
 107 AM_CONDITIONAL([EINA_HAVE_THREADS], [! test "x${efl_have_threads}" = "xno"])
 108
 109 if test "x${efl_have_debug_threads}" = "xyes"; then
 110    EINA_CONFIGURE_HAVE_DEBUG_THREADS="#define EINA_HAVE_DEBUG_THREADS"
 111 fi
 112 AC_SUBST(EINA_CONFIGURE_HAVE_DEBUG_THREADS)
 113 AM_CONDITIONAL([EINA_DEBUG_THREADS], [test "x${efl_have_debug_threads}" = "xyes"])
 114
 115 if ! test "x${efl_have_on_off_threads}" = "xno"; then
 116    EINA_CONFIGURE_HAVE_ON_OFF_THREADS="#define EINA_HAVE_ON_OFF_THREADS"
 117 fi
 118 AC_SUBST(EINA_CONFIGURE_HAVE_ON_OFF_THREADS)
 119 AM_CONDITIONAL([EINA_ON_OFF_THREADS], [! test "x${efl_have_on_off_threads}" = "xno"])
 120
 121 ### Additional options to configure
 122
 123 # Magic debug
 124 AC_ARG_ENABLE([magic-debug],
 125    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 126    [
 127     if test "x${enableval}" = "xyes" ; then
 128        have_magic_debug="yes"
 129     else
 130        have_magic_debug="no"
 131     fi
 132    ],
 133    [have_magic_debug="yes"])
 134
 135 AC_MSG_CHECKING([whether magic debug is enable])
 136 AC_MSG_RESULT([${have_magic_debug}])
 137
 138 if test "x${have_magic_debug}" = "xyes" ; then
 139    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 140 fi
 141 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 142
 143 # Safety checks (avoid crashes on wrong api usage)
 144 AC_ARG_ENABLE(safety-checks,
 145    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 146    [
 147     if test "x${enableval}" = "xyes" ; then
 148        have_safety_checks="yes"
 149     else
 150        have_safety_checks="no"
 151     fi
 152    ],
 153    [have_safety_checks="yes"])
 154
 155 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 156 AC_MSG_RESULT($have_safety_checks)
 157
 158 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 159 if test "x$have_safety_checks" = "xyes"; then
 160   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 161   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 162 fi
 163 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 164
 165 with_max_log_level="<unset>"
 166 AC_ARG_WITH(internal-maximum-log-level,
 167    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 168                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 169    [
 170     if test "x${withval}" != "xno"; then
 171        if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
 172           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 173           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 174           with_max_log_level="${withval}"
 175        else
 176           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 177        fi
 178     fi
 179     ], [:])
 180
 181 AC_ARG_ENABLE([amalgamation],
 182    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 183    [if test "x${enableval}" = "xyes"; then
 184        do_amalgamation="yes"
 185     else
 186        do_amalgamation="no"
 187     fi
 188    ],
 189    [do_amalgamation="no"]
 190 )
 191 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 192
 193 # Choose best memory pool
 194 AC_ARG_ENABLE([default-mempool],
 195    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 196    [
 197     if test "x${enableval}" = "xyes"; then
 198        have_default_mempool="yes"
 199     else
 200        have_default_mempool="no"
 201     fi
 202    ],
 203    [have_default_mempool="no"]
 204 )
 205 AC_MSG_CHECKING([whether to use default mempool allocator])
 206 AC_MSG_RESULT([${have_default_mempool}])
 207
 208 if test "x${have_default_mempool}" = "xyes" ; then
 209    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 210 fi
 211 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 212
 213 # Report stringshare usage
 214 AC_ARG_ENABLE([stringshare-usage],
 215    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 216    [
 217     if test "x${enableval}" = "xyes"; then
 218        have_stringshare_usage="yes"
 219     else
 220        have_stringshare_usage="no"
 221     fi
 222    ],
 223    [have_stringshare_usage="no"]
 224 )
 225 AC_MSG_CHECKING([whether to report stringshare usage])
 226 AC_MSG_RESULT([${have_stringshare_usage}])
 227
 228 if test "x${have_stringshare_usage}" = "xyes"; then
 229    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 230 fi
 231
 232 # Check if we want to benchmark on real data
 233 enable_benchmark_e17="no"
 234 AC_ARG_ENABLE([e17],
 235    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 236    [
 237     if test "x${enableval}" = "xyes" ; then
 238        enable_benchmark_e17="yes"
 239     else
 240        enable_benchmark_e17="no"
 241     fi
 242    ],
 243    [enable_benchmark_e17="no"])
 244
 245 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 246 AC_MSG_RESULT([${enable_benchmark_e17}])
 247
 248 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 249
 250
 251 ### Checks for programs
 252 AC_PROG_CC
 253 #for src/tests...
 254 AC_PROG_CXX
 255
 256 # pkg-config
 257 PKG_PROG_PKG_CONFIG
 258
 259 # Check whether pkg-config supports Requires.private
 260 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 261    pkgconfig_requires_private="Requires.private"
 262 else
 263    pkgconfig_requires_private="Requires"
 264 fi
 265 AC_SUBST(pkgconfig_requires_private)
 266
 267 # doxygen program for documentation building
 268
 269 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 270
 271
 272 ### Checks for libraries
 273
 274 ## Compatibility layers
 275
 276 # Evil library for compilation on Windows
 277
 278 EFL_EINA_BUILD=""
 279 case "$host_os" in
 280    mingw*)
 281       PKG_CHECK_EXISTS([evil >= 1.1.0])
 282       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil package is installed])
 283       requirements_pc_eina="${requirements_pc_eina} evil"
 284       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 285    ;;
 286 esac
 287 AC_SUBST([EFL_EINA_BUILD])
 288
 289 # Escape library for compilation on Playstation 3
 290
 291 case "$host_vendor" in
 292   ps3*)
 293       PKG_CHECK_EXISTS([escape])
 294       AC_DEFINE([HAVE_ESCAPE], [1], [Set to 1 if Escape package is installed])
 295       requirements_pc_eina="${requirements_pc_eina} escape"
 296     ;;
 297 esac
 298
 299 # Exotic library for copilation on Coyote
 300
 301 PKG_CHECK_EXISTS([exotic],
 302    [
 303     enable_exotic="yes"
 304     AC_DEFINE([HAVE_EXOTIC_H], [1], [Define to 1 if you have Exotic.])
 305     EINA_CONFIGURE_HAVE_EXOTIC="#define EINA_HAVE_EXOTIC"
 306     requirements_pc_eina="exotic ${requirements_pc_eina}"
 307    ],
 308    [enable_exotic="no"])
 309
 310 AM_CONDITIONAL([EINA_HAVE_EXOTIC], [test "x${enable_exotic}" = "xyes"])
 311 AC_SUBST([EINA_CONFIGURE_HAVE_EXOTIC])
 312
 313 if ! test "x${requirements_pc_eina}" = "x" ; then
 314    PKG_CHECK_MODULES([EINA], [${requirements_pc_eina}])
 315 fi
 316
 317 ## Options
 318
 319 # Valgrind
 320
 321 AC_ARG_ENABLE([valgrind],
 322    [AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.])],
 323    [
 324     if test "x${enableval}" = "xyes" ; then
 325        want_valgrind="yes"
 326     else
 327        want_valgrind="no"
 328     fi
 329    ],
 330    [want_valgrind="auto"])
 331
 332 AC_MSG_CHECKING([whether to enable build with valgrind])
 333 AC_MSG_RESULT([${want_valgrind}])
 334
 335 if test "x${want_valgrind}" = "xyes" || test "x${want_valgrind}" = "xauto"; then
 336    PKG_CHECK_MODULES([VALGRIND], [valgrind >= 2.4.0],
 337       [
 338        have_valgrind="yes"
 339        requirements_pc_eina="valgrind ${requirements_pc_eina}"
 340       ],
 341       [
 342        have_valgrind="no"
 343        AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 344        if test "x${want_valgrind}" = "xyes"; then
 345           AC_MSG_ERROR([Valgrind >= 2.4.0 is required])
 346        fi
 347       ])
 348 else
 349     AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 350 fi
 351
 352 ## Modules
 353
 354 # Check ememoa memory pool library
 355
 356 AC_ARG_ENABLE([ememoa],
 357    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 358    [
 359     if test "x${enableval}" = "xyes" ; then
 360        enable_ememoa="yes"
 361     else
 362        enable_ememoa="no"
 363     fi
 364    ],
 365    [enable_ememoa="yes"])
 366
 367 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 368 AC_MSG_RESULT([${enable_ememoa}])
 369
 370 if test "x${enable_ememoa}" = "xyes" ; then
 371    PKG_CHECK_MODULES([EMEMOA],
 372       [ememoa >= 0.0.26 ],
 373       [enable_ememoa="yes"],
 374       [enable_ememoa="no"])
 375 fi
 376
 377 ## Examples
 378
 379 PKG_CHECK_MODULES([ECORE_EVAS],
 380    [ecore-evas ecore evas],
 381    [build_tiler_example="yes"],
 382    [build_tiler_example="no"])
 383
 384 AM_CONDITIONAL([BUILD_TILER_EXAMPLE], [test "x${build_tiler_example}" = "xyes"])
 385
 386 ### Checks for header files
 387 AC_HEADER_ASSERT
 388 AC_HEADER_TIME
 389 AC_HEADER_DIRENT
 390
 391 AC_CHECK_HEADERS([unistd.h libgen.h inttypes.h stdint.h sys/types.h siginfo.h strings.h sys/mman.h execinfo.h mcheck.h])
 392
 393 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 394    EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 395    AC_DEFINE([HAVE_INTTYPES_H], [1], [Define to 1 if you have the <inttypes.h> header file.])
 396 fi
 397 AC_SUBST([EINA_CONFIGURE_HAVE_INTTYPES_H])
 398
 399 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 400     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 401     AC_DEFINE([HAVE_STDINT_H], [1], [Define to 1 if you have the <stdint.h> header file.])
 402 fi
 403 AC_SUBST([EINA_CONFIGURE_HAVE_STDINT_H])
 404
 405 ### Checks for types
 406
 407 # wchar_t
 408
 409 AC_CHECK_SIZEOF([wchar_t])
 410 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 411 AC_SUBST([EINA_SIZEOF_WCHAR_T])
 412 AC_CHECK_TYPES([siginfo_t], [], [],
 413    [[
 414 #include <signal.h>
 415 #if HAVE_SIGINFO_H
 416 # include <siginfo.h>
 417 #endif
 418    ]])
 419
 420 # struct dirent
 421
 422 AC_CHECK_TYPES([struct dirent], [have_dirent="yes"], [have_dirent="no"],
 423    [[
 424 #include <dirent.h>
 425    ]])
 426
 427 if test "x${have_dirent}" = "xyes" ; then
 428     EINA_CONFIGURE_HAVE_DIRENT_H="#define EINA_HAVE_DIRENT_H"
 429     AC_DEFINE([HAVE_DIRENT_H], [1], [Define to 1 if you have a valid <dirent.h> header file.])
 430 fi
 431 AC_SUBST([EINA_CONFIGURE_HAVE_DIRENT_H])
 432
 433 ### Checks for structures
 434
 435 ### Checks for compiler characteristics
 436 AC_C_BIGENDIAN
 437 AC_C_INLINE
 438 AC_PROG_CC_STDC
 439 EFL_ATTRIBUTE_UNUSED
 440
 441 m4_ifdef([v_mic],
 442    [
 443     EFL_COMPILER_FLAG([-Wall])
 444     EFL_COMPILER_FLAG([-W])
 445    ])
 446
 447 EFL_COMPILER_FLAG([-Wshadow])
 448
 449 EFL_CHECK_PATH_MAX
 450
 451 ### Checks for linker characteristics
 452 lt_enable_auto_import=""
 453 case "${host_os}" in
 454    mingw*)
 455       lt_enable_auto_import="-Wl,--enable-auto-import"
 456    ;;
 457 esac
 458 AC_SUBST([lt_enable_auto_import])
 459
 460 EFL_LINKER_FLAG([-fno-strict-aliasing])
 461
 462 ### Checks for library functions
 463 AC_FUNC_ALLOCA
 464
 465 AC_CHECK_FUNCS([strlcpy openat fstatat fpathconf execvp backtrace backtrace_symbols malloc_usable_size mtrace])
 466
 467 EFL_CHECK_FUNCS([eina], [dirfd dlopen dladdr fnmatch iconv shm_open setxattr])
 468
 469 want_debug_malloc="no"
 470 AC_ARG_ENABLE([debug-malloc],
 471    [AC_HELP_STRING([--enable-debug-malloc], [enable debugging of malloc usage overhead in our allocator @<:@default=enabled@:>@])],
 472    [
 473      if test "x${enableval}" = "xyes" ; then
 474         want_debug_malloc="yes"
 475      else
 476         want_debug_malloc="no"
 477      fi
 478    ], [want_debug_malloc="no"])
 479
 480 if test "x${ac_cv_func_malloc_usable_size}" = "xyes" && test "x${want_debug_malloc}" = "xyes"; then
 481    AC_DEFINE([EINA_DEBUG_MALLOC], [1], [Turn on debugging overhead in mempool])
 482 fi
 483
 484 AC_ARG_ENABLE([log],
 485    [AC_HELP_STRING([--disable-log], [disable Eina_Log infrastructure completly @<:@default=enabled@:>@])],
 486    [
 487     if test "x${enableval}" = "xyes" ; then
 488        want_log="yes"
 489     else
 490        want_log="no"
 491     fi
 492    ],
 493    [want_log="yes"])
 494
 495 enable_log="no"
 496 if test "x${efl_func_fnmatch}" = "xyes" && test "x${want_log}" = "xyes" ; then
 497    enable_log="yes"
 498 fi
 499
 500 AC_MSG_CHECKING([wether to build Eina_Log infrastructure])
 501 AC_MSG_RESULT([${enable_log}])
 502
 503 if test "x${enable_log}" = "xyes"; then
 504     EINA_CONFIGURE_ENABLE_LOG="#define EINA_ENABLE_LOG"
 505     AC_DEFINE([HAVE_LOG], [1], [Define to 1 if we log support is on])
 506 fi
 507 AC_SUBST([EINA_CONFIGURE_ENABLE_LOG])
 508
 509
 510 ### Modules
 511
 512 if test "x${have_default_mempool}" = "xyes" ; then
 513    enable_chained_pool="no"
 514    enable_pass_through="static"
 515 else
 516    enable_chained_pool="static"
 517    enable_pass_through="no"
 518 fi
 519
 520 enable_one_big="static"
 521
 522 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 523 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 524 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 525 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 526 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 527 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 528 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 529
 530 ### Make the debug preprocessor configurable
 531
 532 ### Unit tests, coverage and benchmarking
 533
 534 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 535
 536 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 537 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 538 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 539 if test "x$enable_coverage" = "xyes" ; then
 540    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 541 fi
 542
 543 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 544 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 545 if test -n "$CXX" && test "x$enable_benchmark" = "xyes" ; then
 546    AC_DEFINE_UNQUOTED([CITYHASH_BENCH], [1], [enable bench tests for google hash method])
 547 fi
 548 AM_CONDITIONAL([CITYHASH_BENCH], [test -n "$CXX" && test "x$enable_benchmark" = "xyes"])
 549
 550 AC_SUBST([requirements_pc_eina])
 551 AC_SUBST([requirements_libs_eina])
 552
 553 ### Build and install examples
 554 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 555 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 556
 557 AC_CONFIG_FILES([
 558 Makefile
 559 eina.pc
 560 eina.spec
 561 doc/Makefile
 562 doc/Doxyfile
 563 src/Makefile
 564 src/include/Makefile
 565 src/include/eina_config.h
 566 src/lib/Makefile
 567 src/modules/Makefile
 568 src/modules/mp/Makefile
 569 src/modules/mp/chained_pool/Makefile
 570 src/modules/mp/ememoa_fixed/Makefile
 571 src/modules/mp/ememoa_unknown/Makefile
 572 src/modules/mp/pass_through/Makefile
 573 src/modules/mp/fixed_bitmap/Makefile
 574 src/modules/mp/buddy/Makefile
 575 src/modules/mp/one_big/Makefile
 576 src/tests/Makefile
 577 src/examples/Makefile
 578 ])
 579
 580 AC_OUTPUT
 581
 582 #####################################################################
 583 ## Info
 584
 585 echo
 586 echo
 587 echo
 588 echo "------------------------------------------------------------------------"
 589 echo "$PACKAGE $VERSION"
 590 echo "------------------------------------------------------------------------"
 591 echo
 592 echo
 593 echo "Configuration Options Summary:"
 594 echo
 595 echo "  Magic debug..........: ${have_magic_debug}"
 596 echo "  Safety checks........: ${have_safety_checks}"
 597 echo "  Maximum log level....: ${with_max_log_level}"
 598 echo "  Report string usage..: ${have_stringshare_usage}"
 599 echo "  Valgrind support.....: ${have_valgrind}"
 600 echo "  Default mempool......: ${have_default_mempool}"
 601 echo "  Log support..........: ${enable_log}"
 602 echo "  Thread Support.......: ${efl_have_threads}"
 603 if test "${efl_have_threads}" = "POSIX" ; then
 604 echo "    spinlock...........: ${efl_have_posix_threads_spinlock}"
 605 echo "    debug usage........: ${efl_have_debug_threads}"
 606 echo "    on/off support.....: ${efl_have_on_off_threads}"
 607 fi
 608 echo "  Amalgamation.........: ${do_amalgamation}"
 609 echo "  Iconv support........: ${efl_func_iconv}"
 610 echo "  File dirfd...........: ${efl_func_dirfd}"
 611 echo "  File xattr...........: ${efl_func_setxattr}"
 612 echo "  shm_open.............: ${efl_func_shm_open}"
 613 echo
 614 echo "  Documentation........: ${build_doc}"
 615 echo "  Tests................: ${enable_tests}"
 616 echo "  Coverage.............: ${enable_coverage}"
 617 echo "  Examples.............: ${enable_build_examples}"
 618 echo "  Tiler Example........: ${build_tiler_example}"
 619 echo "  Examples installed...: ${enable_install_examples}"
 620 echo "  Benchmark............: ${enable_benchmark}"
 621 if test "x${enable_benchmark}" = "xyes" ; then
 622 echo "    Glib...............: ${enable_benchmark_glib}"
 623 echo "    E17 real data......: ${enable_benchmark_e17}"
 624 fi
 625 echo
 626 echo "  CPU Specific Extensions:"
 627 echo "    MMX................: ${have_mmx}"
 628 echo "    SSE................: ${have_sse}"
 629 echo "    SSE2...............: ${have_sse2}"
 630 echo "    ALTIVEC............: ${have_altivec}"
 631 echo
 632 echo "  Memory pools:"
 633 echo "    Buddy..............: ${enable_buddy}"
 634 echo "    Chained pool.......: ${enable_chained_pool}"
 635 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 636 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 637 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 638 echo "    One big............: ${enable_one_big}"
 639 echo "    Pass through.......: ${enable_pass_through}"
 640 echo
 641 echo "Compilation............: make (or gmake)"
 642 echo "  CPPFLAGS.............: $CPPFLAGS"
 643 echo "  CFLAGS...............: $CFLAGS"
 644 echo "  LDFLAGS..............: $LDFLAGS"
 645 echo
 646 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 647 echo "  prefix...............: $prefix"
 648 echo
 649 EFL_FORM_VOLTRON