configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 if test "$glib_native_win32" = "yes"; then
 516   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 517     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 518   fi
 519   if test x$enable_static = xyes; then
 520     glib_win32_static_compilation=yes
 521     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 522 #define GOBJECT_STATIC_COMPILATION 1"
 523     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 524   fi
 525 fi
 526 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 527
 528 dnl
 529 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 530 dnl
 531 if test $cross_compiling != yes ; then
 532     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 533     glib_save_LIBS=$LIBS
 534     LIBS="$LIBS -lm"
 535     AC_TRY_RUN([#include <math.h>
 536                  int main (void) { return (log(1) != log(1.)); }],
 537          AC_MSG_RESULT(none needed),
 538          glib_save_CFLAGS=$CFLAGS
 539          CFLAGS="$CFLAGS -std1"
 540          AC_TRY_RUN([#include <math.h>
 541                      int main (void) { return (log(1) != log(1.)); }],
 542              AC_MSG_RESULT(-std1),
 543              AC_MSG_RESULT()
 544              CFLAGS=$glib_save_CFLAGS
 545              AC_MSG_WARN(
 546                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 547          )
 548     )
 549     LIBS=$glib_save_LIBS
 550 fi
 551
 552 dnl NeXTStep cc seems to need this
 553 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 554 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 555   AC_MSG_RESULT(none needed),
 556   glib_save_CFLAGS=$CFLAGS
 557   CFLAGS="$CFLAGS -posix"
 558   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 559     AC_MSG_RESULT(-posix),
 560     AC_MSG_RESULT()
 561     CFLAGS=$glib_save_CFLAGS
 562     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 563
 564 # Checks for header files.
 565 AC_HEADER_STDC
 566
 567 # Checks for library functions.
 568 AC_FUNC_VPRINTF
 569 AC_FUNC_ALLOCA
 570 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 571 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 572
 573 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 574 dnl be automatically defined, which we don't want to do
 575 dnl until we have checked this function is actually usable
 576 AC_CHECK_FUNC([qsort_r])
 577
 578 # BSD has a qsort_r with wrong argument order
 579 if test x$ac_cv_func_qsort_r = xyes ; then
 580   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 581   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 582   #define _GNU_SOURCE
 583   #include <stdlib.h>
 584
 585   static int
 586   cmp (const void *a, const void *b, void *c)
 587   {
 588     const int *ia = a;
 589     const int *ib = b;
 590
 591     if (*ia < *ib)
 592       return -1;
 593     else if (*ia > *ib)
 594       return 1;
 595     else
 596       return 0;
 597   }
 598
 599   int
 600   main (int argc, char **argv)
 601   {
 602     int arr[3] = { 1, 2, 0 };
 603     int d = 3;
 604
 605     qsort_r (arr, 3, sizeof (int), cmp, &d);
 606
 607     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 608       return 0;
 609     else
 610       return 1;
 611   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 612 fi
 613
 614 if test x$glib_cv_have_qsort_r = xyes ; then
 615   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 616 fi
 617
 618 AC_CHECK_SIZEOF(char)
 619 AC_CHECK_SIZEOF(short)
 620 AC_CHECK_SIZEOF(long)
 621 AC_CHECK_SIZEOF(int)
 622 AC_CHECK_SIZEOF(void *)
 623 AC_CHECK_SIZEOF(long long)
 624 AC_CHECK_SIZEOF(__int64)
 625
 626 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 627   :
 628 else
 629   AC_MSG_ERROR([
 630 *** GLib requires a 64 bit type. You might want to consider
 631 *** using the GNU C compiler.
 632 ])
 633 fi
 634
 635 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 636         # long long is a 64 bit integer.
 637         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 638         AC_CACHE_VAL(glib_cv_long_long_format,[
 639                 for format in ll q I64; do
 640                   AC_TRY_RUN([#include <stdio.h>
 641                         int main()
 642                         {
 643                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 644                           char buffer[1000];
 645                           sprintf (buffer, "%${format}u", a);
 646                           sscanf (buffer, "%${format}u", &b);
 647                           exit (b!=a);
 648                         }
 649                         ],
 650                         [glib_cv_long_long_format=${format}
 651                         break],
 652                         [],[:])
 653                 done])
 654         if test -n "$glib_cv_long_long_format"; then
 655           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 656           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 657           if test x"$glib_cv_long_long_format" = xI64; then
 658             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 659           fi
 660         else
 661           AC_MSG_RESULT(none)
 662         fi
 663 elif test x$ac_cv_sizeof___int64 = x8; then
 664         # __int64 is a 64 bit integer.
 665         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 666         # We know this is MSVCRT.DLL, and what the formats are
 667         glib_cv_long_long_format=I64
 668         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 669         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 670         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 671 fi
 672
 673 dnl long doubles were not used, and a portability problem
 674 dnl AC_C_LONG_DOUBLE
 675 AC_C_CONST
 676
 677 dnl ok, here we try to check whether the systems prototypes for
 678 dnl malloc and friends actually match the prototypes provided
 679 dnl by gmem.h (keep in sync). i currently only know how to check
 680 dnl this reliably with gcc (-Werror), improvements for other
 681 dnl compilers are apprechiated.
 682 SANE_MALLOC_PROTOS=no
 683 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 684 glib_save_CFLAGS=$CFLAGS
 685 if test "x$GCC" = "xyes"; then
 686   CFLAGS="$CFLAGS -Werror"
 687   AC_TRY_COMPILE([#include <stdlib.h>], [
 688     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 689     void* (*my_malloc_p)  (size_t)         = malloc;
 690     void  (*my_free_p)    (void*)          = free;
 691     void* (*my_realloc_p) (void*, size_t)  = realloc;
 692     my_calloc_p = 0;
 693     my_malloc_p = 0;
 694     my_free_p = 0;
 695     my_realloc_p = 0;
 696   ],
 697     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 698       [Define if you have correct malloc prototypes])
 699     SANE_MALLOC_PROTOS=yes)
 700 fi
 701 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 702 CFLAGS=$glib_save_CFLAGS
 703
 704 dnl
 705 dnl check in which direction the stack grows
 706 dnl
 707 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 708         AC_TRY_RUN([
 709         volatile int *a = 0, *b = 0;
 710         void foo (void);
 711         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 712         void foo (void) { volatile int x = 5; b = &x; }
 713         ],
 714         glib_cv_stack_grows=no
 715         ,
 716         glib_cv_stack_grows=yes
 717         ,)
 718 ])
 719
 720 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 721 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 722 dnl actually supported.
 723 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline=yes
 729         ,
 730         glib_cv_has__inline=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline in
 734 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 735 esac
 736 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         __inline__ int foo () { return 0; }
 739         int main () { return foo (); }
 740         ]])],
 741         glib_cv_has__inline__=yes
 742         ,
 743         glib_cv_has__inline__=no
 744         ,)
 745 ])
 746 case x$glib_cv_has__inline__ in
 747 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 748 esac
 749 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 750         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 751         #undef inline
 752         inline int foo () { return 0; }
 753         int main () { return foo (); }
 754         ]])],
 755         glib_cv_hasinline=yes
 756         ,
 757         glib_cv_hasinline=no
 758         ,)
 759 ])
 760 case x$glib_cv_hasinline in
 761 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 762 esac
 763
 764 # if we can use inline functions in headers
 765 AC_MSG_CHECKING(if inline functions in headers work)
 766 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 767 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 768 #  undef inline
 769 #  define inline __inline__
 770 #elif !defined (G_HAVE_INLINE)
 771 #  undef inline
 772 #  if defined (G_HAVE___INLINE__)
 773 #    define inline __inline__
 774 #  elif defined (G_HAVE___INLINE)
 775 #    define inline __inline
 776 #  endif
 777 #endif
 778
 779 int glib_test_func2 (int);
 780
 781 static inline int
 782 glib_test_func1 (void) {
 783   return glib_test_func2 (1);
 784 }
 785
 786 int
 787 main (void) {
 788   int i = 1;
 789 }]])],[g_can_inline=yes],[g_can_inline=no])
 790 AC_MSG_RESULT($g_can_inline)
 791
 792 dnl *** check for working do while(0) macros ***
 793 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 794         AC_TRY_COMPILE([],[
 795         #define STMT_START do
 796         #define STMT_END while(0)
 797         #define STMT_TEST STMT_START { i = 0; } STMT_END
 798         int main(void) { int i = 1; STMT_TEST; return i; }],
 799         [g_cv_support_dowhile_macros=yes],
 800         [g_cv_support_dowhile_macros=no],
 801         [g_cv_support_dowhile_macros=yes])
 802 ])
 803 if test x$g_cv_support_dowhile_macros = xyes; then
 804   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 805 fi
 806
 807 # check for flavours of varargs macros
 808 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 809 AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 814 AC_MSG_RESULT($g_have_iso_c_varargs)
 815
 816 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 817 if test "$CXX" = ""; then
 818 dnl No C++ compiler
 819   g_have_iso_cxx_varargs=no
 820 else
 821   AC_LANG_CPLUSPLUS
 822   AC_TRY_COMPILE([],[
 823 int a(int p1, int p2, int p3);
 824 #define call_a(...) a(1,__VA_ARGS__)
 825 call_a(2,3);
 826 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 827   AC_LANG_C
 828 fi
 829 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 830
 831 AC_MSG_CHECKING(for GNUC varargs macros)
 832 AC_TRY_COMPILE([],[
 833 int a(int p1, int p2, int p3);
 834 #define call_a(params...) a(1,params)
 835 call_a(2,3);
 836 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 837 AC_MSG_RESULT($g_have_gnuc_varargs)
 838
 839 # check for GNUC visibility support
 840 AC_MSG_CHECKING(for GNUC visibility attribute)
 841 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 842 void
 843 __attribute__ ((visibility ("hidden")))
 844      f_hidden (void)
 845 {
 846 }
 847 void
 848 __attribute__ ((visibility ("internal")))
 849      f_internal (void)
 850 {
 851 }
 852 void
 853 __attribute__ ((visibility ("protected")))
 854      f_protected (void)
 855 {
 856 }
 857 void
 858 __attribute__ ((visibility ("default")))
 859      f_default (void)
 860 {
 861 }
 862 int main (int argc, char **argv)
 863 {
 864         f_hidden();
 865         f_internal();
 866         f_protected();
 867         f_default();
 868         return 0;
 869 }
 870 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 871 AC_MSG_RESULT($g_have_gnuc_visibility)
 872 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 873
 874 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 875 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 876 #else
 877 # include "error: this is not Sun Studio."
 878 #endif
 879 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 880 AC_MSG_RESULT($g_have_sunstudio_visibility)
 881 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 882
 883 # check for bytesex stuff
 884 AC_C_BIGENDIAN
 885 if test x$ac_cv_c_bigendian = xuniversal ; then
 886 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 887 #else
 888 #error Not a big endian.
 889 #endif],
 890     ac_cv_c_bigendian=yes
 891     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 892 #else
 893 #error Not a little endian.
 894 #endif],
 895     ac_cv_c_bigendian=no
 896     ,AC_MSG_WARN([Could not determine endianness.])))
 897 fi
 898
 899
 900 # check for header files
 901 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 902 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 903 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 904 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 905 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 906 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 907 AC_CHECK_HEADERS([linux/magic.h])
 908 AC_CHECK_HEADERS([sys/prctl.h])
 909
 910 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 911 [#if HAVE_SYS_PARAM_H
 912  #include <sys/param.h>
 913  #endif
 914 ])
 915
 916 AC_CHECK_HEADERS([xlocale.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 935 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 936
 937 # Checks for libcharset
 938 AM_LANGINFO_CODESET
 939 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 940 AC_CHECK_FUNCS(setlocale)
 941
 942 # check additional type sizes
 943 AC_CHECK_SIZEOF(size_t)
 944
 945 dnl Try to figure out whether gsize, gssize should be long or int
 946 AC_MSG_CHECKING([for the appropriate definition for size_t])
 947
 948 case $ac_cv_sizeof_size_t in
 949   $ac_cv_sizeof_short)
 950       glib_size_type=short
 951       ;;
 952   $ac_cv_sizeof_int)
 953       glib_size_type=int
 954       ;;
 955   $ac_cv_sizeof_long)
 956       glib_size_type=long
 957       ;;
 958   $ac_cv_sizeof_long_long)
 959       glib_size_type='long long'
 960       ;;
 961   $ac_cv_sizeof__int64)
 962       glib_size_type='__int64'
 963       ;;
 964   *)  AC_MSG_ERROR([No type matching size_t in size])
 965       ;;
 966 esac
 967
 968 dnl If int/long are the same size, we see which one produces
 969 dnl warnings when used in the location as size_t. (This matters
 970 dnl on AIX with xlc)
 971 dnl
 972 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 973    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 974   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 975 #if defined(_AIX) && !defined(__GNUC__)
 976 #pragma options langlvl=stdc89
 977 #endif
 978 #include <stddef.h>
 979 int main ()
 980 {
 981   size_t s = 1;
 982   unsigned int *size_int = &s;
 983   return (int)*size_int;
 984 }
 985     ]])],glib_size_type=int,
 986       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 987 #if defined(_AIX) && !defined(__GNUC__)
 988 #pragma options langlvl=stdc89
 989 #endif
 990 #include <stddef.h>
 991 int main ()
 992 {
 993    size_t s = 1;
 994    unsigned long *size_long = &s;
 995    return (int)*size_long;
 996 }
 997         ]])],glib_size_type=long)])
 998 fi
 999
