configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [5])
   6 m4_define([dbus_micro_version], [9])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22  ## must come before we use the $USE_MAINTAINER_MODE variable later
  23 AM_MAINTAINER_MODE
  24
  25 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  26
  27 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  28
  29 # libtool versioning - this applies to libdbus
  30 #
  31 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  32 #
  33
  34 ## increment if the interface has additions, changes, removals.
  35 LT_CURRENT=9
  36
  37 ## increment any time the source changes; set to
  38 ##  0 if you increment CURRENT
  39 LT_REVISION=4
  40
  41 ## increment if any interfaces have been added; set to 0
  42 ## if any interfaces have been changed or removed. removal has
  43 ## precedence over adding, so set to 0 if both happened.
  44 LT_AGE=6
  45
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 AC_SUBST(LT_AGE)
  49
  50 DBUS_MAJOR_VERSION=dbus_major_version
  51 DBUS_MINOR_VERSION=dbus_minor_version
  52 DBUS_MICRO_VERSION=dbus_micro_version
  53 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  54
  55 AC_SUBST(DBUS_MAJOR_VERSION)
  56 AC_SUBST(DBUS_MINOR_VERSION)
  57 AC_SUBST(DBUS_MICRO_VERSION)
  58 AC_SUBST(DBUS_VERSION)
  59
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_USE_SYSTEM_EXTENSIONS
  64 AC_ISC_POSIX
  65 AC_HEADER_STDC
  66 AC_C_INLINE
  67 AM_PROG_LIBTOOL
  68 AC_PROG_MKDIR_P
  69 COMPILER_COVERAGE
  70 COMPILER_OPTIMISATIONS
  71 PKG_PROG_PKG_CONFIG
  72
  73 # Initialize libtool
  74 LT_INIT([win32-dll])
  75 LT_LANG([Windows Resource])
  76
  77 # Set some internal variables depending on the platform for later use.
  78 dbus_win=no
  79 dbus_cygwin=no
  80 dbus_unix=no
  81 case "${host}" in
  82     *-mingw32ce*)
  83         dbus_win=yes
  84         dbus_wince=yes
  85         ;;
  86     *-mingw32*)
  87         dbus_win=yes
  88         ;;
  89     *-cygwin*)
  90         dbus_cygwin=yes
  91         dbus_unix=yes
  92         ;;
  93     *)
  94         dbus_unix=yes
  95        ;;
  96 esac
  97
  98 # Special defines for certain platforms
  99 if test "$dbus_win" = yes; then
 100     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 101     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 102     AC_SUBST(BUILD_TIMESTAMP)
 103     # Assume DBUS_VERSION is always three numbers
 104     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 105     AC_SUBST(BUILD_FILEVERSION)
 106     AC_CHECK_TOOL(WINDRES, windres, no)
 107     if test "$WINDRES" = no; then
 108       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 109     fi
 110     if test "$dbus_wince" = yes; then
 111       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 112       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 113     fi
 114 else
 115     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 116 fi
 117 if test "$dbus_cygwin" = yes; then
 118     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 119 fi
 120
 121 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 122 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 123 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 124 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 125
 126 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 127 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 128 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 129 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 130 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 131 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 132 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 133 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 134 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 135 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 136 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 137 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 138 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 139 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 140 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 141 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 142
 143 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 144 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 145 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 146 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 147 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 148 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 149 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 150 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 151 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 152 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 153 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 154 AC_ARG_WITH(dbus_session_bus_default_address, AS_HELP_STRING([--with-dbus-session-bus-default-address=[nonce-tcp:/autolaunch:/tcp:host:port]],[Transport Type to be used (default: nonce-tcp:)]),with_dbus_session_bus_default_address=$withval,with_dbus_session_bus_default_address=nonce-tcp:)
 155
 156 AC_ARG_ENABLE([embedded-tests],
 157   AS_HELP_STRING([--enable-embedded-tests],
 158     [enable unit test code in the library and binaries]),
 159   [], [enable_embedded_tests=$USE_MAINTAINER_MODE])
 160 AC_ARG_ENABLE([modular-tests],
 161   AS_HELP_STRING([--enable-modular-tests],
 162     [enable modular regression tests (requires GLib)]),
 163   [], [enable_modular_tests=auto])
 164 # --enable-tests overrides both --enable-embedded-tests and
 165 # --enable-modular-tests
 166 AC_ARG_ENABLE([tests],
 167   AS_HELP_STRING([--enable-tests],
 168     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 169   [
 170   if test "x$enableval" = xyes; then
 171     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 172     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 173   fi
 174   enable_embedded_tests=$enableval
 175   enable_modular_tests=$enableval
 176   ],
 177   [])
 178
 179 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 180 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 181 # name for this.
 182 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 183 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 184   [test "x$enable_embedded_tests" = xyes])
 185 if test "x$enable_embedded_tests" = xyes; then
 186     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 187       [Define to build test code into the library and binaries])
 188     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 189       [Define to build test code into the library and binaries])
 190 fi
 191
 192 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 193 # These use GTest, from GLib, because life's too short. They're enabled by
 194 # default (unless you don't have GLib), because they don't bloat the library
 195 # or binaries.
 196 if test "x$enable_modular_tests" != xno; then
 197   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 198     [],
 199     [if test "x$enable_modular_tests" = xyes; then
 200       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 201       AC_MSG_ERROR([$GLIB_ERRORS])
 202     else # assumed to be "auto"
 203       enable_modular_tests=no
 204     fi])
 205   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 206   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 207     [],
 208     [if test "x$enable_modular_tests" = xyes; then
 209       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 210       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 211     else # assumed to be "auto"
 212       enable_modular_tests=no
 213     fi])
 214   if test "x$enable_modular_tests" != xno; then
 215     # dependencies checked, switch from auto to yes
 216     enable_modular_tests=yes
 217   fi
 218 fi
 219 if test "x$enable_modular_tests" = xyes; then
 220   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 221     [Define to build independent test binaries (requires GLib)])
 222 fi
 223 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 224   [test "x$enable_modular_tests" = xyes])
 225
 226 AC_ARG_ENABLE([installed-tests],
 227   AS_HELP_STRING([--enable-installed-tests],
 228     [enable unit test code in the library and binaries]),
 229   [], [enable_installed_tests=no])
 230 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 231   [test "x$enable_installed_tests" = xyes])
 232
 233 if test "x$enable_tests" = xyes; then
 234   # full test coverage is required, Python is a hard dependency
 235   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 236   AM_PATH_PYTHON([2.6])
 237   AC_MSG_CHECKING([for Python modules for full test coverage])
 238   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 239     AC_MSG_RESULT([yes])
 240   else
 241     AC_MSG_RESULT([no])
 242     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 243   fi
 244 else
 245   # --enable-tests not given: do not abort if Python is missing
 246   AM_PATH_PYTHON([2.6], [], [:])
 247 fi
 248
 249 if test x$enable_verbose_mode = xyes; then
 250     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 251 fi
 252
 253 if test x$enable_asserts = xno; then
 254     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 255     DISABLE_UNUSED_WARNINGS="unused-label"
 256     R_DYNAMIC_LDFLAG=""
 257 else
 258     # -rdynamic is needed for glibc's backtrace_symbols to work.
 259     # No clue how much overhead this adds, but it's useful
 260     # to do this on any assertion failure,
 261     # so for now it's enabled anytime asserts are (currently not
 262     # in production builds).
 263
 264     # To get -rdynamic you pass -export-dynamic to libtool.
 265     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 266     R_DYNAMIC_LDFLAG=-export-dynamic
 267 fi
 268 AC_SUBST(R_DYNAMIC_LDFLAG)
 269
 270 if test x$enable_checks = xno; then
 271     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 272     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 273     DISABLE_UNUSED_WARNINGS="unused-label"
 274 fi
 275
 276 if test x$enable_userdb_cache = xyes; then
 277     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 278 fi
 279
 280 if test x$enable_compiler_coverage = xyes; then
 281      ## so that config.h changes when you toggle gcov support
 282      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 283 fi
 284
 285 # glibc21.m4 serial 3
 286 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 287 dnl This file is free software; the Free Software Foundation
 288 dnl gives unlimited permission to copy and/or distribute it,
 289 dnl with or without modifications, as long as this notice is preserved.
 290
 291 # Test for the GNU C Library, version 2.1 or newer.
 292 # From Bruno Haible.
 293
 294 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 295   ac_cv_gnu_library_2_1,
 296   [AC_EGREP_CPP([Lucky GNU user],
 297     [
 298 #include <features.h>
 299 #ifdef __GNU_LIBRARY__
 300  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 301   Lucky GNU user
 302  #endif
 303 #endif
 304     ],
 305     ac_cv_gnu_library_2_1=yes,
 306     ac_cv_gnu_library_2_1=no)
 307   ]
 308 )
 309
 310 #### Integer sizes
 311
 312 AC_CHECK_SIZEOF(char)
 313 AC_CHECK_SIZEOF(short)
 314 AC_CHECK_SIZEOF(long)
 315 AC_CHECK_SIZEOF(int)
 316 AC_CHECK_SIZEOF(void *)
 317 AC_CHECK_SIZEOF(long long)
 318 AC_CHECK_SIZEOF(__int64)
 319
 320 AC_ARG_WITH([64-bit],
 321   [AS_HELP_STRING([--without-64-bit],
 322     [If you have to use this option, please report it as a bug])],
 323   [],
 324   [with_64_bit=yes])
 325
 326 ### See what our 64 bit type is called
 327 AC_MSG_CHECKING([64-bit integer type])
 328
 329 case 8 in
 330 $ac_cv_sizeof_int)
 331   dbusint64=int
 332   dbusint64_constant='(val)'
 333   dbusuint64_constant='(val)'
 334   dbusint64_printf_modifier='""'
 335   ;;
 336 $ac_cv_sizeof_long)
 337   dbusint64=long
 338   dbusint64_constant='(val##L)'
 339   dbusuint64_constant='(val##UL)'
 340   dbusint64_printf_modifier='"l"'
 341   ;;
 342 $ac_cv_sizeof_long_long)
 343   dbusint64='long long'
 344   dbusint64_constant='(val##LL)'
 345   dbusuint64_constant='(val##ULL)'
 346   # Ideally we discover what the format is, but this is
 347   # only used in verbose mode, so eh...
 348   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 349     dbusint64_printf_modifier='"ll"'
 350   fi
 351   ;;
 352 $ac_cv_sizeof___int64)
 353   dbusint64=__int64
 354   dbusint64_constant='(val##i64)'
 355   dbusuint64_constant='(val##ui64)'
 356   # See above case
 357   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 358     dbusint64_printf_modifier='"ll"'
 359   fi
 360   ;;
 361 esac
 362
 363 AS_IF(
 364   [test "x$with_64_bit" = xno],
 365   [
 366         DBUS_INT64_TYPE="no_int64_type_detected"
 367         DBUS_HAVE_INT64=0
 368         DBUS_INT64_CONSTANT=
 369         DBUS_UINT64_CONSTANT=
 370         AC_MSG_RESULT([disabled via --without-64-bit])
 371   ],
 372   dnl else if
 373   [test -z "$dbusint64"],
 374   [AC_MSG_RESULT([not found])
 375   AC_MSG_ERROR([Could not find a 64-bit integer type.
 376
 377 Please report a bug here with details of your platform and compiler:
 378
 379     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 380
 381 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 382 the option "--without-64-bit".
 383
 384 This option is likely to be removed in future, unless you report that your
 385 platform needs it.])
 386   ],
 387   dnl else
 388   [
 389         DBUS_INT64_TYPE="$dbusint64"
 390         DBUS_HAVE_INT64=1
 391         DBUS_INT64_CONSTANT="$dbusint64_constant"
 392         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 393         if test x"$dbusint64_printf_modifier" != x; then
 394                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 395         fi
 396         AC_MSG_RESULT($DBUS_INT64_TYPE)
 397   ])
 398
 399 AC_SUBST(DBUS_INT64_TYPE)
 400 AC_SUBST(DBUS_INT64_CONSTANT)
 401 AC_SUBST(DBUS_UINT64_CONSTANT)
 402 AC_SUBST(DBUS_HAVE_INT64)
 403
 404 ### see what 32-bit int is called
 405 AC_MSG_CHECKING([32-bit integer type])
 406
 407 case 4 in
 408 $ac_cv_sizeof_short)
 409   dbusint32=short
 410   ;;
 411 $ac_cv_sizeof_int)
 412   dbusint32=int
 413   ;;
 414 $ac_cv_sizeof_long)
 415   dbusint32=long
 416   ;;
 417 esac
 418
 419 if test -z "$dbusint32" ; then
 420         DBUS_INT32_TYPE="no_int32_type_detected"
 421         AC_MSG_ERROR([No 32-bit integer type found])
 422 else
 423         DBUS_INT32_TYPE="$dbusint32"
 424         AC_MSG_RESULT($DBUS_INT32_TYPE)
 425 fi
 426
 427 AC_SUBST(DBUS_INT32_TYPE)
 428
 429 ### see what 16-bit int is called
 430 AC_MSG_CHECKING([16-bit integer type])
 431
 432 case 2 in
 433 $ac_cv_sizeof_short)
 434   dbusint16=short
 435   ;;
 436 $ac_cv_sizeof_int)
 437   dbusint16=int
 438   ;;
 439 esac
 440
 441 if test -z "$dbusint16" ; then
 442         DBUS_INT16_TYPE="no_int16_type_detected"
 443         AC_MSG_ERROR([No 16-bit integer type found])
 444 else
 445         DBUS_INT16_TYPE="$dbusint16"
 446         AC_MSG_RESULT($DBUS_INT16_TYPE)
 447 fi
 448
 449 AC_SUBST(DBUS_INT16_TYPE)
 450
 451 ## byte order
 452 case $host_os in
 453         darwin*)
 454                 # check at compile-time, so that it is possible to build universal
 455                 # (with multiple architectures at once on the compile line)
 456                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 457                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 458                         #if defined(__BIG_ENDIAN__)
 459                         #define WORDS_BIGENDIAN 1
 460                         #endif
 461                 ])
 462                 ;;
 463         *)
 464                 AC_C_BIGENDIAN
 465                 ;;
 466 esac
 467
 468 dnl **********************************
 469 dnl *** va_copy checks (from GLib) ***
 470 dnl **********************************
 471 dnl we currently check for all three va_copy possibilities, so we get
 472 dnl all results in config.log for bug reports.
 473 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 474         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 475 #include <stdlib.h>
 476         static void f (int i, ...) {
 477         va_list args1, args2;
 478         va_start (args1, i);
 479         va_copy (args2, args1);
 480         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 481           exit (1);
 482         va_end (args1); va_end (args2);
 483         }
 484         int main() {
 485           f (0, 42);
 486           return 0;
 487         }])],
 488         [dbus_cv_va_copy=yes],
 489         [dbus_cv_va_copy=no])
 490 ])
 491 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 492         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 493 #include <stdlib.h>
 494         static void f (int i, ...) {
 495         va_list args1, args2;
 496         va_start (args1, i);
 497         __va_copy (args2, args1);
 498         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 499           exit (1);
 500         va_end (args1); va_end (args2);
 501         }
 502         int main() {
 503           f (0, 42);
 504           return 0;
 505         }])],
 506         [dbus_cv___va_copy=yes],
 507         [dbus_cv___va_copy=no])
 508 ])
 509
 510 if test "x$dbus_cv_va_copy" = "xyes"; then
 511   dbus_va_copy_func=va_copy
 512 else if test "x$dbus_cv___va_copy" = "xyes"; then
 513   dbus_va_copy_func=__va_copy
 514 fi
 515 fi
 516
 517 if test -n "$dbus_va_copy_func"; then
 518   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 519 fi
 520
 521 AC_LANG_PUSH(C)
 522 AC_CACHE_CHECK([whether va_lists can be copied by value],
 523         dbus_cv_va_val_copy,
 524         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 525 [[
 526         #include <stdarg.h>
 527         #include <stdlib.h>
 528 ]],
 529 [[
 530         static void f (int i, ...) {
 531         va_list args1, args2;
 532         va_start (args1, i);
 533         args2 = args1;
 534         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 535           exit (1);
 536         va_end (args1); va_end (args2);
 537         }
 538         int main() {
 539           f (0, 42);
 540           return 0;
 541         }
 542 ]])],
 543         [dbus_cv_va_val_copy=yes],
 544         [dbus_cv_va_val_copy=no],
 545         [dbus_cv_va_val_copy=yes])
 546 ])
 547 AC_LANG_POP(C)
 548
 549 if test "x$dbus_cv_va_val_copy" = "xno"; then
 550   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 551 fi
 552
 553
 554 #### Atomic integers
 555
 556 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 557   dbus_cv_sync_sub_and_fetch,
 558   [AC_LINK_IFELSE([
 559      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 560      [dbus_cv_sync_sub_and_fetch=yes],
 561      [dbus_cv_sync_sub_and_fetch=no])
 562   ])
 563
 564 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 565    have_sync=1
 566 else
 567    have_sync=0
 568 fi
 569
 570 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 571
 572 #### Various functions
 573 AC_SEARCH_LIBS(socket,[socket network])
 574 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 575
 576 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 577
 578 AC_CHECK_HEADERS([syslog.h])
 579 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 580   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 581 fi
 582
 583 #### Check for broken poll; taken from Glib's configure
 584
 585 AC_MSG_CHECKING([for broken poll])
 586 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 587     #include <stdlib.h>
 588     #include <fcntl.h>
 589     #include <poll.h>
 590     #ifdef HAVE_SYS_POLL_H
 591     #include <sys/poll.h>
 592     #endif
 593     int main(void) {
 594       struct pollfd fds[1];
 595       int fd;
 596       fd = open("/dev/null", 1);
 597       fds[0].fd = fd;
 598       fds[0].events = POLLIN;
 599       fds[0].revents = 0;
 600       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 601             exit(1);  /* Does not work for devices -- fail */
 602       }
 603       exit(0);
 604     }]])],
 605   [broken_poll=no],
 606   [broken_poll=yes
 607    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 608   [broken_poll="no (cross compiling)"])
 609 AC_MSG_RESULT($broken_poll)
 610
 611 AC_MSG_CHECKING(for dirfd)
 612 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 613 #include <sys/types.h>
 614 #include <dirent.h>
 615 ]], [[
 616 DIR *dirp;
 617 dirp = opendir(".");
 618 dirfd(dirp);
 619 closedir(dirp);
 620 ]])],
 621 [dbus_have_dirfd=yes],
 622 [dbus_have_dirfd=no])
 623 AC_MSG_RESULT($dbus_have_dirfd)
 624 if test "$dbus_have_dirfd" = yes; then
 625         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 626 else
 627         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 628         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 629 #include <sys/types.h>
 630 #include <dirent.h>
 631         ]], [[
 632 DIR *dirp;
 633 int fd;
 634 dirp = opendir(".");
 635 fd = dirp->dd_fd;
 636 closedir(dirp);
 637         ]])],
 638         [dbus_have_ddfd=yes],
 639         [dbus_have_ddfd=no])
 640         AC_MSG_RESULT($dbus_have_ddfd)
 641         if test "$dbus_have_ddfd" = yes; then
 642                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 643         fi
 644 fi
 645
 646 AC_CHECK_HEADERS(sys/resource.h)
 647
 648 AC_CHECK_HEADERS(dirent.h)
 649
 650 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 651
 652 AC_CHECK_HEADERS(errno.h)
 653
 654 AC_CHECK_HEADERS(signal.h)
 655
 656 AC_CHECK_HEADERS(locale.h)
 657
 658 AC_CHECK_HEADERS(byteswap.h)
 659
 660 AC_CHECK_HEADERS(unistd.h)
 661
 662 AC_CHECK_HEADERS(ws2tcpip.h)
 663
 664 AC_CHECK_HEADERS(wspiapi.h)
 665
 666 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 667 #
 668 case $host_os in
 669     solaris*)
 670        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 671 esac
 672
 673 # checking for a posix version of getpwnam_r
 674 # if we are cross compiling and can not run the test
 675 # assume getpwnam_r is the posix version
 676 # it is up to the person cross compiling to change
 677 # this behavior if desired
 678 AC_LANG_PUSH(C)
 679 AC_CACHE_CHECK([for posix getpwnam_r],
 680                 ac_cv_func_posix_getpwnam_r,
 681                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 682 [[
 683 #include <errno.h>
 684 #include <pwd.h>
 685 ]],
 686 [[
 687     char buffer[10000];
 688     struct passwd pwd, *pwptr = &pwd;
 689     int error;
 690     errno = 0;
 691     error = getpwnam_r ("", &pwd, buffer,
 692                         sizeof (buffer), &pwptr);
 693    return (error < 0 && errno == ENOSYS)
 694            || error == ENOSYS;
 695 ]])],
 696         [ac_cv_func_posix_getpwnam_r=yes],
 697         [ac_cv_func_posix_getpwnam_r=no],
 698         [ac_cv_func_posix_getpwnam_r=yes]
 699 )])
 700 AC_LANG_POP(C)
 701
 702 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 703         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 704                 [Have POSIX function getpwnam_r])
 705 else
 706         AC_CACHE_CHECK([for nonposix getpwnam_r],
 707                 ac_cv_func_nonposix_getpwnam_r,
 708                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 709                         struct passwd pwd;
 710                         getpwnam_r ("", &pwd, buffer,
 711                                         sizeof (buffer));]])],
 712                         [ac_cv_func_nonposix_getpwnam_r=yes],
 713                         [ac_cv_func_nonposix_getpwnam_r=no])])
 714                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 715                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 716                         [Have non-POSIX function getpwnam_r])
 717         fi
 718 fi
 719
 720 dnl check for socklen_t
 721 AC_MSG_CHECKING(whether socklen_t is defined)
 722 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 723 #include <sys/types.h>
 724 #include <sys/socket.h>
 725 #include <netdb.h>
 726 ]], [[
 727 socklen_t foo;
 728 foo = 1;
 729 ]])],
 730 [dbus_have_socklen_t=yes],
 731 [dbus_have_socklen_t=no])
 732 AC_MSG_RESULT($dbus_have_socklen_t)
 733
 734 if test "x$dbus_have_socklen_t" = "xyes"; then
 735     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 736 fi
 737
 738 dnl check for writev header and writev function so we're
 739 dnl good to go if HAVE_WRITEV gets defined.
 740 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 741
 742 dnl needed on darwin for NAME_MAX
 743 AC_CHECK_HEADERS(sys/syslimits.h)
 744
 745 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 746 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 747
 748 dnl check for flavours of varargs macros (test from GLib)
 749 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 750 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 751 int a(int p1, int p2, int p3);
 752 #define call_a(...) a(1,__VA_ARGS__)
 753 call_a(2,3);
 754 ]])],
 755 [dbus_have_iso_c_varargs=yes],
 756 [dbus_have_iso_c_varargs=no])
 757 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 758
 759 AC_MSG_CHECKING(for GNUC varargs macros)
 760 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 761 int a(int p1, int p2, int p3);
 762 #define call_a(params...) a(1,params)
 763 call_a(2,3);
 764 ]])],
 765 [dbus_have_gnuc_varargs=yes],
 766 [dbus_have_gnuc_varargs=no])
 767 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 768
 769 dnl Output varargs tests
 770 if test x$dbus_have_iso_c_varargs = xyes; then
 771     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 772 fi
 773 if test x$dbus_have_gnuc_varargs = xyes; then
 774     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 775 fi
 776
 777 dnl Check for various credentials.
 778 AC_MSG_CHECKING(for struct cmsgcred)
 779 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 780 #include <sys/types.h>
 781 #include <sys/socket.h>
 782 ]], [[
 783 struct cmsgcred cred;
 784
 785 cred.cmcred_pid = 0;
 786 ]])],
 787 [dbus_have_struct_cmsgcred=yes],
 788 [dbus_have_struct_cmsgcred=no])
 789 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 790
 791 if test x$dbus_have_struct_cmsgcred = xyes; then
 792     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 793 fi
 794
 795 AC_CHECK_FUNCS(getpeerucred getpeereid)
 796
 797 AC_CHECK_FUNCS(pipe2 accept4)
 798
 799 #### Abstract sockets
 800
 801 if test x$enable_abstract_sockets = xauto; then
 802 AC_LANG_PUSH(C)
 803 warn_on_xcompile=no
 804 AC_CACHE_CHECK([abstract socket namespace],
 805                 ac_cv_have_abstract_sockets,
 806                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 807 [[
 808 #include <sys/types.h>
 809 #include <stdlib.h>
 810 #include <string.h>
 811 #include <stdio.h>
 812 #include <sys/socket.h>
 813 #include <sys/un.h>
 814 #include <errno.h>
 815 ]],
 816 [[
 817   size_t slen;
 818   int listen_fd;
 819   struct sockaddr_un addr;
 820
 821   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 822
 823   if (listen_fd < 0)
 824     {
 825       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 826       exit (1);
 827     }
 828
 829   memset (&addr, '\0', sizeof (addr));
 830   addr.sun_family = AF_UNIX;
 831   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 832   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 833    * beginning.
 834    */
 835   slen = SUN_LEN(&addr);
 836   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 837
 838   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 839     {
 840        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 841                 strerror (errno));
 842        exit (1);
 843     }
 844   else
 845     exit (0);
 846 ]])],
 847               [ac_cv_have_abstract_sockets=yes],
 848               [ac_cv_have_abstract_sockets=no],
 849               [
 850                 ac_cv_have_abstract_sockets=no
 851                 warn_on_xcompile=yes
 852               ]
 853 )])
 854 if test x$warn_on_xcompile = xyes ; then
 855   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 856 fi
 857 AC_LANG_POP(C)
 858 fi
 859
 860 if test x$enable_abstract_sockets = xyes; then
 861     if test x$ac_cv_have_abstract_sockets = xno; then
 862         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 863     fi
 864 fi
 865
 866 if test x$enable_abstract_sockets = xno; then
 867    ac_cv_have_abstract_sockets=no;
 868 fi
 869
 870 if test x$ac_cv_have_abstract_sockets = xyes ; then
 871    DBUS_PATH_OR_ABSTRACT=abstract
 872    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 873 else
 874    DBUS_PATH_OR_ABSTRACT=path
 875 fi
 876
 877 # this is used in addresses to prefer abstract, e.g.
 878 # unix:path=/foo or unix:abstract=/foo
 879 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 880
 881 PKG_PROG_PKG_CONFIG
 882
 883 #### Sort out XML library
 884
 885 # see what we have
 886 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 887              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 888              have_expat=false)
 889
 890 # see what we want to use
 891 dbus_use_libxml=false
 892 dbus_use_expat=false
 893 if test x$with_xml = xexpat; then
 894         if ! $have_expat ; then
 895            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 896         fi
 897         dbus_use_expat=true
 898 elif test x$with_xml = xlibxml; then
 899         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 900         if ! $have_libxml ; then
 901            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 902         fi
 903         dbus_use_libxml=true
 904 else
 905         ### expat is the default because libxml can't currently survive
 906         ### our brutal OOM-handling unit test setup.
 907         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 908         if test x$have_expat = xfalse; then
 909                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 910         fi
 911         ### By default, only use Expat since it's tested and known to work.  If you're a
 912         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 913         ### if your OS is built around libxml, that's another case.
 914         dbus_use_expat=true
 915 fi
 916
 917 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 918 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 919
 920 if $dbus_use_expat; then
 921    XML_LIBS=-lexpat
 922    XML_CFLAGS=
 923 fi
 924 if $dbus_use_libxml; then
 925    XML_LIBS=$LIBXML_LIBS
 926    XML_CFLAGS=$LIBXML_CFLAGS
 927 fi
 928 AC_SUBST([XML_CFLAGS])
 929 AC_SUBST([XML_LIBS])
 930
 931 # Thread lib detection
 932 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 933                                                     [THREAD_LIBS="-lpthread"])])
 934 save_libs="$LIBS"
 935 LIBS="$LIBS $THREAD_LIBS"
 936 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 937 if test x$have_pthread_condattr_setclock = xtrue; then
 938     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 939     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 940     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 941 #include <pthread.h>
 942 ]], [[
 943 struct timespec monotonic_timer;
 944 pthread_condattr_t attr;
 945 pthread_condattr_init (&attr);
 946 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 947 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 948 ]])],
 949 [have_clock_monotonic=true],
 950 [have_clock_monotonic=false])
 951 if test x$have_clock_monotonic = xtrue; then
 952     AC_MSG_RESULT([found])
 953     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 954 else
 955     AC_MSG_RESULT([not found])
 956 fi
 957 fi
 958 LIBS="$save_libs"
 959
 960 AC_SUBST([THREAD_LIBS])
 961
 962 # SELinux detection
 963 if test x$enable_selinux = xno ; then
 964     have_selinux=no;
 965 else
 966     # See if we have SELinux library
 967     AC_CHECK_LIB(selinux, is_selinux_enabled,
 968                  have_selinux=yes, have_selinux=no)
 969
 970     # see if we have the SELinux header with the new D-Bus stuff in it
 971     if test x$have_selinux = xyes ; then
 972         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 973         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 974                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 975                             #else
 976                             #error DBUS__ACQUIRE_SVC not defined
 977                             #endif]])],
 978                           [have_selinux=yes],
 979                           [have_selinux=no])
 980         AC_MSG_RESULT($have_selinux)
 981     fi
 982
 983     if test x$enable_selinux = xauto ; then
 984         if test x$have_selinux = xno ; then
 985                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 986         fi
 987     else
 988         if test x$have_selinux = xno ; then
 989                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 990         fi
 991     fi
 992 fi
 993
 994 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 995
 996 if test x$have_selinux = xyes ; then
 997     # the selinux code creates threads
 998     # which requires libpthread even on linux
 999     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1000                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1001
