configure.ac

   1 AC_INIT([at-spi2-core], [2.25.2], [accessibility-atspi@lists.linux-foundation.org])
   2 AC_PREREQ([2.59])
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_MACRO_DIR([m4])
   5
   6 AT_SPI_CORE_MAJOR_VERSION=0
   7 AT_SPI_CORE_MINOR_VERSION=1
   8 AT_SPI_CORE_MICRO_VERSION=3
   9 AT_SPI_CORE_VERSION="$AT_SPI_CORE_MAJOR_VERSION.$AT_SPI_CORE_MINOR_VERSION"
  10 AC_SUBST(AT_SPI_CORE_VERSION)
  11
  12 LT_RELEASE=$AT_SPI_CORE_VERSION
  13 LT_CURRENT=0
  14 LT_REVISION=1
  15 LT_AGE=0
  16 LT_VERSION_INFO='-version-info ${LT_CURRENT}:${LT_REVISION}:${LT_AGE}'
  17 AC_SUBST(LT_VERSION_INFO)
  18 AC_SUBST(LT_RELEASE)
  19 AC_SUBST(LT_CURRENT)
  20 AC_SUBST(LT_REVISION)
  21 AC_SUBST(LT_AGE)
  22
  23 AM_INIT_AUTOMAKE([1.9 -Wall foreign no-dist-gzip dist-xz])
  24
  25 # Support silent build rules. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AM_PROG_AR
  32 LT_INIT([disable-static])
  33 PKG_PROG_PKG_CONFIG
  34
  35 AC_CONFIG_HEADERS([config.h])
  36
  37 dnl translation of at-spi strings
  38 IT_PROG_INTLTOOL([0.40.0])
  39
  40 AC_PROG_SED
  41
  42 GETTEXT_PACKAGE="${PACKAGE}"
  43 AC_SUBST(GETTEXT_PACKAGE)
  44
  45 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.0])
  46 AC_SUBST(DBUS_LIBS)
  47 AC_SUBST(DBUS_CFLAGS)
  48
  49 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.36.0])
  50 AC_SUBST(GLIB_LIBS)
  51 AC_SUBST(GLIB_CFLAGS)
  52
  53 PKG_CHECK_MODULES(GOBJ, [gobject-2.0 >= 2.0.0])
  54 AC_SUBST(GOBJ_LIBS)
  55 AC_SUBST(GOBJ_CFLAGS)
  56
  57 PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.28])
  58 AC_SUBST(GIO_LIBS)
  59 AC_SUBST(GIO_CFLAGS)
  60
  61 # --------------------------------------------------------------------
  62 # Find DL functionality
  63
  64 AC_CHECK_LIB(c, dlopen, DL_LIBS="",
  65         AC_CHECK_LIB(dl, dlopen, DL_LIBS="-ldl",
  66                 AC_MSG_ERROR([Could not find a library with the dlopen function])
  67         )
  68 )
  69
  70 AC_SUBST(DL_LIBS)
  71
  72 AC_ARG_ENABLE(x11,
  73               [AS_HELP_STRING([--disable-x11],
  74                               [disable the X11 backend])],,
  75                               [enable_x11=auto])
  76
  77 AS_IF([test "x$enable_x11" = xno], [
  78   AM_CONDITIONAL(USE_X11, false)
  79 ], [
  80   PKG_CHECK_MODULES(X11, [x11], [
  81     AC_DEFINE(HAVE_X11, 1, [Define to use X11])
  82     AC_SUBST(HAVE_X11)
  83     have_x11=yes
  84   ], [
  85     AS_IF([test "x$enable_x11" = xyes], [
  86       AC_MSG_ERROR([Unable to find X11 development files])
  87     ])
  88     have_x11=no
  89   ])
  90
  91   # Check for additional X11 extensions
  92   AS_IF([test "x$have_x11" = xyes], [
  93     # XTest (mandatory)
  94     PKG_CHECK_MODULES(XTST, [xtst])
  95     X11_CFLAGS="$X11_CFLAGS $XTST_CFLAGS"
  96     X11_LIBS="$X11_LIBS $XTST_LIBS"
  97
  98     # XInput (mandatory)
  99     PKG_CHECK_MODULES(XINPUT, [xi])
 100     X11_CFLAGS="$X11_CFLAGS $XINPUT_CFLAGS"
 101     X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 102
 103     # XKB (optional)
 104     PKG_CHECK_MODULES(XKB, [xkbcommon-x11], [
 105       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB])
 106       X11_CFLAGS="$X11_CFLAGS $XKB_CFLAGS"
 107       X11_LIBS="$X11_LIBS $XKB_LIBS"
 108     ], [])
 109   ])
 110
 111   AC_SUBST(X11_CFLAGS)
 112   AC_SUBST(X11_LIBS)
 113
 114   AM_CONDITIONAL(USE_X11, test "x$have_x11" = xyes)
 115 ])
 116
 117 AC_ARG_WITH([dbus_daemondir],
 118         [AS_HELP_STRING([--with-dbus-daemondir=<directory>],
 119                 [Directory where the DBUS daemon is installed])],
 120     [DBUS_DAEMON="$with_dbus_daemondir/dbus-daemon"],
 121     [AC_PATH_PROG([DBUS_DAEMON], [dbus-daemon], [XXXDBUSDAEMONNOTFOUND],
 122                 [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR]dnl
 123 [/libexec$PATH_SEPARATOR/usr/libexec$PATH_SEPARATOR/usr/local/bin]dnl
 124 [$PATH_SEPARATOR/usr/pkg/bin])]
 125         )
 126 if test "$DBUS_DAEMON" = "XXXDBUSDAEMONNOTFOUND"; then
 127         DBUS_DAEMON = "$bindir/dbus-daemon"
 128         AC_MSG_WARN([at-spi2 relies on dbus, and the dbus-daemon was not found])
 129         AC_MSG_WARN([we assume that it will be installed in "$bindir"])
 130 fi
 131 AC_SUBST(DBUS_DAEMON)
 132
 133 AC_ARG_WITH(dbus-services,
 134            [AS_HELP_STRING([--with-dbus-services=<directory>],
 135            [where D-BUS services directory is])])
 136 if ! test -z "$with_dbus_services" ; then
 137            DBUS_SERVICES_DIR="$with_dbus_services"
 138 else
 139            DBUS_SERVICES_DIR="$datadir/dbus-1/services"
 140 fi
 141 AC_SUBST(DBUS_SERVICES_DIR)
 142
 143 AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)
 144
 145 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 146
 147 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 148
 149 dnl find sizes & alignments
 150 orig_CPPFLAGS=$CPPFLAGS
 151 CPPFLAGS="$CPPFLAGS $DBUS_CFLAGS"
 152 AC_CHECK_ALIGNOF(char)
 153 AC_CHECK_ALIGNOF(dbus_bool_t, [#include <dbus/dbus.h>])
 154 AC_CHECK_ALIGNOF(dbus_int16_t, [#include <dbus/dbus.h>])
 155 AC_CHECK_ALIGNOF(dbus_int32_t, [#include <dbus/dbus.h>])
 156 AC_CHECK_ALIGNOF(dbus_int64_t, [#include <dbus/dbus.h>])
 157 AC_CHECK_ALIGNOF(double, [#include <dbus/dbus.h>])
 158 AC_CHECK_ALIGNOF(dbind_pointer, [AC_INCLUDES_DEFAULT
 159 typedef void *dbind_pointer;])
 160 AC_CHECK_ALIGNOF(dbind_struct, [AC_INCLUDES_DEFAULT
 161 typedef struct {char s1;} dbind_struct;])
 162
 163 GTK_DOC_CHECK([1.09])
 164
 165 if test "x$GCC" = xyes; then
 166         CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 167 fi
 168 CPPFLAGS=$orig_CPPFLAGS
 169 AC_CONFIG_FILES([Makefile po/Makefile.in
 170         xml/Makefile
 171         dbind/Makefile
 172         atspi/Makefile
 173         registryd/Makefile
 174         bus/Makefile
 175 doc/Makefile
 176 doc/libatspi/Makefile
 177 doc/libatspi/version.xml
 178 test/Makefile
 179 atspi-2.pc
 180 atspi-2-uninstalled.pc
 181 ])
 182
 183 AC_OUTPUT