configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([eet], [1.2.2], [enlightenment-devel@lists.sourceforge.net])
   5 AC_PREREQ([2.52])
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_CANONICAL_BUILD
   9 AC_CANONICAL_HOST
  10 AC_ISC_POSIX
  11
  12 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  13 AM_CONFIG_HEADER([config.h])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 AC_LIBTOOL_WIN32_DLL
  17 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  18 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  19 AC_PROG_LIBTOOL
  20
  21 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  22 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  23 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  24 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  25 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  26 #release="ver-pre-svn-00"
  27 #release_info="-release $release"
  28 release_info=""
  29 AC_SUBST(version_info)
  30 AC_SUBST(release_info)
  31
  32 ### Default options with respect to host
  33
  34 case "$host_os" in
  35    mingw* | cegcc*)
  36       want_gnutls="no"
  37       want_openssl="no"
  38       want_cipher="no"
  39       want_signature="no"
  40       ;;
  41    *)
  42       want_gnutls="auto"
  43       want_openssl="auto"
  44       want_cipher="yes"
  45       want_signature="yes"
  46       ;;
  47 esac
  48
  49 requirement_eet=""
  50
  51
  52 ### Additional options to configure
  53
  54 AC_ARG_ENABLE([amalgamation],
  55    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  56    [if test "x${enableval}" = "xyes"; then
  57        do_amalgamation="yes"
  58     else
  59        do_amalgamation="no"
  60     fi
  61    ],
  62    [do_amalgamation="no"]
  63 )
  64 AM_CONDITIONAL(EET_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
  65
  66 # Old eet file format support
  67
  68 old_eet_file_format="yes"
  69 AC_ARG_ENABLE(old-eet-file-format,
  70    [AC_HELP_STRING(
  71       [--disable-old-eet-file-format],
  72       [disable old eet file format support. [[default=enabled]]]
  73     )],
  74    [old_eet_file_format=$enableval]
  75 )
  76 AC_MSG_CHECKING([whether to support old eet file format])
  77 AC_MSG_RESULT([${old_eet_file_format}])
  78
  79 if test "x${old_eet_file_format}" = "xyes" ; then
  80    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
  81 else
  82    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
  83 fi
  84
  85 # Gnutls support
  86
  87 AC_ARG_ENABLE([gnutls],
  88    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support])],
  89    [want_gnutls=$enableval]
  90 )
  91 AC_MSG_CHECKING([whether to use Gnutls])
  92 AC_MSG_RESULT([${want_gnutls}])
  93
  94 # Specific GNUTLS improvement
  95
  96 new_gnutls_api="no"
  97 AC_ARG_ENABLE(new-gnutls-api,
  98    [AC_HELP_STRING(
  99       [--enable-new-gnutls-api],
 100       [enable use of gnutls_x509_crt_verify_hash. [[default=disable]]]
 101     )],
 102    [new_gnutls_api=$enableval]
 103 )
 104 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 105 AC_MSG_RESULT([${new_gnutls_api}])
 106
 107 if test "x${new_gnutls_api}" = "xyes" ; then
 108    AC_DEFINE(EET_USE_NEW_GNUTLS_API, 1, [use gnutls_x509_crt_verify_hash])
 109 else
 110    AC_DEFINE(EET_USE_NEW_GNUTLS_API, 0, [don't use gnutls_x509_crt_verify_hash])
 111 fi
 112
 113 # Openssl support
 114
 115 AC_ARG_ENABLE([openssl],
 116    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support])],
 117    [want_openssl=$enableval]
 118 )
 119 AC_MSG_CHECKING([whether to use OpenSSL])
 120 AC_MSG_RESULT([${want_openssl}])
 121
 122 # Cryptography support
 123
 124 AC_ARG_ENABLE([cipher],
 125    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API])],
 126    [want_cipher=$enableval]
 127 )
 128 AC_MSG_CHECKING([whether to use cipher])
 129 AC_MSG_RESULT([${want_cipher}])
 130
 131 AC_ARG_ENABLE([signature],
 132    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet])],
 133    [want_signature=$enableval]
 134 )
 135 AC_MSG_CHECKING([whether to use signature])
 136 AC_MSG_RESULT([${want_signature}])
 137
 138 # Assert or fail.
 139 prefer_assert="no"
 140 AC_ARG_ENABLE([assert],
 141    [AC_HELP_STRING([--enable-assert], [enable assert, [[default=disabled]]])],
 142    [prefer_assert=$enableval]
 143 )
 144
 145 # Unit tests, coverage and benchmarking
 146
 147 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 148 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 149
 150 if test "x${prefer_assert}" = "xno"; then
 151    DEBUG_CFLAGS="-DNDEBUG"
 152 else
 153 # use debug symbols and set DEBUG if coverage support is enabled
 154    DEBUG_CFLAGS="${EFL_DEBUG_CFLAGS}"
 155 fi
 156 AC_SUBST(DEBUG_CFLAGS)
 157
 158
 159 ### Checks for programs
 160 AC_PROG_CC
 161
 162 # pkg-config
 163 PKG_PROG_PKG_CONFIG
 164
 165 # Check whether pkg-config supports Requires.private
 166 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 167    pkgconfig_requires_private="Requires.private"
 168 else
 169    pkgconfig_requires_private="Requires"
 170 fi
 171 AC_SUBST(pkgconfig_requires_private)
 172
 173
 174 # doxygen program for documentation building
 175
 176 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 177
 178
 179 ### Checks for libraries
 180
 181 # Evil library for compilation on Windows
 182
 183 EFL_EET_BUILD=""
 184 case "$host_os" in
 185    mingw* | cegcc*)
 186       PKG_CHECK_MODULES([EVIL], [evil])
 187       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 188       requirement_eet="evil ${requirement_eet}"
 189       EFL_EET_BUILD="-DEFL_EET_BUILD"
 190    ;;
 191 esac
 192 AC_SUBST(EFL_EET_BUILD)
 193
 194 EET_LIBS=""
 195 case "$host_os" in
 196    mingw32ce*)
 197       EET_LIBS="-lws2"
 198       ;;
 199    cegcc*)
 200       EET_LIBS="-lws2"
 201       ;;
 202    mingw*)
 203       EET_LIBS="-lws2_32"
 204       ;;
 205 esac
 206 AC_SUBST(EET_LIBS)
 207
 208 # Eina library
 209
 210 PKG_CHECK_MODULES(EINA, [eina-0])
 211 requirement_eet="eina-0 ${requirement_eet}"
 212
 213 # Gnutls library
 214 have_gnutls="no"
 215 if test "x${want_gnutls}" = "xyes" -o "x${want_gnutls}" = "xauto" ; then
 216    PKG_CHECK_MODULES(GNUTLS, [gnutls >= 1.7.6],
 217       [
 218        have_gnutls="yes"
 219        want_openssl="no"
 220        AC_DEFINE(HAVE_GNUTLS, 1, [Have Gnutls support])
 221        requirement_eet="gnutls ${requirement_eet}"
 222       ],
 223       [
 224        have_gnutls="no"
 225       ])
 226 fi
 227
 228 # Openssl library
 229 have_openssl="no"
 230 if test "x${want_openssl}" = "xyes" -o "x${want_openssl}" = "xauto" ; then
 231    PKG_CHECK_MODULES(OPENSSL, openssl,
 232       [
 233        have_openssl="yes"
 234        AC_DEFINE(HAVE_OPENSSL, 1, [Have Openssl support])
 235        requirement_eet="openssl ${requirement_eet}"
 236       ],
 237       [have_openssl="no"])
 238 fi
 239
 240 have_cipher="no"
 241 if test "x${have_gnutls}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 242    have_cipher="yes"
 243    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 244 elif test "x${have_openssl}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 245    have_cipher="yes"
 246    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 247 fi
 248
 249 AC_MSG_CHECKING(whether to activate cipher support in eet)
 250 AC_MSG_RESULT(${have_cipher})
 251
 252 have_signature="no"
 253 if test "x${have_gnutls}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 254    have_signature="yes"
 255    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 256 elif test "x${have_openssl}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 257    have_signature="yes"
 258    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 259 fi
 260
 261 AC_MSG_CHECKING(whether to activate signature support in eet)
 262 AC_MSG_RESULT(${have_signature})
 263
 264
 265 ### Checks for header files
 266
 267 AC_CHECK_HEADER([zlib.h],
 268    [dummy="yes"],
 269    [AC_MSG_ERROR("Cannot find zlib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 270
 271 AC_CHECK_HEADER([jpeglib.h],
 272    [dummy="yes"],
 273    [AC_MSG_ERROR("Cannot find jpeglib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 274
 275 AC_CHECK_HEADERS(netinet/in.h)
 276
 277 AC_CHECK_HEADER([fnmatch.h],
 278    [dummy="yes"],
 279    [AC_MSG_ERROR([Cannot find fnmatch.h. Make sure your CFLAGS environment variable contains include lines for the location of this file. MinGW users: see the INSTALL file])])
 280
 281
 282 ### Checks for types
 283
 284
 285 ### Checks for structures
 286
 287
 288 ### Checks for compiler characteristics
 289 AM_PROG_CC_C_O
 290 AC_C_CONST
 291 AC_C_INLINE
 292 AC_PROG_CC_STDC
 293 AC_C___ATTRIBUTE__
 294
 295 # Check whether the null pointer is zero on this arch
 296 AC_TRY_RUN(
 297    [
 298 #include <stdlib.h>
 299 int main (int argc, char **argv) {
 300   void *foo = NULL;
 301   int bar = (int)foo;
 302   return (int)foo;
 303 }
 304    ],
 305    [have_null="yes"],
 306    [have_null="no"],
 307    [
 308     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 309     have_null="yes"
 310    ])
 311 AC_MSG_CHECKING([value of the null pointer])
 312 AC_MSG_RESULT([${have_null}])
 313
 314 if test ! "x${have_null}" = "xyes" ; then
 315    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 316 fi
 317
 318 # These are needed for fmemopen/open_memstream
 319 AC_DEFINE(_GNU_SOURCE, , [Enable GNU extensions])
 320
 321 EET_CPPFLAGS=""
 322 EET_CFLAGS=""
 323 case "$host_os" in
 324    mingw32ce*)
 325       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 326       ;;
 327    cegcc*)
 328       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 329       EET_CFLAGS="-mwin32"
 330       ;;
 331 esac
 332 AC_SUBST(EET_CPPFLAGS)
 333 AC_SUBST(EET_CFLAGS)
 334
 335
 336 ### Checks for linker characteristics
 337
 338 # use --enable-auto-import on Windows
 339
 340 lt_enable_auto_import=""
 341 case "$host_os" in
 342    mingw* | cegcc*)
 343       lt_enable_auto_import="-Wl,--enable-auto-import"
 344       ;;
 345 esac
 346 AC_SUBST(lt_enable_auto_import)
 347
 348 # use --as-needed if supported
 349
 350 LDFLAGS_SAVE=${LDFLAGS}
 351 LDFLAGS="${LDFLAGS} -Wl,--as-needed"
 352
 353 AC_LINK_IFELSE(
 354    [AC_LANG_PROGRAM([[]], [])],
 355    [ld_as_needed="-Wl,--as-needed"],
 356    [ld_as_needed=""]
 357 )
 358
 359 LDFLAGS=${LDFLAGS_SAVE}
 360 AC_SUBST(ld_as_needed)
 361
 362
 363 ### Checks for library functions
 364 AC_FUNC_ALLOCA
 365
 366 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 367
 368 fnmatch_libs=""
 369 AC_CHECK_FUNCS([fnmatch], [res="yes"], [res="no"])
 370 if test "x$res" = "xno"; then
 371    AC_SEARCH_LIBS([fnmatch],
 372       [fnmatch evil iberty],
 373       [res="yes"],
 374       [res="no"])
 375    if test "x$res" = "xno"; then
 376       AC_MSG_ERROR([Cannot find fnmatch() in neither libc nor libfnmatch, nor libiberty, nor libevil])
 377    fi
 378    fnmatch_libs="${ac_cv_search_fnmatch}"
 379 fi
 380 AC_SUBST(fnmatch_libs)
 381
 382
 383 AC_SUBST(requirement_eet)
 384
 385 AC_OUTPUT([
 386 Makefile
 387 eet.pc
 388 doc/Makefile
 389 doc/eet.dox
 390 src/Makefile
 391 src/lib/Makefile
 392 src/bin/Makefile
 393 src/tests/Makefile
 394 README
 395 eet.spec
 396 ])
 397
 398
 399 #####################################################################
 400 ## Info
 401
 402 echo
 403 echo
 404 echo
 405 echo "------------------------------------------------------------------------"
 406 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 407 echo "------------------------------------------------------------------------"
 408 echo
 409 echo "Configuration Options Summary:"
 410 echo
 411 echo "  Gnutls...............: ${have_gnutls}"
 412 echo "  Openssl..............: ${have_openssl}"
 413 echo "    Cipher support.....: ${have_cipher}"
 414 echo "    Signature..........: ${have_signature}"
 415 echo
 416 echo "  Amalgamation.........: ${do_amalgamation}"
 417 echo "  Documentation........: ${build_doc}"
 418 echo "  Tests................: ${enable_tests}"
 419 echo "  Coverage.............: ${enable_coverage}"
 420 echo
 421 echo "  Old eet file format..: ${old_eet_file_format}"
 422 echo
 423 echo "  Compilation..........: make"
 424 echo
 425 echo "  Installation.........: make install"
 426 echo
 427 echo "    prefix.............: $prefix"
 428 echo