configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.2
  24 GLPROTO_REQUIRED=1.4.11
  25
  26 dnl Check for progs
  27 AC_PROG_CPP
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_CHECK_PROGS([MAKE], [gmake make])
  31 AC_PATH_PROG([MKDEP], [makedepend])
  32 AC_PATH_PROG([SED], [sed])
  33
  34 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  35 dnl configuration in that case.
  36 AC_PROG_INSTALL
  37 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  38
  39 dnl We need a POSIX shell for parts of the build. Assume we have one
  40 dnl in most cases.
  41 case "$host_os" in
  42 solaris*)
  43     # Solaris /bin/sh is too old/non-POSIX compliant
  44     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  45     SHELL="$POSIX_SHELL"
  46     ;;
  47 esac
  48
  49 MKDEP_OPTIONS=-fdepend
  50 dnl Ask gcc where it's keeping its secret headers
  51 if test "x$GCC" = xyes; then
  52     for dir in include include-fixed; do
  53         GCC_INCLUDES=`$CC -print-file-name=$dir`
  54         if test "x$GCC_INCLUDES" != x && \
  55            test "$GCC_INCLUDES" != "$dir" && \
  56            test -d "$GCC_INCLUDES"; then
  57             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  58         fi
  59     done
  60 fi
  61 AC_SUBST([MKDEP_OPTIONS])
  62
  63 dnl Make sure the pkg-config macros are defined
  64 m4_ifndef([PKG_PROG_PKG_CONFIG],
  65     [m4_fatal([Could not locate the pkg-config autoconf macros.
  66   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  67   are in a different location, try setting the environment variable
  68   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  69 PKG_PROG_PKG_CONFIG()
  70
  71 dnl LIB_DIR - library basename
  72 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  73 AC_SUBST([LIB_DIR])
  74
  75 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  76 _SAVE_LDFLAGS="$LDFLAGS"
  77 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  78 AC_SUBST([EXTRA_LIB_PATH])
  79
  80 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  81 _SAVE_CPPFLAGS="$CPPFLAGS"
  82 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  83 AC_SUBST([X11_INCLUDES])
  84
  85 dnl Compiler macros
  86 DEFINES=""
  87 AC_SUBST([DEFINES])
  88 case "$host_os" in
  89 linux*|*-gnu*|gnu*)
  90     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  91     ;;
  92 solaris*)
  93     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  94     ;;
  95 esac
  96
  97 dnl Add flags for gcc and g++
  98 if test "x$GCC" = xyes; then
  99     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 100
 101     # Enable -fvisibility=hidden if using a gcc that supports it
 102     save_CFLAGS="$CFLAGS"
 103     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 104     CFLAGS="$CFLAGS -fvisibility=hidden"
 105     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 106                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CFLAGS="$CFLAGS -fno-strict-aliasing"
 110 fi
 111 if test "x$GXX" = xyes; then
 112     CXXFLAGS="$CXXFLAGS -Wall"
 113
 114     # Work around aliasing bugs - developers should comment this out
 115     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 116 fi
 117
 118 dnl These should be unnecessary, but let the user set them if they want
 119 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 120     Default is to use CFLAGS.])
 121 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 122     compiler. Default is to use CFLAGS.])
 123 AC_SUBST([OPT_FLAGS])
 124 AC_SUBST([ARCH_FLAGS])
 125
 126 dnl
 127 dnl Hacks to enable 32 or 64 bit build
 128 dnl
 129 AC_ARG_ENABLE([32-bit],
 130     [AS_HELP_STRING([--enable-32-bit],
 131         [build 32-bit libraries @<:@default=auto@:>@])],
 132     [enable_32bit="$enableval"],
 133     [enable_32bit=auto]
 134 )
 135 if test "x$enable_32bit" = xyes; then
 136     if test "x$GCC" = xyes; then
 137         CFLAGS="$CFLAGS -m32"
 138         ARCH_FLAGS="$ARCH_FLAGS -m32"
 139     fi
 140     if test "x$GXX" = xyes; then
 141         CXXFLAGS="$CXXFLAGS -m32"
 142     fi
 143 fi
 144 AC_ARG_ENABLE([64-bit],
 145     [AS_HELP_STRING([--enable-64-bit],
 146         [build 64-bit libraries @<:@default=auto@:>@])],
 147     [enable_64bit="$enableval"],
 148     [enable_64bit=auto]
 149 )
 150 if test "x$enable_64bit" = xyes; then
 151     if test "x$GCC" = xyes; then
 152         CFLAGS="$CFLAGS -m64"
 153     fi
 154     if test "x$GXX" = xyes; then
 155         CXXFLAGS="$CXXFLAGS -m64"
 156     fi
 157 fi
 158
 159 dnl
 160 dnl shared/static libraries, mimic libtool options
 161 dnl
 162 AC_ARG_ENABLE([static],
 163     [AS_HELP_STRING([--enable-static],
 164         [build static libraries @<:@default=disabled@:>@])],
 165     [enable_static="$enableval"],
 166     [enable_static=no]
 167 )
 168 case "x$enable_static" in
 169 xyes|xno ) ;;
 170 x ) enable_static=no ;;
 171 * )
 172     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 173     ;;
 174 esac
 175 AC_ARG_ENABLE([shared],
 176     [AS_HELP_STRING([--disable-shared],
 177         [build shared libraries @<:@default=enabled@:>@])],
 178     [enable_shared="$enableval"],
 179     [enable_shared=yes]
 180 )
 181 case "x$enable_shared" in
 182 xyes|xno ) ;;
 183 x ) enable_shared=yes ;;
 184 * )
 185     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 186     ;;
 187 esac
 188
 189 dnl Can't have static and shared libraries, default to static if user
 190 dnl explicitly requested. If both disabled, set to static since shared
 191 dnl was explicitly requirested.
 192 case "x$enable_static$enable_shared" in
 193 xyesyes )
 194     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 195     enable_shared=no
 196     ;;
 197 xnono )
 198     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 199     enable_static=yes
 200     ;;
 201 esac
 202
 203 dnl
 204 dnl mklib options
 205 dnl
 206 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 207 if test "$enable_static" = yes; then
 208     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 209 fi
 210 AC_SUBST([MKLIB_OPTIONS])
 211
 212 dnl
 213 dnl other compiler options
 214 dnl
 215 AC_ARG_ENABLE([debug],
 216     [AS_HELP_STRING([--enable-debug],
 217         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 218     [enable_debug="$enableval"],
 219     [enable_debug=no]
 220 )
 221 if test "x$enable_debug" = xyes; then
 222     DEFINES="$DEFINES -DDEBUG"
 223     if test "x$GCC" = xyes; then
 224         CFLAGS="$CFLAGS -g"
 225     fi
 226     if test "x$GXX" = xyes; then
 227         CXXFLAGS="$CXXFLAGS -g"
 228     fi
 229 fi
 230
 231 dnl
 232 dnl library names
 233 dnl
 234 if test "$enable_static" = yes; then
 235     LIB_EXTENSION='a'
 236 else
 237     case "$host_os" in
 238     darwin* )
 239         LIB_EXTENSION='dylib' ;;
 240     cygwin* )
 241         LIB_EXTENSION='dll' ;;
 242     aix* )
 243         LIB_EXTENSION='a' ;;
 244     * )
 245         LIB_EXTENSION='so' ;;
 246     esac
 247 fi
 248
 249 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 250 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 251 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 252 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 253 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 254 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 255
 256 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 257 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 258 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 259 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 260 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 261 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 262
 263 AC_SUBST([GL_LIB_NAME])
 264 AC_SUBST([GLU_LIB_NAME])
 265 AC_SUBST([GLUT_LIB_NAME])
 266 AC_SUBST([GLW_LIB_NAME])
 267 AC_SUBST([OSMESA_LIB_NAME])
 268 AC_SUBST([EGL_LIB_NAME])
 269
 270 AC_SUBST([GL_LIB_GLOB])
 271 AC_SUBST([GLU_LIB_GLOB])
 272 AC_SUBST([GLUT_LIB_GLOB])
 273 AC_SUBST([GLW_LIB_GLOB])
 274 AC_SUBST([OSMESA_LIB_GLOB])
 275 AC_SUBST([EGL_LIB_GLOB])
 276
 277 dnl
 278 dnl Arch/platform-specific settings
 279 dnl
 280 AC_ARG_ENABLE([asm],
 281     [AS_HELP_STRING([--disable-asm],
 282         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 283     [enable_asm="$enableval"],
 284     [enable_asm=yes]
 285 )
 286 asm_arch=""
 287 ASM_FLAGS=""
 288 MESA_ASM_SOURCES=""
 289 GLAPI_ASM_SOURCES=""
 290 AC_MSG_CHECKING([whether to enable assembly])
 291 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 292 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 293 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 294     case "$host_cpu" in
 295     i?86 | x86_64)
 296         enable_asm=no
 297         AC_MSG_RESULT([no, cross compiling])
 298         ;;
 299     esac
 300 fi
 301 # check for supported arches
 302 if test "x$enable_asm" = xyes; then
 303     case "$host_cpu" in
 304     i?86)
 305         case "$host_os" in
 306         linux* | *freebsd* | dragonfly*)
 307             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 308             ;;
 309         esac
 310         ;;
 311     x86_64)
 312         case "$host_os" in
 313         linux* | *freebsd* | dragonfly*)
 314             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 315             ;;
 316         esac
 317         ;;
 318     powerpc)
 319         case "$host_os" in
 320         linux*)
 321             asm_arch=ppc
 322             ;;
 323         esac
 324         ;;
 325     sparc*)
 326         case "$host_os" in
 327         linux*)
 328             asm_arch=sparc
 329             ;;
 330         esac
 331         ;;
 332     esac
 333
 334     case "$asm_arch" in
 335     x86)
 336         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 337         MESA_ASM_SOURCES='$(X86_SOURCES)'
 338         GLAPI_ASM_SOURCES='$(X86_API)'
 339         AC_MSG_RESULT([yes, x86])
 340         ;;
 341     x86_64)
 342         ASM_FLAGS="-DUSE_X86_64_ASM"
 343         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 344         GLAPI_ASM_SOURCES='$(X86-64_API)'
 345         AC_MSG_RESULT([yes, x86_64])
 346         ;;
 347     ppc)
 348         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 349         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 350         AC_MSG_RESULT([yes, ppc])
 351         ;;
 352     sparc)
 353         ASM_FLAGS="-DUSE_SPARC_ASM"
 354         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 355         GLAPI_ASM_SOURCES='$(SPARC_API)'
 356         AC_MSG_RESULT([yes, sparc])
 357         ;;
 358     *)
 359         AC_MSG_RESULT([no, platform not supported])
 360         ;;
 361     esac
 362 fi
 363 AC_SUBST([ASM_FLAGS])
 364 AC_SUBST([MESA_ASM_SOURCES])
 365 AC_SUBST([GLAPI_ASM_SOURCES])
 366
 367 dnl PIC code macro
 368 MESA_PIC_FLAGS
 369
 370 dnl Check to see if dlopen is in default libraries (like Solaris, which
 371 dnl has it in libc), or if libdl is needed to get it.
 372 AC_CHECK_FUNC([dlopen], [],
 373     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 374
 375 dnl See if posix_memalign is available
 376 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 377
 378 dnl SELinux awareness.
 379 AC_ARG_ENABLE([selinux],
 380     [AS_HELP_STRING([--enable-selinux],
 381         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 382     [MESA_SELINUX="$enableval"],
 383     [MESA_SELINUX=no])
 384 if test "x$enable_selinux" = "xyes"; then
 385     AC_CHECK_HEADER([selinux/selinux.h],[],
 386                     [AC_MSG_ERROR([SELinux headers not found])])
 387     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 388                  [AC_MSG_ERROR([SELinux library not found])])
 389     SELINUX_LIBS="-lselinux"
 390     DEFINES="$DEFINES -DMESA_SELINUX"
 391 fi
 392
 393 dnl
 394 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 395 dnl More later: directfb, fbdev, ...
 396 dnl
 397 default_driver="xlib"
 398
 399 case "$host_os" in
 400 linux*)
 401     case "$host_cpu" in
 402     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 403     esac
 404     ;;
 405 *freebsd* | dragonfly*)
 406     case "$host_cpu" in
 407     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 408     esac
 409     ;;
 410 esac
 411
 412 AC_ARG_WITH([driver],
 413     [AS_HELP_STRING([--with-driver=DRIVER],
 414         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 415     [mesa_driver="$withval"],
 416     [mesa_driver="$default_driver"])
 417 dnl Check for valid option
 418 case "x$mesa_driver" in
 419 xxlib|xdri|xosmesa)
 420     ;;
 421 *)
 422     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 423     ;;
 424 esac
 425
 426 dnl
 427 dnl Driver specific build directories
 428 dnl
 429
 430 dnl this variable will be prepended to SRC_DIRS and is not exported
 431 CORE_DIRS="glsl mesa"
 432
 433 SRC_DIRS="glew"
 434 GLU_DIRS="sgi"
 435 WINDOW_SYSTEM=""
 436 GALLIUM_DIRS="auxiliary drivers state_trackers"
 437 GALLIUM_WINSYS_DIRS=""
 438 GALLIUM_WINSYS_DRM_DIRS=""
 439 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 440 GALLIUM_STATE_TRACKERS_DIRS=""
 441
 442 case "$mesa_driver" in
 443 xlib)
 444     DRIVER_DIRS="x11"
 445     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 446     ;;
 447 dri)
 448     CORE_DIRS="glx/x11 $CORE_DIRS"
 449     DRIVER_DIRS="dri"
 450     WINDOW_SYSTEM="dri"
 451     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 452     ;;
 453 osmesa)
 454     DRIVER_DIRS="osmesa"
 455     ;;
 456 esac
 457 AC_SUBST([SRC_DIRS])
 458 AC_SUBST([GLU_DIRS])
 459 AC_SUBST([DRIVER_DIRS])
 460 AC_SUBST([WINDOW_SYSTEM])
 461 AC_SUBST([GALLIUM_DIRS])
 462 AC_SUBST([GALLIUM_WINSYS_DIRS])
 463 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 464 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 465 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 466
 467 dnl
 468 dnl User supplied program configuration
 469 dnl
 470 if test -d "$srcdir/progs/demos"; then
 471     default_demos=yes
 472 else
 473     default_demos=no
 474 fi
 475 AC_ARG_WITH([demos],
 476     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 477         [optional comma delimited demo directories to build
 478         @<:@default=auto if source available@:>@])],
 479     [with_demos="$withval"],
 480     [with_demos="$default_demos"])
 481 if test "x$with_demos" = x; then
 482     with_demos=no
 483 fi
 484
 485 dnl If $with_demos is yes, directories will be added as libs available
 486 PROGRAM_DIRS=""
 487 case "$with_demos" in
 488 no) ;;
 489 yes)
 490     # If the driver isn't osmesa, we have libGL and can build xdemos
 491     if test "$mesa_driver" != osmesa; then
 492         PROGRAM_DIRS="xdemos"
 493     fi
 494     ;;
 495 *)
 496     # verify the requested demos directories exist
 497     demos=`IFS=,; echo $with_demos`
 498     for demo in $demos; do
 499         test -d "$srcdir/progs/$demo" || \
 500             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 501     done
 502     PROGRAM_DIRS="$demos"
 503     ;;
 504 esac
 505
 506 dnl
 507 dnl Find out if X is available. The variable have_x is set if libX11 is
 508 dnl found to mimic AC_PATH_XTRA.
 509 dnl
 510 if test -n "$PKG_CONFIG"; then
 511     AC_MSG_CHECKING([pkg-config files for X11 are available])
 512     PKG_CHECK_EXISTS([x11],[
 513         x11_pkgconfig=yes
 514         have_x=yes
 515         ],[
 516         x11_pkgconfig=no
 517     ])
 518     AC_MSG_RESULT([$x11_pkgconfig])
 519 else
 520     x11_pkgconfig=no
 521 fi
 522 dnl Use the autoconf macro if no pkg-config files
 523 if test "$x11_pkgconfig" = no; then
 524     AC_PATH_XTRA
 525 fi
 526
 527 dnl Try to tell the user that the --x-* options are only used when
 528 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 529 m4_divert_once([HELP_BEGIN],
 530 [These options are only used when the X libraries cannot be found by the
 531 pkg-config utility.])
 532
 533 dnl We need X for xlib and dri, so bomb now if it's not found
 534 case "$mesa_driver" in
 535 xlib|dri)
 536     if test "$no_x" = yes; then
 537         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 538     fi
 539     ;;
 540 esac
 541
 542 dnl XCB - this is only used for GLX right now
 543 AC_ARG_ENABLE([xcb],
 544     [AS_HELP_STRING([--enable-xcb],
 545         [use XCB for GLX @<:@default=disabled@:>@])],
 546     [enable_xcb="$enableval"],
 547     [enable_xcb=no])
 548 if test "x$enable_xcb" = xyes; then
 549     DEFINES="$DEFINES -DUSE_XCB"
 550 else
 551     enable_xcb=no
 552 fi
 553
 554 dnl
 555 dnl libGL configuration per driver
 556 dnl
 557 case "$mesa_driver" in
 558 xlib)
 559     if test "$x11_pkgconfig" = yes; then
 560         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 561         GL_PC_REQ_PRIV="x11 xext"
 562         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 563         GL_LIB_DEPS="$XLIBGL_LIBS"
 564     else
 565         # should check these...
 566         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 567         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 568         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 569         GL_PC_CFLAGS="$X11_INCLUDES"
 570     fi
 571     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 572     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 573
 574     # if static, move the external libraries to the programs
 575     # and empty the libraries for libGL
 576     if test "$enable_static" = yes; then
 577         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 578         GL_LIB_DEPS=""
 579     fi
 580     ;;
 581 dri)
 582     # DRI must be shared, I think
 583     if test "$enable_static" = yes; then
 584         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 585     fi
 586
 587     # Check for libdrm
 588     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 589     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 590     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 591     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 592     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 593
 594     # find the DRI deps for libGL
 595     if test "$x11_pkgconfig" = yes; then
 596         # add xcb modules if necessary
 597         dri_modules="x11 xext xxf86vm xdamage xfixes"
 598         if test "$enable_xcb" = yes; then
 599             dri_modules="$dri_modules x11-xcb xcb-glx"
 600         fi
 601
 602         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 603         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 604         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 605         GL_LIB_DEPS="$DRIGL_LIBS"
 606     else
 607         # should check these...
 608         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 609         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 610         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 611         GL_PC_CFLAGS="$X11_INCLUDES"
 612
 613         # XCB can only be used from pkg-config
 614         if test "$enable_xcb" = yes; then
 615             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 616             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 617             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 618             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 619         fi
 620     fi
 621
 622     # need DRM libs, -lpthread, etc.
 623     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 624     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 625     ;;
 626 osmesa)
 627     # No libGL for osmesa
 628     GL_LIB_DEPS=""
 629     ;;
 630 esac
 631 AC_SUBST([GL_LIB_DEPS])
 632 AC_SUBST([GL_PC_REQ_PRIV])
 633 AC_SUBST([GL_PC_LIB_PRIV])
 634 AC_SUBST([GL_PC_CFLAGS])
 635 AC_SUBST([DRI_PC_REQ_PRIV])
 636
 637 dnl
 638 dnl More X11 setup
 639 dnl
 640 if test "$mesa_driver" = xlib; then
 641     DEFINES="$DEFINES -DUSE_XSHM"
 642 fi
 643
 644 dnl
 645 dnl More DRI setup
 646 dnl
 647 AC_ARG_ENABLE([glx-tls],
 648     [AS_HELP_STRING([--enable-glx-tls],
 649         [enable TLS support in GLX @<:@default=disabled@:>@])],
 650     [GLX_USE_TLS="$enableval"],
 651     [GLX_USE_TLS=no])
 652 dnl Directory for DRI drivers
 653 AC_ARG_WITH([dri-driverdir],
 654     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 655         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 656     [DRI_DRIVER_INSTALL_DIR="$withval"],
 657     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 658 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 659 dnl Extra search path for DRI drivers
 660 AC_ARG_WITH([dri-searchpath],
 661     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 662         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 663     [DRI_DRIVER_SEARCH_DIR="$withval"],
 664     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 665 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 666 dnl Direct rendering or just indirect rendering
 667 AC_ARG_ENABLE([driglx-direct],
 668     [AS_HELP_STRING([--disable-driglx-direct],
 669         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 670     [driglx_direct="$enableval"],
 671     [driglx_direct="yes"])
 672 dnl Which drivers to build - default is chosen by platform
 673 AC_ARG_WITH([dri-drivers],
 674     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 675         [comma delimited DRI drivers list, e.g.
 676         "swrast,i965,radeon" @<:@default=auto@:>@])],
 677     [with_dri_drivers="$withval"],
 678     [with_dri_drivers=yes])
 679 if test "x$with_dri_drivers" = x; then
 680     with_dri_drivers=no
 681 fi
 682
 683 dnl If $with_dri_drivers is yes, directories will be added through
 684 dnl platform checks
 685 DRI_DIRS=""
 686 case "$with_dri_drivers" in
 687 no) ;;
 688 yes)
 689     DRI_DIRS="yes"
 690     ;;
 691 *)
 692     # verify the requested driver directories exist
 693     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 694     for driver in $dri_drivers; do
 695         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 696             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 697     done
 698     DRI_DIRS="$dri_drivers"
 699     ;;
 700 esac
 701
 702 dnl Just default to no EGL for now
 703 USING_EGL=0
 704 AC_SUBST([USING_EGL])
 705
 706 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 707 if test "$mesa_driver" = dri; then
 708     # Use TLS in GLX?
 709     if test "x$GLX_USE_TLS" = xyes; then
 710         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 711     fi
 712
 713     if test "x$USING_EGL" = x1; then
 714         PROGRAM_DIRS="egl"
 715     fi
 716
 717     # Platform specific settings and drivers to build
 718     case "$host_os" in
 719     linux*)
 720         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 721         if test "x$driglx_direct" = xyes; then
 722             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 723         fi
 724         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 725
 726         case "$host_cpu" in
 727         x86_64)
 728             # ffb, gamma, and sis are missing because they have not be
 729             # converted to use the new interface.  i810 are missing
 730             # because there is no x86-64 system where they could *ever*
 731             # be used.
 732             if test "x$DRI_DIRS" = "xyes"; then
 733                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 734                     savage tdfx unichrome swrast"
 735             fi
 736             ;;
 737         powerpc*)
 738             # Build only the drivers for cards that exist on PowerPC.
 739             # At some point MGA will be added, but not yet.
 740             if test "x$DRI_DIRS" = "xyes"; then
 741                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 742             fi
 743             ;;
 744         sparc*)
 745             # Build only the drivers for cards that exist on sparc`
 746             if test "x$DRI_DIRS" = "xyes"; then
 747                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon ffb swrast"
 748             fi
 749             ;;
 750         esac
 751         ;;
 752     freebsd* | dragonfly*)
 753         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 754         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 755         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 756         if test "x$driglx_direct" = xyes; then
 757             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 758         fi
 759         if test "x$GXX" = xyes; then
 760             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 761         fi
 762
 763         # ffb and gamma are missing because they have not been converted
 764         # to use the new interface.
 765         if test "x$DRI_DIRS" = "xyes"; then
 766             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 767                 unichrome savage sis swrast"
 768         fi
 769         ;;
 770     gnu*)
 771         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 772         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 773         ;;
 774     solaris*)
 775         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 776         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 777         if test "x$driglx_direct" = xyes; then
 778             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 779         fi
 780         ;;
 781     esac
 782
 783     # default drivers
 784     if test "x$DRI_DIRS" = "xyes"; then
 785         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 786             savage sis tdfx unichrome ffb swrast"
 787     fi
 788
 789     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 790
 791     # Check for expat
 792     EXPAT_INCLUDES=""
 793     EXPAT_LIB=-lexpat
 794     AC_ARG_WITH([expat],
 795         [AS_HELP_STRING([--with-expat=DIR],
 796             [expat install directory])],[
 797         EXPAT_INCLUDES="-I$withval/include"
 798         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 799         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 800         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 801         ])
 802     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 803     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 804         [AC_MSG_ERROR([Expat required for DRI.])])
 805
 806     # put all the necessary libs together
 807     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 808 fi
 809 AC_SUBST([DRI_DIRS])
 810 AC_SUBST([EXPAT_INCLUDES])
 811 AC_SUBST([DRI_LIB_DEPS])
 812
 813 case $DRI_DIRS in
 814 *i915*|*i965*)
 815     PKG_CHECK_MODULES([INTEL], [libdrm_intel])
 816     ;;
 817 esac
 818
 819 case $DRI_DIRS in
 820 *radeon*|*r200*|*r300*|*r600*)
 821     PKG_CHECK_MODULES([LIBDRM_RADEON],
 822                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 823                       HAVE_LIBDRM_RADEON=yes,
 824                       HAVE_LIBDRM_RADEON=no)
 825
 826     if test "$HAVE_LIBDRM_RADEON" = yes; then
 827         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 828         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 829     fi
 830     ;;
 831 esac
 832 AC_SUBST([RADEON_CFLAGS])
 833 AC_SUBST([RADEON_LDFLAGS])
 834
 835
 836 dnl
 837 dnl OSMesa configuration
 838 dnl
 839 if test "$mesa_driver" = xlib; then
 840     default_gl_osmesa=yes
 841 else
 842     default_gl_osmesa=no
 843 fi
 844 AC_ARG_ENABLE([gl-osmesa],
 845     [AS_HELP_STRING([--enable-gl-osmesa],
 846         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 847     [gl_osmesa="$enableval"],
 848     [gl_osmesa="$default_gl_osmesa"])
 849 if test "x$gl_osmesa" = xyes; then
 850     if test "$mesa_driver" = osmesa; then
 851         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 852     else
 853         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 854     fi
 855 fi
 856
 857 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 858 AC_ARG_WITH([osmesa-bits],
 859     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 860         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 861     [osmesa_bits="$withval"],
 862     [osmesa_bits=8])
 863 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 864     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 865     osmesa_bits=8
 866 fi
 867 case "x$osmesa_bits" in
 868 x8)
 869     OSMESA_LIB=OSMesa
 870     ;;
 871 x16|x32)
 872     OSMESA_LIB="OSMesa$osmesa_bits"
 873     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 874     ;;
 875 *)
 876     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 877     ;;
 878 esac
 879 AC_SUBST([OSMESA_LIB])
 880
 881 case "$mesa_driver" in
 882 osmesa)
 883     # only link libraries with osmesa if shared
 884     if test "$enable_static" = no; then
 885         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 886     else
 887         OSMESA_LIB_DEPS=""
 888     fi
 889     OSMESA_MESA_DEPS=""
 890     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 891     ;;
 892 *)
 893     # Link OSMesa to libGL otherwise
 894     OSMESA_LIB_DEPS=""
 895     # only link libraries with osmesa if shared
 896     if test "$enable_static" = no; then
 897         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 898     else
 899         OSMESA_MESA_DEPS=""
 900     fi
 901     OSMESA_PC_REQ="gl"
 902     ;;
 903 esac
 904 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 905 AC_SUBST([OSMESA_LIB_DEPS])
 906 AC_SUBST([OSMESA_MESA_DEPS])
 907 AC_SUBST([OSMESA_PC_REQ])
 908 AC_SUBST([OSMESA_PC_LIB_PRIV])
 909
 910 dnl
 911 dnl EGL configuration
 912 dnl
 913 AC_ARG_ENABLE([egl],
 914     [AS_HELP_STRING([--disable-egl],
 915         [disable EGL library @<:@default=enabled@:>@])],
 916     [enable_egl="$enableval"],
 917     [enable_egl=yes])
 918 if test "x$enable_egl" = xyes; then
 919     SRC_DIRS="$SRC_DIRS egl"
 920     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 921     EGL_DRIVERS_DIRS=""
 922     if test "$enable_static" != yes && test "$mesa_driver" != osmesa; then
 923         # build egl_glx when libGL is built
 924         EGL_DRIVERS_DIRS="glx"
 925     fi
 926 fi
 927 AC_SUBST([EGL_LIB_DEPS])
 928 AC_SUBST([EGL_DRIVERS_DIRS])
 929
 930 dnl
 931 dnl GLU configuration
 932 dnl
 933 AC_ARG_ENABLE([glu],
 934     [AS_HELP_STRING([--disable-glu],
 935         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 936     [enable_glu="$enableval"],
 937     [enable_glu=yes])
 938 if test "x$enable_glu" = xyes; then
 939     SRC_DIRS="$SRC_DIRS glu"
 940
 941     case "$mesa_driver" in
 942     osmesa)
 943         # If GLU is available and we have libOSMesa (not 16 or 32),
 944         # we can build the osdemos
 945         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 946             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 947         fi
 948
 949         # Link libGLU to libOSMesa instead of libGL
 950         GLU_LIB_DEPS=""
 951         GLU_PC_REQ="osmesa"
 952         if test "$enable_static" = no; then
 953             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 954         else
 955             GLU_MESA_DEPS=""
 956         fi
 957         ;;
 958     *)
 959         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 960         GLU_PC_REQ="gl"
 961         GLU_PC_LIB_PRIV="-lm"
 962         if test "$enable_static" = no; then
 963             GLU_LIB_DEPS="-lm"
 964             GLU_MESA_DEPS='-l$(GL_LIB)'
 965         else
 966             GLU_LIB_DEPS=""
 967             GLU_MESA_DEPS=""
 968             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 969         fi
 970         ;;
 971     esac
 972 fi
 973 if test "$enable_static" = no; then
 974     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 975 fi
 976 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 977 AC_SUBST([GLU_LIB_DEPS])
 978 AC_SUBST([GLU_MESA_DEPS])
 979 AC_SUBST([GLU_PC_REQ])
 980 AC_SUBST([GLU_PC_REQ_PRIV])
 981 AC_SUBST([GLU_PC_LIB_PRIV])
 982 AC_SUBST([GLU_PC_CFLAGS])
 983
 984 dnl
 985 dnl GLw configuration
 986 dnl
 987 AC_ARG_ENABLE([glw],
 988     [AS_HELP_STRING([--disable-glw],
 989         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 990     [enable_glw="$enableval"],
 991     [enable_glw=yes])
 992 dnl Don't build GLw on osmesa
 993 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 994     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 995     enable_glw=no
 996 fi
 997 AC_ARG_ENABLE([motif],
 998     [AS_HELP_STRING([--enable-motif],
 999         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1000     [enable_motif="$enableval"],
1001     [enable_motif=no])
1002
1003 if test "x$enable_glw" = xyes; then
1004     SRC_DIRS="$SRC_DIRS glw"
1005     if test "$x11_pkgconfig" = yes; then
1006         PKG_CHECK_MODULES([GLW],[x11 xt])
1007         GLW_PC_REQ_PRIV="x11 xt"
1008         GLW_LIB_DEPS="$GLW_LIBS"
1009     else
1010         # should check these...
1011         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1012         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1013         GLW_PC_CFLAGS="$X11_INCLUDES"
1014     fi
1015
1016     GLW_SOURCES="GLwDrawA.c"
1017     MOTIF_CFLAGS=
1018     if test "x$enable_motif" = xyes; then
1019         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1020         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1021         if test "x$MOTIF_CONFIG" != xno; then
1022             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1023             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1024         else
1025             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1026                 [AC_MSG_ERROR([Can't locate Motif headers])])
1027             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1028                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1029         fi
1030         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1031         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1032         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1033         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1034     fi
1035
1036     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1037     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1038     if test "$enable_static" = no; then
1039         GLW_MESA_DEPS='-l$(GL_LIB)'
1040         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1041     else
1042         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1043         GLW_LIB_DEPS=""
1044         GLW_MESA_DEPS=""
1045     fi
1046 fi
1047 AC_SUBST([GLW_LIB_DEPS])
1048 AC_SUBST([GLW_MESA_DEPS])
1049 AC_SUBST([GLW_SOURCES])
1050 AC_SUBST([MOTIF_CFLAGS])
1051 AC_SUBST([GLW_PC_REQ_PRIV])
1052 AC_SUBST([GLW_PC_LIB_PRIV])
1053 AC_SUBST([GLW_PC_CFLAGS])
1054
1055 dnl
1056 dnl GLUT configuration
1057 dnl
1058 if test -f "$srcdir/include/GL/glut.h"; then
1059     default_glut=yes
1060 else
1061     default_glut=no
1062 fi
1063 AC_ARG_ENABLE([glut],
1064     [AS_HELP_STRING([--disable-glut],
1065         [enable GLUT library @<:@default=enabled if source available@:>@])],
1066     [enable_glut="$enableval"],
1067     [enable_glut="$default_glut"])
1068
1069 dnl Can't build glut if GLU not available
1070 if test "x$enable_glu$enable_glut" = xnoyes; then
1071     AC_MSG_WARN([Disabling glut since GLU is disabled])
1072     enable_glut=no
1073 fi
1074 dnl Don't build glut on osmesa
1075 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1076     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1077     enable_glut=no
1078 fi
1079
1080 if test "x$enable_glut" = xyes; then
1081     SRC_DIRS="$SRC_DIRS glut/glx"
1082     GLUT_CFLAGS=""
1083     if test "x$GCC" = xyes; then
1084         GLUT_CFLAGS="-fexceptions"
1085     fi
1086     if test "$x11_pkgconfig" = yes; then
1087         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1088         GLUT_PC_REQ_PRIV="x11 xmu xi"
1089         GLUT_LIB_DEPS="$GLUT_LIBS"
1090     else
1091         # should check these...
1092         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1093         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1094         GLUT_PC_CFLAGS="$X11_INCLUDES"
1095     fi
1096     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1097     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1098
1099     # If glut is available, we can build most programs
1100     if test "$with_demos" = yes; then
1101         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1102     fi
1103
1104     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1105     if test "$enable_static" = no; then
1106         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1107     else
1108         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1109         GLUT_LIB_DEPS=""
1110         GLUT_MESA_DEPS=""
1111     fi
1112 fi
1113 AC_SUBST([GLUT_LIB_DEPS])
1114 AC_SUBST([GLUT_MESA_DEPS])
1115 AC_SUBST([GLUT_CFLAGS])
1116 AC_SUBST([GLUT_PC_REQ_PRIV])
1117 AC_SUBST([GLUT_PC_LIB_PRIV])
1118 AC_SUBST([GLUT_PC_CFLAGS])
1119
1120 dnl
1121 dnl Program library dependencies
1122 dnl    Only libm is added here if necessary as the libraries should
1123 dnl    be pulled in by the linker
1124 dnl
1125 if test "x$APP_LIB_DEPS" = x; then
1126     case "$host_os" in
1127     solaris*)
1128         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1129         ;;
1130     cygwin*)
1131         APP_LIB_DEPS="-lX11"
1132         ;;
1133     *)
1134         APP_LIB_DEPS="-lm"
1135         ;;
1136     esac
1137 fi
1138 AC_SUBST([APP_LIB_DEPS])
1139 AC_SUBST([PROGRAM_DIRS])
1140
1141 dnl
1142 dnl Gallium configuration
1143 dnl
1144 AC_ARG_ENABLE([gallium],
1145     [AS_HELP_STRING([--disable-gallium],
1146         [build gallium @<:@default=enabled@:>@])],
1147     [enable_gallium="$enableval"],
1148     [enable_gallium=yes])
1149 if test "x$enable_gallium" = xyes; then
1150     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1151 fi
1152
1153 dnl
1154 dnl Gallium state trackers configuration
1155 dnl
1156 AC_ARG_WITH([state-trackers],
1157     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1158         [comma delimited state_trackers list, e.g.
1159         "egl,glx" @<:@default=auto@:>@])],
1160     [with_state_trackers="$withval"],
1161     [with_state_trackers=yes])
1162
1163 case "$with_state_trackers" in
1164 no)
1165     GALLIUM_STATE_TRACKERS_DIRS=""
1166     ;;
1167 yes)
1168     # look at what else is built
1169     case "$mesa_driver" in
1170     xlib)
1171         GALLIUM_STATE_TRACKERS_DIRS=glx
1172         ;;
1173     dri)
1174         GALLIUM_STATE_TRACKERS_DIRS="dri"
1175         if test "x$enable_egl" = xyes; then
1176             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl egl_g3d"
1177         fi
1178         # Have only tested st/xorg on 1.6.0 servers
1179         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0],
1180             HAVE_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1181             HAVE_XORG="no")
1182         ;;
1183     esac
1184     ;;
1185 *)
1186     # verify the requested state tracker exist
1187     state_trackers=`IFS=', '; echo $with_state_trackers`
1188     for tracker in $state_trackers; do
1189         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1190             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1191
1192         case "$tracker" in
1193         egl)
1194             if test "x$enable_egl" != xyes; then
1195                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1196             fi
1197             ;;
1198         xorg)
1199             PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1200                   HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1201                   HAVE_XEXTPROTO_71="no")
1202             ;;
1203         es)
1204             # mesa/es is required to build es state tracker
1205             CORE_DIRS="$CORE_DIRS mesa/es"
1206             ;;
1207         esac
1208     done
1209     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1210     ;;
1211 esac
1212
1213 AC_ARG_WITH([egl-displays],
1214     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1215         [comma delimited native displays libEGL supports, e.g.
1216         "x11,kms" @<:@default=auto@:>@])],
1217     [with_egl_displays="$withval"],
1218     [with_egl_displays=yes])
1219
1220 EGL_DISPLAYS=""
1221 case "$with_egl_displays" in
1222 yes)
1223     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1224         EGL_DISPLAYS="x11"
1225     fi
1226     ;;
1227 *)
1228     if test "x$enable_egl" != xyes; then
1229         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1230     fi
1231     # verify the requested driver directories exist
1232     egl_displays=`IFS=', '; echo $with_egl_displays`
1233     for dpy in $egl_displays; do
1234         test -d "$srcdir/src/gallium/state_trackers/egl_g3d/$dpy" || \
1235             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1236     done
1237     EGL_DISPLAYS="$egl_displays"
1238     ;;
1239 esac
1240 AC_SUBST([EGL_DISPLAYS])
1241
1242 AC_ARG_WITH([xorg-driver-dir],
1243     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1244                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1245     [XORG_DRIVER_INSTALL_DIR="$withval"],
1246     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1247 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1248
1249 AC_ARG_WITH([max-width],
1250     [AS_HELP_STRING([--with-max-width=N],
1251                     [Maximum framebuffer width (4096)])],
1252     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1253      AS_IF([test "${withval}" -gt "4096"],
1254            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1255 )
1256 AC_ARG_WITH([max-height],
1257     [AS_HELP_STRING([--with-max-height=N],
1258                     [Maximum framebuffer height (4096)])],
1259     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1260      AS_IF([test "${withval}" -gt "4096"],
1261            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1262 )
1263
1264 dnl
1265 dnl Gallium SVGA configuration
1266 dnl
1267 AC_ARG_ENABLE([gallium-svga],
1268     [AS_HELP_STRING([--enable-gallium-svga],
1269         [build gallium SVGA @<:@default=disabled@:>@])],
1270     [enable_gallium_svga="$enableval"],
1271     [enable_gallium_svga=auto])
1272 if test "x$enable_gallium_svga" = xyes; then
1273     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS vmware"
1274     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1275 elif test "x$enable_gallium_svga" = xauto; then
1276     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1277 fi
1278
1279 dnl
1280 dnl Gallium Intel configuration
1281 dnl
1282 AC_ARG_ENABLE([gallium-intel],
1283     [AS_HELP_STRING([--enable-gallium-intel],
1284         [build gallium intel @<:@default=disabled@:>@])],
1285     [enable_gallium_intel="$enableval"],
1286     [enable_gallium_intel=auto])
1287 if test "x$enable_gallium_intel" = xyes; then
1288     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel i965"
1289     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1290 elif test "x$enable_gallium_intel" = xauto; then
1291     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1292 fi
1293
1294 dnl
1295 dnl Gallium Radeon configuration
1296 dnl
1297 AC_ARG_ENABLE([gallium-radeon],
1298     [AS_HELP_STRING([--enable-gallium-radeon],
1299         [build gallium radeon @<:@default=disabled@:>@])],
1300     [enable_gallium_radeon="$enableval"],
1301     [enable_gallium_radeon=auto])
1302 if test "x$enable_gallium_radeon" = xyes; then
1303     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1304     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1305 elif test "x$enable_gallium_radeon" = xauto; then
1306     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1307 fi
1308
1309 dnl
1310 dnl Gallium Nouveau configuration
1311 dnl
1312 AC_ARG_ENABLE([gallium-nouveau],
1313     [AS_HELP_STRING([--enable-gallium-nouveau],
1314         [build gallium nouveau @<:@default=disabled@:>@])],
1315     [enable_gallium_nouveau="$enableval"],
1316     [enable_gallium_nouveau=no])
1317 if test "x$enable_gallium_nouveau" = xyes; then
1318     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1319     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv04 nv10 nv20 nv30 nv40 nv50"
1320 fi
1321
1322 dnl prepend CORE_DIRS to SRC_DIRS
1323 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1324
1325 dnl Restore LDFLAGS and CPPFLAGS
1326 LDFLAGS="$_SAVE_LDFLAGS"
1327 CPPFLAGS="$_SAVE_CPPFLAGS"
1328
1329 dnl Substitute the config
1330 AC_CONFIG_FILES([configs/autoconf])
1331
1332 dnl Replace the configs/current symlink
1333 AC_CONFIG_COMMANDS([configs],[
1334 if test -f configs/current || test -L configs/current; then
1335     rm -f configs/current
1336 fi
1337 ln -s autoconf configs/current
1338 ])
1339
1340 AC_OUTPUT
1341
1342 dnl
1343 dnl Output some configuration info for the user
1344 dnl
1345 echo ""
1346 echo "        prefix:          $prefix"
1347 echo "        exec_prefix:     $exec_prefix"
1348 echo "        libdir:          $libdir"
1349 echo "        includedir:      $includedir"
1350
1351 dnl Driver info
1352 echo ""
1353 echo "        Driver:          $mesa_driver"
1354 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1355     echo "        OSMesa:          lib$OSMESA_LIB"
1356 else
1357     echo "        OSMesa:          no"
1358 fi
1359 if test "$mesa_driver" = dri; then
1360     # cleanup the drivers var
1361     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1362 if test "x$DRI_DIRS" = x; then
1363     echo "        DRI drivers:     no"
1364 else
1365     echo "        DRI drivers:     $dri_dirs"
1366 fi
1367     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1368 fi
1369 echo "        Use XCB:         $enable_xcb"
1370
1371 echo ""
1372 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1373     echo "        Gallium:         yes"
1374     echo "        Gallium dirs:    $GALLIUM_DIRS"
1375     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1376     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1377     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1378     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1379 else
1380     echo "        Gallium:         no"
1381 fi
1382
1383 dnl Libraries
1384 echo ""
1385 echo "        Shared libs:     $enable_shared"
1386 echo "        Static libs:     $enable_static"
1387 echo "        EGL:             $enable_egl"
1388 echo "        GLU:             $enable_glu"
1389 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1390 echo "        glut:            $enable_glut"
1391
1392 dnl Programs
1393 # cleanup the programs var for display
1394 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1395 if test "x$program_dirs" = x; then
1396     echo "        Demos:           no"
1397 else
1398     echo "        Demos:           $program_dirs"
1399 fi
1400
1401 dnl Compiler options
1402 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1403 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1404     $SED 's/^ *//;s/  */ /;s/ *$//'`
1405 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1406     $SED 's/^ *//;s/  */ /;s/ *$//'`
1407 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1408 echo ""
1409 echo "        CFLAGS:          $cflags"
1410 echo "        CXXFLAGS:        $cxxflags"
1411 echo "        Macros:          $defines"
1412
1413 echo ""
1414 echo "        Run '${MAKE-make}' to build Mesa"
1415 echo ""