configure.ac

   1 AC_PREREQ(2.53)
   2 AC_INIT([rygel],
   3         m4_esyscmd([GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version]),
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel])
   5 AC_CONFIG_AUX_DIR([build-aux])
   6
   7 # require automake-1.11 for vala support
   8 AM_INIT_AUTOMAKE([1.11])
   9 AC_CONFIG_SRCDIR([src/rygel/rygel-root-device.vala])
  10 AM_CONFIG_HEADER([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12 AM_MAINTAINER_MODE
  13
  14 # Disable generation of static libraries
  15 AC_DISABLE_STATIC
  16
  17 AC_ISC_POSIX
  18 AC_PROG_CC
  19 AC_STDC_HEADERS
  20 AC_PROG_LIBTOOL
  21 AC_FUNC_MMAP
  22
  23 VALA_REQUIRED=0.9.5
  24 GUPNP_REQUIRED=0.13.4
  25 GUPNP_AV_REQUIRED=0.5.9
  26 GUPNP_DLNA_REQUIRED=0.3.0
  27 GUPNP_VALA_REQUIRED=0.6.11
  28 DBUS_GLIB_REQUIRED=0.74
  29 GSTREAMER_REQUIRED=0.10.23
  30 GSTREAMER_TAG_REQUIRED=0.10.28
  31 GSTREAMER_APP_REQUIRED=0.10.28
  32 GIO_REQUIRED=2.16
  33 GEE_REQUIRED=0.5.2
  34 UUID_REQUIRED=1.41.3
  35 LIBSOUP_REQUIRED=2.26.0
  36 LIBSQLITE3_REQUIRED=3.5
  37
  38 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  39 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  40 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  41 PKG_CHECK_MODULES(LIBDBUS_GLIB, dbus-glib-1 >= $DBUS_GLIB_REQUIRED)
  42 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  43 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  44 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  45 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  46 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  47
  48 # glib-genmarshal
  49 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  50 AC_SUBST(GLIB_GENMARSHAL)
  51
  52 AC_ARG_ENABLE(vala,
  53         [  --enable-vala          enable checks for vala],,
  54         enable_vala=no)
  55 AC_ARG_ENABLE(sql-debugging,
  56               [  --enable-sql-debugging         enable SQL statement debugging],,
  57                  enable_sql_debugging=no)
  58
  59 if test x$enable_sql_debugging = xyes ; then
  60     VALAFLAGS="$VALAFLAGS -D RYGEL_DEBUG_SQL"
  61 fi
  62
  63 # Enable check for Vala even if not asked to do so if stamp files are absent.
  64 if test ! -e src/rygel/rygel_vala.stamp -o \
  65         ! -e src/rygel/librygel_configuration_a_vala.stamp -o \
  66         ! -e src/ui/rygel_preferences_vala.stamp -o \
  67         ! -e src/plugins/playbin/librygel_playbin_la_vala.stamp -o \
  68         ! -e src/plugins/tracker/librygel_media_tracker_la_vala.stamp -o \
  69         ! -e src/plugins/test/librygel_test_la_vala.stamp -o \
  70         ! -e src/plugins/media-export/librygel_media_export_la_vala.stamp -o \
  71         ! -e src/plugins/mediathek/librygel_mediathek_la_vala.stamp -o \
  72         ! -e src/plugins/gst-launch/librygel_gst_launch_la_vala.stamp -o \
  73         ! -e src/plugins/mpris/librygel_mpris_la_vala.stamp -o \
  74         ! -e src/plugins/external/librygel_external_la_vala.stamp ; then
  75     enable_vala=yes
  76 fi
  77
  78 # Vala
  79 if test x$enable_vala = xyes ; then
  80     # check for vala
  81     AM_PROG_VALAC([$VALA_REQUIRED])
  82
  83     if test "x$VALAC" = "x"; then
  84         AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])
  85     fi
  86
  87     PKG_CHECK_MODULES(GUPNP_VALA, gupnp-vala-1.0 >= $GUPNP_VALA_REQUIRED)
  88
  89     VALA_CHECK_PACKAGES([gupnp-1.0
  90                          gupnp-av-1.0
  91                          gupnp-dlna-1.0
  92                          dbus-glib-1
  93                          gstreamer-0.10
  94                          gstreamer-discoverer-gupnp-dlna-0.10
  95                          gio-2.0
  96                          gee-1.0
  97                          posix])
  98 else
  99     VAPIDIR=`echo ${datadir}/vala/vapi`
 100 fi
 101
 102 AC_SUBST(VAPIDIR)
 103
 104 # Maemo support
 105 AC_ARG_ENABLE(maemo,
 106         [  --enable-maemo          enable maemo support],,
 107         enable_maemo=no)
 108
 109 # Debugging
 110 AC_ARG_ENABLE(debug,
 111         [  --enable-debug          enable debugging],,
 112         enable_debug=no)
 113 if test "x$enable_debug" = "xyes"; then
 114         CFLAGS="$CFLAGS -O0 -g"
 115 fi
 116
 117 # Strict compiler
 118 AC_ARG_ENABLE(strict-cc,
 119         [  --enable-strict-cc          enable strict C compiler],,
 120         enable_strict_cc=no)
 121 if test "x$enable_strict_cc" = "xyes"; then
 122         CFLAGS="$CFLAGS -Wall -Werror"
 123 else
 124         CFLAGS="$CFLAGS -w"
 125 fi
 126
 127 # Run uninstalled
 128 AC_ARG_ENABLE(uninstalled,
 129         [  --enable-uninstalled          run uninstalled],,
 130         enable_uninstalled=no)
 131 if test "x$enable_uninstalled" = "xyes"; then
 132         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 133 fi
 134
 135 AC_MSG_CHECKING([which gtk+ version to compile against])
 136 AC_ARG_WITH([gtk],
 137   [AS_HELP_STRING([--with-gtk=2.0|3.0],[which gtk+ version to compile against (default: 2.0)])],
 138   [case "$with_gtk" in
 139      2.0|3.0) ;;
 140      *) AC_MSG_ERROR([invalid gtk version specified]) ;;
 141    esac],
 142   [with_gtk=2.0])
 143 AC_MSG_RESULT([$with_gtk])
 144
 145 case "$with_gtk" in
 146   2.0) GTK_VAPI_VERSION=2.0
 147        GTK_REQUIRED=2.20.0
 148        ;;
 149   3.0) GTK_VAPI_VERSION=3.0
 150        GTK_REQUIRED=2.90.3
 151        ;;
 152 esac
 153
 154 # Check wether user wants to build UIs
 155 AC_ARG_WITH( ui,
 156   AC_HELP_STRING([--without-ui],[Do not build UI applications]),
 157   try_ui=$withval, try_ui=yes )
 158
 159 HAVE_GTK=no
 160 if test x$try_ui = xyes ; then
 161     dnl check for gtk
 162     PKG_CHECK_MODULES(GTK, gtk+-$GTK_VAPI_VERSION >= $GTK_REQUIRED ,
 163       [
 164         AC_SUBST(GTK_CFLAGS)
 165         AC_SUBST(GTK_LIBS)
 166         if test x$enable_vala = xyes ; then
 167                 VALA_CHECK_PACKAGES([gtk+-$GTK_VAPI_VERSION], [HAVE_GTK=yes])
 168         else
 169                 HAVE_GTK=yes
 170         fi
 171       ],
 172       [
 173         HAVE_GTK=no
 174         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 175         AC_MSG_WARN([UI applications will not be built.])
 176       ])
 177 else
 178     AC_MSG_NOTICE([UI applications disabled.])
 179 fi
 180
 181 if test x$HAVE_GTK = xno; then
 182   BUILD_UI=no
 183   with_gtk="n/a"
 184 else
 185   BUILD_UI=yes
 186   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 187 fi
 188
 189 AC_SUBST(HAVE_GTK)
 190 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 191
 192 # Build test plugin
 193 AC_ARG_ENABLE(test-plugin,
 194         [  --enable-test-plugin          build test plugin],,
 195         enable_test_plugin=no)
 196
 197 # Build Tracker plugin
 198 AC_ARG_ENABLE(tracker-plugin,
 199         [  --enable-tracker-plugin      build tracker plugin],,
 200         enable_tracker_plugin=yes)
 201
 202 # Build MediaExport plugin
 203 AC_ARG_ENABLE(media-export-plugin,
 204         [  --enable-media-export-plugin          build MediaExport plugin],,
 205         enable_media_export_plugin=yes)
 206
 207 # Build External plugin
 208 AC_ARG_ENABLE(external-plugin,
 209         [  --enable-external-plugin          build External plugin],,
 210         enable_external_plugin=yes)
 211
 212 # Build MPRIS2 plugin
 213 AC_ARG_ENABLE(mpris-plugin,
 214         [  --enable-mpris-plugin             build MPRIS2 plugin],,
 215         enable_mpris_plugin=yes)
 216
 217 # Build GstRenderer plugin
 218 AC_ARG_ENABLE(playbin-plugin,
 219         [  --enable-playbin_plugin          build Gstreamer Playbin plugin],,
 220         enable_playbin_plugin=yes)
 221
 222 # Build Mediathek plugin
 223 AC_ARG_ENABLE(mediathek-plugin,
 224         [  --enable-mediathek-plugin          build Mediathek plugin],,
 225         enable_mediathek_plugin=no)
 226
 227 # Build GstLaunch plugin
 228 AC_ARG_ENABLE(gst-launch-plugin,
 229         [  --enable-gst-launch-plugin          build Gstreamer launchline plugin],,
 230         enable_gst_launch_plugin=no)
 231
 232
 233 AC_SUBST(abs_top_builddir)
 234
 235 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 236 AM_CONDITIONAL([ENABLE_MAEMO], [test "x$enable_maemo" = "xyes"])
 237 AM_CONDITIONAL([BUILD_TEST_PLUGIN], [test "x$enable_test_plugin" = "xyes"])
 238 AM_CONDITIONAL([BUILD_TRACKER_PLUGIN],
 239                [test "x$enable_tracker_plugin" = "xyes"])
 240 AM_CONDITIONAL([BUILD_MEDIATHEK_PLUGIN], [test "x$enable_mediathek_plugin" = "xyes"])
 241 AM_CONDITIONAL([BUILD_MEDIA_EXPORT_PLUGIN], [test "x$enable_media_export_plugin" = "xyes"])
 242 AM_CONDITIONAL([BUILD_EXTERNAL_PLUGIN], [test "x$enable_external_plugin" = "xyes"])
 243 AM_CONDITIONAL([BUILD_MPRIS_PLUGIN], [test "x$enable_mpris_plugin" = "xyes"])
 244 AM_CONDITIONAL([BUILD_PLAYBIN_PLUGIN], [test "x$enable_playbin_plugin" = "xyes"])
 245 AM_CONDITIONAL([BUILD_GST_LAUNCH_PLUGIN], [test "x$enable_gst_launch_plugin" = "xyes"])
 246
 247 if test "x$enable_media_export_plugin" = "xyes";
 248 then
 249     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 250     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 251     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 252     if test x$enable_vala = xyes ; then
 253         VALA_CHECK_PACKAGES([sqlite3
 254                              gstreamer-tag-0.10
 255                              gstreamer-app-0.10])
 256     fi
 257 fi
 258
 259 # Gettext
 260 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 261 AC_SUBST(GETTEXT_PACKAGE)
 262 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 263   [Define the gettext package to be used])
 264
 265 AM_GLIB_GNU_GETTEXT
 266 IT_PROG_INTLTOOL([0.35.0])
 267
 268 AC_SUBST(VALAFLAGS)
 269
 270 dnl Shave the output
 271 AM_SILENT_RULES([yes])
 272
 273 dnl documenation
 274 AC_PATH_PROG([XSLTPROC], [xsltproc])
 275 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 276
 277 AC_SUBST(VERSION)
 278
 279 AC_OUTPUT([
 280 Makefile
 281 src/Makefile
 282 src/rygel/Makefile
 283 src/ui/Makefile
 284 src/plugins/Makefile
 285 src/plugins/media-export/Makefile
 286 src/plugins/external/Makefile
 287 src/plugins/mpris/Makefile
 288 src/plugins/gst-launch/Makefile
 289 src/plugins/mediathek/Makefile
 290 src/plugins/tracker/Makefile
 291 src/plugins/playbin/Makefile
 292 src/plugins/test/Makefile
 293 data/Makefile
 294 data/xml/Makefile
 295 data/icons/Makefile
 296 data/icons/32x32/Makefile
 297 data/icons/48x48/Makefile
 298 data/icons/120x120/Makefile
 299 data/icons/scalable/Makefile
 300 data/rygel.desktop.in
 301 data/rygel-preferences.desktop.in
 302 doc/Makefile
 303 po/Makefile.in
 304 rygel-1.0.pc
 305 tests/Makefile
 306 ])
 307
 308 echo "
 309
 310                     ${PACKAGE} ${VERSION}
 311                     ============
 312
 313
 314         Prefix:                 ${prefix}
 315         Source code location:   ${srcdir}
 316         Compiler:               ${CC}
 317         CFLAGS:                 ${CFLAGS}
 318         uninstalled:            ${enable_uninstalled}
 319         maemo support:          ${enable_maemo}
 320         preferences ui:         ${BUILD_UI}
 321         GTK+ version:           ${with_gtk}
 322         SQL debugging:          ${enable_sql_debugging}
 323     Plugins:
 324         test:                   ${enable_test_plugin}
 325         tracker:                ${enable_tracker_plugin}
 326         mediathek:              ${enable_mediathek_plugin}
 327         media-export            ${enable_media_export_plugin}
 328         external:               ${enable_external_plugin}
 329         MPRIS2:                 ${enable_mpris_plugin}
 330         gst-launch:             ${enable_gst_launch_plugin}
 331         playbin:                ${enable_playbin_plugin}
 332 "