1002     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1003     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1004 else
1005     SELINUX_LIBS=
1006 fi
1007
1008 # inotify checks
1009 if test x$enable_inotify = xno ; then
1010     have_inotify=no;
1011 else
1012     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1013 fi
1014
1015 dnl check if inotify backend is enabled
1016 if test x$have_inotify = xyes; then
1017    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1018    AC_CHECK_FUNCS(inotify_init1)
1019 fi
1020
1021 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1022
1023 # dnotify checks
1024 if test x$enable_dnotify = xno ; then
1025     have_dnotify=no;
1026 else
1027     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1028         have_dnotify=yes;
1029     else
1030         have_dnotify=no;
1031     fi
1032 fi
1033
1034 dnl check if dnotify backend is enabled
1035 if test x$have_dnotify = xyes; then
1036    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1037 fi
1038
1039 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1040
1041 # For simplicity, we require the userland API for epoll_create1 at
1042 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1043 # not to have it at runtime.
1044 AC_ARG_ENABLE([epoll],
1045               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1046               [enable_epoll=$enableval], [enable_epoll=auto])
1047 if test x$enable_epoll = xno; then
1048     have_linux_epoll=no
1049 else
1050     AC_MSG_CHECKING([for Linux epoll(4)])
1051     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1052         [
1053         #ifndef __linux__
1054         #error This is not Linux
1055         #endif
1056         #include <sys/epoll.h>
1057         ],
1058         [epoll_create1 (EPOLL_CLOEXEC);])],
1059         [have_linux_epoll=yes],
1060         [have_linux_epoll=no])
1061     AC_MSG_RESULT([$have_linux_epoll])
1062 fi
1063 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1064     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1065 fi
1066 if test x$have_linux_epoll = xyes; then
1067   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1068 fi
1069 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1070
1071 # kqueue checks
1072 if test x$enable_kqueue = xno ; then
1073     have_kqueue=no
1074 else
1075     have_kqueue=yes
1076     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1077     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1078
1079     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1080         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1081     fi
1082 fi
1083
1084 dnl check if kqueue backend is enabled
1085 if test x$have_kqueue = xyes; then
1086    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1087 fi
1088
1089 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1090
1091 # launchd checks
1092 if test x$enable_launchd = xno ; then
1093     have_launchd=no
1094 else
1095     have_launchd=yes
1096     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1097     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1098     if test "x$LAUNCHCTL" = "x"; then
1099         have_launchd=no
1100     fi
1101
1102     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1103         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1104     fi
1105 fi
1106
1107 dnl check if launchd is enabled
1108 if test x$have_launchd = xyes; then
1109     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1110 fi
1111
1112 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1113
1114 #### Directory to place launchd agent file
1115 if test "x$with_launchd_agent_dir" = "x"; then
1116    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1117 else
1118    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1119 fi
1120
1121 AC_SUBST(LAUNCHD_AGENT_DIR)
1122
1123 dnl console owner file
1124 if test x$enable_console_owner_file = xno ; then
1125     have_console_owner_file=no;
1126 else
1127     case $host_os in
1128     solaris*)
1129         have_console_owner_file=yes;
1130         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1131         ;;
1132     *)
1133         have_console_owner_file=no;;
1134     esac
1135 fi
1136
1137 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1138
1139 dnl systemd detection
1140 if test x$enable_systemd = xno ; then
1141     have_systemd=no;
1142 else
1143     PKG_CHECK_MODULES(SYSTEMD,
1144         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1145         have_systemd=yes,
1146         have_systemd=no)
1147 fi
1148
1149 if test x$have_systemd = xyes; then
1150     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1151 fi
1152
1153 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1154     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1155 fi
1156
1157 # libaudit detection
1158 if test x$enable_libaudit = xno ; then
1159     have_libaudit=no;
1160 else
1161     # See if we have audit daemon & capabilities library
1162     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1163                  have_libaudit=yes, have_libaudit=no)
1164     if test x$have_libaudit = xyes ; then
1165         AC_CHECK_LIB(cap-ng, capng_clear,
1166                  have_libaudit=yes, have_libaudit=no)
1167     fi
1168 fi
1169
1170 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1171
1172 if test x$have_libaudit = xyes ; then
1173     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1174     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1175 fi
1176
1177 AC_SUBST([SELINUX_LIBS])
1178
1179 # Check for ADT API (Solaris Basic Security Mode auditing)
1180 AC_MSG_CHECKING(for ADT API)
1181 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1182 #include <bsm/adt.h>
1183 adt_user_context = ADT_USER;
1184 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1185
1186 if test ${check_adt_audit} = yes
1187 then
1188    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1189    ADT_LIBS="-lbsm"
1190    LIBS="-lbsm $LIBS"
1191    AC_MSG_RESULT(yes)
1192 else
1193    AC_MSG_RESULT(no)
1194 fi
1195 AC_SUBST([ADT_LIBS])
1196
1197 # Check for SCM_RIGHTS
1198 AC_MSG_CHECKING([for SCM_RIGHTS])
1199 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1200 #include <sys/socket.h>
1201 #include <sys/un.h>
1202 static int x = SCM_RIGHTS;
1203 ]], [[]])],
1204 [ AC_MSG_RESULT([supported])
1205   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1206 [ AC_MSG_RESULT([not supported]) ])
1207
1208 NETWORK_libs=
1209 if test x$dbus_win = xyes ; then
1210   if test x$dbus_wince = xyes ; then
1211     NETWORK_libs="-lws2"
1212   else
1213     NETWORK_libs="-lws2_32"
1214   fi
1215 fi
1216
1217 AC_SUBST([NETWORK_libs])
1218
1219 AC_ARG_WITH([valgrind],
1220   [AS_HELP_STRING([--with-valgrind],
1221      [Add instrumentation to help valgrind to understand our allocator])],
1222   [],
1223   [with_valgrind=no])
1224
1225 if test x$with_valgrind != xno; then
1226   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1227   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1228 fi
1229
1230 #### Set up final flags
1231 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1232 AC_SUBST([LIBDBUS_LIBS])
1233
1234 ### X11 detection
1235 DBUS_X_LIBS=
1236 DBUS_X_CFLAGS=
1237
1238 AC_ARG_ENABLE([x11-autolaunch],
1239   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1240   [], [enable_x11_autolaunch=auto])
1241
1242 if test "x$dbus_win" = xyes; then
1243     if test "x$enable_x11_autolaunch" = xyes; then
1244         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1245     fi
1246
1247     enable_x11_autolaunch=no
1248     have_x11=no
1249 else
1250     AC_PATH_XTRA
1251
1252     if test "x$no_x" = xyes; then
1253         have_x11=no
1254     else
1255         have_x11=yes
1256         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1257         DBUS_X_CFLAGS="$X_CFLAGS"
1258     fi
1259 fi
1260
1261 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1262     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1263 else
1264     # move from "auto" to "yes" or "no" if necessary
1265     if test "x$enable_x11_autolaunch" != xno; then
1266         enable_x11_autolaunch="$have_x11"
1267     fi
1268 fi
1269
1270 if test "x$have_x11" = xyes ; then
1271    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1272 fi
1273
1274 if test "x$enable_x11_autolaunch" = xyes ; then
1275    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1276 fi
1277
1278 AC_SUBST([DBUS_X_CFLAGS])
1279 AC_SUBST([DBUS_X_LIBS])
1280
1281 #### gcc warning flags
1282
1283 cc_supports_flag() {
1284   AC_MSG_CHECKING(whether $CC supports "$*")
1285   save_CFLAGS="$CFLAGS"
1286   CFLAGS="$*"
1287   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1288   CFLAGS="$save_CFLAGS"
1289   AC_MSG_RESULT([$rc])
1290   test "x$rc" = xyes
1291 }
1292
1293 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1294   dnl Use -Werror by default if:
1295   dnl - we're not on Windows (too many warnings), and
1296   dnl - we're in maintainer mode (a D-Bus developer, not a distro or end-user)
1297   dnl Override with --enable-Werror or --disable-Werror
1298   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes],
1299
1300   dnl Enable these warnings if possible:
1301   [all \
1302    extra \
1303    char-subscripts \
1304    missing-declarations \
1305    missing-prototypes \
1306    nested-externs \
1307    pointer-arith \
1308    cast-align \
1309    no-address \
1310    float-equal \
1311    declaration-after-statement \
1312   ],
1313
1314   dnl Disable these warnings if possible, make them non-fatal if possible,
1315   dnl and don't enable -Werror unless we succeeded.
1316   dnl
1317   dnl Intentional:
1318   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1319   dnl   checking or not asserting
1320   dnl - missing field initializers being 0 is a C feature, not a bug
1321   dnl - unused-parameter is to make writing callbacks less annoying
1322   dnl
1323   dnl To be fixed one day:
1324   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1325   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1326   dnl   is better than nothing
1327   [$DISABLE_UNUSED_WARNINGS \
1328    missing-field-initializers \
1329    unused-parameter \
1330    sign-compare \
1331    pointer-sign \
1332    type-limits \
1333   ])
1334
1335 if test "x$GCC" = "xyes"; then
1336   # We're treating -fno-common like a warning: it makes the linker more
1337   # strict, because on some systems the linker is *always* this strict
1338   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1339
1340   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1341   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1342
1343   if test "x$enable_ansi" = "xyes"; then
1344     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1345       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1346   fi
1347 fi
1348
1349 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1350 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1351 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1352 dnl is the next best thing
1353 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1354
1355 case $host_os in
1356     solaris*)
1357         # Solaris' C library apparently needs these runes to be threadsafe...
1358         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1359         # ... and this opt-in to get file descriptor passing support
1360         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1361         ;;
1362 esac
1363
1364 ### Doxygen Documentation
1365
1366 AC_PATH_PROG(DOXYGEN, doxygen, no)
1367
1368 AC_MSG_CHECKING([whether to build Doxygen documentation])
1369
1370 if test x$DOXYGEN = xno ; then
1371     have_doxygen=no
1372 else
1373     have_doxygen=yes
1374 fi
1375
1376 if test x$enable_doxygen_docs = xauto ; then
1377     if test x$have_doxygen = xno ; then
1378         enable_doxygen_docs=no
1379     else
1380         enable_doxygen_docs=yes
1381     fi
1382 fi
1383
1384 if test x$enable_doxygen_docs = xyes; then
1385     if test x$have_doxygen = xno; then
1386         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1387     fi
1388 fi
1389
1390 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1391 AC_MSG_RESULT($enable_doxygen_docs)
1392
1393 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1394 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1395
1396 ### XML Documentation
1397
1398 AC_PATH_PROG(XMLTO, xmlto, no)
1399
1400 AC_MSG_CHECKING([whether to build XML documentation])
1401
1402 if test x$XMLTO = xno ; then
1403     have_xmlto=no
1404 else
1405     have_xmlto=yes
1406 fi
1407
1408 if test x$enable_xml_docs = xauto ; then
1409     if test x$have_xmlto = xno ; then
1410         enable_xml_docs=no
1411     else
1412         enable_xml_docs=yes
1413     fi
1414 fi
1415
1416 if test x$enable_xml_docs = xyes; then
1417     if test x$have_xmlto = xno; then
1418         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1419     fi
1420 fi
1421
1422 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1423 AC_MSG_RESULT($enable_xml_docs)
1424
1425 AC_PATH_PROG([MAN2HTML], [man2html])
1426 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1427 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1428
1429 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1430     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1431          x$MAN2HTML != x)
1432
1433 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1434
1435 #### find the actual value for $prefix that we'll end up with
1436 ##   (I know this is broken and should be done in the Makefile, but
1437 ##    that's a major pain and almost nobody actually seems to care)
1438 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1439 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1440 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1441 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1442 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1443 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1444 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1445
1446 #### Check our operating system
1447 operating_system=unknown
1448 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1449    operating_system=redhat
1450 fi
1451
1452 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1453    operating_system=slackware
1454 fi
1455
1456 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1457    operating_system=cygwin
1458 fi
1459
1460 #### Sort out init scripts
1461
1462 if test x$with_init_scripts = x; then
1463     case x$operating_system in
1464         xredhat)        with_init_scripts=redhat ;;
1465         xslackware)     with_init_scripts=slackware ;;
1466         xcygwin)        with_init_scripts=cygwin ;;
1467         *)                      with_init_scripts=none ;;
1468     esac
1469 fi
1470
1471 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1472 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1473 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1474
1475 ##### systemd unit files
1476 AC_ARG_WITH([systemdsystemunitdir],
1477 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1478     [],
1479     [
1480     PKG_CHECK_EXISTS([systemd],
1481       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1482       [with_systemdsystemunitdir=no])
1483     ])
1484 if test "x$with_systemdsystemunitdir" != xno; then
1485    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1486 fi
1487 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1488
1489 ##### Set up location for system bus socket
1490 if ! test -z "$with_system_socket"; then
1491    DBUS_SYSTEM_SOCKET=$with_system_socket
1492 else
1493    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1494 fi
1495
1496 AC_SUBST(DBUS_SYSTEM_SOCKET)
1497 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1498
1499 ## system bus only listens on local domain sockets, and never
1500 ## on an abstract socket (so only root can create the socket)
1501 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1502 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1503 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1504
1505 #### Set up the pid file
1506 if ! test -z "$with_system_pid_file"; then
1507    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1508 elif test x$with_init_scripts = xredhat ; then
1509    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1510 else
1511    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1512 fi
1513
1514 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1515
1516 #### Directory to check for console ownership
1517 if ! test -z "$with_console_auth_dir"; then
1518    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1519 else
1520    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1521 fi
1522
1523 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1524 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1525
1526 #### File to check for console ownership
1527 if test x$have_console_owner_file = xyes; then
1528    if ! test -z "$with_console_owner_file"; then
1529       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1530    else
1531       DBUS_CONSOLE_OWNER_FILE=/dev/console
1532    fi
1533 else
1534   DBUS_CONSOLE_OWNER_FILE=
1535 fi
1536
1537 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1538 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1539
1540 #### User to start the system bus as
1541 if test -z "$with_dbus_user" ; then
1542     DBUS_USER=messagebus
1543 else
1544     DBUS_USER=$with_dbus_user
1545 fi
1546 AC_SUBST(DBUS_USER)
1547 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1548
1549 #### Prefix to install into
1550 DBUS_PREFIX=$EXPANDED_PREFIX
1551 AC_SUBST(DBUS_PREFIX)
1552 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1553
1554 #### Direcotry to install data files into
1555 DBUS_DATADIR=$EXPANDED_DATADIR
1556 AC_SUBST(DBUS_DATADIR)
1557 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1558
1559 #### Directory to install dbus-daemon
1560 if test -z "$with_dbus_daemondir" ; then
1561     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1562 else
1563     DBUS_DAEMONDIR=$with_dbus_daemondir
1564 fi
1565 AC_SUBST(DBUS_DAEMONDIR)
1566 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1567
1568 #### Directory to install the other binaries
1569 DBUS_BINDIR="$EXPANDED_BINDIR"
1570 AC_SUBST(DBUS_BINDIR)
1571 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1572
1573 #### Directory to install the libexec binaries
1574 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1575 AC_SUBST(DBUS_LIBEXECDIR)
1576 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1577
1578 #### Tell tests where to find certain stuff in builddir
1579
1580 DBUS_PWD=`pwd`
1581 # Useful in a cross-compilation environment, where the tests are run on the host system.
1582 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1583                            DBUS_PWD=$withval)
1584
1585 DBUS_TEST_EXEC="$DBUS_PWD/test"
1586 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1587
1588 AC_SUBST([DBUS_TEST_DATA])
1589 AC_SUBST([DBUS_TEST_EXEC])
1590
1591 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1592                    [Full path to the daemon in the builddir])
1593 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1594                    [Extension for executables, typically empty or .exe])
1595
1596 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1597                    [Full path to the daemon in the builddir])
1598 AC_SUBST(TEST_BUS_BINARY)
1599
1600 ## Export the non-setuid external helper
1601 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1602 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1603 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1604                    [Full path to the launch helper test program in the builddir])
1605
1606 #### Find socket directories
1607 if ! test -z "$TMPDIR" ; then
1608    DEFAULT_SOCKET_DIR=$TMPDIR
1609 elif ! test -z "$TEMP" ; then
1610    DEFAULT_SOCKET_DIR=$TEMP
1611 elif ! test -z "$TMP" ; then
1612    DEFAULT_SOCKET_DIR=$TMP
1613 else
1614    DEFAULT_SOCKET_DIR=/tmp
1615 fi
1616
1617 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1618
1619 if ! test -z "$with_test_socket_dir" ; then
1620    TEST_SOCKET_DIR="$with_test_socket_dir"
1621 else
1622    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1623 fi
1624 AC_SUBST(TEST_SOCKET_DIR)
1625 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1626
1627 if test "x$dbus_unix" = xyes; then
1628   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1629 else
1630   TEST_LISTEN="tcp:host=localhost"
1631 fi
1632 AC_SUBST([TEST_LISTEN])
1633 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1634   [Listening address for regression tests])
1635
1636 if ! test -z "$with_session_socket_dir" ; then
1637    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1638 else
1639    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1640 fi
1641 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1642 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1643
1644 if test x$dbus_win = xyes; then
1645         DBUS_SESSION_BUS_DEFAULT_ADDRESS="$with_dbus_session_bus_default_address"
1646 elif test x$have_launchd = xyes; then
1647         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1648 else
1649         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1650 fi
1651 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1652
1653 # darwin needs this to initialize the environment
1654 AC_CHECK_HEADERS(crt_externs.h)
1655 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1656 AH_VERBATIM(_DARWIN_ENVIRON,
1657 [
1658 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1659 # include <sys/time.h>
1660 # include <crt_externs.h>
1661 # define environ (*_NSGetEnviron())
1662 #endif
1663 ])
1664
1665 AC_ARG_ENABLE([stats],
1666   [AS_HELP_STRING([--enable-stats],
1667     [enable bus daemon usage statistics])],
1668   [], [enable_stats=no])
1669 if test "x$enable_stats" = xyes; then
1670   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1671     [Define to enable bus daemon usage statistics])
1672 fi
1673
1674 AC_CONFIG_FILES([
1675 Doxyfile
1676 dbus/versioninfo.rc
1677 dbus/dbus-arch-deps.h
1678 bus/system.conf
1679 bus/session.conf
1680 bus/messagebus
1681 bus/messagebus-config
1682 bus/org.freedesktop.dbus-session.plist
1683 bus/rc.messagebus
1684 bus/dbus.service
1685 bus/dbus.socket
1686 Makefile
1687 dbus/Makefile
1688 bus/Makefile
1689 tools/Makefile
1690 test/Makefile
1691 test/name-test/Makefile
1692 doc/Makefile
1693 doc/dbus-daemon.1
1694 dbus-1.pc
1695 dbus-1-uninstalled.pc
1696 test/data/valid-config-files/debug-allow-all.conf
1697 test/data/valid-config-files/debug-allow-all-sha1.conf
1698 test/data/valid-config-files-system/debug-allow-all-pass.conf
1699 test/data/valid-config-files-system/debug-allow-all-fail.conf
1700 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1701 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1702 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1703 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1704 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1705 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1706 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1707 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1708 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1709 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1710 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1711 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1712 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1713 ])
1714 AC_OUTPUT
1715
1716 dnl ==========================================================================
1717 echo "
1718                     D-Bus $VERSION
1719                   ==============
1720
1721         prefix:                   ${EXPANDED_PREFIX}
1722         exec_prefix:              ${exec_prefix}
1723         libdir:                   ${EXPANDED_LIBDIR}
1724         libexecdir:               ${EXPANDED_LIBEXECDIR}
1725         bindir:                   ${EXPANDED_BINDIR}
1726         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1727         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1728         datadir:                  ${EXPANDED_DATADIR}
1729         source code location:     ${srcdir}
1730         compiler:                 ${CC}
1731         cflags:                   ${CFLAGS}
1732         cppflags:                 ${CPPFLAGS}
1733         cxxflags:                 ${CXXFLAGS}
1734         64-bit int:               ${DBUS_INT64_TYPE}
1735         32-bit int:               ${DBUS_INT32_TYPE}
1736         16-bit int:               ${DBUS_INT16_TYPE}
1737         Doxygen:                  ${DOXYGEN:-not found}
1738         xmlto:                    ${XMLTO:-not found}
1739         man2html:                 ${MAN2HTML:-not found}"
1740
1741 echo "
1742         Maintainer mode:          ${USE_MAINTAINER_MODE}
1743         gcc coverage profiling:   ${enable_compiler_coverage}
1744         Building embedded tests:  ${enable_embedded_tests}
1745         Building modular tests:   ${enable_modular_tests}
1746         Building verbose mode:    ${enable_verbose_mode}
1747         Building assertions:      ${enable_asserts}
1748         Building checks:          ${enable_checks}
1749         Building bus stats API:   ${enable_stats}
1750         Building SELinux support: ${have_selinux}
1751         Building inotify support: ${have_inotify}
1752         Building dnotify support: ${have_dnotify}
1753         Building kqueue support:  ${have_kqueue}
1754         Building systemd support: ${have_systemd}
1755         Building X11 code:        ${enable_x11}
1756         Building Doxygen docs:    ${enable_doxygen_docs}
1757         Building XML docs:        ${enable_xml_docs}
1758         Building cache support:   ${enable_userdb_cache}
1759         Building launchd support: ${have_launchd}
1760         Using XML parser:         ${with_xml}
1761         Init scripts style:       ${with_init_scripts}
1762         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1763         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1764         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1765         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1766         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1767         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1768         Console owner file:       ${have_console_owner_file}
1769         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1770         System bus user:          ${DBUS_USER}
1771         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1772         'make check' socket dir:  ${TEST_SOCKET_DIR}
1773 "
1774 if test x$have_launchd = xyes; then
1775         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1776 fi
1777 echo
1778
1779 if test x$enable_embedded_tests = xyes; then
1780         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1781 fi
1782 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1783         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1784 fi
1785 if test x$enable_compiler_coverage = xyes; then
1786         echo "NOTE: building with coverage profiling is definitely for developers only."
1787 fi
1788 if test x$enable_verbose_mode = xyes; then
1789         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1790 fi
1791 if test x$enable_asserts = xyes; then
1792         echo "NOTE: building with assertions increases library size and decreases performance."
1793 fi
1794 if test x$enable_checks = xno; then
1795         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1796 fi
1797 if test x$dbus_use_libxml = xtrue; then
1798         echo
1799         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1800 fi
1801
1802 if test "x$DBUS_HAVE_INT64" = x0; then
1803   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1804
1805   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1806   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1807   used if your compiler lacks support for 64-bit integers. Please report a bug
1808   with details of your platform and compiler.
1809
1810   This option is likely to be removed in future, unless the D-Bus developers
1811   receive reports that it is still needed.
1812   ])
1813 fi