configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  26 AC_CONFIG_SRCDIR([src/daemon/main.c])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_AUX_DIR([build-aux])
  30 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability subdir-objects silent-rules color-tests dist-xz tar-ustar])
  31
  32 AS_IF([! test -n "$VERSION"], [
  33    AC_MSG_ERROR([git-version-gen failed])
  34 ])
  35
  36 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  37 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  38
  39 AC_SUBST(PA_MAJOR, pa_major)
  40 AC_SUBST(PA_MINOR, pa_minor)
  41 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  42
  43 AC_SUBST(PA_API_VERSION, 12)
  44 AC_SUBST(PA_PROTOCOL_VERSION, 30)
  45
  46 # The stable ABI for client applications, for the version info x:y:z
  47 # always will hold y=z
  48 AC_SUBST(LIBPULSE_VERSION_INFO, [17:3:17])
  49
  50 # A simplified, synchronous, ABI-stable interface for client
  51 # applications, for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [1:0:1])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:5:0])
  57
  58 AC_CANONICAL_HOST
  59 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  60
  61 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  62
  63 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  64     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  65     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  66 ])
  67
  68 AM_SILENT_RULES([yes])
  69
  70
  71 #### Checks for programs. ####
  72
  73 # mkdir -p
  74
  75 AC_PROG_MKDIR_P
  76
  77 # ln -s
  78
  79 AC_PROG_LN_S
  80
  81 # CC
  82
  83 AC_PROG_CC
  84 AC_PROG_CC_C99
  85 AM_PROG_CC_C_O
  86 # Only required if you want the WebRTC canceller -- no runtime dep on
  87 # libstdc++ otherwise
  88 AC_PROG_CXX
  89 AC_PROG_GCC_TRADITIONAL
  90 AC_USE_SYSTEM_EXTENSIONS
  91
  92 # M4
  93
  94 AC_CHECK_PROGS([M4], gm4 m4, no)
  95 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  96
  97 # pkg-config
  98
  99 PKG_PROG_PKG_CONFIG
 100
 101 # gettext
 102
 103 if test "x$enable_nls" != "xno"; then
 104 IT_PROG_INTLTOOL([0.35.0])
 105
 106 AM_GNU_GETTEXT_VERSION([0.18.1])
 107 AM_GNU_GETTEXT([external])
 108
 109 GETTEXT_PACKAGE=pulseaudio
 110 AC_SUBST([GETTEXT_PACKAGE])
 111 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 112
 113 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 114 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 115 else
 116 # workaround till an intltool m4 bug is fixed upstream
 117 # (https://bugs.launchpad.net/intltool/+bug/904647)
 118 USE_NLS=no
 119 AC_SUBST(USE_NLS)
 120 fi
 121
 122
 123 #### Determine host OS ####
 124
 125 # if the host has the possibility of sys/capability.h for dropping privileges
 126 # used to determine if we should error out if it is not found
 127 host_has_caps=0
 128
 129 os_is_linux=0
 130 os_is_win32=0
 131 os_is_darwin=0
 132
 133 AC_MSG_CHECKING([host operating system])
 134 case "$host_os" in
 135     linux*)
 136         AC_MSG_RESULT([linux])
 137         host_has_caps=1
 138         os_is_linux=1
 139     ;;
 140     freebsd*)
 141         AC_MSG_RESULT([freebsd])
 142         host_has_caps=1
 143     ;;
 144     darwin*)
 145         AC_MSG_RESULT([darwin])
 146         os_is_darwin=1
 147         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 148     ;;
 149     mingw*)
 150         AC_MSG_RESULT([win32])
 151         os_is_win32=1
 152         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 153     ;;
 154     *)
 155         AC_MSG_RESULT([unknown])
 156     ;;
 157 esac
 158
 159 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 160 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 161 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 162
 163 # Platform specific hacks
 164 case "$host_os" in
 165     darwin* )
 166         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 167     ;;
 168     mingw* )
 169         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 170     ;;
 171     solaris* )
 172         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 173         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 174     ;;
 175 esac
 176
 177
 178 #### Compiler flags ####
 179
 180 AX_APPEND_COMPILE_FLAGS(
 181     [-Wall -W -Wextra -pipe -Wno-long-long -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -fno-common -fdiagnostics-show-option -fdiagnostics-color=auto],
 182     [], [-pedantic -Werror])
 183
 184 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [
 185     # Don't append the flag if it already exists.
 186     # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 187     AX_APPEND_FLAG([-DFASTPATH], [CPPFLAGS])
 188
 189     # Cannot use AX_APPEND_FLAG here, as it assumes no space inside the added flags.
 190     # Cannot append flags with AX_APPEND_FLAG one by one, as this would destroy all fortifications
 191     # if CPPFLAGS already contain -D_FORTIFY_SOURCE=2.
 192
 193     # Warnings to be aware of that appear with -D_FORTIFY_SOURCE=2 but without -U_FORTIFY_SOURCE:
 194     # On Fedora 20 with -O0: #warning _FORTIFY_SOURCE requires compiling with optimization (-O) [-Wcpp]
 195     # On Gentoo with -O2:    "_FORTIFY_SOURCE" redefined [enabled by default]
 196     AS_VAR_APPEND([CPPFLAGS],[" -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"])
 197 ])
 198
 199 #### Linker flags ####
 200
 201 # Check whether the linker supports the -version-script option.
 202 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 203 # so that it is expanded the right way in every subdir.
 204 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 205     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/src/map-file'])
 206 AC_SUBST([VERSIONING_LDFLAGS])
 207
 208 # Use immediate (now) bindings; avoids the funky re-call in itself.
 209 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 210 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 211 AC_SUBST([IMMEDIATE_LDFLAGS])
 212
 213 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 214 # so we request the nodelete flag to be enabled.
 215 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 216 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 217 AC_SUBST([NODELETE_LDFLAGS])
 218
 219 # Check for the proper way to build libraries that have no undefined symbols
 220 case $host in
 221     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 222     # are requested, as different implementations are present.
 223     *-freebsd* | *-openbsd*) ;;
 224     *)
 225         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 226             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 227         done
 228     ;;
 229 esac
 230 AC_SUBST([NOUNDEFINED_LDFLAGS])
 231
 232
 233 #### Atomic operations ####
 234
 235 # Native atomic operation support
 236 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 237     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 238
 239 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 240     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 241
 242 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 243     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 244 fi
 245
 246 # If everything else fails use libatomic_ops
 247 need_libatomic_ops=yes
 248
 249 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 250     pulseaudio_cv_sync_bool_compare_and_swap, [
 251     AC_LINK_IFELSE(
 252         [AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]])],
 253         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 254         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 255     ])
 256
 257 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 258     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 259     need_libatomic_ops=no
 260 else
 261     # HW specific atomic ops stuff
 262     AC_MSG_CHECKING([architecture for native atomic operations])
 263     case $host in
 264         arm*)
 265             AC_MSG_RESULT([arm])
 266             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 267             # The Linux kernel helper functions have been there since 2.6.16. However
 268             # compile time checking for kernel version in cross compile environment
 269             # (which is usually the case for arm cpu) is tricky (or impossible).
 270             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 271                 AC_MSG_RESULT([yes])
 272                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 273                 need_libatomic_ops=no
 274             else
 275                 AC_MSG_RESULT([no])
 276                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 277                     pulseaudio_cv_support_arm_atomic_ops, [
 278                     AC_COMPILE_IFELSE(
 279                         [AC_LANG_PROGRAM([], [[
 280                             volatile int a=0;
 281                             int o=0, n=1, r;
 282                             asm volatile ("ldrex    %0, [%1]\n"
 283                                           "subs  %0, %0, %2\n"
 284                                           "strexeq %0, %3, [%1]\n"
 285                                           : "=&r" (r)
 286                                           : "r" (&a), "Ir" (o), "r" (n)
 287                                           : "cc");
 288                             return (a==1 ? 0 : -1);
 289                         ]])],
 290                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 291                         [pulseaudio_cv_support_arm_atomic_ops=no])
 292                 ])
 293                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 294                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 295                     need_libatomic_ops=no
 296                 ])
 297             fi
 298         ;;
 299         *-netbsdelf5*)
 300             AC_MSG_RESULT([yes])
 301             need_libatomic_ops=no
 302         ;;
 303         *-freebsd*)
 304             AC_MSG_RESULT([yes])
 305             need_libatomic_ops=no
 306         ;;
 307         *)
 308             AC_MSG_RESULT([unknown])
 309         ;;
 310     esac
 311 fi
 312
 313 # If we're on ARM, check for the ARMV6 instructions we need */
 314 case $host in
 315   arm*)
 316     AC_CACHE_CHECK([support for required armv6 instructions],
 317       pulseaudio_cv_support_armv6,
 318       [AC_COMPILE_IFELSE(
 319          [AC_LANG_PROGRAM([],
 320            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 321              asm volatile ("ldr r0, %2 \n"
 322                            "ldr r2, %3 \n"
 323                            "ldr r3, %4 \n"
 324                            "ssat r1, #8, r0 \n"
 325                            "str r1, %0 \n"
 326                            "pkhbt r1, r3, r2, LSL #8 \n"
 327                            "str r1, %1 \n"
 328                            : "=m" (a), "=m" (b)
 329                            : "m" (a), "m" (b), "m" (c)
 330                            : "r0", "r1", "r2", "r3", "cc");
 331              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 332            ]])],
 333          [pulseaudio_cv_support_armv6=yes],
 334          [pulseaudio_cv_support_armv6=no])
 335       ])
 336     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 337         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 338       ])
 339   ;;
 340   *)
 341   ;;
 342 esac
 343
 344 #### NEON optimisations ####
 345 AC_ARG_ENABLE([neon-opt],
 346     AS_HELP_STRING([--enable-neon-opt], [Enable NEON optimisations on ARM CPUs that support it]))
 347
 348 AS_IF([test "x$enable_neon_opt" != "xno"],
 349     [save_CFLAGS="$CFLAGS"; CFLAGS="-mfpu=neon $CFLAGS"
 350      AC_COMPILE_IFELSE(
 351         [AC_LANG_PROGRAM([[#include <arm_neon.h>]], [])],
 352         [
 353          HAVE_NEON=1
 354          NEON_CFLAGS="-mfpu=neon"
 355         ],
 356         [
 357          HAVE_NEON=0
 358          NEON_CFLAGS=
 359         ])
 360      CFLAGS="$save_CFLAGS"
 361     ],
 362     [HAVE_NEON=0])
 363
 364 AS_IF([test "x$enable_neon_opt" = "xyes" && test "x$HAVE_NEON" = "x0"],
 365       [AC_MSG_ERROR([*** Compiler does not support -mfpu=neon or CFLAGS override -mfpu])])
 366
 367 AC_SUBST(HAVE_NEON)
 368 AC_SUBST(NEON_CFLAGS)
 369 AM_CONDITIONAL([HAVE_NEON], [test "x$HAVE_NEON" = x1])
 370 AS_IF([test "x$HAVE_NEON" = "x1"], AC_DEFINE([HAVE_NEON], 1, [Have NEON support?]))
 371
 372
 373 #### libtool stuff ####
 374
 375 LT_PREREQ(2.4)
 376 LT_INIT([dlopen win32-dll disable-static])
 377
 378 dnl As an extra safety device, check for lt_dladvise_init() which is
 379 dnl only implemented in libtool 2.x, and refine as we go if we have
 380 dnl refined requirements.
 381 dnl
 382 dnl Check the header files first since the system may have a
 383 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 384 dnl soon as possible.
 385 dnl
 386 dnl We don't need any special variable for this though, since the user
 387 dnl can give the proper place to find libltdl through the standard
 388 dnl variables like LDFLAGS and CPPFLAGS.
 389
 390 AC_CHECK_HEADER([ltdl.h],
 391     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 392     [LIBLTDL=])
 393
 394 AS_IF([test "x$LIBLTDL" = "x"],
 395     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.4 or later installed.])])
 396 AC_SUBST([LIBLTDL])
 397
 398
 399 ###################################
 400 #   Basic environment checks      #
 401 ###################################
 402
 403 #### Checks for header files. ####
 404
 405 # ISO
 406 AC_HEADER_STDC
 407
 408 # POSIX
 409 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 410     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 411     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 412     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 413 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 414                  [#include <sys/types.h>
 415                   #if HAVE_NETINET_IN_H
 416                   # include <netinet/in.h>
 417                   #endif
 418                   #if HAVE_NETINET_IN_SYSTM_H
 419                   # include <netinet/in_systm.h>
 420                   #endif
 421                  ])
 422 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 423 AC_SUBST(HAVE_SYS_RESOURCE_H)
 424 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 425 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 426 AC_SUBST(HAVE_AF_UNIX)
 427
 428 # Linux
 429 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 430 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 431
 432 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 433
 434 # Solaris
 435 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 436
 437 # Windows
 438 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 439
 440 # NetBSD
 441 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 442
 443 # Other
 444 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 445 AC_CHECK_HEADERS_ONCE([byteswap.h])
 446 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 447 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 448 AC_CHECK_HEADERS_ONCE([execinfo.h])
 449 AC_CHECK_HEADERS_ONCE([langinfo.h])
 450 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 451
 452
 453 #### Typdefs, structures, etc. ####
 454
 455 AC_C_CONST
 456 AC_C_BIGENDIAN
 457 AC_TYPE_PID_T
 458 AC_TYPE_SIZE_T
 459 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 460 AC_TYPE_OFF_T
 461
 462 AC_TYPE_UID_T
 463 AC_CHECK_DECLS(environ)
 464
 465 # SIGXCPU
 466 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 467 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 468 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 469
 470 # INADDR_NONE, Solaris lacks this
 471 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 472     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 473         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 474
 475
 476 # _Bool
 477 AC_CACHE_CHECK([whether $CC knows _Bool],
 478     pulseaudio_cv__Bool,
 479     [AC_COMPILE_IFELSE(
 480         [AC_LANG_PROGRAM([], [[_Bool b;]])],
 481         [pulseaudio_cv__Bool=yes],
 482         [pulseaudio_cv__Bool=no])
 483     ])
 484
 485 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 486
 487
 488 #### Thread support ####
 489
 490 AX_TLS
 491 AS_IF([test "$ac_cv_tls" == "__thread"],
 492     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 493
 494 # Win32 build breaks with win32 pthread installed
 495 AS_IF([test "x$os_is_win32" != "x1"],
 496   [AX_PTHREAD])
 497
 498 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 499     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 500
 501
 502 #### Check for libs ####
 503
 504 # ISO
 505 AC_SEARCH_LIBS([pow], [m])
 506
 507 # POSIX
 508 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 509 AC_SEARCH_LIBS([dlopen], [dl])
 510 AC_SEARCH_LIBS([shm_open], [rt])
 511 AC_SEARCH_LIBS([inet_ntop], [nsl])
 512 AC_SEARCH_LIBS([timer_create], [rt])
 513 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 514 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 515 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 516
 517 # BSD
 518 AC_SEARCH_LIBS([connect], [socket])
 519 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 520
 521 # Darwin/OS X
 522 if test "x$os_is_darwin" = "x1" ; then
 523     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 524     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 525     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 526         [LIBS="$LIBS -framework CoreServices"],
 527         [AC_CHECK_HEADERS([/System/Library/Frameworks/CoreServices.framework/Headers/CoreServices.h],
 528             [LIBS="$LIBS -framework CoreServices"],
 529             [AC_MSG_ERROR([CoreServices.h header file not found])]
 530         )]
 531     )
 532
 533     AC_MSG_RESULT([ok])
 534     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 535     HAVE_BONJOUR=1
 536 fi
 537
 538 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 539
 540 # Windows
 541 AC_SEARCH_LIBS([regexec], [pcreposix])
 542 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 543 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 544
 545
 546 #### Check for functions ####
 547
 548 # ISO
 549 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 550
 551 # POSIX
 552 AC_FUNC_FORK
 553 AC_FUNC_GETGROUPS
 554 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 555     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 556     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 557     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 558 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 559 AC_SUBST(HAVE_MKFIFO)
 560 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 561
 562 # X/OPEN
 563 AC_CHECK_FUNCS_ONCE([readlink])
 564
 565 # SUSv2
 566 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 567
 568 # SUSv3
 569 AC_CHECK_FUNCS_ONCE([strerror_r])
 570
 571 # BSD
 572 AC_CHECK_FUNCS_ONCE([lstat])
 573
 574 # Non-standard
 575 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 576
 577 AC_FUNC_ALLOCA
 578
 579 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 580 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 581
 582 # Large File-Support (LFS)
 583 AC_SYS_LARGEFILE
 584 # Check for open64 to know if the current system does have open64() and similar functions
 585 AC_CHECK_FUNCS_ONCE([open64])
 586
 587 AC_SEARCH_LIBS([dladdr], [dl], [HAVE_DLADDR=1], [HAVE_DLADDR=0])
 588 AC_DEFINE(HAVE_DLADDR, [1], [Have dladdr?])
 589
 590 ###################################
 591 #      External libraries         #
 592 ###################################
 593
 594 #### [lib]iconv ####
 595
 596 AM_ICONV
 597
 598 #### X11 (optional) ####
 599
 600 AC_ARG_ENABLE([x11],
 601     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 602
 603 AS_IF([test "x$enable_x11" != "xno"],
 604     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 605     HAVE_X11=0)
 606
 607 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 608     [AC_MSG_ERROR([*** X11 not found])])
 609
 610 AC_SUBST(HAVE_X11)
 611 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 612 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 613
 614 #### Capabilities (optional) ####
 615
 616 CAP_LIBS=''
 617
 618 AC_ARG_WITH([caps],
 619     AS_HELP_STRING([--without-caps],[Omit support for dropping capabilities.]))
 620
 621 if test "x${with_caps}" != "xno"; then
 622     AC_SEARCH_LIBS([cap_init], [cap], [], [])
 623
 624     # Only give an error on hosts that we know could support capabilities
 625     AC_CHECK_HEADERS([sys/capability.h], [], [
 626       if test "${host_has_caps}" = "1"; then
 627         AC_MSG_ERROR([*** sys/capability.h not found.  Use --without-caps to disable capabilities support.])
 628       fi])
 629 fi
 630
 631 #### Valgrind (optional) ####
 632
 633 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 634
 635 #### check unit tests ####
 636
 637 AC_ARG_ENABLE([tests],
 638     AS_HELP_STRING([--disable-tests],[Disable unit tests]))
 639
 640 AS_IF([test "x$enable_tests" != "xno"],
 641     [PKG_CHECK_MODULES(LIBCHECK, [ check ], HAVE_LIBCHECK=1, HAVE_LIBCHECK=0)],
 642     HAVE_LIBCHECK=0)
 643
 644 AS_IF([test "x$enable_tests" = "xyes" && test "x$HAVE_LIBCHECK" = "x0"],
 645     [AC_MSG_ERROR([*** check library not found])])
 646
 647 AM_CONDITIONAL([HAVE_TESTS], [test "x$HAVE_LIBCHECK" = x1])
 648
 649 #### json parsing ####
 650
 651 PKG_CHECK_MODULES(LIBJSON, [ json-c >= 0.11 ])
 652
 653 #### Sound file ####
 654
 655 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 656
 657 #### atomic-ops ####
 658
 659 AC_MSG_CHECKING([whether we need libatomic_ops])
 660 if test "x$need_libatomic_ops" = "xyes"; then
 661     AC_MSG_RESULT([yes])
 662     AC_CHECK_HEADERS([atomic_ops.h],
 663         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 664         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 665
 666     # Win32 does not need the lib and breaks horribly if we try to include it
 667     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 668 else
 669     AC_MSG_RESULT([no])
 670 fi
 671
 672 #### Libsamplerate support (optional) ####
 673
 674 AC_ARG_ENABLE([samplerate],
 675     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
 676
 677 AS_IF([test "x$enable_samplerate" != "xno"],
 678     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 679     HAVE_LIBSAMPLERATE=0)
 680
 681 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 682     [AC_MSG_ERROR([*** Libsamplerate not found])])
 683
 684 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 685 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 686
 687 #### Database support ####
 688
 689 AC_ARG_WITH([database],
 690     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 691
 692
 693 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 694     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 695     HAVE_TDB=0)
 696 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 697
 698 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 699     [AC_MSG_ERROR([*** tdb not found])])
 700
 701
 702 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 703     [
 704         HAVE_GDBM=1
 705         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 706         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 707     ],
 708     HAVE_GDBM=0)
 709 AS_IF([test "x$HAVE_GDBM" = "x1"],
 710     [
 711         with_database=gdbm
 712         GDBM_CFLAGS=
 713         GDBM_LIBS=-lgdbm
 714     ])
 715
 716 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 717     [AC_MSG_ERROR([*** gdbm not found])])
 718
 719
 720 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 721     HAVE_SIMPLEDB=1,
 722     HAVE_SIMPLEDB=0)
 723 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 724
 725 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 726     AC_MSG_ERROR([*** missing database backend]))
 727
 728
 729 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 730 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 731
 732 AC_SUBST(GDBM_CFLAGS)
 733 AC_SUBST(GDBM_LIBS)
 734 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 735 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 736
 737 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 738 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 739
 740 #### OSS support (optional) ####
 741
 742 AC_ARG_ENABLE([oss-output],
 743     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 744
 745 AC_ARG_ENABLE([oss-wrapper],
 746     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 747
 748 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 749     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 750     HAVE_OSS=0)
 751
 752 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 753     [AC_MSG_ERROR([*** OSS support not found])])
 754
 755 AS_IF([test "x$enable_oss_output" != "xno"],
 756     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 757     HAVE_OSS_OUTPUT=0)
 758
 759 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 760     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 761     HAVE_OSS_WRAPPER=0)
 762
 763 AC_SUBST(HAVE_OSS_OUTPUT)
 764 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 765 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 766 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 767 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 768
 769 #### CoreAudio support (optional) ####
 770
 771 AC_ARG_ENABLE([coreaudio-output],
 772     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 773
 774 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 775     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 776     HAVE_COREAUDIO=0)
 777
 778 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 779     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 780
 781 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 782
 783 #### ALSA support (optional) ####
 784
 785 AC_ARG_ENABLE([alsa],
 786     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 787
 788 AS_IF([test "x$enable_alsa" != "xno"],
 789     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 790     HAVE_ALSA=0)
 791
 792 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 793     [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
 794
 795 AS_IF([test "x$HAVE_ALSA" = "x1"],
 796     [
 797         save_CPPFLAGS="$CPPFLAGS"; CPPFLAGS="$CPPFLAGS $ASOUNDLIB_CFLAGS"
 798         AC_CHECK_HEADERS([use-case.h], HAVE_ALSA_UCM=1, HAVE_ALSA_UCM=0)
 799         CPPFLAGS="$save_CPPFLAGS"
 800     ],
 801     HAVE_ALSA_UCM=0)
 802
 803 AC_SUBST(HAVE_ALSA)
 804 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 805 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 806 AS_IF([test "x$HAVE_ALSA_UCM" = "x1"], AC_DEFINE([HAVE_ALSA_UCM], 1, [Have ALSA UCM?]))
 807
 808 #### EsounD support (optional) ####
 809
 810 AC_ARG_ENABLE([esound],
 811     AS_HELP_STRING([--disable-esound],[Disable optional EsounD support]))
 812 AM_CONDITIONAL([HAVE_ESOUND], [test "x$enable_esound" != "xno"])
 813 AS_IF([test "x$enable_esound" != "xno"], [HAVE_ESOUND=1])
 814
 815 #### Solaris audio support (optional) ####
 816
 817 AC_ARG_ENABLE([solaris],
 818     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 819
 820 AS_IF([test "x$enable_solaris" != "xno"],
 821     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 822     HAVE_SOLARIS=0)
 823
 824 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 825     [AC_MSG_ERROR([*** Solaris audio support not found])])
 826
 827 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 828 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 829
 830 #### WaveOut audio support (optional) ####
 831
 832 AC_ARG_ENABLE([waveout],
 833     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 834
 835 AS_IF([test "x$enable_waveout" != "xno"],
 836     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 837     HAVE_WAVEOUT=0)
 838
 839 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 840     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 841
 842 AC_SUBST(HAVE_WAVEOUT)
 843 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 844 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 845
 846 #### GLib 2 support (optional) ####
 847
 848 AC_ARG_ENABLE([glib2],
 849     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 850
 851 AS_IF([test "x$enable_glib2" != "xno"],
 852     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 853     HAVE_GLIB20=0)
 854
 855 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 856     [AC_MSG_ERROR([*** GLib 2 support not found])])
 857
 858 AC_SUBST(HAVE_GLIB20)
 859 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 860 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 861
 862 #### GTK3 support (optional) ####
 863
 864 AC_ARG_ENABLE([gtk3],
 865     AS_HELP_STRING([--disable-gtk3],[Disable optional Gtk+ 3 support]))
 866
 867 AS_IF([test "x$enable_gtk3" != "xno"],
 868     [PKG_CHECK_MODULES(GTK30, [ gtk+-3.0 ], HAVE_GTK30=1, HAVE_GTK30=0)],
 869     HAVE_GTK30=0)
 870
 871 AS_IF([test "x$enable_gtk3" = "xyes" && test "x$HAVE_GTK30" = "x0"],
 872     [AC_MSG_ERROR([*** Gtk+ 3 support not found])])
 873
 874 AM_CONDITIONAL([HAVE_GTK30], [test "x$HAVE_GTK30" = x1])
 875 AS_IF([test "x$HAVE_GTK30" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 876
 877 #### GConf support (optional) ####
 878
 879 AC_ARG_ENABLE([gconf],
 880     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 881
 882 AS_IF([test "x$enable_gconf" != "xno"],
 883     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 884     HAVE_GCONF=0)
 885
 886 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 887     [AC_MSG_ERROR([*** GConf support not found])])
 888
 889 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 890
 891 #### Avahi support (optional) ####
 892
 893 AC_ARG_ENABLE([avahi],
 894     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 895
 896 AS_IF([test "x$enable_avahi" != "xno"],
 897     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 898     HAVE_AVAHI=0)
 899
 900 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 901     [AC_MSG_ERROR([*** Avahi support not found])])
 902
 903 AC_SUBST(HAVE_AVAHI)
 904 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 905
 906 #### JACK (optional) ####
 907
 908 AC_ARG_ENABLE([jack],
 909     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 910
 911 AS_IF([test "x$enable_jack" != "xno"],
 912     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 913     HAVE_JACK=0)
 914
 915 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 916     [AC_MSG_ERROR([*** JACK support not found])])
 917
 918 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 919
 920 #### Async DNS support (optional) ####
 921
 922 AC_ARG_ENABLE([asyncns],
 923     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 924
 925 AS_IF([test "x$enable_asyncns" != "xno"],
 926     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 927     HAVE_LIBASYNCNS=0)
 928
 929 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 930     [AC_MSG_ERROR([*** Async DNS support not found])])
 931
 932 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 933 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 934
 935 #### TCP wrappers (optional) ####
 936
 937 AC_ARG_ENABLE([tcpwrap],
 938     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 939
 940 AS_IF([test "x$enable_tcpwrap" != "xno"],
 941     [
 942         ACX_LIBWRAP
 943         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 944     ],
 945     HAVE_TCPWRAP=0)
 946
 947 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 948     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 949
 950 AC_SUBST(LIBWRAP_LIBS)
 951
 952 #### LIRC support (optional) ####
 953
 954 AC_ARG_ENABLE([lirc],
 955     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 956
 957 LIRC_CFLAGS=
 958 LIRC_LIBS=
 959
 960 AS_IF([test "x$enable_lirc" != "xno"],
 961     [
 962         HAVE_LIRC=1
 963         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 964         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 965     ],
 966     HAVE_LIRC=0)
 967
 968 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 969     [AC_MSG_ERROR([*** LIRC support not found])])
 970
 971 AC_SUBST(LIRC_CFLAGS)
 972 AC_SUBST(LIRC_LIBS)
 973 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 974
 975 #### D-Bus support (optional) ####
 976
 977 AC_ARG_ENABLE([dbus],
 978     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 979
 980 AS_IF([test "x$enable_dbus" != "xno"],
 981     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.4.12 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 982     HAVE_DBUS=0)
 983
 984 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 985     [AC_MSG_ERROR([*** D-Bus not available or too old version])])
 986
 987 AS_IF([test "x$HAVE_DBUS" = "x1"],
 988     [
 989         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 990         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 991         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 992         CFLAGS="$save_CFLAGS"
 993         LIBS="$save_LIBS"
 994     ])
 995
 996 AC_SUBST(HAVE_DBUS)
 997 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 998 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
 999
1000 PA_MACHINE_ID="${sysconfdir}/machine-id"
1001 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
1002 PA_MACHINE_ID_FALLBACK="${localstatedir}/lib/dbus/machine-id"
1003 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
1004               [Fallback machine-id file])
1005
1006 #### BlueZ support (optional, dependent on D-Bus and SBC) ####
1007
1008 AC_ARG_ENABLE([bluez4],
1009     AS_HELP_STRING([--disable-bluez4],[Disable optional BlueZ 4 support]))
1010 AC_ARG_ENABLE([bluez5],
1011     AS_HELP_STRING([--disable-bluez5],[Disable optional BlueZ 5 support]))
1012
1013 ## SBC ##
1014 AS_IF([test "x$enable_bluez4" != "xno" || test "x$enable_bluez5" != "xno"],
1015     [PKG_CHECK_MODULES(SBC, [ sbc >= 1.0 ], HAVE_SBC=1, HAVE_SBC=0)],
1016     HAVE_SBC=0)
1017
1018 ## BlueZ 4 ##
1019 AS_IF([test "x$enable_bluez4" != "xno" && test "x$HAVE_DBUS" = "x1" && test "x$HAVE_SBC" = "x1"], HAVE_BLUEZ_4=1)
1020 AS_IF([test "x$enable_bluez4" = "xyes" && test "x$HAVE_BLUEZ_4" != "x1"],
1021     [AC_MSG_ERROR([*** BLUEZ 4 support not found (requires sbc and D-Bus)])])
1022 AC_SUBST(HAVE_BLUEZ_4)
1023 AM_CONDITIONAL([HAVE_BLUEZ_4], [test "x$HAVE_BLUEZ_4" = x1])
1024
1025 ## BlueZ 5 ##
1026 AS_IF([test "x$enable_bluez5" != "xno" && test "x$HAVE_DBUS" = "x1" && test "x$HAVE_SBC" = "x1"], HAVE_BLUEZ_5=1)
1027 AS_IF([test "x$enable_bluez5" = "xyes" && test "x$HAVE_BLUEZ_5" != "x1"],
1028     [AC_MSG_ERROR([*** BLUEZ 5 support not found (requires sbc and D-Bus)])])
1029 AC_SUBST(HAVE_BLUEZ_5)
1030 AM_CONDITIONAL([HAVE_BLUEZ_5], [test "x$HAVE_BLUEZ_5" = x1])
1031
1032 AS_IF([test "x$HAVE_BLUEZ_4" = "x1" || test "x$HAVE_BLUEZ_5" = "x1"], HAVE_BLUEZ=1)
1033 AC_SUBST(HAVE_BLUEZ)
1034 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
1035
1036 ## Bluetooth Headset profiles backend ##
1037
1038 AC_ARG_WITH(bluetooth_headset_backend,
1039     AS_HELP_STRING([--with-bluetooth-headset-backend=<ofono|native|null>],[Backend for Bluetooth headset profiles (native)]))
1040 if test -z "$with_bluetooth_headset_backend" ; then
1041     BLUETOOTH_HEADSET_BACKEND=native
1042 else
1043     BLUETOOTH_HEADSET_BACKEND=$with_bluetooth_headset_backend
1044 fi
1045
1046 AS_IF([test "x$BLUETOOTH_HEADSET_BACKEND" != "xofono" && test "x$BLUETOOTH_HEADSET_BACKEND" != "xnull" && test "x$BLUETOOTH_HEADSET_BACKEND" != "xnative"],
1047     [AC_MSG_ERROR([*** Invalid Bluetooth Headset backend])])
1048
1049 AC_SUBST(BLUETOOTH_HEADSET_BACKEND)
1050
1051 #### UDEV support (optional) ####
1052
1053 AC_ARG_ENABLE([udev],
1054     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
1055
1056 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
1057     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
1058     HAVE_UDEV=0)
1059
1060 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
1061     [AC_MSG_ERROR([*** UDEV support not found])])
1062
1063 AC_SUBST(HAVE_UDEV)
1064 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
1065 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
1066
1067 #### HAL compat support (optional, dependent on UDEV) ####
1068
1069 AC_ARG_ENABLE([hal-compat],
1070     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1071
1072 AS_IF([test "x$enable_hal_compat" != "xno"],
1073     [AS_IF([test "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1074     HAVE_HAL_COMPAT=0)
1075
1076 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1077 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1078
1079 #### IPv6 connection support (optional) ####
1080
1081 AC_ARG_ENABLE([ipv6],
1082     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1083
1084 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1085
1086 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1087
1088 #### OpenSSL support (optional) ####
1089
1090 AC_ARG_ENABLE([openssl],
1091     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1092
1093 AS_IF([test "x$enable_openssl" != "xno"],
1094     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1095     HAVE_OPENSSL=0)
1096
1097 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1098     [AC_MSG_ERROR([*** OpenSSL support not found])])
1099
1100 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1101 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1102
1103 #### FFTW (optional) ####
1104
1105 AC_ARG_WITH([fftw],
1106     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1107
1108 AS_IF([test "x$with_fftw" != "xno"],
1109     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1110     HAVE_FFTW=0)
1111
1112 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1113     [AC_MSG_ERROR([*** FFTW support not found])])
1114
1115 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1116
1117 #### speex (optional) ####
1118
1119 AC_ARG_WITH([speex],
1120     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1121
1122 AS_IF([test "x$with_speex" != "xno"],
1123     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1124     HAVE_SPEEX=0)
1125
1126 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1127     [AC_MSG_ERROR([*** speex support not found])])
1128
1129 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1130 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1131
1132 #### Xen support (optional) ####
1133
1134 AC_ARG_ENABLE([xen],
1135     AS_HELP_STRING([--disable-xen],[Disable optional Xen paravirtualized driver]))
1136
1137 XEN_CFLAGS=
1138 XEN_LIBS=
1139
1140 AS_IF([test "x$enable_xen" != "xno"],
1141     [
1142         HAVE_XEN=1
1143         AC_CHECK_HEADER(xenctrl.h, [], [HAVE_XEN=0])
1144         AC_CHECK_HEADER(xs.h, [], [HAVE_XEN=0])
1145         AC_CHECK_LIB(xenctrl, xc_interface_open, [XEN_LIBS="$XEN_LIBS -lxenctrl"], [HAVE_XEN=0])
1146         AC_CHECK_LIB(xenstore, xs_domain_open, [XEN_LIBS="$XEN_LIBS -lxenstore"], [HAVE_XEN=0])
1147     ],
1148     HAVE_XEN=0)
1149
1150 AS_IF([test "x$enable_xen" = "xyes" && test "x$HAVE_XEN" = "x0"],
1151     [AC_MSG_ERROR([*** Xen development headers or libraries not found])])
1152
1153 AC_SUBST(XEN_CFLAGS)
1154 AC_SUBST(XEN_LIBS)
1155 AM_CONDITIONAL([HAVE_XEN], [test "x$HAVE_XEN" = x1])
1156
1157 #### gcov support (optional) #####
1158
1159 AC_ARG_ENABLE([gcov],
1160     AS_HELP_STRING([--enable-gcov],[Enable optional gcov coverage analysis]))
1161
1162 GCOV_CFLAGS=
1163 GCOV_LIBS=" -lgcov"
1164
1165 AS_IF([test "x$enable_gcov" = "xyes"],
1166     [
1167         HAVE_GCOV=1
1168         GCOV_CFLAGS="$GCOV_CFLAGS -fprofile-arcs -ftest-coverage"
1169         GCOV_LIBS="$GCOV_LIBS -fprofile-arcs"
1170     ],
1171     HAVE_GCOV=0)
1172
1173 AC_SUBST(GCOV_CFLAGS)
1174 AC_SUBST(GCOV_LIBS)
1175 AM_CONDITIONAL([HAVE_GCOV], [test "x$HAVE_GCOV" = x1])
1176
1177 #### ORC (optional) ####
1178
1179 ORC_CHECK([0.4.11])
1180
1181 #### systemd login support (optional) ####
1182
1183 AC_ARG_ENABLE([systemd-login],
1184     AS_HELP_STRING([--disable-systemd-login],[Disable optional systemd login support]))
1185
1186 AS_IF([test "x$enable_systemd_login" != "xno"],
1187     [PKG_CHECK_MODULES(SYSTEMDLOGIN, [ libsystemd-login ], HAVE_SYSTEMD_LOGIN=1, HAVE_SYSTEMD_LOGIN=0)],
1188     HAVE_SYSTEMD_LOGIN=0)
1189
1190 AS_IF([test "x$enable_systemd_login" = "xyes" && test "x$HAVE_SYSTEMD_LOGIN" = "x0"],
1191     [AC_MSG_ERROR([*** Needed systemd login support not found])])
1192
1193 AC_SUBST(HAVE_SYSTEMD_LOGIN)
1194 AM_CONDITIONAL([HAVE_SYSTEMD_LOGIN], [test "x$HAVE_SYSTEMD_LOGIN" = x1])
1195 AS_IF([test "x$HAVE_SYSTEMD_LOGIN" = "x1"], AC_DEFINE([HAVE_SYSTEMD_LOGIN], 1, [Have SYSTEMDLOGIN?]))
1196
1197 #### systemd journal support (optional) ####
1198
1199 AC_ARG_ENABLE([systemd-journal],
1200     AS_HELP_STRING([--disable-systemd-journal],[Disable optional systemd journal support]))
1201
1202 AS_IF([test "x$enable_systemd_journal" != "xno"],
1203     [PKG_CHECK_MODULES(SYSTEMDJOURNAL, [ libsystemd-journal ], HAVE_SYSTEMD_JOURNAL=1, HAVE_SYSTEMD_JOURNAL=0)],
1204     HAVE_SYSTEMD_JOURNAL=0)
1205
1206 AS_IF([test "x$enable_systemd_journal" = "xyes" && test "x$HAVE_SYSTEMD_JOURNAL" = "x0"],
1207     [AC_MSG_ERROR([*** Needed systemd journal support not found])])
1208
1209 AC_SUBST(HAVE_SYSTEMD_JOURNAL)
1210 AM_CONDITIONAL([HAVE_SYSTEMD_JOURNAL], [test "x$HAVE_SYSTEMD_JOURNAL" = x1])
1211 AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" = "x1"], AC_DEFINE([HAVE_SYSTEMD_JOURNAL], 1, [Have SYSTEMDJOURNAL?]))
1212
1213 #### Build and Install man pages ####
1214
1215 AC_ARG_ENABLE([manpages],
1216     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1217
1218 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1219
1220 #### PulseAudio system group & user  #####
1221
1222 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1223 if test -z "$with_system_user" ; then
1224     PA_SYSTEM_USER=pulse
1225 else
1226     PA_SYSTEM_USER=$with_system_user
1227 fi
1228 AC_SUBST(PA_SYSTEM_USER)
1229 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1230
1231 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1232 if test -z "$with_system_group" ; then
1233     PA_SYSTEM_GROUP=pulse
1234 else
1235     PA_SYSTEM_GROUP=$with_system_group
1236 fi
1237 AC_SUBST(PA_SYSTEM_GROUP)
1238 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1239
1240 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1241 if test -z "$with_access_group" ; then
1242     PA_ACCESS_GROUP=pulse-access
1243 else
1244     PA_ACCESS_GROUP=$with_access_group
1245 fi
1246 AC_SUBST(PA_ACCESS_GROUP)
1247 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1248
1249 AC_ARG_ENABLE([per-user-esound-socket],
1250     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1251
1252 if test "x$enable_per_user_esound_socket" != "xno"; then
1253     USE_PER_USER_ESOUND_SOCKET=1
1254     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1255 else
1256     USE_PER_USER_ESOUND_SOCKET=0
1257 fi
1258
1259 #### PulseAudio system runtime dir ####
1260
1261 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1262 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1263 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1264 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1265 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1266 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1267
1268 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1269 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1270
1271 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1272 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1273
1274 AC_SUBST(PA_SOEXT, [.so])
1275 AC_DEFINE(PA_SOEXT, [".so"], [Shared object extension])
1276
1277 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1278 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1279
1280 #### Mac OSX specific stuff #####
1281
1282 AC_ARG_ENABLE(mac-universal,
1283     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1284     enable_mac_universal=$enableval, enable_mac_universal="no")
1285
1286 AC_ARG_WITH(mac-version-min,
1287     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1288     mac_version_min=$withval, mac_version_min="10.5")
1289
1290 AC_ARG_WITH(mac-sysroot,
1291     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1292     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1293
1294 if test "x$os_is_darwin" = "x1" ; then
1295     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1296     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1297
1298     if test "x$enable_mac_universal" = "xyes" ; then
1299         mac_arches="-arch i386 -arch x86_64"
1300         LDFLAGS="$LDFLAGS $mac_arches"
1301         CFLAGS="$CFLAGS $mac_arches"
1302     fi
1303 fi
1304
1305 AC_ARG_ENABLE([webrtc-aec],
1306     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1307
1308 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1309     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1310     [HAVE_WEBRTC=0])
1311
1312 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1313     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1314
1315 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1316
1317 AC_ARG_ENABLE([adrian-aec],
1318     AS_HELP_STRING([--enable-adrian-aec], [Enable Adrian's optional echo canceller]))
1319 AS_IF([test "x$enable_adrian_aec" != "xno"],
1320     [HAVE_ADRIAN_EC=1])
1321 AM_CONDITIONAL([HAVE_ADRIAN_EC], [test "x$HAVE_ADRIAN_EC" = "x1"])
1322
1323
1324
1325 ###################################
1326 #            Output               #
1327 ###################################
1328
1329 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1330
1331 # Check whether to build tests by default (as compile-test) or not
1332 AC_ARG_ENABLE([default-build-tests],
1333     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1334 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1335
1336 AC_ARG_ENABLE([legacy-database-entry-format],
1337         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1338 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1339         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1340 fi
1341
1342 AC_ARG_ENABLE([static-bins],
1343     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1344 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1345
1346 AC_ARG_WITH(
1347         [preopen-mods],
1348         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1349         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1350 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1351 if test "x$PREOPEN_MODS" != "xall" ; then
1352     tmpLIBS=""
1353     for mod in $PREOPEN_MODS; do
1354         tmpLIBS="$tmpLIBS module-$mod.la"
1355     done
1356     PREOPEN_MODS="$tmpLIBS"
1357     AC_SUBST(PREOPEN_MODS)
1358 fi
1359
1360 AC_ARG_WITH(
1361         [module-dir],
1362         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1363         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1364
1365 AC_SUBST(modlibexecdir)
1366 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1367
1368 AC_ARG_WITH(
1369         [udev-rules-dir],
1370         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1371         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1372
1373 AC_SUBST(udevrulesdir)
1374
1375 AC_ARG_WITH(
1376         [zsh-completion-dir],
1377         AS_HELP_STRING([--with-zsh-completion-dir], [Zsh completions directory (defaults to ${datadir}/zsh/site-functions)]),
1378         [zshcompletiondir=$withval], [zshcompletiondir="${datadir}/zsh/site-functions"])
1379
1380 AC_SUBST(zshcompletiondir)
1381
1382 AC_ARG_ENABLE([force-preopen],
1383     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1384
1385 if test "x$enable_force_preopen" = "xyes"; then
1386     FORCE_PREOPEN=yes
1387 else
1388     FORCE_PREOPEN=no
1389 fi
1390
1391 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1392
1393 AC_CONFIG_FILES([
1394 Makefile
1395 src/Makefile
1396 man/Makefile
1397 libpulse.pc
1398 libpulse-simple.pc
1399 libpulse-mainloop-glib.pc
1400 doxygen/Makefile
1401 doxygen/doxygen.conf
1402 src/pulse/version.h
1403 po/Makefile.in
1404 man/pulseaudio.1.xml
1405 man/esdcompat.1.xml
1406 man/pax11publish.1.xml
1407 man/paplay.1.xml
1408 man/pacat.1.xml
1409 man/pacmd.1.xml
1410 man/pactl.1.xml
1411 man/pasuspender.1.xml
1412 man/padsp.1.xml
1413 man/pulse-daemon.conf.5.xml
1414 man/pulse-client.conf.5.xml
1415 man/default.pa.5.xml
1416 man/pulse-cli-syntax.5.xml
1417 man/start-pulseaudio-x11.1.xml
1418 ])
1419
1420 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1421 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1422 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1423 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1424     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1425 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1426     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1427 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1428     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1429
1430 # CMake related ProjectConfig files
1431 PA_LIBDIR="$libdir"
1432 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1433 PA_INCDIR="$includedir"
1434 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1435
1436 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1437     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1438 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1439
1440 AC_OUTPUT
1441
1442 # ==========================================================================
1443
1444 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1445 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1446 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1447 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1448 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1449 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1450 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1451 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1452 AS_IF([test "x$HAVE_GTK30" = "x1"], ENABLE_GTK30=yes, ENABLE_GTK30=no)
1453 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1454 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1455 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1456 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1457 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1458 AS_IF([test "x$HAVE_XEN" = "x1"], ENABLE_XEN=yes, ENABLE_XEN=no)
1459 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1460 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1461 AS_IF([test "x$HAVE_SYSTEMD_LOGIN" = "x1"], ENABLE_SYSTEMD_LOGIN=yes, ENABLE_SYSTEMD_LOGIN=no)
1462 AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" = "x1"], ENABLE_SYSTEMD_JOURNAL=yes, ENABLE_SYSTEMD_JOURNAL=no)
1463 AS_IF([test "x$HAVE_BLUEZ_4" = "x1"], ENABLE_BLUEZ_4=yes, ENABLE_BLUEZ_4=no)
1464 AS_IF([test "x$HAVE_BLUEZ_5" = "x1"], ENABLE_BLUEZ_5=yes, ENABLE_BLUEZ_5=no)
1465 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1466 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1467 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1468 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1469 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1470 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1471 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1472 AS_IF([test "x$HAVE_ADRIAN_EC" = "x1"], ENABLE_ADRIAN_EC=yes, ENABLE_ADRIAN_EC=no)
1473 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1474 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1475 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1476 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1477 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1478 AS_IF([test "x$HAVE_ESOUND" = "x1"], ENABLE_ESOUND=yes, ENABLE_ESOUND=no)
1479 AS_IF([test "x$HAVE_ESOUND" = "x1" -a "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1480 AS_IF([test "x$HAVE_GCOV" = "x1"], ENABLE_GCOV=yes, ENABLE_GCOV=no)
1481 AS_IF([test "x$HAVE_LIBCHECK" = "x1"], ENABLE_TESTS=yes, ENABLE_TESTS=no)
1482 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1483
1484 echo "
1485  ---{ $PACKAGE_NAME $VERSION }---
1486
1487     prefix:                        ${prefix}
1488     sysconfdir:                    ${sysconfdir}
1489     localstatedir:                 ${localstatedir}
1490     modlibexecdir:                 ${modlibexecdir}
1491     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1492     System State Path:             ${PA_SYSTEM_STATE_PATH}
1493     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1494     Zsh completions directory:     ${zshcompletiondir}
1495     Compiler:                      ${CC}
1496     CFLAGS:                        ${CFLAGS}
1497     CPPFLAGS:                      ${CPPFLAGS}
1498     LIBS:                          ${LIBS}
1499
1500     Enable X11:                    ${ENABLE_X11}
1501     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1502     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1503     Enable EsounD:                 ${ENABLE_ESOUND}
1504     Enable Alsa:                   ${ENABLE_ALSA}
1505     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1506     Enable Solaris:                ${ENABLE_SOLARIS}
1507     Enable WaveOut:                ${ENABLE_WAVEOUT}
1508     Enable GLib 2.0:               ${ENABLE_GLIB20}
1509     Enable Gtk+ 3.0:               ${ENABLE_GTK30}
1510     Enable GConf:                  ${ENABLE_GCONF}
1511     Enable Avahi:                  ${ENABLE_AVAHI}
1512     Enable Jack:                   ${ENABLE_JACK}
1513     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1514     Enable LIRC:                   ${ENABLE_LIRC}
1515     Enable Xen PV driver:          ${ENABLE_XEN}
1516     Enable D-Bus:                  ${ENABLE_DBUS}
1517       Enable BlueZ 4:              ${ENABLE_BLUEZ_4}
1518       Enable BlueZ 5:              ${ENABLE_BLUEZ_5}
1519         headset backend:           ${BLUETOOTH_HEADSET_BACKEND}
1520     Enable udev:                   ${ENABLE_UDEV}
1521       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1522     Enable systemd login:          ${ENABLE_SYSTEMD_LOGIN}
1523     Enable systemd journal:        ${ENABLE_SYSTEMD_JOURNAL}
1524     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1525     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1526     Enable IPv6:                   ${ENABLE_IPV6}
1527     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1528     Enable fftw:                   ${ENABLE_FFTW}
1529     Enable orc:                    ${ENABLE_ORC}
1530     Enable Adrian echo canceller:  ${ENABLE_ADRIAN_EC}
1531     Enable speex (resampler, AEC): ${ENABLE_SPEEX}
1532     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1533     Enable gcov coverage:          ${ENABLE_GCOV}
1534     Enable unit tests:             ${ENABLE_TESTS}
1535     Database
1536       tdb:                         ${ENABLE_TDB}
1537       gdbm:                        ${ENABLE_GDBM}
1538       simple database:             ${ENABLE_SIMPLEDB}
1539
1540     System User:                   ${PA_SYSTEM_USER}
1541     System Group:                  ${PA_SYSTEM_GROUP}
1542     Access Group:                  ${PA_ACCESS_GROUP}
1543     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1544     Force preopen:                 ${FORCE_PREOPEN}
1545     Preopened modules:             ${PREOPEN_MODS}
1546
1547     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1548 "
1549
1550 if test "${ENABLE_SPEEX}" = "no" && test "${ENABLE_WEBRTC}" = "no" && test "${ENABLE_ADRIAN_EC}" = "no" ; then
1551 AC_MSG_ERROR([At least one echo canceller implementation must be available.])
1552 fi
1553
1554 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1555    echo "
1556 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1557 You do not have D-Bus support enabled. It is strongly recommended
1558 that you enable D-Bus support if your platform supports it.
1559 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1560 to the Device Reservation Protocol to speak to JACK, Bluetooth
1561 support and even a native control protocol for communicating and
1562 controling the PulseAudio daemon itself.
1563 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1564 "
1565 fi
1566
1567 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1568    echo "
1569 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1570 You do not have udev support enabled. It is strongly recommended
1571 that you enable udev support if your platform supports it as it is
1572 the primary method used to detect hardware audio devices (on Linux)
1573 and is thus a critical part of PulseAudio on that platform.
1574 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1575 "
1576 fi
1577
1578 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1579    echo "
1580 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1581 You do not have speex support enabled. It is strongly recommended
1582 that you enable speex support if your platform supports it as it is
1583 the primary method used for audio resampling and is thus a critical
1584 part of PulseAudio on that platform.
1585 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1586 "
1587 fi