1000 AC_MSG_RESULT(unsigned $glib_size_type)
1001
1002 # Check for some functions
1003 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1004 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1005 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1006 # Check for high-resolution sleep functions
1007 AC_CHECK_FUNCS(splice)
1008 AC_CHECK_FUNCS(prlimit)
1009
1010 # To avoid finding a compatibility unusable statfs, which typically
1011 # successfully compiles, but warns to use the newer statvfs interface:
1012 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1013 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1014
1015 AC_MSG_CHECKING([whether to use statfs or statvfs])
1016 # Some systems have both statfs and statvfs, pick the most "native" for these
1017 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1018    [
1019    # on solaris and irix, statfs doesn't even have the f_bavail field
1020    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1021       [ac_cv_func_statfs=no],
1022    # else, at least on linux, statfs is the actual syscall
1023       [ac_cv_func_statvfs=no])
1024    ])
1025
1026 AS_IF([test x$ac_cv_func_statfs = xyes],
1027       [
1028          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1029          AC_MSG_RESULT([statfs])
1030       ],
1031       [test x$ac_cv_func_statvfs = xyes],
1032       [
1033          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1034          AC_MSG_RESULT([statvfs])
1035       ],
1036       [  AC_MSG_RESULT([neither])])
1037
1038 AC_CHECK_HEADERS(crt_externs.h)
1039 AC_CHECK_FUNCS(_NSGetEnviron)
1040
1041 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1042
1043 AC_FUNC_VSNPRINTF_C99
1044 AC_FUNC_PRINTF_UNIX98
1045
1046 # Internet address families
1047 if test $glib_native_win32 = yes; then
1048   glib_inet_includes=["
1049 #include <winsock2.h>
1050   "]
1051 else
1052   glib_inet_includes=["
1053 #include <sys/types.h>
1054 #include <sys/socket.h>
1055   "]
1056 fi
1057
1058 glib_failed=false
1059 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1061 # winsock defines this even though it doesn't support it
1062 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1063 if $glib_failed ; then
1064   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1065 fi
1066
1067 glib_failed=false
1068 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1069 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1070 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1071 if $glib_failed ; then
1072   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1073 fi
1074
1075 AC_CHECK_FUNCS(getprotobyname_r endservent)
1076 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1077
1078 if test $glib_native_win32 = no; then
1079   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1080   NETWORK_LIBS=""
1081   AC_MSG_CHECKING([for res_query])
1082   AC_TRY_LINK([#include <sys/types.h>
1083                #include <netinet/in.h>
1084                #include <arpa/nameser.h>
1085                #include <resolv.h>
1086               ],[
1087                res_query("test", 0, 0, (void *)0, 0);
1088               ],[AC_MSG_RESULT([yes])],
1089               [save_libs="$LIBS"
1090                LIBS="-lresolv $LIBS"
1091                AC_TRY_LINK([#include <sys/types.h>
1092                             #include <netinet/in.h>
1093                             #include <arpa/nameser.h>
1094                             #include <resolv.h>
1095                            ],[
1096                             res_query("test", 0, 0, (void *)0, 0);
1097                            ],[AC_MSG_RESULT([in -lresolv])
1098                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1099                            [LIBS="-lbind $save_libs"
1100                             AC_TRY_LINK([#include <resolv.h>],
1101                                         [res_query("test", 0, 0, (void *)0, 0);],
1102                                         [AC_MSG_RESULT([in -lbind])
1103                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1104                                         [AC_MSG_ERROR(not found)])])
1105                LIBS="$save_libs"])
1106   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1107                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1108                                         [AC_MSG_ERROR(Could not find socket())]))
1109 fi
1110 AC_SUBST(NETWORK_LIBS)
1111
1112 case $host in
1113   *-*-solaris* )
1114      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1115      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1116      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1117      ;;
1118 esac
1119
1120 dnl
1121 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1122 dnl
1123 if test "$ac_cv_func_statfs" = yes ; then
1124   AC_MSG_CHECKING([number of arguments to statfs()])
1125   AC_TRY_COMPILE([#include <unistd.h>
1126   #ifdef HAVE_SYS_PARAM_H
1127   #include <sys/param.h>
1128   #endif
1129   #ifdef HAVE_SYS_VFS_H
1130   #include <sys/vfs.h>
1131   #endif
1132   #ifdef HAVE_SYS_MOUNT_H
1133   #include <sys/mount.h>
1134   #endif
1135   #ifdef HAVE_SYS_STATFS_H
1136   #include <sys/statfs.h>
1137   #endif], [struct statfs st;
1138   statfs(NULL, &st);],[
1139     AC_MSG_RESULT([2])
1140     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1141     AC_TRY_COMPILE([#include <unistd.h>
1142   #ifdef HAVE_SYS_PARAM_H
1143   #include <sys/param.h>
1144   #endif
1145   #ifdef HAVE_SYS_VFS_H
1146   #include <sys/vfs.h>
1147   #endif
1148   #ifdef HAVE_SYS_MOUNT_H
1149   #include <sys/mount.h>
1150   #endif
1151   #ifdef HAVE_SYS_STATFS_H
1152   #include <sys/statfs.h>
1153   #endif], [struct statfs st;
1154   statfs(NULL, &st, sizeof (st), 0);],[
1155       AC_MSG_RESULT([4])
1156       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1157       AC_MSG_RESULT(unknown)
1158       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1159 fi
1160
1161 #
1162 # Check whether to use an included printf
1163 #
1164
1165 AC_ARG_ENABLE(included-printf,
1166               [AC_HELP_STRING([--enable-included-printf],
1167                               [use included printf [default=auto]])],
1168               enable_included_printf="$enableval")
1169
1170 need_included_printf=no
1171 if test "x$enable_included_printf" = "xyes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1175   need_included_printf=yes
1176 fi
1177 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1178   need_included_printf=yes
1179 fi
1180 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1181    test -z "$glib_cv_long_long_format" ; then
1182   need_included_printf=yes
1183 fi
1184
1185 if test "x$enable_included_printf" = "xno" &&
1186    test "x$need_included_printf" = "xyes" ; then
1187   AC_MSG_ERROR([
1188 *** Your C library's printf doesn't appear to have the features that
1189 *** GLib needs, but you specified --enable-included-printf=no.])
1190 fi
1191
1192 enable_included_printf=$need_included_printf
1193
1194 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1195 if test "$enable_included_printf" != "yes" ; then
1196   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1197 else
1198   if test -z "$glib_cv_long_long_format" ; then
1199     glib_cv_long_long_format="ll"
1200   fi
1201   AC_DEFINE(HAVE_VASPRINTF,1)
1202 fi
1203
1204 # Checks needed for gnulib vasnprintf
1205 bh_C_SIGNED
1206 jm_AC_TYPE_LONG_LONG
1207 gt_TYPE_LONGDOUBLE
1208 gt_TYPE_WCHAR_T
1209 gt_TYPE_WINT_T
1210 AC_TYPE_SIZE_T
1211 AC_CHECK_TYPES(ptrdiff_t)
1212 jm_AC_TYPE_INTMAX_T
1213 AC_CHECK_FUNCS([snprintf wcslen])
1214 AC_FUNC_SNPRINTF_C99
1215
1216 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1217 # The check is borrowed from the PERL Configure script.
1218 if test "$ac_cv_func_memmove" != "yes"; then
1219   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1220     glib_cv_working_bcopy,[AC_TRY_RUN([
1221       int main() {
1222         char buf[128], abc[128], *b;
1223         int len, off, align;
1224         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1225         for (align = 7; align >= 0; align--) {
1226           for (len = 36; len; len--) {
1227             b = buf+align; bcopy(abc, b, len);
1228             for (off = 1; off <= len; off++) {
1229               bcopy(b, b+off, len); bcopy(b+off, b, len);
1230                 if (bcmp(b, abc, len)) return(1);
1231             }
1232           }
1233         }
1234         return(0);
1235       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1236
1237   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1238   if test "$glib_cv_working_bcopy" = "yes"; then
1239     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1240   fi
1241 fi
1242
1243 # Check if <sys/select.h> needs to be included for fd_set
1244 AC_MSG_CHECKING([for fd_set])
1245 AC_TRY_COMPILE([#include <sys/types.h>],
1246         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1247 if test "$gtk_ok" = "yes"; then
1248     AC_MSG_RESULT([yes, found in sys/types.h])
1249 else
1250     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1251     if test "$gtk_ok" = "yes"; then
1252         # *** FIXME: give it a different name
1253         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1254         AC_MSG_RESULT([yes, found in sys/select.h])
1255     else
1256         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1257         AC_MSG_RESULT(no)
1258     fi
1259 fi
1260
1261 dnl *** check for sane realloc() ***
1262 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1263         AC_TRY_RUN([#include <stdlib.h>
1264         int main() {
1265           return realloc (0, sizeof (int)) == 0;
1266         }],
1267         [glib_cv_sane_realloc=yes],
1268         [glib_cv_sane_realloc=no],
1269         [glib_cv_sane_realloc=yes])
1270 ])
1271 if test x$glib_cv_sane_realloc = xyes; then
1272   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1273 fi
1274
1275 dnl Check for nl_langinfo and CODESET
1276 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1277         AC_TRY_COMPILE([#include <langinfo.h>],
1278                 [char *codeset = nl_langinfo (CODESET);],
1279                 [glib_cv_langinfo_codeset=yes],
1280                 [glib_cv_langinfo_codeset=no])])
1281 if test x$glib_cv_langinfo_codeset = xyes; then
1282   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1283 fi
1284
1285 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1286 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1287         AC_TRY_COMPILE([#include <langinfo.h>],
1288                 [char *str;
1289                  str = nl_langinfo (PM_STR);
1290                  str = nl_langinfo (D_T_FMT);
1291                  str = nl_langinfo (D_FMT);
1292                  str = nl_langinfo (T_FMT);
1293                  str = nl_langinfo (T_FMT_AMPM);
1294                  str = nl_langinfo (MON_1);
1295                  str = nl_langinfo (ABMON_12);
1296                  str = nl_langinfo (DAY_1);
1297                  str = nl_langinfo (ABDAY_7);],
1298                 [glib_cv_langinfo_time=yes],
1299                 [glib_cv_langinfo_time=no])])
1300 if test x$glib_cv_langinfo_time = xyes; then
1301   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1302 fi
1303
1304 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1305 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1306         AC_TRY_COMPILE([#include <langinfo.h>],
1307                 [char *str;
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1318                 [glib_cv_langinfo_outdigit=yes],
1319                 [glib_cv_langinfo_outdigit=no])])
1320 if test x$glib_cv_langinfo_outdigit = xyes; then
1321   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1322 fi
1323
1324 dnl ****************************************
1325 dnl *** posix_memalign                   ***
1326 dnl ****************************************
1327 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1328 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1329     glib_cv_compliant_posix_memalign=0
1330     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1331         AC_TRY_RUN([
1332                 #define _XOPEN_SOURCE 600
1333                 #include <stdlib.h> /* posix_memalign() should be defined here */
1334                 /* some systems break if #include <malloc.h> used */
1335                 static void test_memalign (size_t boundary, size_t size) {
1336                     void *mem = 0;
1337                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1338                         exit (1);
1339                     else
1340                       free (mem);
1341                 }
1342                 int main() {
1343                     test_memalign (  128,   128 - 2 * sizeof (void*));
1344                     test_memalign (  256,   256 - 2 * sizeof (void*));
1345                     test_memalign (  512,   512 - 2 * sizeof (void*));
1346                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1347                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1348                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1349                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1350                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1351                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1352                     exit (0); /* success */
1353                 }
1354                 ],
1355             [glib_cv_compliant_posix_memalign=1], [], [:])
1356       :
1357     fi
1358     ])
1359 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1360     AC_MSG_RESULT(yes)
1361     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1362 else
1363     AC_MSG_RESULT(no)
1364 fi
1365
1366
1367 dnl ****************************************
1368 dnl *** strlcpy/strlcat                  ***
1369 dnl ****************************************
1370 # Check for strlcpy
1371 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1372 AC_TRY_RUN([#include <stdlib.h>
1373 #include <string.h>
1374 int main() {
1375   char p[10];
1376   (void) strlcpy (p, "hi", 10);
1377   if (strlcat (p, "bye", 0) != 3)
1378     return 1;
1379   return 0;
1380 }], glib_cv_have_strlcpy=yes,
1381     glib_cv_have_strlcpy=no,
1382     glib_cv_have_strlcpy=no)])
1383 if test "$glib_cv_have_strlcpy" = "yes"; then
1384     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1385 fi
1386
1387
1388 dnl **********************
1389 dnl *** va_copy checks ***
1390 dnl **********************
1391 dnl we currently check for all three va_copy possibilities, so we get
1392 dnl all results in config.log for bug reports.
1393 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1394         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1395 #include <stdlib.h>
1396         void f (int i, ...) {
1397         va_list args1, args2;
1398         va_start (args1, i);
1399         va_copy (args2, args1);
1400         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1401           exit (1);
1402         va_end (args1); va_end (args2);
1403         }
1404         int main() {
1405           f (0, 42);
1406           return 0;
1407         }]])],
1408         [glib_cv_va_copy=yes],
1409         [glib_cv_va_copy=no])
1410 ])
1411 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1412         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1413 #include <stdlib.h>
1414         void f (int i, ...) {
1415         va_list args1, args2;
1416         va_start (args1, i);
1417         __va_copy (args2, args1);
1418         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1419           exit (1);
1420         va_end (args1); va_end (args2);
1421         }
1422         int main() {
1423           f (0, 42);
1424           return 0;
1425         }]])],
1426         [glib_cv___va_copy=yes],
1427         [glib_cv___va_copy=no])
1428 ])
1429
1430 if test "x$glib_cv_va_copy" = "xyes"; then
1431   g_va_copy_func=va_copy
1432 else if test "x$glib_cv___va_copy" = "xyes"; then
1433   g_va_copy_func=__va_copy
1434 fi
1435 fi
1436
1437 if test -n "$g_va_copy_func"; then
1438   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1439 fi
1440
1441 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1442         AC_TRY_RUN([#include <stdarg.h>
1443 #include <stdlib.h>
1444         void f (int i, ...) {
1445         va_list args1, args2;
1446         va_start (args1, i);
1447         args2 = args1;
1448         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1449           exit (1);
1450         va_end (args1); va_end (args2);
1451         }
1452         int main() {
1453           f (0, 42);
1454           return 0;
1455         }],
1456         [glib_cv_va_val_copy=yes],
1457         [glib_cv_va_val_copy=no],
1458         [glib_cv_va_val_copy=yes])
1459 ])
1460
1461 if test "x$glib_cv_va_val_copy" = "xno"; then
1462   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1463 fi
1464
1465 dnl ***********************
1466 dnl *** g_module checks ***
1467 dnl ***********************
1468 G_MODULE_LIBS=
1469 G_MODULE_LIBS_EXTRA=
1470 G_MODULE_PLUGIN_LIBS=
1471 if test x"$glib_native_win32" = xyes; then
1472   dnl No use for this on Win32
1473   G_MODULE_LDFLAGS=
1474 else
1475   export SED
1476   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1477 fi
1478 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1479 G_MODULE_NEED_USCORE=0
1480 G_MODULE_BROKEN_RTLD_GLOBAL=0
1481 G_MODULE_HAVE_DLERROR=0
1482 dnl *** force native WIN32 shared lib loader
1483 if test -z "$G_MODULE_IMPL"; then
1484   case "$host" in
1485   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1486   esac
1487 fi
1488 dnl *** force native AIX library loader
1489 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1490 if test -z "$G_MODULE_IMPL"; then
1491   case "$host" in
1492   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1493   esac
1494 fi
1495 dnl *** dlopen() and dlsym() in system libraries
1496 if test -z "$G_MODULE_IMPL"; then
1497         AC_CHECK_FUNC(dlopen,
1498                       [AC_CHECK_FUNC(dlsym,
1499                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1500                       [])
1501 fi
1502 dnl *** load_image (BeOS)
1503 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1504   AC_CHECK_LIB(root, load_image,
1505       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1506       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1507       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1508       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1509       [])
1510 fi
1511 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1512 if test -z "$G_MODULE_IMPL"; then
1513         AC_CHECK_FUNC(NSLinkModule,
1514                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1515                        G_MODULE_NEED_USCORE=1],
1516                       [])
1517 fi
1518 dnl *** dlopen() and dlsym() in libdl
1519 if test -z "$G_MODULE_IMPL"; then
1520         AC_CHECK_LIB(dl, dlopen,
1521                      [AC_CHECK_LIB(dl, dlsym,
1522                                    [G_MODULE_LIBS=-ldl
1523                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1524                      [])
1525 fi
1526 dnl *** shl_load() in libdld (HP-UX)
1527 if test -z "$G_MODULE_IMPL"; then
1528         AC_CHECK_LIB(dld, shl_load,
1529                 [G_MODULE_LIBS=-ldld
1530                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1531                 [])
1532 fi
1533 dnl *** additional checks for G_MODULE_IMPL_DL
1534 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1535         LIBS_orig="$LIBS"
1536         LDFLAGS_orig="$LDFLAGS"
1537         LIBS="$G_MODULE_LIBS $LIBS"
1538         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1539 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1540         echo "void glib_plugin_test(void) { }" > plugin.c
1541         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1542                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1543         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1544                 glib_cv_rtldglobal_broken,[
1545                 AC_TRY_RUN([
1546 #include <dlfcn.h>
1547 #ifndef RTLD_GLOBAL
1548 #  define RTLD_GLOBAL 0
1549 #endif
1550 #ifndef RTLD_LAZY
1551 #  define RTLD_LAZY 0
1552 #endif
1553 int glib_plugin_test;
1554 int main () {
1555     void *handle, *global, *local;
1556     global = &glib_plugin_test;
1557     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1558     if (!handle) return 0;
1559     local = dlsym (handle, "glib_plugin_test");
1560     return global == local;
1561 }                       ],
1562                         [glib_cv_rtldglobal_broken=no],
1563                         [glib_cv_rtldglobal_broken=yes],
1564                         [glib_cv_rtldglobal_broken=no])
1565                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1566                 rmdir .libs 2>/dev/null
1567         ])
1568         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1569                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1570         else
1571                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1572         fi
1573 dnl *** check whether we need preceeding underscores
1574         AC_CACHE_CHECK([for preceeding underscore in symbols],
1575                 glib_cv_uscore,[
1576                 AC_TRY_RUN([#include <dlfcn.h>
1577                 int glib_underscore_test (void) { return 42; }
1578                 int main() {
1579                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1580                   handle = dlopen ((void*)0, 0);
1581                   if (handle) {
1582                     f1 = dlsym (handle, "glib_underscore_test");
1583                     f2 = dlsym (handle, "_glib_underscore_test");
1584                   } return (!f2 || f1);
1585                 }],
1586                         [glib_cv_uscore=yes],
1587                         [glib_cv_uscore=no],
1588                         [])
1589                 rm -f plugin.c plugin.$ac_objext plugin.lo
1590         ])
1591         GLIB_ASSERT_SET(glib_cv_uscore)
1592         if test "x$glib_cv_uscore" = "xyes"; then
1593                 G_MODULE_NEED_USCORE=1
1594         else
1595                 G_MODULE_NEED_USCORE=0
1596         fi
1597
1598         LDFLAGS="$LDFLAGS_orig"
1599 dnl *** check for having dlerror()
1600         AC_CHECK_FUNC(dlerror,
1601                 [G_MODULE_HAVE_DLERROR=1],
1602                 [G_MODULE_HAVE_DLERROR=0])
1603         LIBS="$LIBS_orig"
1604 fi
1605 dnl *** done, have we got an implementation?
1606 if test -z "$G_MODULE_IMPL"; then
1607         G_MODULE_IMPL=0
1608         G_MODULE_SUPPORTED=false
1609 else
1610         G_MODULE_SUPPORTED=true
1611 fi
1612
1613 AC_MSG_CHECKING(for the suffix of module shared libraries)
1614 export SED
1615 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1616 eval $shrext_cmds
1617 module=yes eval std_shrext=$shrext_cmds
1618 # chop the initial dot
1619 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1620 AC_MSG_RESULT(.$glib_gmodule_suffix)
1621 # any reason it may fail?
1622 if test "x$glib_gmodule_suffix" = x; then
1623         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1624 fi
1625
1626 AC_SUBST(G_MODULE_SUPPORTED)
1627 AC_SUBST(G_MODULE_IMPL)
1628 AC_SUBST(G_MODULE_LIBS)
1629 AC_SUBST(G_MODULE_LIBS_EXTRA)
1630 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1631 AC_SUBST(G_MODULE_LDFLAGS)
1632 AC_SUBST(G_MODULE_HAVE_DLERROR)
1633 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1634 AC_SUBST(G_MODULE_NEED_USCORE)
1635 AC_SUBST(GLIB_DEBUG_FLAGS)
1636
1637 dnl **********************
1638 dnl *** g_spawn checks ***
1639 dnl **********************
1640
1641 AC_MSG_CHECKING(for gspawn implementation)
1642 case "$host" in
1643   *-*-mingw*)
1644     GSPAWN=gspawn-win32.lo
1645     ;;
1646   *)
1647     GSPAWN=gspawn.lo
1648     ;;
1649 esac
1650 AC_MSG_RESULT($GSPAWN)
1651 AC_SUBST(GSPAWN)
1652
1653 dnl *************************
1654 dnl *** GIOChannel checks ***
1655 dnl *************************
1656
1657 AC_MSG_CHECKING(for GIOChannel implementation)
1658 case "$host" in
1659   *-*-mingw*)
1660     GIO=giowin32.lo
1661     ;;
1662   *)
1663     GIO=giounix.lo
1664     ;;
1665 esac
1666 AC_MSG_RESULT($GIO)
1667 AC_SUBST(GIO)
1668
1669 dnl *********************************
1670 dnl *** Directory for GIO modules ***
1671 dnl *********************************
1672
1673 AC_ARG_WITH(gio-module-dir,
1674            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1675                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1676            [],
1677            [with_gio_module_dir='${libdir}/gio/modules'])
1678 GIO_MODULE_DIR=$with_gio_module_dir
1679 AC_SUBST(GIO_MODULE_DIR)
1680
1681 dnl **********************************
1682 dnl *** Check for libselinux (GIO) ***
1683 dnl **********************************
1684 AC_ARG_ENABLE(selinux,
1685               AC_HELP_STRING([--disable-selinux],
1686                              [build without selinux support]))
1687 msg_selinux=no
1688 SELINUX_LIBS=
1689 if test "x$enable_selinux" != "xno"; then
1690
1691  AC_CHECK_LIB(selinux, is_selinux_enabled,
1692    [AC_CHECK_HEADERS(selinux/selinux.h,
1693      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1694        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1695         SELINUX_LIBS="-lselinux"
1696         msg_selinux=yes])
1697      ])
1698    ])
1699 fi
1700 AC_SUBST(SELINUX_LIBS)
1701
1702 dnl *****************************
1703 dnl ** Check for inotify (GIO) **
1704 dnl *****************************
1705 inotify_support=no
1706 AC_CHECK_HEADERS([sys/inotify.h],
1707 [
1708         inotify_support=yes
1709         AC_CHECK_FUNCS(inotify_init1)
1710 ])
1711
1712 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1713
1714 dnl *********************************
1715 dnl ** Check for Solaris FEN (GIO) **
1716 dnl *********************************
1717 fen_support=no
1718 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1719 #include <port.h>
1720 #ifndef PORT_SOURCE_FILE
1721 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1722 #endif
1723 int main() { return 0; } ]])],
1724 [
1725         fen_support=yes
1726 ],)
1727
1728 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1729
1730 dnl ****************************
1731 dnl *** Checks for FAM (GIO) ***
1732 dnl ****************************
1733
1734 should_disable_fam=no
1735
1736 AC_ARG_ENABLE(fam,
1737               AC_HELP_STRING([--disable-fam],
1738                              [don't use fam for file system monitoring]),
1739                          [
1740                                 if test "x$enable_fam" = "xno"; then
1741                                         should_disable_fam=yes
1742                                 fi
1743                          ]
1744                          )
1745 fam_support=no
1746 FAM_LIBS=
1747 if test "x$should_disable_fam" = "xno"; then
1748 AC_CHECK_LIB(fam, FAMOpen,
1749   [AC_CHECK_HEADERS(fam.h,
1750     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1751      AC_CHECK_LIB(fam, FAMNoExists,
1752                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1753      FAM_LIBS="-lfam"]
1754      fam_support=yes,
1755     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1756   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1757 AC_SUBST(FAM_LIBS)
1758 fi
1759 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1760
1761
1762 dnl *****************************
1763 dnl *** Check for xattr (GIO) ***
1764 dnl *****************************
1765 AC_ARG_ENABLE(xattr,
1766               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1767 msg_xattr=no
1768 XATTR_LIBS=
1769 if test "x$enable_xattr" != "xno"; then
1770
1771 dnl either glibc or libattr can provide xattr support
1772
1773 dnl for both of them, we check for getxattr being in
1774 dnl the library and a valid xattr header.
1775
1776 dnl try glibc
1777  AC_CHECK_LIB(c, getxattr,
1778    [AC_CHECK_HEADERS(sys/xattr.h,
1779      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1780       msg_xattr=yes])
1781    ])
1782
1783   if test "x$msg_xattr" != "xyes"; then
1784 dnl   failure. try libattr
1785    AC_CHECK_LIB(attr, getxattr,
1786       [AC_CHECK_HEADERS(attr/xattr.h,
1787        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1788         XATTR_LIBS="-lattr"
1789         msg_xattr=yes])
1790       ])
1791   fi
1792
1793   if test "x$msg_xattr" = "xyes"; then
1794     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1795     AC_TRY_COMPILE([
1796       #include <stdio.h>
1797       #ifdef HAVE_SYS_TYPES_H
1798       #include <sys/types.h>
1799       #endif
1800       #ifdef HAVE_SYS_XATTR_H
1801       #include <sys/xattr.h>
1802       #elif HAVE_ATTR_XATTR_H
1803       #include <attr/xattr.h>
1804       #endif
1805     ],
1806     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1807     [
1808       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1809       AC_MSG_RESULT([yes])
1810     ],
1811     [AC_MSG_RESULT([no])]
1812     )
1813   fi
1814
1815 fi
1816 AC_SUBST(XATTR_LIBS)
1817
1818 dnl ****************************************
1819 dnl *** platform dependent source checks ***
1820 dnl ****************************************
1821
1822 AC_MSG_CHECKING(for platform-dependent source)
1823 case "$host" in
1824   *-*-cygwin*|*-*-mingw*)
1825     PLATFORMDEP=gwin32.lo
1826     ;;
1827   *)
1828     PLATFORMDEP=
1829     ;;
1830 esac
1831 AC_MSG_RESULT($PLATFORMDEP)
1832 AC_SUBST(PLATFORMDEP)
1833
1834 AC_MSG_CHECKING([whether to compile timeloop])
1835 case "$host" in
1836   *-*-cygwin*|*-*-mingw*|*-*-minix)
1837     enable_timeloop=no
1838     ;;
1839   *)
1840     enable_timeloop=yes
1841     ;;
1842 esac
1843 AC_MSG_RESULT($enable_timeloop)
1844 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1845
1846 AC_MSG_CHECKING([if building for some Win32 platform])
1847 case "$host" in
1848   *-*-mingw*|*-*-cygwin*)
1849     platform_win32=yes
1850     ;;
1851   *)
1852     platform_win32=no
1853     ;;
1854 esac
1855 AC_MSG_RESULT($platform_win32)
1856 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1857
1858 dnl ***********************
1859 dnl *** g_thread checks ***
1860 dnl ***********************
1861
1862 AC_ARG_WITH(threads,
1863            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1864                            [specify a thread implementation to use])],
1865            [if test "x$with_threads" = x; then
1866                 want_threads=yes
1867             else
1868                 want_threads=$with_threads
1869             fi],
1870            [want_threads=yes])
1871
1872 dnl error and warning message
1873 dnl *************************
1874
1875 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1876                 computer."
1877
1878 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1879                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1880                 compilation now, but then your programs might not work.
1881                 Please provide information on how it is done on your system."
1882
1883 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1884                 "
1885
1886 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1887                 provide information on your thread implementation."
1888
1889 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1890                 functions will not be MT-safe during their first call because
1891                 there is no working 'getpwuid_r' on your system."
1892
1893 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1894                 because there is no 'localtime_r' on your system."
1895
1896 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1897                 crude surrogate will be used. If you happen to know a
1898                 yield function for your system, please inform the GLib
1899                 developers."
1900
1901 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1902                 threads on your system. Thus threads can only have the default
1903                 priority. If you happen to know these main/max
1904                 priorities, please inform the GLib developers."
1905
1906 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1907                 linking threaded applications. As GLib cannot do that
1908                 automatically, you will get an linkg error everytime you are
1909                 not using the right compiler. In that case you have to relink
1910                 with the right compiler. Ususally just '_r' is appended
1911                 to the compiler name."
1912
1913 dnl determination of thread implementation
1914 dnl ***************************************
1915
1916 have_threads=no
1917 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1918                                 || test "x$want_threads" = xdce; then
1919         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1920         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1921         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1922         glib_save_CPPFLAGS="$CPPFLAGS"
1923         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1924         if test "x$have_threads" = xno; then
1925                 AC_TRY_COMPILE([#include <pthread.h>],
1926                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1927                         have_threads=posix)
1928         fi
1929         # Tru64Unix requires -pthread to find pthread.h. See #103020
1930         CPPFLAGS="$CPPFLAGS -pthread"
1931         if test "x$have_threads" = xno; then
1932         AC_TRY_COMPILE([#include <pthread.h>],
1933                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1934                        have_threads=posix)
1935         fi
1936         CPPFLAGS="$glib_save_CPPFLAGS"
1937 fi
1938 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1939         case $host in
1940                 *-*-mingw*)
1941                 have_threads=win32
1942                 ;;
1943         esac
1944 fi
1945
1946 AC_MSG_CHECKING(for thread implementation)
1947
1948 if test "x$have_threads" = xno; then
1949         AC_MSG_RESULT(none available)
1950         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1951 else
1952         AC_MSG_RESULT($have_threads)
1953 fi
1954
1955
1956 dnl determination of G_THREAD_CFLAGS
1957 dnl ********************************
1958
1959 G_THREAD_LIBS=
1960 G_THREAD_LIBS_EXTRA=
1961 G_THREAD_CFLAGS=
1962
1963 dnl
1964 dnl Test program for basic POSIX threads functionality
1965 dnl
1966 m4_define([glib_thread_test],[
1967 #include <pthread.h>
1968 int check_me = 0;
1969 void* func(void* data) {check_me = 42; return &check_me;}
1970 int main()
1971  { pthread_t t;
1972    void *ret;
1973    pthread_create (&t, $1, func, 0);
1974    pthread_join (t, &ret);
1975    return (check_me != 42 || ret != &check_me);
1976 }])
1977
1978 dnl
1979 dnl Test program for sched_get_priority_min()
1980 dnl
1981 m4_define([glib_sched_priority_test],[
1982 #include <sched.h>
1983 #include <errno.h>
1984 int main() {
1985     errno = 0;
1986     return sched_get_priority_min(SCHED_OTHER)==-1
1987            && errno != 0;
1988 }])
1989
1990 if test x"$have_threads" = xposix; then
1991   # First we test for posix, whether -pthread or -pthreads do the trick as
1992   # both CPPFLAG and LIBS.
1993   # One of them does for most gcc versions and some other platforms/compilers
1994   # too and could be considered as the canonical way to go.
1995   case $host in
1996     *-*-cygwin*|*-*-darwin*)
1997        # skip cygwin and darwin -pthread or -pthreads test
1998        ;;
1999     *-solaris*)
2000       # These compiler/linker flags work with both Sun Studio and gcc
2001       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2002       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2003       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2004       G_THREAD_LIBS="-lpthread -lthread"
2005       ;;
2006     *)
2007       for flag in pthread pthreads mt; do
2008         glib_save_CFLAGS="$CFLAGS"
2009         CFLAGS="$CFLAGS -$flag"
2010         AC_TRY_RUN(glib_thread_test(0),
2011                    glib_flag_works=yes,
2012                    glib_flag_works=no,
2013                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2014                                    glib_flag_works=yes,
2015                                    glib_flag_works=no)])
2016         CFLAGS="$glib_save_CFLAGS"
2017         if test $glib_flag_works = yes ; then
2018            G_THREAD_CFLAGS=-$flag
2019         G_THREAD_LIBS=-$flag
2020         break;
2021         fi
2022       done
2023        ;;
2024   esac
2025 fi
2026
2027 if test x"$G_THREAD_CFLAGS" = x; then
2028
2029   # The canonical -pthread[s] does not work. Try something different.
2030
2031   case $host in
2032         *-aix*)
2033                 if test x"$GCC" = xyes; then
2034                         # GCC 3.0 and above needs -pthread.
2035                         # Should be coverd by the case above.
2036                         # GCC 2.x and below needs -mthreads
2037                         G_THREAD_CFLAGS="-mthreads"
2038                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2039                 else
2040                         # We are probably using the aix compiler. Normaly a
2041                         # program would have to be compiled with the _r variant
2042                         # of the corresponding compiler, but we as GLib cannot
2043                         # do that: but the good news is that for compiling the
2044                         # only difference is the added -D_THREAD_SAFE compile
2045                         # option. This is according to the "C for AIX User's
2046                         # Guide".
2047                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2048                 fi
2049                 ;;
2050         *-dg-dgux*)  # DG/UX
2051                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2052                 ;;
2053         *-sysv5uw7*) # UnixWare 7
2054                 # We are not using gcc with -pthread. Catched above.
2055                 G_THREAD_CFLAGS="-Kthread"
2056                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2057                 ;;
2058         *-mingw*)
2059                 # No flag needed when using MSVCRT.DLL
2060                 G_THREAD_CFLAGS=""
2061                 ;;
2062         *)
2063                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2064                 ;;
2065   esac
2066
2067 fi
2068
2069 # if we are not finding the localtime_r function, then we probably are
2070 # not using the proper multithread flag
2071
2072 glib_save_CPPFLAGS="$CPPFLAGS"
2073 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2074
2075 # First we test, whether localtime_r is declared in time.h
2076 # directly. Then we test whether a macro localtime_r exists, in
2077 # which case localtime_r in the test program is replaced and thus
2078 # if we still find localtime_r in the output, it is not defined as
2079 # a macro.
2080
2081 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2082   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2083                                                            localtime_r(a,b)],
2084                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2085
2086 CPPFLAGS="$glib_save_CPPFLAGS"
2087
2088 AC_MSG_CHECKING(thread related cflags)
2089 AC_MSG_RESULT($G_THREAD_CFLAGS)
2090 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2091
2092 dnl determination of G_THREAD_LIBS
2093 dnl ******************************
2094
2095 case $have_threads in
2096         posix)
2097           glib_save_CPPFLAGS="$CPPFLAGS"
2098           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2099           if test x"$G_THREAD_LIBS" = x; then
2100             case $host in
2101               *-aix*)
2102                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2103                 # probably using the aix compiler.
2104                 AC_MSG_WARN($AIX_COMPILE_INFO)
2105                 ;;
2106               *)
2107                 G_THREAD_LIBS=error
2108                 glib_save_LIBS="$LIBS"
2109                 for thread_lib in "" pthread pthread32 pthreads thread; do
2110                         if test x"$thread_lib" = x; then
2111                                 add_thread_lib=""
2112                                 IN=""
2113                         else
2114                                 add_thread_lib="-l$thread_lib"
2115                                 IN=" in -l$thread_lib"
2116                         fi
2117                         if test x"$have_threads" = xposix; then
2118                                 defattr=0
2119                         else
2120                                 defattr=pthread_attr_default
2121                         fi
2122
2123                         LIBS="$add_thread_lib $glib_save_LIBS"
2124
2125                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2126                         AC_TRY_RUN(glib_thread_test($defattr),
2127                                    glib_result=yes,
2128                                    glib_result=no,
2129                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2130                                                    glib_result=yes,
2131                                                    glib_result=no)])
2132                         AC_MSG_RESULT($glib_result)
2133
2134                         if test "$glib_result" = "yes" ; then
2135                           G_THREAD_LIBS="$add_thread_lib"
2136                           break
2137                         fi
2138                 done
2139                 if test "x$G_THREAD_LIBS" = xerror; then
2140                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2141                 fi
2142                 LIBS="$glib_save_LIBS"
2143                 ;;
2144             esac
2145           fi
2146
2147           glib_save_LIBS="$LIBS"
2148           for thread_lib in "" rt rte; do
2149             if test x"$thread_lib" = x; then
2150               add_thread_lib=""
2151               IN=""
2152             else
2153               add_thread_lib="-l$thread_lib"
2154               IN=" in -l$thread_lib"
2155             fi
2156             LIBS="$add_thread_lib $glib_save_LIBS"
2157
2158             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2159             AC_TRY_RUN(glib_sched_priority_test,
2160                        glib_result=yes,
2161                        glib_result=no,
2162                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2163                                        glib_result=yes,
2164                                        glib_result=no)])
2165             AC_MSG_RESULT($glib_result)
2166
2167             if test "$glib_result" = "yes" ; then
2168                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2169                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2170                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2171                break
2172             fi
2173           done
2174           LIBS="$glib_save_LIBS"
2175           g_threads_impl="POSIX"
2176           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2177           CPPFLAGS="$glib_save_CPPFLAGS"
2178           ;;
2179         win32)
2180            g_threads_impl="WIN32"
2181            ;;
2182         *)
2183            g_threads_impl="NONE"
2184            G_THREAD_LIBS=error
2185            ;;
2186 esac
2187
2188 if test "x$G_THREAD_LIBS" = xerror; then
2189         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2190 fi
2191
2192 case $host in
2193   *-*-beos*)
2194     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2195     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2196     ;;
2197   *)
2198     ;;
2199 esac
2200
2201 AC_MSG_CHECKING(thread related libraries)
2202 AC_MSG_RESULT($G_THREAD_LIBS)
2203
2204 dnl check for mt safe function variants and some posix functions
2205 dnl ************************************************************
2206
2207 glib_save_LIBS="$LIBS"
2208 # we are not doing the following for now, as this might require glib
2209 # to always be linked with the thread libs on some platforms.
2210 # LIBS="$LIBS $G_THREAD_LIBS"
2211 AC_CHECK_FUNCS(localtime_r gmtime_r)
2212 if test "$ac_cv_header_pwd_h" = "yes"; then
2213         AC_CACHE_CHECK([for posix getpwuid_r],
2214                 ac_cv_func_posix_getpwuid_r,
2215                 [AC_TRY_RUN([
2216 #include <errno.h>
2217 #include <pwd.h>
2218 int main () {
2219     char buffer[10000];
2220     struct passwd pwd, *pwptr = &pwd;
2221     int error;
2222     errno = 0;
2223     error = getpwuid_r (0, &pwd, buffer,
2224                         sizeof (buffer), &pwptr);
2225    return (error < 0 && errno == ENOSYS)
2226            || error == ENOSYS;
2227 }                               ],
2228                         [ac_cv_func_posix_getpwuid_r=yes],
2229                         [ac_cv_func_posix_getpwuid_r=no])])
2230         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2231         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2232                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2233                         [Have POSIX function getpwuid_r])
2234         else
2235                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2236                         ac_cv_func_nonposix_getpwuid_r,
2237                         [AC_TRY_LINK([#include <pwd.h>],
2238                                 [char buffer[10000];
2239                                 struct passwd pwd;
2240                                 getpwuid_r (0, &pwd, buffer,
2241                                                 sizeof (buffer));],
2242                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2243                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2244                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2245                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2246                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2247                                 [Have non-POSIX function getpwuid_r])
2248                 fi
2249         fi
2250 fi
2251 if test "$ac_cv_header_grp_h" = "yes"; then
2252         AC_CACHE_CHECK([for posix getgrgid_r],
2253                 ac_cv_func_posix_getgrgid_r,
2254                 [AC_TRY_RUN([
2255 #include <errno.h>
2256 #include <grp.h>
2257 int main () {
2258     char buffer[10000];
2259     struct group grp, *grpptr = &grp;
2260     int error;
2261     errno = 0;
2262     error = getgrgid_r (0, &grp, buffer,
2263                         sizeof (buffer), &grpptr);
2264    return (error < 0 && errno == ENOSYS)
2265            || error == ENOSYS;
2266 }                              ],
2267                        [ac_cv_func_posix_getgrgid_r=yes],
2268                        [ac_cv_func_posix_getgrgid_r=no])])
2269         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2270         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2271                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2272                         [Have POSIX function getgrgid_r])
2273         else
2274                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2275                         ac_cv_func_nonposix_getgrgid_r,
2276                         [AC_TRY_LINK([#include <grp.h>],
2277                                 [char buffer[10000];
2278                                 struct group grp;
2279                                 getgrgid_r (0, &grp, buffer,
2280                                 sizeof (buffer));],
2281                         [ac_cv_func_nonposix_getgrgid_r=yes],
2282                         [ac_cv_func_nonposix_getgrgid_r=no])])
2283                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2284                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2285                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2286                                 [Have non-POSIX function getgrgid_r])
2287                 fi
2288         fi
2289 fi
2290 LIBS="$G_THREAD_LIBS $LIBS"
2291 if test x"$have_threads" = xposix; then
2292         glib_save_CPPFLAGS="$CPPFLAGS"
2293         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2294         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2295         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2296         # This is not AC_CHECK_FUNC to also work with function
2297         # name mangling in header files.
2298         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2299         AC_TRY_LINK([#include <pthread.h>],
2300                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2301                 [AC_MSG_RESULT(yes)
2302                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2303                           [Have function pthread_attr_setstacksize])],
2304                 [AC_MSG_RESULT(no)])
2305         AC_MSG_CHECKING(for minimal/maximal thread priority)
2306         if test x"$posix_priority_min" = x; then
2307                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2308                         PX_PRIO_MIN],,[
2309                         posix_priority_min=PX_PRIO_MIN
2310                         posix_priority_max=PX_PRIO_MAX])
2311         fi
2312         if test x"$posix_priority_min" = x; then
2313                 # AIX
2314                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2315                         PTHREAD_PRIO_MIN],,[
2316                         posix_priority_min=PTHREAD_PRIO_MIN
2317                         posix_priority_max=PTHREAD_PRIO_MAX])
2318         fi
2319         if test x"$posix_priority_min" = x; then
2320                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2321                         PRI_OTHER_MIN],,[
2322                         posix_priority_min=PRI_OTHER_MIN
2323                         posix_priority_max=PRI_OTHER_MAX])
2324         fi
2325         if test x"$posix_priority_min" = x; then
2326                 AC_MSG_RESULT(none found)
2327                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2328                 posix_priority_min=-1
2329                 posix_priority_max=-1
2330         else
2331                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2332                 AC_MSG_CHECKING(for pthread_setschedparam)
2333                 AC_TRY_LINK([#include <pthread.h>],
2334                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2335                   [AC_MSG_RESULT(yes)
2336                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2337                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2338                   [AC_MSG_RESULT(no)
2339                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2340         fi
2341         posix_yield_func=none
2342         AC_MSG_CHECKING(for posix yield function)
2343         for yield_func in sched_yield pthread_yield_np pthread_yield \
2344                                                 thr_yield; do
2345                 AC_TRY_LINK([#include <pthread.h>],
2346                         [$yield_func()],
2347                         [posix_yield_func="$yield_func"
2348                         break])
2349         done
2350         if test x"$posix_yield_func" = xnone; then
2351                 AC_MSG_RESULT(none found)
2352                 AC_MSG_WARN($POSIX_NO_YIELD)
2353                 posix_yield_func="g_usleep(1000)"
2354         else
2355                 AC_MSG_RESULT($posix_yield_func)
2356                 posix_yield_func="$posix_yield_func()"
2357         fi
2358         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2359         CPPFLAGS="$glib_save_CPPFLAGS"
2360
2361 elif test x"$have_threads" = xwin32; then
2362         # It's a pointer to a private struct
2363         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2364 fi
2365
2366 LIBS="$glib_save_LIBS"
2367
2368 # now spit out all the warnings.
2369 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2370    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2371         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2372 fi
2373 if test "$ac_cv_func_localtime_r" != "yes"; then
2374         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2375 fi
2376
2377 if test x"$glib_cv_sizeof_system_thread" = x; then
2378    # use a pointer as a fallback.
2379    GLIB_SIZEOF(,void *, system_thread)
2380 fi
2381
2382 #
2383 # Hack to deal with:
2384 #
2385 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2386 #     building shared libraries with linux.
2387 #  b) FreeBSD doesn't do this either.
2388 #
2389 case $host in
2390   *-*-freebsd*|*-*-linux*)
2391     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2392     ;;
2393   *-*-openbsd*)
2394     LDFLAGS="$LDFLAGS -pthread"
2395     ;;
2396   *)
2397     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2398     ;;
2399 esac
2400
2401 AC_SUBST(G_THREAD_CFLAGS)
2402 AC_SUBST(G_THREAD_LIBS)
2403 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2404 AC_SUBST(G_THREAD_LIBS_EXTRA)
2405
2406 AC_CHECK_FUNCS(clock_gettime, [], [
2407   AC_CHECK_LIB(rt, clock_gettime, [
2408     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2409     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2410     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2411     GLIB_RT_LIBS="-lrt"
2412   ])
2413 ])
2414 AC_SUBST(GLIB_RT_LIBS)
2415
2416
2417 dnl ************************
2418 dnl *** g_atomic_* tests ***
2419 dnl ************************
2420
2421 dnl We need to decide at configure time if GLib will use real atomic
2422 dnl operations ("lock free") or emulated ones with a mutex.  This is
2423 dnl because we must put this information in glibconfig.h so we know if
2424 dnl it is safe or not to inline using compiler intrinsics directly from
2425 dnl the header.
2426 dnl
2427 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2428 dnl user is interested in knowing if they can use the atomic ops across
2429 dnl processes.
2430 dnl
2431 dnl We can currently support the atomic ops natively when building GLib
2432 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2433 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2434 dnl we are using GCC.
2435 dnl
2436 dnl Note that the atomic ops are only available with GCC on x86 when
2437 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2438 dnl not available but would be available given the right flags, we want
2439 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2440 dnl that then to silently fall back on emulated atomic ops just because
2441 dnl the user had the wrong build environment.
2442
2443 dnl We may add other compilers here in the future...
2444 AC_MSG_CHECKING([for lock-free atomic intrinsics])
2445 AC_TRY_COMPILE([],
2446                [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2447                [glib_cv_g_atomic_lock_free=yes],
2448                [glib_cv_g_atomic_lock_free=no])
2449 AC_MSG_RESULT($glib_cv_g_atomic_lock_free)
2450
2451 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2452   SAVE_CFLAGS="${CFLAGS}"
2453   CFLAGS="-march=i486"
2454   AC_TRY_COMPILE([],
2455                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2456                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2457                  [])
2458   CFLAGS="${SAVE_CFLAGS}"
2459 fi
2460
2461 dnl We need a more robust approach here...
2462 case $host_cpu in
2463   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2464     glib_memory_barrier_needed=no
2465     ;;
2466   sparc*|alpha*|powerpc*|ia64)
2467     glib_memory_barrier_needed=yes
2468     ;;
2469   *)
2470     glib_memory_barrier_needed=yes
2471     ;;
2472 esac
2473
2474 dnl ************************
2475 dnl ** Check for futex(2) **
2476 dnl ************************
2477 AC_CACHE_CHECK(for futex(2) system call,
2478     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2479 #include <linux/futex.h>
2480 #include <sys/syscall.h>
2481 #include <unistd.h>
2482 ],[
2483 int
2484 main (void)
2485 {
2486   /* it is not like this actually runs or anything... */
2487   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2488   return 0;
2489 }
2490 ])],glib_cv_futex=yes,glib_cv_futex=no))
2491 if test x"$glib_cv_futex" = xyes; then
2492   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2493 fi
2494
2495 AC_CACHE_CHECK(for eventfd(2) system call,
2496     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2497 #include <sys/eventfd.h>
2498 #include <unistd.h>
2499 ],[
2500 int
2501 main (void)
2502 {
2503   eventfd (0, EFD_CLOEXEC);
2504   return 0;
2505 }
2506 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2507 if test x"$glib_cv_eventfd" = x"yes"; then
2508   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2509 fi
2510 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2511
2512 dnl ****************************************
2513 dnl *** GLib POLL* compatibility defines ***
2514 dnl ****************************************
2515
2516 glib_poll_includes=["
2517 #include <sys/types.h>
2518 #include <sys/poll.h>
2519 "]
2520
2521 if test $ac_cv_header_sys_types_h = yes &&
2522    test $ac_cv_header_sys_poll_h = yes ; then
2523   glib_failed=false
2524   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2525   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2526   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2527   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2528   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2529   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2530   if $glib_failed ; then
2531     AC_MSG_ERROR([Could not determine values for POLL* constants])
2532   fi
2533 else
2534   glib_cv_value_POLLIN=1
2535   glib_cv_value_POLLOUT=4
2536   glib_cv_value_POLLPRI=2
2537   glib_cv_value_POLLERR=8
2538   glib_cv_value_POLLHUP=16
2539   glib_cv_value_POLLNVAL=32
2540 fi
2541
2542 AC_MSG_CHECKING([for broken poll])
2543 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2544         #include <stdlib.h>
2545         #include <fcntl.h>
2546         #include <poll.h>
2547         #ifdef HAVE_SYS_POLL_H
2548         #include <sys/poll.h>
2549         #endif
2550         int main(void) {
2551           struct pollfd fds[1];
2552           int fd;
2553           fd = open("/dev/null", 1);
2554           fds[0].fd = fd;
2555           fds[0].events = POLLIN;
2556           fds[0].revents = 0;
2557           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2558                 exit(1);  /* Does not work for devices -- fail */
2559           }
2560           exit(0);
2561         }]])],
2562   [broken_poll=no],
2563   [broken_poll=yes
2564    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2565   [broken_poll="no (cross compiling)"])
2566 AC_MSG_RESULT($broken_poll)
2567
2568 dnl *********************
2569 dnl *** GRegex checks ***
2570 dnl *********************
2571 PCRE_REQUIRED_VERSION=8.11
2572
2573 # Check if we should compile GRegex
2574 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2575                                     [disable the compilation of GRegex]),
2576 [case "${enableval}" in
2577   yes) enable_regex=true ;;
2578   no)  enable_regex=false ;;
2579   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2580 esac],
2581 [enable_regex=true])
2582
2583 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2584
2585 if test x$enable_regex = xtrue; then
2586   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2587   # Check if we should use the internal or the system-supplied pcre
2588   AC_ARG_WITH(pcre,
2589              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2590                              [whether to use system PCRE [default=internal]])])
2591
2592   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2593
2594   if test "x$with_pcre" = xsystem; then
2595     PKG_CHECK_MODULES(PCRE,
2596                       libpcre >= $PCRE_REQUIRED_VERSION)
2597     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2598                    glib_save_CFLAGS="$CFLAGS"
2599                    glib_save_LIBS="$LIBS"
2600                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2601                    AC_TRY_RUN([#include <pcre.h>
2602                                int main () {
2603                                  int support;
2604                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2605                                  if (!support)
2606                                    return 1;
2607                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2608                                  if (!support)
2609                                    return 1;
2610                                  return 0;
2611                                }],
2612                    glib_cv_pcre_has_unicode=yes,
2613                    glib_cv_pcre_has_unicode=no,
2614                    glib_cv_pcre_has_unicode=yes)
2615                    CFLAGS="$glib_save_CFLAGS"
2616                    LIBS="$glib_save_LIBS"
2617         ])
2618     if test "$glib_cv_pcre_has_unicode" = "no"; then
2619       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2620     fi
2621     AC_SUBST(PCRE_CFLAGS)
2622     AC_SUBST(PCRE_LIBS)
2623     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2624     PCRE_REQUIRES=libpcre
2625     AC_SUBST(PCRE_REQUIRES)
2626   else
2627     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2628     if test x"$GCC" = xyes; then
2629       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2630       save_CFLAGS="$CFLAGS"
2631       CFLAGS="$CFLAGS -Wno-pointer-sign"
2632       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2633                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2634       CFLAGS="$save_CFLAGS"
2635     fi
2636   fi
2637   AC_SUBST(PCRE_WARN_CFLAGS)
2638 else
2639   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2640 fi
2641
2642 dnl **********************
2643 dnl *** Win32 API libs ***
2644 dnl **********************
2645
2646 case $host in
2647   *-*-cygwin*)
2648         G_LIBS_EXTRA="-luser32 -lkernel32"
2649     ;;
2650   *-*-mingw*)
2651         G_LIBS_EXTRA="-lws2_32 -lole32"
2652     ;;
2653   *)
2654         G_LIBS_EXTRA=""
2655     ;;
2656 esac
2657 AC_SUBST(G_LIBS_EXTRA)
2658
2659 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2660 dnl since we need it for g_iconv()
2661
2662 AC_MSG_CHECKING([for EILSEQ])
2663 AC_TRY_COMPILE([
2664 #include <errno.h>
2665 ],
2666 [
2667 int error = EILSEQ;
2668 ], have_eilseq=yes, have_eilseq=no);
2669 AC_MSG_RESULT($have_eilseq)
2670
2671 dnl ******************************************************************
2672 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2673 dnl *** glib-compile-schemas in PATH                               ***
2674 dnl ******************************************************************
2675
2676 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2677
2678 if test $cross_compiling = yes; then
2679   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2680   if test x$GLIB_GENMARSHAL = xno; then
2681     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2682   fi
2683
2684   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2685   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2686     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2687   fi
2688 fi
2689
2690 dnl **************************
2691 dnl *** Checks for gtk-doc ***
2692 dnl **************************
2693
2694 GTK_DOC_CHECK([1.15])
2695
2696 AC_ARG_ENABLE(man,
2697               [AC_HELP_STRING([--enable-man],
2698                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2699               enable_man=no)
2700
2701 if test "${enable_man}" != no; then
2702 dnl
2703 dnl Check for xsltproc
2704 dnl
2705 AC_PATH_PROG([XSLTPROC], [xsltproc])
2706   if test -z "$XSLTPROC"; then
2707     enable_man=no
2708   fi
2709
2710   dnl check for DocBook DTD and stylesheets in the local catalog.
2711   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2712      [DocBook XML DTD V4.1.2],,enable_man=no)
2713   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2714      [DocBook XSL Stylesheets],,enable_man=no)
2715 fi
2716
2717 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2718
2719 dnl
2720 dnl Tracing
2721 dnl
2722
2723 AC_ARG_ENABLE([dtrace],
2724              [AS_HELP_STRING([--enable-dtrace],
2725                               [include tracing support for dtrace])])
2726 have_dtrace=no
2727 AC_MSG_CHECKING([whether to include dtrace tracing support])
2728 if test "x$enable_dtrace" != xno; then
2729   if test x$glib_have_carbon = xyes; then
2730     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2731   else
2732     AC_MSG_RESULT([yes])
2733     AC_CHECK_PROGS(DTRACE, dtrace)
2734     if test -z "$DTRACE"; then
2735       if test "x$enable_dtrace" = xyes; then
2736         AC_MSG_ERROR([dtrace not found])
2737       fi
2738     else
2739       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2740                       [if test "x$enable_dtrace" = xyes; then
2741                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2742                        fi])
2743     fi
2744   fi
2745 else
2746   AC_MSG_RESULT([no])
2747 fi
2748 if test "x$have_dtrace" = xyes; then
2749   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2750 fi
2751 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2752
2753 AC_MSG_CHECKING([whether to include systemtap tracing support])
2754 AC_ARG_ENABLE([systemtap],
2755              [AS_HELP_STRING([--enable-systemtap],
2756                               [include tracing support for systemtap])])
2757 have_systemtap=no
2758 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2759   have_systemtap=yes
2760 fi
2761 AC_MSG_RESULT(${have_systemtap})
2762
2763 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2764
2765 AC_ARG_WITH([tapset-install-dir],
2766             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2767                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2768             [if test "x${withval}" = x; then
2769                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2770              else
2771                ABS_TAPSET_DIR="${withval}"
2772               fi],
2773             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2774 AC_SUBST(ABS_TAPSET_DIR)
2775
2776 dnl ************************************
2777 dnl *** Enable lcov coverage reports ***
2778 dnl ************************************
2779
2780 AC_ARG_ENABLE(gcov,
2781   AS_HELP_STRING([--enable-gcov],
2782                  [enable coverage testing with gcov]),
2783   [use_gcov=$enableval], [use_gcov=no])
2784
2785 if test "x$use_gcov" = "xyes"; then
2786   dnl we need gcc:
2787   if test "$GCC" != "yes"; then
2788     AC_MSG_ERROR([GCC is required for --enable-gcov])
2789   fi
2790
2791   dnl Check if ccache is being used
2792   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2793   case `$SHTOOL path $CC` in
2794     *ccache*[)] gcc_ccache=yes;;
2795     *[)] gcc_ccache=no;;
2796   esac
2797
2798   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2799     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2800   fi
2801
2802   ltp_version_list="1.6 1.7 1.8 1.9"
2803   AC_CHECK_PROG(LTP, lcov, lcov)
2804   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2805
2806   if test "$LTP"; then
2807     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2808       glib_cv_ltp_version=invalid
2809       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2810       for ltp_check_version in $ltp_version_list; do
2811         if test "$ltp_version" = "$ltp_check_version"; then
2812           glib_cv_ltp_version="$ltp_check_version (ok)"
2813         fi
2814       done
2815     ])
2816   else
2817     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2818     AC_MSG_ERROR([$ltp_msg])
2819   fi
2820
2821   case $glib_cv_ltp_version in
2822     ""|invalid[)]
2823       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2824       AC_MSG_ERROR([$ltp_msg])
2825       LTP="exit 0;"
2826       ;;
2827   esac
2828
2829   if test -z "$LTP_GENHTML"; then
2830     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2831   fi
2832
2833   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2834
2835   dnl Remove all optimization flags from CFLAGS
2836   changequote({,})
2837   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2838   changequote([,])
2839
2840   dnl Add the special gcc flags
2841   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2842   LDFLAGS="$LDFLAGS -lgcov"
2843 fi
2844
2845 dnl ******************************
2846 dnl *** output the whole stuff ***
2847 dnl ******************************
2848
2849 dnl this section will only be run if config.status is invoked with no
2850 dnl arguments, or with "glib/glibconfig.h" as an argument.
2851 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2852 [
2853         outfile=glib/glibconfig.h-tmp
2854         cat > $outfile <<\_______EOF
2855 /* glibconfig.h
2856  *
2857  * This is a generated file.  Please modify 'configure.ac'
2858  */
2859
2860 #ifndef __G_LIBCONFIG_H__
2861 #define __G_LIBCONFIG_H__
2862
2863 #include <glib/gmacros.h>
2864
2865 _______EOF
2866
2867         if test x$glib_limits_h = xyes; then
2868           echo '#include <limits.h>' >> $outfile
2869         fi
2870         if test x$glib_float_h = xyes; then
2871           echo '#include <float.h>' >> $outfile
2872         fi
2873         if test x$glib_values_h = xyes; then
2874           echo '#include <values.h>' >> $outfile
2875         fi
2876         if test "$glib_header_alloca_h" = "yes"; then
2877           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2878         fi
2879         if test x$glib_sys_poll_h = xyes; then
2880           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2881         fi
2882         if test x$glib_included_printf != xyes; then
2883           echo "
2884 /* Specifies that GLib's g_print*() functions wrap the
2885  * system printf functions.  This is useful to know, for example,
2886  * when using glibc's register_printf_function().
2887  */" >> $outfile
2888           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2889         fi
2890
2891         cat >> $outfile <<_______EOF
2892
2893 G_BEGIN_DECLS
2894
2895 #define G_MINFLOAT      $glib_mf
2896 #define G_MAXFLOAT      $glib_Mf
2897 #define G_MINDOUBLE     $glib_md
2898 #define G_MAXDOUBLE     $glib_Md
2899 #define G_MINSHORT      $glib_ms
2900 #define G_MAXSHORT      $glib_Ms
2901 #define G_MAXUSHORT     $glib_Mus
2902 #define G_MININT        $glib_mi
2903 #define G_MAXINT        $glib_Mi
2904 #define G_MAXUINT       $glib_Mui
2905 #define G_MINLONG       $glib_ml
2906 #define G_MAXLONG       $glib_Ml
2907 #define G_MAXULONG      $glib_Mul
2908
2909 _______EOF
2910
2911
2912         ### this should always be true in a modern C/C++ compiler
2913         cat >>$outfile <<_______EOF
2914 typedef signed char gint8;
2915 typedef unsigned char guint8;
2916 _______EOF
2917
2918
2919         if test -n "$gint16"; then
2920           cat >>$outfile <<_______EOF
2921 typedef signed $gint16 gint16;
2922 typedef unsigned $gint16 guint16;
2923 #define G_GINT16_MODIFIER $gint16_modifier
2924 #define G_GINT16_FORMAT $gint16_format
2925 #define G_GUINT16_FORMAT $guint16_format
2926 _______EOF
2927         fi
2928
2929
2930         if test -n "$gint32"; then
2931           cat >>$outfile <<_______EOF
2932 typedef signed $gint32 gint32;
2933 typedef unsigned $gint32 guint32;
2934 #define G_GINT32_MODIFIER $gint32_modifier
2935 #define G_GINT32_FORMAT $gint32_format
2936 #define G_GUINT32_FORMAT $guint32_format
2937 _______EOF
2938         fi
2939
2940         cat >>$outfile <<_______EOF
2941 #define G_HAVE_GINT64 1          /* deprecated, always true */
2942
2943 ${glib_extension}typedef signed $gint64 gint64;
2944 ${glib_extension}typedef unsigned $gint64 guint64;
2945
2946 #define G_GINT64_CONSTANT(val)  $gint64_constant
2947 #define G_GUINT64_CONSTANT(val) $guint64_constant
2948 _______EOF
2949
2950         if test x$gint64_format != x ; then
2951           cat >>$outfile <<_______EOF
2952 #define G_GINT64_MODIFIER $gint64_modifier
2953 #define G_GINT64_FORMAT $gint64_format
2954 #define G_GUINT64_FORMAT $guint64_format
2955 _______EOF
2956         else
2957           cat >>$outfile <<_______EOF
2958 #undef G_GINT64_MODIFIER
2959 #undef G_GINT64_FORMAT
2960 #undef G_GUINT64_FORMAT
2961 _______EOF
2962         fi
2963
2964         cat >>$outfile <<_______EOF
2965
2966 #define GLIB_SIZEOF_VOID_P $glib_void_p
2967 #define GLIB_SIZEOF_LONG   $glib_long
2968 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2969
2970 _______EOF
2971
2972         cat >>$outfile <<_______EOF
2973 typedef signed $glib_size_type_define gssize;
2974 typedef unsigned $glib_size_type_define gsize;
2975 #define G_GSIZE_MODIFIER $gsize_modifier
2976 #define G_GSSIZE_FORMAT $gssize_format
2977 #define G_GSIZE_FORMAT $gsize_format
2978
2979 #define G_MAXSIZE       G_MAXU$glib_msize_type
2980 #define G_MINSSIZE      G_MIN$glib_msize_type
2981 #define G_MAXSSIZE      G_MAX$glib_msize_type
2982
2983 typedef gint64 goffset;
2984 #define G_MINOFFSET     G_MININT64
2985 #define G_MAXOFFSET     G_MAXINT64
2986
2987 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2988 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2989 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2990
2991 _______EOF
2992
2993         if test -z "$glib_unknown_void_p"; then
2994           cat >>$outfile <<_______EOF
2995
2996 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2997 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2998
2999 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3000 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3001
3002 typedef signed $glib_intptr_type_define gintptr;
3003 typedef unsigned $glib_intptr_type_define guintptr;
3004
3005 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3006 #define G_GINTPTR_FORMAT        $gintptr_format
3007 #define G_GUINTPTR_FORMAT       $guintptr_format
3008 _______EOF
3009         else
3010           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3011         fi
3012
3013
3014
3015         cat >>$outfile <<_______EOF
3016 $glib_atexit
3017 $glib_memmove
3018 $glib_defines
3019 $glib_os
3020 $glib_static_compilation
3021
3022 $glib_vacopy
3023
3024 #ifdef  __cplusplus
3025 #define G_HAVE_INLINE   1
3026 #else   /* !__cplusplus */
3027 $glib_inline
3028 #endif  /* !__cplusplus */
3029
3030 #ifdef  __cplusplus
3031 #define G_CAN_INLINE    1
3032 _______EOF
3033
3034         if test x$g_can_inline = xyes ; then
3035                 cat >>$outfile <<_______EOF
3036 #else   /* !__cplusplus */
3037 #define G_CAN_INLINE    1
3038 _______EOF
3039         fi
3040
3041         cat >>$outfile <<_______EOF
3042 #endif
3043
3044 _______EOF
3045
3046         if test x$g_have_iso_c_varargs = xyes ; then
3047                 cat >>$outfile <<_______EOF
3048 #ifndef __cplusplus
3049 # define G_HAVE_ISO_VARARGS 1
3050 #endif
3051 _______EOF
3052         fi
3053         if test x$g_have_iso_cxx_varargs = xyes ; then
3054                 cat >>$outfile <<_______EOF
3055 #ifdef __cplusplus
3056 # define G_HAVE_ISO_VARARGS 1
3057 #endif
3058 _______EOF
3059         fi
3060         if test x$g_have_gnuc_varargs = xyes ; then
3061                 cat >>$outfile <<_______EOF
3062
3063 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3064  * is passed ISO vararg support is turned off, and there is no work
3065  * around to turn it on, so we unconditionally turn it off.
3066  */
3067 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3068 #  undef G_HAVE_ISO_VARARGS
3069 #endif
3070
3071 #define G_HAVE_GNUC_VARARGS 1
3072 _______EOF
3073         fi
3074
3075         case x$g_stack_grows in
3076         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3077         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3078         esac
3079
3080
3081         echo >>$outfile
3082         if test x$g_have_eilseq = xno; then
3083                 cat >>$outfile <<_______EOF
3084 #ifndef EILSEQ
3085 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3086  * The correspondence between this and the corresponding definition
3087  * in libiconv is essential.
3088  */
3089 #  define EILSEQ ENOENT
3090 #endif
3091 _______EOF
3092
3093         fi
3094
3095         if test x$g_have_gnuc_visibility = xyes; then
3096                 cat >>$outfile <<_______EOF
3097 #define G_HAVE_GNUC_VISIBILITY 1
3098 _______EOF
3099         fi
3100                 cat >>$outfile <<_______EOF
3101 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3102 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3103 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3104 #define G_GNUC_INTERNAL __hidden
3105 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3106 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3107 #else
3108 #define G_GNUC_INTERNAL
3109 #endif
3110 _______EOF
3111
3112         echo >>$outfile
3113         cat >>$outfile <<_______EOF
3114 #define G_THREADS_ENABLED
3115 #define G_THREADS_IMPL_$g_threads_impl_def
3116 _______EOF
3117
3118         if test x"$g_memory_barrier_needed" != xno; then
3119           echo >>$outfile
3120           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3121         fi
3122         if test x"$g_atomic_lock_free" = xyes; then
3123           echo >>$outfile
3124           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3125         fi
3126         echo >>$outfile
3127         g_bit_sizes="16 32 64"
3128         for bits in $g_bit_sizes; do
3129           cat >>$outfile <<_______EOF
3130 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3131 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3132 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3133 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3134 _______EOF
3135         done
3136
3137         cat >>$outfile <<_______EOF
3138 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3139 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3140 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3141 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3142 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3143 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3144 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3145 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3146 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3147 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3148 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3149 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3150 #define G_BYTE_ORDER $g_byte_order
3151
3152 #define GLIB_SYSDEF_POLLIN =$g_pollin
3153 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3154 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3155 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3156 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3157 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3158
3159 #define G_MODULE_SUFFIX "$g_module_suffix"
3160
3161 /* A GPid is an abstraction for a process "handle". It is *not* an
3162  * abstraction for a process identifier in general. GPid is used in
3163  * GLib only for descendant processes spawned with the g_spawn*
3164  * functions. On POSIX there is no "process handle" concept as such,
3165  * but on Windows a GPid is a handle to a process, a kind of pointer,
3166  * not a process identifier.
3167  */
3168 typedef $g_pid_type GPid;
3169
3170 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3171 #define GLIB_SYSDEF_AF_INET $g_af_inet
3172 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3173
3174 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3175 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3176 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3177
3178 G_END_DECLS
3179
3180 #endif /* GLIBCONFIG_H */
3181 _______EOF
3182
3183
3184         if cmp -s $outfile glib/glibconfig.h; then
3185           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3186           rm -f $outfile
3187         else
3188           mv $outfile glib/glibconfig.h
3189         fi
3190 ],[
3191
3192 # Note that if two cases are the same, case goes with the first one.
3193 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3194 # on variable expansion in case labels.  Look at the generated config.status
3195 # for a hint.
3196
3197 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3198   glib_header_alloca_h="$ac_cv_working_alloca_h"
3199 else
3200   glib_header_alloca_h="$ac_cv_header_alloca_h"
3201 fi
3202
3203 case xyes in
3204 x$ac_cv_header_float_h)
3205   glib_float_h=yes
3206   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3207   glib_md=DBL_MIN glib_Md=DBL_MAX
3208   ;;
3209 x$ac_cv_header_values_h)
3210   glib_values_h=yes
3211   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3212   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3213   ;;
3214 esac
3215
3216 case xyes in
3217 x$ac_cv_header_limits_h)
3218   glib_limits_h=yes
3219   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3220   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3221   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3222   ;;
3223 x$ac_cv_header_values_h)
3224   glib_values_h=yes
3225   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3226   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3227   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3228   ;;
3229 esac
3230
3231 if test x$ac_cv_header_sys_poll_h = xyes ; then
3232   glib_sys_poll_h=yes
3233 fi
3234
3235 if test x$enable_included_printf = xyes ; then
3236   glib_included_printf=yes
3237 fi
3238
3239 case 2 in
3240 $ac_cv_sizeof_short)
3241   gint16=short
3242   gint16_modifier='"h"'
3243   gint16_format='"hi"'
3244   guint16_format='"hu"'
3245   ;;
3246 $ac_cv_sizeof_int)
3247   gint16=int
3248   gint16_modifier='""'
3249   gint16_format='"i"'
3250   guint16_format='"u"'
3251   ;;
3252 esac
3253 case 4 in
3254 $ac_cv_sizeof_short)
3255   gint32=short
3256   gint32_modifier='"h"'
3257   gint32_format='"hi"'
3258   guint32_format='"hu"'
3259   ;;
3260 $ac_cv_sizeof_int)
3261   gint32=int
3262   gint32_modifier='""'
3263   gint32_format='"i"'
3264   guint32_format='"u"'
3265   ;;
3266 $ac_cv_sizeof_long)
3267   gint32=long
3268   gint32_modifier='"l"'
3269   gint32_format='"li"'
3270   guint32_format='"lu"'
3271   ;;
3272 esac
3273 case 8 in
3274 $ac_cv_sizeof_int)
3275   gint64=int
3276   gint64_modifier='""'
3277   gint64_format='"i"'
3278   guint64_format='"u"'
3279   glib_extension=
3280   gint64_constant='(val)'
3281   guint64_constant='(val)'
3282   ;;
3283 $ac_cv_sizeof_long)
3284   gint64=long
3285   gint64_modifier='"l"'
3286   gint64_format='"li"'
3287   guint64_format='"lu"'
3288   glib_extension=
3289   gint64_constant='(val##L)'
3290   guint64_constant='(val##UL)'
3291   ;;
3292 $ac_cv_sizeof_long_long)
3293   gint64='long long'
3294   if test -n "$glib_cv_long_long_format"; then
3295     gint64_modifier='"'$glib_cv_long_long_format'"'
3296     gint64_format='"'$glib_cv_long_long_format'i"'
3297     guint64_format='"'$glib_cv_long_long_format'u"'
3298   fi
3299   glib_extension='G_GNUC_EXTENSION '
3300   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3301   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3302   ;;
3303 $ac_cv_sizeof___int64)
3304   gint64='__int64'
3305   if test -n "$glib_cv_long_long_format"; then
3306     gint64_modifier='"'$glib_cv_long_long_format'"'
3307     gint64_format='"'$glib_cv_long_long_format'i"'
3308     guint64_format='"'$glib_cv_long_long_format'u"'
3309   fi
3310   glib_extension=
3311   gint64_constant='(val##i64)'
3312   guint64_constant='(val##ui64)'
3313   ;;
3314 esac
3315 glib_size_t=$ac_cv_sizeof_size_t
3316 glib_size_type_define="$glib_size_type"
3317 glib_void_p=$ac_cv_sizeof_void_p
3318 glib_long=$ac_cv_sizeof_long
3319
3320 case "$glib_size_type" in
3321 short)
3322   gsize_modifier='"h"'
3323   gsize_format='"hu"'
3324   gssize_format='"hi"'
3325   glib_msize_type='SHRT'
3326   ;;
3327 int)
3328   gsize_modifier='""'
3329   gsize_format='"u"'
3330   gssize_format='"i"'
3331   glib_msize_type='INT'
3332   ;;
3333 long)
3334   gsize_modifier='"l"'
3335   gsize_format='"lu"'
3336   gssize_format='"li"'
3337   glib_msize_type='LONG'
3338   ;;
3339 "long long"|__int64)
3340   gsize_modifier='"I64"'
3341   gsize_format='"I64u"'
3342   gssize_format='"I64i"'
3343   glib_msize_type='INT64'
3344   ;;
3345 esac
3346
3347 gintbits=`expr $ac_cv_sizeof_int \* 8`
3348 glongbits=`expr $ac_cv_sizeof_long \* 8`
3349 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3350
3351 case $ac_cv_sizeof_void_p in
3352 $ac_cv_sizeof_int)
3353   glib_intptr_type_define=int
3354   gintptr_modifier='""'
3355   gintptr_format='"i"'
3356   guintptr_format='"u"'
3357   glib_gpi_cast=''
3358   glib_gpui_cast=''
3359   ;;
3360 $ac_cv_sizeof_long)
3361   glib_intptr_type_define=long
3362   gintptr_modifier='"l"'
3363   gintptr_format='"li"'
3364   guintptr_format='"lu"'
3365   glib_gpi_cast='(glong)'
3366   glib_gpui_cast='(gulong)'
3367   ;;
3368 $ac_cv_sizeof_long_long)
3369   glib_intptr_type_define='long long'
3370   gintptr_modifier='"I64"'
3371   gintptr_format='"I64i"'
3372   guintptr_format='"I64u"'
3373   glib_gpi_cast='(gint64)'
3374   glib_gpui_cast='(guint64)'
3375   ;;
3376 $ac_cv_sizeof___int64)
3377   glib_intptr_type_define=__int64
3378   gintptr_modifier='"I64"'
3379   gintptr_format='"I64i"'
3380   guintptr_format='"I64u"'
3381   glib_gpi_cast='(gint64)'
3382   glib_gpui_cast='(guint64)'
3383   ;;
3384 *)
3385   glib_unknown_void_p=yes
3386   ;;
3387 esac
3388
3389
3390 case xyes in
3391 x$ac_cv_func_atexit)
3392   glib_atexit="
3393 #ifdef NeXT /* @#%@! NeXTStep */
3394 # define g_ATEXIT(proc) (!atexit (proc))
3395 #else
3396 # define g_ATEXIT(proc) (atexit (proc))
3397 #endif"
3398   ;;
3399 x$ac_cv_func_on_exit)
3400   glib_atexit="
3401 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3402   ;;
3403 esac
3404
3405 case xyes in
3406 x$ac_cv_func_memmove)
3407   glib_memmove='
3408 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3409   ;;
3410 x$glib_cv_working_bcopy)
3411   glib_memmove="
3412 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3413 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3414   ;;
3415 *)
3416   glib_memmove="
3417 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3418  * so we have to roll our own copy routine. */
3419 void g_memmove (void* dest, const void * src, unsigned long len);"
3420   ;;
3421 esac
3422
3423 glib_defines="
3424 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3425 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3426 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3427 "
3428
3429 case xyes in
3430 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3431 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3432 *)                      glib_vacopy=''
3433 esac
3434
3435 if test x$glib_cv_va_val_copy = xno; then
3436   glib_vacopy="\$glib_vacopy
3437 #define G_VA_COPY_AS_ARRAY 1"
3438 fi
3439
3440 if test x$glib_cv_hasinline = xyes; then
3441     glib_inline='#define G_HAVE_INLINE 1'
3442 fi
3443 if test x$glib_cv_has__inline = xyes; then
3444     glib_inline="\$glib_inline
3445 #define G_HAVE___INLINE 1"
3446 fi
3447 if test x$glib_cv_has__inline__ = xyes; then
3448     glib_inline="\$glib_inline
3449 #define G_HAVE___INLINE__ 1"
3450 fi
3451
3452 g_have_gnuc_varargs=$g_have_gnuc_varargs
3453 g_have_iso_c_varargs=$g_have_iso_c_varargs
3454 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3455
3456 g_can_inline=$g_can_inline
3457 g_have_gnuc_visibility=$g_have_gnuc_visibility
3458 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3459
3460 if test x$ac_cv_c_bigendian = xyes; then
3461   g_byte_order=G_BIG_ENDIAN
3462   g_bs_native=BE
3463   g_bs_alien=LE
3464 else
3465   g_byte_order=G_LITTLE_ENDIAN
3466   g_bs_native=LE
3467   g_bs_alien=BE
3468 fi
3469
3470 g_pollin=$glib_cv_value_POLLIN
3471 g_pollout=$glib_cv_value_POLLOUT
3472 g_pollpri=$glib_cv_value_POLLPRI
3473 g_pollhup=$glib_cv_value_POLLHUP
3474 g_pollerr=$glib_cv_value_POLLERR
3475 g_pollnval=$glib_cv_value_POLLNVAL
3476
3477 g_af_unix=$glib_cv_value_AF_UNIX
3478 g_af_inet=$glib_cv_value_AF_INET
3479 g_af_inet6=$glib_cv_value_AF_INET6
3480
3481 g_msg_peek=$glib_cv_value_MSG_PEEK
3482 g_msg_oob=$glib_cv_value_MSG_OOB
3483 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3484
3485 g_stack_grows=$glib_cv_stack_grows
3486
3487 g_have_eilseq=$have_eilseq
3488
3489 g_threads_impl_def=$g_threads_impl
3490
3491 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3492
3493 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3494 g_memory_barrier_needed="$glib_memory_barrier_needed"
3495 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3496
3497 g_module_suffix="$glib_gmodule_suffix"
3498
3499 g_pid_type="$glib_pid_type"
3500 case $host in
3501   *-*-beos*)
3502     glib_os="#define G_OS_BEOS"
3503     ;;
3504   *-*-cygwin*)
3505     glib_os="#define G_OS_UNIX
3506 #define G_PLATFORM_WIN32
3507 #define G_WITH_CYGWIN"
3508     ;;
3509   *-*-mingw*)
3510     glib_os="#define G_OS_WIN32
3511 #define G_PLATFORM_WIN32"
3512     ;;
3513   *)
3514     glib_os="#define G_OS_UNIX"
3515     ;;
3516 esac
3517 glib_static_compilation=""
3518 if test x$glib_win32_static_compilation = xyes; then
3519   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3520 #define GOBJECT_STATIC_COMPILATION 1"
3521 fi
3522 ])
3523
3524 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3525 #
3526 # 1.2.14 required for dbus_message_set_serial
3527 PKG_CHECK_MODULES(DBUS1,
3528                   dbus-1 >= 1.2.14,
3529                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3530                   have_dbus1=no)
3531 AC_SUBST(DBUS1_CFLAGS)
3532 AC_SUBST(DBUS1_LIBS)
3533 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3534
3535 dnl
3536 dnl Check for -Bsymbolic-functions linker flag used to avoid
3537 dnl intra-library PLT jumps, if available.
3538 dnl
3539
3540 AC_ARG_ENABLE(Bsymbolic,
3541               [AC_HELP_STRING([--disable-Bsymbolic],
3542                               [avoid linking with -Bsymbolic])],,
3543               [SAVED_LDFLAGS="${LDFLAGS}"
3544                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3545                LDFLAGS=-Wl,-Bsymbolic-functions
3546                AC_TRY_LINK([], [int main (void) { return 0; }],
3547                            AC_MSG_RESULT(yes)
3548                            enable_Bsymbolic=yes,
3549                            AC_MSG_RESULT(no)
3550                            enable_Bsymbolic=no)
3551                LDFLAGS="${SAVED_LDFLAGS}"])
3552
3553 if test "x${enable_Bsymbolic}" == "xyes"; then
3554   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3555 fi
3556
3557 AC_SUBST(GLIB_LINK_FLAGS)
3558
3559 #
3560 # Define variables corresponding to the correct include paths to use for
3561 # in-tree building.
3562 #
3563
3564 # for config.h:
3565 config_h_INCLUDES='-I$(top_builddir)'
3566 AC_SUBST(config_h_INCLUDES)
3567
3568 # glib:
3569 #   config.h
3570 #   $(top_builddir)/glib: for glibconfig.h
3571 #   $(top_srcdir)/glib:   for glib.h
3572 #   $(top_srcdir):        for everything
3573 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3574 AC_SUBST(glib_INCLUDES)
3575
3576 # gthread:
3577 #   same as glib
3578 gthread_INCLUDES='$(glib_INCLUDES)'
3579 AC_SUBST(gthread_INCLUDES)
3580
3581 # gobject:
3582 #   same as gthread
3583 gobject_INCLUDES='$(gthread_INCLUDES)'
3584 AC_SUBST(gobject_INCLUDES)
3585
3586 # gmodule:
3587 #   glib includes
3588 #   $(top_srcdir)/gmodule: for gmodule.h
3589 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3590 AC_SUBST(gmodule_INCLUDES)
3591
3592 # gio:
3593 #   same as gmodule
3594 gio_INCLUDES='$(gmodule_INCLUDES)'
3595 AC_SUBST(gio_INCLUDES)
3596
3597
3598 AC_CONFIG_FILES([
3599 glib-2.0.pc
3600 gmodule-2.0.pc
3601 gmodule-export-2.0.pc
3602 gmodule-no-export-2.0.pc
3603 gthread-2.0.pc
3604 gobject-2.0.pc
3605 gio-2.0.pc
3606 gio-unix-2.0.pc
3607 gio-windows-2.0.pc
3608 glib-zip
3609 glib-gettextize
3610 Makefile
3611 build/Makefile
3612 build/win32/Makefile
3613 build/win32/dirent/Makefile
3614 build/win32/vs9/Makefile
3615 build/win32/vs10/Makefile
3616 glib/Makefile
3617 glib/glib.stp
3618 glib/libcharset/Makefile
3619 glib/gnulib/Makefile
3620 glib/pcre/Makefile
3621 glib/update-pcre/Makefile
3622 glib/tests/Makefile
3623 gmodule/Makefile
3624 gmodule/gmoduleconf.h
3625 gobject/Makefile
3626 gobject/gobject.stp
3627 gobject/glib-mkenums
3628 gobject/tests/Makefile
3629 gthread/Makefile
3630 gio/Makefile
3631 gio/gdbus-2.0/codegen/Makefile
3632 gio/gdbus-2.0/codegen/config.py
3633 gio/xdgmime/Makefile
3634 gio/inotify/Makefile
3635 gio/fen/Makefile
3636 gio/fam/Makefile
3637 gio/win32/Makefile
3638 gio/tests/Makefile
3639 gio/tests/gdbus-object-manager-example/Makefile
3640 po/Makefile.in
3641 docs/Makefile
3642 docs/reference/Makefile
3643 docs/reference/glib/Makefile
3644 docs/reference/glib/version.xml
3645 docs/reference/gobject/Makefile
3646 docs/reference/gobject/version.xml
3647 docs/reference/gio/Makefile
3648 docs/reference/gio/gdbus-object-manager-example/Makefile
3649 docs/reference/gio/version.xml
3650 tests/Makefile
3651 tests/gobject/Makefile
3652 tests/refcount/Makefile
3653 m4macros/Makefile
3654 ])
3655
3656 AC_CONFIG_COMMANDS([chmod-scripts],
3657 [chmod 0755 glib-zip
3658 chmod 0755 glib-gettextize
3659 chmod 0755 gobject/glib-mkenums])
3660
3661 # we want to invoke this macro solely so that the config.status script
3662 # and automake generated makefiles know about these generated files.
3663 # They are only needed to distcheck the package
3664 if false; then
3665   AC_CONFIG_FILES([
3666     INSTALL
3667     README
3668     config.h.win32
3669     glib/glibconfig.h.win32
3670     glib/makefile.msc
3671     glib/glib.rc
3672     gmodule/makefile.msc
3673     gmodule/gmodule.rc
3674     gobject/makefile.msc
3675     gobject/gobject.rc
3676     gthread/makefile.msc
3677     gthread/gthread.rc
3678     gio/gio.rc
3679     tests/makefile.msc
3680   ])
3681 fi
3682
3683 AC_OUTPUT