configure.ac

   1 # intel-driver package version number
   2 m4_define([intel_driver_major_version], [1])
   3 m4_define([intel_driver_minor_version], [0])
   4 m4_define([intel_driver_micro_version], [14])
   5 m4_define([intel_driver_pre_version],   [0])
   6 m4_define([intel_driver_version],
   7           [intel_driver_major_version.intel_driver_minor_version.intel_driver_micro_version])
   8 m4_if(intel_driver_pre_version, [0], [], [
   9 m4_append([intel_driver_version], intel_driver_pre_version, [.pre])
  10 ])
  11
  12 AC_PREREQ([2.57])
  13 AC_INIT([intel_driver], [intel_driver_version], [haihao.xiang@intel.com],
  14         [libva-driver-intel])
  15 AC_CONFIG_SRCDIR([Makefile.am])
  16 AM_INIT_AUTOMAKE
  17
  18 AM_CONFIG_HEADER([src/config.h])
  19
  20 INTEL_DRIVER_MAJOR_VERSION=intel_driver_major_version
  21 INTEL_DRIVER_MINOR_VERSION=intel_driver_minor_version
  22 INTEL_DRIVER_MICRO_VERSION=intel_driver_micro_version
  23 AC_DEFINE([INTEL_DRIVER_MAJOR_VERSION], [intel_driver_major_version], [Major version of the driver])
  24 AC_DEFINE([INTEL_DRIVER_MINOR_VERSION], [intel_driver_minor_version], [Minor version of the driver])
  25 AC_DEFINE([INTEL_DRIVER_MICRO_VERSION], [intel_driver_micro_version], [Micro version of the driver])
  26 AC_DEFINE([INTEL_DRIVER_PRE_VERSION], [intel_driver_pre_version], [Preversion of the driver])
  27
  28 INTEL_DRIVER_LT_LDFLAGS="-avoid-version"
  29 AC_SUBST(INTEL_DRIVER_LT_LDFLAGS)
  30
  31 dnl Use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  33     AM_DEFAULT_VERBOSITY=1
  34     AC_SUBST(AM_DEFAULT_VERBOSITY)
  35 ])
  36
  37 AC_DISABLE_STATIC
  38 AC_PROG_LIBTOOL
  39 AC_PROG_CC
  40 AM_PROG_CC_C_O
  41
  42 AC_C_BIGENDIAN
  43 AC_HEADER_STDC
  44 AC_SYS_LARGEFILE
  45
  46 dnl Check for recent enough DRM
  47 PKG_CHECK_MODULES([DRM], [libdrm >= 2.4.23])
  48
  49 dnl Check for gen4asm
  50 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.2], [gen4asm=yes], [gen4asm=no])
  51 AM_CONDITIONAL(HAVE_GEN4ASM, test x$gen4asm = xyes)
  52
  53 dnl Check for VA-API
  54 PKG_CHECK_MODULES(LIBVA_DEPS,     [libva])
  55 PKG_CHECK_MODULES(LIBVA_X11_DEPS, [libva-x11])
  56
  57 VA_VERSION=`$PKG_CONFIG --modversion libva`
  58 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
  59 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
  60 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
  61 VA_VERSION_STR="$VA_VERSION"
  62
  63 va_full_version_int=`expr ${VA_MAJOR_VERSION:-0} "*" 1000000 + \
  64                           ${VA_MINOR_VERSION:-0} "*" 10000   + \
  65                           ${VA_MICRO_VERSION:-0} "*" 100     + \
  66                           0`
  67 VA_DRIVER_INIT_FUNC="__vaDriverInit_${VA_MAJOR_VERSION}_${VA_MINOR_VERSION}"
  68 AC_DEFINE_UNQUOTED([VA_DRIVER_INIT_FUNC], [$VA_DRIVER_INIT_FUNC],
  69     [Define driver entry-point])
  70
  71 dnl Check for VA-API drivers path
  72 AC_MSG_CHECKING([for VA drivers path])
  73 LIBVA_DRIVERS_PATH=`$PKG_CONFIG libva --variable driverdir`
  74 if test -z "$LIBVA_DRIVERS_PATH"; then
  75     LIBVA_DRIVERS_PATH="/usr/lib/xorg/modules/drivers"
  76 fi
  77 AC_MSG_RESULT([$LIBVA_DRIVERS_PATH])
  78 AC_SUBST(LIBVA_DRIVERS_PATH)
  79
  80 AC_OUTPUT([
  81     Makefile
  82     src/Makefile
  83     src/shaders/Makefile
  84     src/shaders/h264/Makefile
  85     src/shaders/h264/mc/Makefile
  86     src/shaders/mpeg2/Makefile
  87     src/shaders/mpeg2/vld/Makefile
  88     src/shaders/post_processing/Makefile
  89     src/shaders/render/Makefile
  90     src/shaders/vme/Makefile
  91 ])
  92
  93 dnl Print summary
  94 echo
  95 echo $PACKAGE configuration summary:
  96 echo
  97 echo VA-API version ................... : $VA_VERSION_STR
  98 echo VA-API drivers path .............. : $LIBVA_DRIVERS_PATH
  99 echo