configure.ac

   1 # configure.ac - for GnuPG 2.1
   2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
   3 # Copyright (C) 1998-2015 Werner Koch
   4 #
   5 # This file is part of GnuPG.
   6 #
   7 # GnuPG is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # GnuPG is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
  19
  20 # Process this file with autoconf to produce a configure script.
  21 AC_PREREQ(2.61)
  22 min_automake_version="1.14"
  23
  24 # To build a release you need to create a tag with the version number
  25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
  26 # bump the version number immediately *after* the release and do
  27 # another commit and push so that the git magic is able to work.
  28 m4_define([mym4_package],[gnupg])
  29 m4_define([mym4_major], [2])
  30 m4_define([mym4_minor], [1])
  31 m4_define([mym4_micro], [3])
  32
  33 # To start a new development series, i.e a new major or minor number
  34 # you need to mark an arbitrary commit before the first beta release
  35 # with an annotated tag.  For example the 2.1 branch starts off with
  36 # the tag "gnupg-2.1-base".  This is used as the base for counting
  37 # beta numbers before the first release of a series.
  38
  39 # Below is m4 magic to extract and compute the git revision number,
  40 # the decimalized short revision number, a beta version string and a
  41 # flag indicating a development version (mym4_isbeta).  Note that the
  42 # m4 processing is done by autoconf and not during the configure run.
  43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
  44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
  45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
  46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
  47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
  48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
  49 m4_esyscmd([echo ]mym4_version[>VERSION])
  50 AC_INIT([mym4_package],[mym4_version], [http://bugs.gnupg.org])
  51
  52 NEED_GPG_ERROR_VERSION=1.16
  53
  54 NEED_LIBGCRYPT_API=1
  55 NEED_LIBGCRYPT_VERSION=1.6.0
  56
  57 NEED_LIBASSUAN_API=2
  58 NEED_LIBASSUAN_VERSION=2.1.0
  59
  60 NEED_KSBA_API=1
  61 NEED_KSBA_VERSION=1.2.0
  62
  63 NEED_NTBTLS_API=1
  64 NEED_NTBTLS_VERSION=0.1.0
  65
  66 NEED_NPTH_API=1
  67 NEED_NPTH_VERSION=0.91
  68
  69
  70 NEED_GNUTLS_VERSION=3.0
  71
  72
  73 development_version=mym4_isbeta
  74 PACKAGE=$PACKAGE_NAME
  75 PACKAGE_GT=${PACKAGE_NAME}2
  76 VERSION=$PACKAGE_VERSION
  77
  78 AC_CONFIG_AUX_DIR([build-aux])
  79 AC_CONFIG_SRCDIR([sm/gpgsm.c])
  80 AC_CONFIG_HEADER([config.h])
  81 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
  82 AC_CANONICAL_HOST
  83 AB_INIT
  84
  85 AC_GNU_SOURCE
  86
  87 # Some status variables.
  88 have_gpg_error=no
  89 have_libgcrypt=no
  90 have_libassuan=no
  91 have_ksba=no
  92 have_ntbtls=no
  93 have_gnutls=no
  94 have_npth=no
  95 have_libusb=no
  96 have_adns=no
  97 gnupg_have_ldap="n/a"
  98
  99 use_zip=yes
 100 use_bzip2=yes
 101 use_exec=yes
 102 use_trust_models=yes
 103 card_support=yes
 104 use_ccid_driver=yes
 105 dirmngr_auto_start=yes
 106 use_tls_library=no
 107 large_secmem=no
 108
 109 GNUPG_BUILD_PROGRAM(gpg, yes)
 110 GNUPG_BUILD_PROGRAM(gpgsm, yes)
 111 # The agent is a required part and can't be disabled anymore.
 112 build_agent=yes
 113 GNUPG_BUILD_PROGRAM(scdaemon, yes)
 114 GNUPG_BUILD_PROGRAM(g13, yes)
 115 GNUPG_BUILD_PROGRAM(dirmngr, yes)
 116 GNUPG_BUILD_PROGRAM(tools, yes)
 117 GNUPG_BUILD_PROGRAM(doc, yes)
 118 GNUPG_BUILD_PROGRAM(symcryptrun, no)
 119 GNUPG_BUILD_PROGRAM(gpgtar, yes)
 120
 121 AC_SUBST(PACKAGE)
 122 AC_SUBST(PACKAGE_GT)
 123 AC_SUBST(VERSION)
 124 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
 125 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
 126                                 [Name of this package for gettext])
 127 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
 128 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
 129                                         [Bug report address])
 130 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
 131                                        [Required version of Libgcrypt])
 132 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
 133                                        [Required version of Libksba])
 134 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
 135                                        [Required version of NTBTLS])
 136
 137
 138
 139 # The default is to use the modules from this package and the few
 140 # other packages in a standard place; i.e where this package gets
 141 # installed.  With these options it is possible to override these
 142 # ${prefix} depended values with fixed paths, which can't be replaced
 143 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
 144 AC_ARG_WITH(agent-pgm,
 145     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
 146           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
 147 AC_SUBST(GNUPG_AGENT_PGM)
 148 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
 149 show_gnupg_agent_pgm="(default)"
 150 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
 151
 152 AC_ARG_WITH(pinentry-pgm,
 153     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
 154           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
 155 AC_SUBST(GNUPG_PINENTRY_PGM)
 156 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
 157 show_gnupg_pinentry_pgm="(default)"
 158 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
 159
 160
 161 AC_ARG_WITH(scdaemon-pgm,
 162     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
 163           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
 164 AC_SUBST(GNUPG_SCDAEMON_PGM)
 165 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
 166 show_gnupg_scdaemon_pgm="(default)"
 167 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
 168
 169
 170 AC_ARG_WITH(dirmngr-pgm,
 171     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
 172           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
 173 AC_SUBST(GNUPG_DIRMNGR_PGM)
 174 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
 175 show_gnupg_dirmngr_pgm="(default)"
 176 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
 177
 178 AC_ARG_WITH(protect-tool-pgm,
 179     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
 180           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
 181 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
 182 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
 183 show_gnupg_protect_tool_pgm="(default)"
 184 test -n "$GNUPG_PROTECT_TOOL_PGM" \
 185       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
 186
 187 AC_ARG_WITH(dirmngr-ldap-pgm,
 188     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
 189           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
 190 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
 191 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
 192 show_gnupg_dirmngr_ldap_pgm="(default)"
 193 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
 194       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
 195
 196 #
 197 # On some platforms gpg2 is usually installed as gpg without using a
 198 # symlink.  For correct operation of gpgconf it needs to know the
 199 # installed name of gpg.  This option sets "gpg2"'s installed name to
 200 # just "gpg".  Note that it might be required to rename gpg2 to gpg
 201 # manually after the build process.
 202 #
 203 AC_ARG_ENABLE(gpg2-is-gpg,
 204     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
 205     gpg2_is_gpg=$enableval)
 206 if test "$gpg2_is_gpg" = "yes"; then
 207    name_of_installed_gpg=gpg
 208 else
 209    name_of_installed_gpg=gpg2
 210 fi
 211 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
 212                    [The name of the installed GPG tool])
 213
 214
 215 # SELinux support includes tracking of sensitive files to avoid
 216 # leaking their contents through processing these files by gpg itself
 217 AC_MSG_CHECKING([whether SELinux support is requested])
 218 AC_ARG_ENABLE(selinux-support,
 219               AC_HELP_STRING([--enable-selinux-support],
 220                              [enable SELinux support]),
 221               selinux_support=$enableval, selinux_support=no)
 222 AC_MSG_RESULT($selinux_support)
 223
 224
 225 AC_MSG_CHECKING([whether to allocate extra secure memory])
 226 AC_ARG_ENABLE(large-secmem,
 227               AC_HELP_STRING([--enable-large-secmem],
 228                              [allocate extra secure memory]),
 229               large_secmem=$enableval, large_secmem=no)
 230 AC_MSG_RESULT($large_secmem)
 231 if test "$large_secmem" = yes ; then
 232    SECMEM_BUFFER_SIZE=65536
 233 else
 234    SECMEM_BUFFER_SIZE=32768
 235 fi
 236 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
 237                    [Size of secure memory buffer])
 238
 239 AC_MSG_CHECKING([whether to enable trust models])
 240 AC_ARG_ENABLE(trust-models,
 241               AC_HELP_STRING([--disable-trust-models],
 242                              [disable all trust models except "always"]),
 243               use_trust_models=$enableval)
 244 AC_MSG_RESULT($use_trust_models)
 245 if test "$use_trust_models" = no ; then
 246     AC_DEFINE(NO_TRUST_MODELS, 1,
 247              [Define to include only trust-model always])
 248 fi
 249
 250
 251 #
 252 # Options to disable algorithm
 253 #
 254
 255 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
 256 # Elgamal is a MUST algorithm
 257 # DSA is a MUST algorithm
 258 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
 259 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
 260 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
 261
 262 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
 263 # 3DES is a MUST algorithm
 264 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
 265 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
 266 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
 267 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
 268 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
 269 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
 270 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
 271 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
 272 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
 273
 274 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
 275 # SHA1 is a MUST algorithm
 276 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
 277 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
 278 # SHA256 is a MUST algorithm for GnuPG.
 279 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
 280 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
 281
 282
 283 # Allow disabling of zip support.
 284 # This is in general not a good idea because according to rfc4880 OpenPGP
 285 # implementations SHOULD support ZLIB.
 286 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
 287 AC_ARG_ENABLE(zip,
 288    AC_HELP_STRING([--disable-zip],
 289                   [disable the ZIP and ZLIB compression algorithm]),
 290    use_zip=$enableval)
 291 AC_MSG_RESULT($use_zip)
 292
 293 # Allow disabling of bzib2 support.
 294 # It is defined only after we confirm the library is available later
 295 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
 296 AC_ARG_ENABLE(bzip2,
 297    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
 298    use_bzip2=$enableval)
 299 AC_MSG_RESULT($use_bzip2)
 300
 301 # Configure option to allow or disallow execution of external
 302 # programs, like a photo viewer.
 303 AC_MSG_CHECKING([whether to enable external program execution])
 304 AC_ARG_ENABLE(exec,
 305     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
 306     use_exec=$enableval)
 307 AC_MSG_RESULT($use_exec)
 308 if test "$use_exec" = no ; then
 309     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
 310 fi
 311
 312 if test "$use_exec" = yes ; then
 313   AC_MSG_CHECKING([whether to enable photo ID viewing])
 314   AC_ARG_ENABLE(photo-viewers,
 315       [  --disable-photo-viewers disable photo ID viewers],
 316       [if test "$enableval" = no ; then
 317          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
 318       fi],enableval=yes)
 319   gnupg_cv_enable_photo_viewers=$enableval
 320   AC_MSG_RESULT($enableval)
 321
 322   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
 323     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
 324     AC_ARG_WITH(photo-viewer,
 325         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
 326         [if test "$withval" = yes ; then
 327            withval=no
 328         elif test "$withval" != no ; then
 329            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
 330                             [if set, restrict photo-viewer to this])
 331         fi],withval=no)
 332     AC_MSG_RESULT($withval)
 333   fi
 334 fi
 335
 336
 337 #
 338 # Check for the key/uid cache size.  This can't be zero, but can be
 339 # pretty small on embedded systems.  This is used for the gpg part.
 340 #
 341 AC_MSG_CHECKING([for the size of the key and uid cache])
 342 AC_ARG_ENABLE(key-cache,
 343         AC_HELP_STRING([--enable-key-cache=SIZE],
 344                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
 345 if test "$enableval" = "no"; then
 346    enableval=5
 347 elif test "$enableval" = "yes" || test "$enableval" = ""; then
 348    enableval=4096
 349 fi
 350 changequote(,)dnl
 351 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
 352 changequote([,])dnl
 353 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
 354    AC_MSG_ERROR([invalid key-cache size])
 355 fi
 356 AC_MSG_RESULT($key_cache_size)
 357 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
 358                   [Size of the key and UID caches])
 359
 360
 361
 362 #
 363 # Check whether we want to use Linux capabilities
 364 #
 365 AC_MSG_CHECKING([whether use of capabilities is requested])
 366 AC_ARG_WITH(capabilities,
 367     [  --with-capabilities     use linux capabilities [default=no]],
 368 [use_capabilities="$withval"],[use_capabilities=no])
 369 AC_MSG_RESULT($use_capabilities)
 370
 371 #
 372 # Check whether to disable the card support
 373 AC_MSG_CHECKING([whether smartcard support is requested])
 374 AC_ARG_ENABLE(card-support,
 375               AC_HELP_STRING([--disable-card-support],
 376                              [disable smartcard support]),
 377               card_support=$enableval)
 378 AC_MSG_RESULT($card_support)
 379 if test "$card_support" = yes ; then
 380   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
 381 else
 382   build_scdaemon=no
 383 fi
 384
 385 #
 386 # Allow disabling of internal CCID support.
 387 # It is defined only after we confirm the library is available later
 388 #
 389 AC_MSG_CHECKING([whether to enable the internal CCID driver])
 390 AC_ARG_ENABLE(ccid-driver,
 391               AC_HELP_STRING([--disable-ccid-driver],
 392                              [disable the internal CCID driver]),
 393               use_ccid_driver=$enableval)
 394 AC_MSG_RESULT($use_ccid_driver)
 395
 396 AC_MSG_CHECKING([whether to auto start dirmngr])
 397 AC_ARG_ENABLE(dirmngr-auto-start,
 398               AC_HELP_STRING([--disable-dirmngr-auto-start],
 399                              [disable auto starting of the dirmngr]),
 400               dirmngr_auto_start=$enableval)
 401 AC_MSG_RESULT($dirmngr_auto_start)
 402 if test "$dirmngr_auto_start" = yes ; then
 403     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
 404               [Define to enable auto starting of the dirmngr])
 405 fi
 406
 407
 408 #
 409 # To avoid double inclusion of config.h which might happen at some
 410 # places, we add the usual double inclusion protection at the top of
 411 # config.h.
 412 #
 413 AH_TOP([
 414 #ifndef GNUPG_CONFIG_H_INCLUDED
 415 #define GNUPG_CONFIG_H_INCLUDED
 416 ])
 417
 418 #
 419 # Stuff which goes at the bottom of config.h.
 420 #
 421 AH_BOTTOM([
 422 /* This is the major version number of GnuPG so that
 423    source included files can test for this.  Note, that
 424    we use 2 here even for GnuPG 1.9.x. */
 425 #define GNUPG_MAJOR_VERSION 2
 426
 427 /* Now to separate file name parts.
 428    Please note that the string version must not contain more
 429    than one character because the code assumes strlen()==1 */
 430 #ifdef HAVE_DOSISH_SYSTEM
 431 #define DIRSEP_C '\\'
 432 #define DIRSEP_S "\\"
 433 #define EXTSEP_C '.'
 434 #define EXTSEP_S "."
 435 #define PATHSEP_C ';'
 436 #define PATHSEP_S ";"
 437 #define EXEEXT_S ".exe"
 438 #else
 439 #define DIRSEP_C '/'
 440 #define DIRSEP_S "/"
 441 #define EXTSEP_C '.'
 442 #define EXTSEP_S "."
 443 #define PATHSEP_C ':'
 444 #define PATHSEP_S ":"
 445 #define EXEEXT_S ""
 446 #endif
 447
 448 /* This is the same as VERSION, but should be overridden if the
 449    platform cannot handle things like dots '.' in filenames. Set
 450    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
 451    uses for dots and dashes. */
 452 #define SAFE_VERSION VERSION
 453 #define SAFE_VERSION_DOT  '.'
 454 #define SAFE_VERSION_DASH '-'
 455
 456 /* Some global constants. */
 457 #ifdef HAVE_DOSISH_SYSTEM
 458 # ifdef HAVE_DRIVE_LETTERS
 459 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
 460 # else
 461 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
 462 # endif
 463 #elif defined(__VMS)
 464 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
 465 #else
 466 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
 467 #endif
 468 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
 469 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
 470
 471 /* For some systems (DOS currently), we hardcode the path here.  For
 472    POSIX systems the values are constructed by the Makefiles, so that
 473    the values may be overridden by the make invocations; this is to
 474    comply with the GNU coding standards.  Note that these values are
 475    only defaults.  */
 476 #ifdef HAVE_DOSISH_SYSTEM
 477 # ifdef HAVE_DRIVE_LETTERS
 478 #  define GNUPG_BINDIR      "c:\\gnupg"
 479 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
 480 #  define GNUPG_LIBDIR      "c:\\gnupg"
 481 #  define GNUPG_DATADIR     "c:\\gnupg"
 482 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
 483 # else
 484 #  define GNUPG_BINDIR      "\\gnupg"
 485 #  define GNUPG_LIBEXECDIR  "\\gnupg"
 486 #  define GNUPG_LIBDIR      "\\gnupg"
 487 #  define GNUPG_DATADIR     "\\gnupg"
 488 #  define GNUPG_SYSCONFDIR  "\\gnupg"
 489 # endif
 490 #endif
 491
 492 /* Derive some other constants. */
 493 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
 494 #define EXEC_TEMPFILE_ONLY
 495 #endif
 496
 497
 498 /* We didn't define endianness above, so get it from OS macros.  This
 499    is intended for making fat binary builds on OS X. */
 500 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
 501 #if defined(__BIG_ENDIAN__)
 502 #define BIG_ENDIAN_HOST 1
 503 #elif defined(__LITTLE_ENDIAN__)
 504 #define LITTLE_ENDIAN_HOST 1
 505 #else
 506 #error "No endianness found"
 507 #endif
 508 #endif
 509
 510
 511 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
 512    ldap_start_tls_s because that is the actual symbol used in the
 513    library.  winldap.h redefines it to our commonly used value,
 514    thus we define our usual macro here.  */
 515 #ifdef HAVE_LDAP_START_TLS_SA
 516 # ifndef HAVE_LDAP_START_TLS_S
 517 #  define HAVE_LDAP_START_TLS_S 1
 518 # endif
 519 #endif
 520
 521 /* Provide the es_ macro for estream.  */
 522 #define GPGRT_ENABLE_ES_MACROS 1
 523
 524 /* Tell libgcrypt not to use its own libgpg-error implementation. */
 525 #define USE_LIBGPG_ERROR 1
 526
 527 /* Tell Libgcrypt not to include deprecated definitions.  */
 528 #define GCRYPT_NO_DEPRECATED 1
 529
 530 /* We use jnlib, so tell other modules about it.  */
 531 #define HAVE_JNLIB_LOGGING 1
 532
 533 /* Our HTTP code is used in estream mode.  */
 534 #define HTTP_USE_ESTREAM 1
 535
 536 /* Under W32 we do an explicit socket initialization, thus we need to
 537    avoid the on-demand initialization which would also install an atexit
 538    handler.  */
 539 #define HTTP_NO_WSASTARTUP
 540
 541 /* Under Windows we use the gettext code from libgpg-error.  */
 542 #define GPG_ERR_ENABLE_GETTEXT_MACROS
 543
 544 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
 545 #define GPG_ERR_ENABLE_ERRNO_MACROS
 546
 547 #endif /*GNUPG_CONFIG_H_INCLUDED*/
 548 ])
 549
 550
 551 AM_MAINTAINER_MODE
 552 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
 553
 554 # Checks for programs.
 555 AC_MSG_NOTICE([checking for programs])
 556 AC_PROG_MAKE_SET
 557 AM_SANITY_CHECK
 558 missing_dir=`cd $ac_aux_dir && pwd`
 559 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 560 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 561 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
 562 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 563 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
 564 AM_SILENT_RULES
 565 AC_PROG_AWK
 566 AC_PROG_CC
 567 AC_PROG_CPP
 568 AM_PROG_CC_C_O
 569 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
 570   AC_MSG_ERROR([[No C-89 compiler found]])
 571 fi
 572 AC_PROG_INSTALL
 573 AC_PROG_LN_S
 574 AC_PROG_RANLIB
 575 AC_CHECK_TOOL(AR, ar, :)
 576 AC_PATH_PROG(PERL,"perl")
 577 AC_CHECK_TOOL(WINDRES, windres, :)
 578 AC_ISC_POSIX
 579 AC_SYS_LARGEFILE
 580 GNUPG_CHECK_USTAR
 581
 582 # We need to compile and run a program on the build machine.  A
 583 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
 584 # the AC archive is broken for autoconf 2.57.  Given that there is no
 585 # newer version of that macro, we assume that it is also broken for
 586 # autoconf 2.61 and thus we use a simple but usually sufficient
 587 # approach.
 588 AC_MSG_CHECKING(for cc for build)
 589 if test "$cross_compiling" = "yes"; then
 590   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
 591 else
 592   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
 593 fi
 594 AC_MSG_RESULT($CC_FOR_BUILD)
 595 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
 596
 597
 598
 599 try_gettext=yes
 600 require_iconv=yes
 601 have_dosish_system=no
 602 have_w32_system=no
 603 have_w32ce_system=no
 604 have_android_system=no
 605 run_tests=yes
 606 use_simple_gettext=no
 607 use_ldapwrapper=yes
 608 mmap_needed=yes
 609 case "${host}" in
 610     *-mingw32*)
 611         # special stuff for Windoze NT
 612         ac_cv_have_dev_random=no
 613         AC_DEFINE(USE_ONLY_8DOT3,1,
 614                   [Set this to limit filenames to the 8.3 format])
 615         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
 616                   [Because the Unix gettext has too much overhead on
 617                    MingW32 systems and these systems lack Posix functions,
 618                    we use a simplified version of gettext])
 619         have_dosish_system=yes
 620         have_w32_system=yes
 621         run_tests=no
 622         use_ldapwrapper=no  # Fixme: Do this only for CE.
 623         case "${host}" in
 624           *-mingw32ce*)
 625             have_w32ce_system=yes
 626             ;;
 627           *)
 628             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
 629                       [Defined if the OS supports drive letters.])
 630             ;;
 631         esac
 632         try_gettext="no"
 633         use_simple_gettext=yes
 634         mmap_needed=no
 635         ;;
 636     i?86-emx-os2 | i?86-*-os2*emx )
 637         # OS/2 with the EMX environment
 638         ac_cv_have_dev_random=no
 639         AC_DEFINE(HAVE_DRIVE_LETTERS)
 640         have_dosish_system=yes
 641         try_gettext="no"
 642         ;;
 643
 644     i?86-*-msdosdjgpp*)
 645         # DOS with the DJGPP environment
 646         ac_cv_have_dev_random=no
 647         AC_DEFINE(HAVE_DRIVE_LETTERS)
 648         have_dosish_system=yes
 649         try_gettext="no"
 650         ;;
 651
 652     *-*-hpux*)
 653         if test -z "$GCC" ; then
 654             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
 655         fi
 656         ;;
 657     *-dec-osf4*)
 658         if test -z "$GCC" ; then
 659             # Suppress all warnings
 660             # to get rid of the unsigned/signed char mismatch warnings.
 661             CFLAGS="$CFLAGS -w"
 662         fi
 663         ;;
 664     *-dec-osf5*)
 665         if test -z "$GCC" ; then
 666             # Use the newer compiler `-msg_disable ptrmismatch1' to
 667             # get rid of the unsigned/signed char mismatch warnings.
 668             # Using this may hide other pointer mismatch warnings, but
 669             # it at least lets other warning classes through
 670             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
 671         fi
 672         ;;
 673     m68k-atari-mint)
 674         ;;
 675     *-linux-androideabi)
 676         have_android_system=yes
 677         # Android is fully utf-8 and we do not want to use iconv to
 678         # keeps things simple
 679         require_iconv=no
 680         run_tests=no
 681         ;;
 682     *)
 683        ;;
 684 esac
 685
 686 if test "$have_dosish_system" = yes; then
 687    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
 688              [Defined if we run on some of the PCDOS like systems
 689               (DOS, Windoze. OS/2) with special properties like
 690               no file modes, case insensitive file names and preferred
 691               use of backslashes as directory name separators.])
 692 fi
 693 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
 694
 695 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
 696
 697 if test "$have_w32_system" = yes; then
 698    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
 699    if test "$have_w32ce_system" = yes; then
 700       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
 701    fi
 702 fi
 703 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
 704 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
 705
 706 if test "$have_android_system" = yes; then
 707    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
 708 fi
 709 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
 710
 711 if test "$run_tests" = yes; then
 712    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
 713 fi
 714 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
 715
 716
 717 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
 718 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
 719
 720
 721 #
 722 # Checks for libraries.
 723 #
 724 AC_MSG_NOTICE([checking for libraries])
 725
 726
 727 #
 728 # libgpg-error is a library with error codes shared between GnuPG
 729 # related projects.
 730 #
 731 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
 732                   have_gpg_error=yes,have_gpg_error=no)
 733
 734
 735 #
 736 # Libgcrypt is our generic crypto library
 737 #
 738 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
 739         have_libgcrypt=yes,have_libgcrypt=no)
 740
 741
 742 #
 743 # libassuan is used for IPC
 744 #
 745 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
 746                   have_libassuan=yes,have_libassuan=no)
 747 if test "$have_libassuan" = "yes"; then
 748   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
 749                      [version of the libassuan library])
 750 fi
 751
 752
 753
 754 #
 755 # libksba is our X.509 support library
 756 #
 757 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
 758
 759
 760 #
 761 # libusb allows us to use the integrated CCID smartcard reader driver.
 762 #
 763 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
 764 if test "$use_ccid_driver" = yes ; then
 765   AC_CHECK_LIB(usb, usb_bulk_write,
 766                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
 767                   AC_DEFINE(HAVE_LIBUSB,1,
 768                            [defined if libusb is available])
 769                   have_libusb=yes
 770                ])
 771   AC_CHECK_FUNCS(usb_create_match)
 772 fi
 773 AC_SUBST(LIBUSB_LIBS)
 774
 775 #
 776 # Check wether it is necessary to link against libdl.
 777 # (For example to load libpcsclite)
 778 #
 779 gnupg_dlopen_save_libs="$LIBS"
 780 LIBS=""
 781 AC_SEARCH_LIBS(dlopen, c dl,,,)
 782 DL_LIBS=$LIBS
 783 AC_SUBST(DL_LIBS)
 784 LIBS="$gnupg_dlopen_save_libs"
 785
 786 # Checks for g13
 787
 788 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
 789 AC_DEFINE_UNQUOTED(ENCFS,
 790         "${ENCFS}", [defines the filename of the encfs program])
 791
 792 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
 793 AC_DEFINE_UNQUOTED(FUSERMOUNT,
 794         "${FUSERMOUNT}", [defines the filename of the fusermount program])
 795
 796
 797 # Checks for dirmngr
 798
 799
 800 #
 801 # Checks for symcryptrun:
 802 #
 803
 804 # libutil has openpty() and login_tty().
 805 AC_CHECK_LIB(util, openpty,
 806               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
 807                 AC_DEFINE(HAVE_LIBUTIL,1,
 808                          [defined if libutil is available])
 809              ])
 810 AC_SUBST(LIBUTIL_LIBS)
 811
 812 # shred is used to clean temporary plain text files.
 813 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
 814 AC_DEFINE_UNQUOTED(SHRED,
 815         "${SHRED}", [defines the filename of the shred program])
 816
 817
 818 #
 819 # Check whether the nPth library is available
 820 #
 821 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
 822 if test "$have_npth" = "yes"; then
 823   AC_DEFINE(HAVE_NPTH, 1,
 824               [Defined if the New Portable Thread Library is available])
 825   AC_DEFINE(USE_NPTH, 1,
 826               [Defined if support for nPth is requested and nPth is available])
 827 else
 828   AC_MSG_WARN([[
 829 ***
 830 *** To support concurrent access for example in gpg-agent and the SCdaemon
 831 *** we need the support of the New Portable Threads Library.
 832 ***]])
 833 fi
 834
 835
 836 #
 837 # NTBTLS is our TLS library.  If it is not available fallback to
 838 # GNUTLS.
 839 #
 840 AC_ARG_ENABLE(ntbtls,
 841               AC_HELP_STRING([--disable-ntbtls],
 842                              [disable the use of NTBTLS as TLS library]),
 843               try_ntbtls=$enableval, try_ntbtls=yes)
 844 if test x"$try_ntbtls" = xyes ; then
 845   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
 846                  [have_ntbtls=yes],[have_ntbtls=no])
 847 fi
 848 if test "$have_ntbtls" = yes ; then
 849    use_tls_library=ntbtls
 850    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
 851 else
 852   AC_ARG_ENABLE(gnutls,
 853                 AC_HELP_STRING([--disable-gnutls],
 854                                [disable GNUTLS as fallback TLS library]),
 855                 try_gnutls=$enableval, try_gnutls=yes)
 856   if test x"$try_gnutls" = xyes ; then
 857     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
 858                                    [have_gnutls=yes],
 859                                    [have_gnutls=no])
 860   fi
 861   if test "$have_gnutls" = "yes"; then
 862     AC_SUBST([LIBGNUTLS_CFLAGS])
 863     AC_SUBST([LIBGNUTLS_LIBS])
 864     use_tls_library=gnutls
 865     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
 866   else
 867     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
 868     AC_MSG_WARN([[
 869 ***
 870 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
 871 ***
 872 *** $tmp]])
 873   fi
 874 fi
 875
 876
 877 AC_MSG_NOTICE([checking for networking options])
 878
 879 #
 880 # Must check for network library requirements before doing link tests
 881 # for ldap, for example. If ldap libs are static (or dynamic and without
 882 # ELF runtime link paths), then link will fail and LDAP support won't
 883 # be detected.
 884 #
 885 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
 886         [NETLIBS="-lnsl $NETLIBS"]))
 887 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
 888         [NETLIBS="-lsocket $NETLIBS"]))
 889
 890
 891 #
 892 # Check for ADNS.
 893 #
 894 _cppflags="${CPPFLAGS}"
 895 _ldflags="${LDFLAGS}"
 896 AC_ARG_WITH(adns,
 897             AC_HELP_STRING([--with-adns=DIR],
 898                            [look for the adns library in DIR]),
 899             [if test -d "$withval"; then
 900                CPPFLAGS="${CPPFLAGS} -I$withval/include"
 901                LDFLAGS="${LDFLAGS} -L$withval/lib"
 902              fi])
 903 if test "$with_adns" != "no"; then
 904   AC_CHECK_HEADERS(adns.h,
 905                 AC_CHECK_LIB(adns, adns_free,
 906                              [have_adns=yes],
 907                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
 908                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
 909 fi
 910 if test "$have_adns" = "yes"; then
 911   ADNSLIBS="-ladns"
 912 fi
 913
 914
 915 #
 916 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
 917 #
 918 AC_ARG_ENABLE(dns-srv,
 919               AC_HELP_STRING([--disable-dns-srv],
 920                              [disable the use of DNS SRV in HKP and HTTP]),
 921               use_dns_srv=$enableval,use_dns_srv=yes)
 922
 923 AC_ARG_ENABLE(dns-cert,
 924    AC_HELP_STRING([--disable-dns-cert],
 925         [disable the use of CERT records in DNS]),
 926    use_dns_cert=$enableval,use_dns_cert=yes)
 927
 928 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
 929   _dns_save_libs=$LIBS
 930   LIBS=""
 931   # the double underscore thing is a glibc-ism?
 932   AC_SEARCH_LIBS(res_query,resolv bind,,
 933                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
 934   AC_SEARCH_LIBS(dn_expand,resolv bind,,
 935                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
 936   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
 937                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
 938
 939   if test x"$have_resolver" != xno ; then
 940
 941     # Make sure that the BIND 4 resolver interface is workable before
 942     # enabling any code that calls it.  At some point I'll rewrite the
 943     # code to use the BIND 8 resolver API.
 944     # We might also want to use adns instead.  Problem with ADNS is that
 945     # it does not support v6.
 946
 947     AC_MSG_CHECKING([whether the resolver is usable])
 948     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 949 #include <netinet/in.h>
 950 #include <arpa/nameser.h>
 951 #include <resolv.h>]],
 952 [[unsigned char answer[PACKETSZ];
 953   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
 954   dn_skipname(0,0);
 955   dn_expand(0,0,0,0,0);
 956 ]])],have_resolver=yes,have_resolver=no)
 957     AC_MSG_RESULT($have_resolver)
 958
 959     # This is Apple-specific and somewhat bizarre as they changed the
 960     # define in bind 8 for some reason.
 961
 962     if test x"$have_resolver" != xyes ; then
 963        AC_MSG_CHECKING(
 964              [whether I can make the resolver usable with BIND_8_COMPAT])
 965        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
 966 #include <sys/types.h>
 967 #include <netinet/in.h>
 968 #include <arpa/nameser.h>
 969 #include <resolv.h>]],
 970 [[unsigned char answer[PACKETSZ];
 971   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
 972   dn_skipname(0,0); dn_expand(0,0,0,0,0);
 973 ]])],[have_resolver=yes ; need_compat=yes])
 974        AC_MSG_RESULT($have_resolver)
 975     fi
 976   fi
 977
 978   if test x"$have_resolver" = xyes ; then
 979      DNSLIBS=$LIBS
 980
 981      if test x"$use_dns_srv" = xyes ; then
 982         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
 983      fi
 984
 985      if test x"$use_dns_cert" = xyes ; then
 986         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
 987      fi
 988
 989      if test x"$need_compat" = xyes ; then
 990         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
 991      fi
 992   else
 993      # If we have no resolver library but ADNS (e.g. under W32) enable the
 994      # code parts which can be used with ADNS.
 995      if test x"$have_adns" = xyes ; then
 996         DNSLIBS="$ADNSLIBS"
 997         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
 998
 999         if test x"$use_dns_srv" = xyes ; then
1000            AC_DEFINE(USE_DNS_SRV,1)
1001         fi
1002
1003         if test x"$use_dns_cert" = xyes ; then
1004            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1005         fi
1006      else
1007         use_dns_srv=no
1008         use_dns_cert=no
1009      fi
1010   fi
1011
1012   LIBS=$_dns_save_libs
1013 fi
1014
1015 AC_SUBST(DNSLIBS)
1016
1017 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1018
1019
1020 #
1021 # Check for LDAP
1022 #
1023 # Note that running the check changes the variable
1024 # gnupg_have_ldap from "n/a" to "no" or "yes".
1025
1026 AC_ARG_ENABLE(ldap,
1027     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1028     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1029
1030 if test "$gnupg_have_ldap" != "no" ; then
1031   if test "$build_dirmngr" = "yes" ; then
1032      GNUPG_CHECK_LDAP($NETLIBS)
1033      AC_CHECK_LIB(lber, ber_free,
1034                   [ LBER_LIBS="$LBER_LIBS -llber"
1035                     AC_DEFINE(HAVE_LBER,1,
1036                              [defined if liblber is available])
1037                     have_lber=yes
1038                  ])
1039   fi
1040 fi
1041 AC_SUBST(LBER_LIBS)
1042 if test "$gnupg_have_ldap" = "no"; then
1043     AC_MSG_WARN([[
1044 ***
1045 *** Building without LDAP support.
1046 *** No CRL access or X.509 certificate search available.
1047 ***]])
1048 fi
1049
1050 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1051 if test "$gnupg_have_ldap" = yes ; then
1052   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1053 else
1054  use_ldapwrapper=no
1055 fi
1056
1057 if test "$use_ldapwrapper" = yes; then
1058    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1059 fi
1060 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1061
1062
1063
1064
1065 #
1066 # Check for sendmail
1067 #
1068 # This isn't necessarily sendmail itself, but anything that gives a
1069 # sendmail-ish interface to the outside world.  That includes Exim,
1070 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1071 AC_ARG_WITH(mailprog,
1072       AC_HELP_STRING([--with-mailprog=NAME],
1073                      [use "NAME -t" for mail transport]),
1074              ,with_mailprog=yes)
1075 if test x"$with_mailprog" = xyes ; then
1076     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1077 elif test x"$with_mailprog" != xno ; then
1078     AC_MSG_CHECKING([for a mail transport program])
1079     AC_SUBST(SENDMAIL,$with_mailprog)
1080     AC_MSG_RESULT($with_mailprog)
1081 fi
1082
1083
1084 #
1085 # Construct a printable name of the OS
1086 #
1087 case "${host}" in
1088     *-mingw32ce*)
1089         PRINTABLE_OS_NAME="W32CE"
1090         ;;
1091     *-mingw32*)
1092         PRINTABLE_OS_NAME="MingW32"
1093         ;;
1094     *-*-cygwin*)
1095         PRINTABLE_OS_NAME="Cygwin"
1096         ;;
1097     i?86-emx-os2 | i?86-*-os2*emx )
1098         PRINTABLE_OS_NAME="OS/2"
1099         ;;
1100     i?86-*-msdosdjgpp*)
1101         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1102         try_dynload=no
1103         ;;
1104     *-linux*)
1105         PRINTABLE_OS_NAME="GNU/Linux"
1106         ;;
1107     *)
1108         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1109         ;;
1110 esac
1111 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1112                    [A human readable text with the name of the OS])
1113
1114
1115 #
1116 # Checking for iconv
1117 #
1118 if test "$require_iconv" = yes; then
1119   AM_ICONV
1120 else
1121   LIBICONV=
1122   LTLIBICONV=
1123   AC_SUBST(LIBICONV)
1124   AC_SUBST(LTLIBICONV)
1125 fi
1126
1127
1128 #
1129 # Check for gettext
1130 #
1131 # This is "GNU gnupg" - The project-id script from gettext
1132 #                       needs this string
1133 #
1134 AC_MSG_NOTICE([checking for gettext])
1135 AM_PO_SUBDIRS
1136 AM_GNU_GETTEXT_VERSION([0.17])
1137 if test "$try_gettext" = yes; then
1138   AM_GNU_GETTEXT([external],[need-ngettext])
1139
1140   # gettext requires some extra checks.  These really should be part of
1141   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1142   # function checks to here.
1143
1144   AC_CHECK_FUNCS(strchr)
1145 else
1146   USE_NLS=no
1147   USE_INCLUDED_LIBINTL=no
1148   BUILD_INCLUDED_LIBINTL=no
1149   POSUB=po
1150   AC_SUBST(USE_NLS)
1151   AC_SUBST(USE_INCLUDED_LIBINTL)
1152   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1153   AC_SUBST(POSUB)
1154 fi
1155
1156 # We use HAVE_LANGINFO_CODESET in a couple of places.
1157 AM_LANGINFO_CODESET
1158
1159 # Checks required for our use of locales
1160 gt_LC_MESSAGES
1161
1162
1163 #
1164 # SELinux support
1165 #
1166 if test "$selinux_support" = yes ; then
1167   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1168 fi
1169
1170
1171 #
1172 # Checks for header files.
1173 #
1174 AC_MSG_NOTICE([checking for header files])
1175 AC_HEADER_STDC
1176 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1177                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h])
1178 AC_HEADER_TIME
1179
1180
1181 #
1182 # Checks for typedefs, structures, and compiler characteristics.
1183 #
1184 AC_MSG_NOTICE([checking for system characteristics])
1185 AC_C_CONST
1186 AC_C_INLINE
1187 AC_C_VOLATILE
1188 AC_TYPE_SIZE_T
1189 AC_TYPE_MODE_T
1190 AC_TYPE_SIGNAL
1191 AC_DECL_SYS_SIGLIST
1192
1193 gl_HEADER_SYS_SOCKET
1194 gl_TYPE_SOCKLEN_T
1195
1196 AC_SEARCH_LIBS([inet_addr], [nsl])
1197
1198 AC_ARG_ENABLE(endian-check,
1199               AC_HELP_STRING([--disable-endian-check],
1200               [disable the endian check and trust the OS provided macros]),
1201               endiancheck=$enableval,endiancheck=yes)
1202
1203 if test x"$endiancheck" = xyes ; then
1204   GNUPG_CHECK_ENDIAN
1205 fi
1206
1207 # fixme: we should get rid of the byte type
1208 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1209 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1210 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1211 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1212 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1213
1214 AC_CHECK_SIZEOF(unsigned short)
1215 AC_CHECK_SIZEOF(unsigned int)
1216 AC_CHECK_SIZEOF(unsigned long)
1217 AC_CHECK_SIZEOF(unsigned long long)
1218 AC_HEADER_TIME
1219 AC_CHECK_SIZEOF(time_t,,[[
1220 #include <stdio.h>
1221 #if TIME_WITH_SYS_TIME
1222 # include <sys/time.h>
1223 # include <time.h>
1224 #else
1225 # if HAVE_SYS_TIME_H
1226 #  include <sys/time.h>
1227 # else
1228 #  include <time.h>
1229 # endif
1230 #endif
1231 ]])
1232 GNUPG_TIME_T_UNSIGNED
1233
1234
1235 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1236    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1237    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1238     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1239 fi
1240
1241
1242 #
1243 # Checks for library functions.
1244 #
1245 AC_MSG_NOTICE([checking for library functions])
1246 AC_CHECK_DECLS(getpagesize)
1247 AC_FUNC_FSEEKO
1248 AC_FUNC_VPRINTF
1249 AC_FUNC_FORK
1250 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1251 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1252 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1253 AC_CHECK_FUNCS([canonicalize_file_name])
1254 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1255 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1256 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1257 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1258
1259 if test "$have_android_system" = yes; then
1260    # On Android ttyname is a stub but prints an error message.
1261    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1262              [Defined if ttyname does not work properly])
1263 fi
1264
1265 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1266
1267 # Dirmngr requires mmap on Unix systems.
1268 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1269   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1270 fi
1271
1272 #
1273 # These are needed by the jnlib parts in common.
1274 # Note:  We already checked pwd.h.
1275 AC_CHECK_HEADERS([signal.h])
1276 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1277                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1278                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1279                 getenv inet_pton strpbrk])
1280 # end jnlib checks.
1281
1282
1283 #
1284 # W32 specific test
1285 #
1286 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1287
1288 #
1289 # Sanity check regex.  Tests adapted from mutt.
1290 #
1291 AC_MSG_CHECKING([whether regular expression support is requested])
1292 AC_ARG_ENABLE(regex,
1293   AC_HELP_STRING([--disable-regex],
1294     [do not handle regular expressions in trust signatures]),
1295   use_regex=$enableval, use_regex=yes)
1296 AC_MSG_RESULT($use_regex)
1297
1298 if test "$use_regex" = yes ; then
1299   _cppflags="${CPPFLAGS}"
1300   _ldflags="${LDFLAGS}"
1301   AC_ARG_WITH(regex,
1302      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1303       [
1304       if test -d "$withval" ; then
1305         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1306         LDFLAGS="${LDFLAGS} -L$withval/lib"
1307       fi
1308       ],withval="")
1309
1310   # Does the system have regex functions at all?
1311   AC_SEARCH_LIBS([regcomp], [regex])
1312   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1313
1314   if test $gnupg_cv_have_regex = no; then
1315     use_regex=no
1316   else
1317     if test x"$cross_compiling" = xyes; then
1318       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1319     else
1320       AC_CACHE_CHECK([whether your system's regexp library is broken],
1321        [gnupg_cv_regex_broken],
1322        AC_TRY_RUN([
1323 #include <unistd.h>
1324 #include <regex.h>
1325 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1326        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1327
1328       if test $gnupg_cv_regex_broken = yes; then
1329         AC_MSG_WARN([your regex is broken - disabling regex use])
1330         use_regex=no
1331       fi
1332     fi
1333   fi
1334   CPPFLAGS="${_cppflags}"
1335   LDFLAGS="${_ldflags}"
1336 fi
1337
1338 if test "$use_regex" != yes ; then
1339   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1340 fi
1341 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1342
1343
1344
1345 #
1346 # Do we have zlib? Must do it here because Solaris failed
1347 # when compiling a conftest (due to the "-lz" from LIBS).
1348 # Note that we combine zlib and bzlib2 in ZLIBS.
1349 #
1350 if test "$use_zip" = yes ; then
1351   _cppflags="${CPPFLAGS}"
1352   _ldflags="${LDFLAGS}"
1353   AC_ARG_WITH(zlib,
1354     [  --with-zlib=DIR         use libz in DIR],[
1355       if test -d "$withval"; then
1356         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1357         LDFLAGS="${LDFLAGS} -L$withval/lib"
1358       fi
1359     ])
1360
1361   AC_CHECK_HEADER(zlib.h,
1362      AC_CHECK_LIB(z, deflateInit2_,
1363        [
1364        ZLIBS="-lz"
1365        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1366        ],
1367        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1368        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1369 fi
1370
1371
1372 #
1373 # Check whether we can support bzip2
1374 #
1375 if test "$use_bzip2" = yes ; then
1376   _cppflags="${CPPFLAGS}"
1377   _ldflags="${LDFLAGS}"
1378   AC_ARG_WITH(bzip2,
1379      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1380       [
1381       if test -d "$withval" ; then
1382         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1383         LDFLAGS="${LDFLAGS} -L$withval/lib"
1384       fi
1385       ],withval="")
1386
1387   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1388   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1389   # woefully out of date.
1390   if test "$withval" != no ; then
1391      AC_CHECK_HEADER(bzlib.h,
1392         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1393           [
1394           have_bz2=yes
1395           ZLIBS="$ZLIBS -lbz2"
1396           AC_DEFINE(HAVE_BZIP2,1,
1397                   [Defined if the bz2 compression library is available])
1398           ],
1399           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1400           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1401   fi
1402 fi
1403 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1404 AC_SUBST(ZLIBS)
1405
1406
1407 # Check for readline support
1408 GNUPG_CHECK_READLINE
1409
1410
1411 if test "$development_version" = yes; then
1412     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1413             [Defined if this is not a regular release])
1414 fi
1415
1416 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1417
1418 GNUPG_CHECK_GNUMAKE
1419
1420 # Add some extra libs here so that previous tests don't fail for
1421 # mysterious reasons - the final link step should bail out.
1422 # W32SOCKLIBS is also defined so that if can be used for tools not
1423 # requiring any network stuff but linking to code in libcommon which
1424 # tracks in winsock stuff (e.g. init_common_subsystems).
1425 if test "$have_w32_system" = yes; then
1426    if test "$have_w32ce_system" = yes; then
1427      W32SOCKLIBS="-lws2"
1428    else
1429      W32SOCKLIBS="-lws2_32"
1430    fi
1431    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1432 fi
1433
1434 AC_SUBST(NETLIBS)
1435 AC_SUBST(W32SOCKLIBS)
1436
1437 #
1438 # Setup gcc specific options
1439 #
1440 AC_MSG_NOTICE([checking for cc features])
1441 if test "$GCC" = yes; then
1442     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1443     # options.  This is the case for gcc >= 4.6
1444     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1445     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1446 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1447 #kickerror
1448 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1449     AC_MSG_RESULT($_gcc_silent_wno)
1450
1451     # Note that it is okay to use CFLAGS here because these are just
1452     # warning options and the user should have a chance of overriding
1453     # them.
1454     if test "$USE_MAINTAINER_MODE" = "yes"; then
1455         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1456         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1457         if test x"$_gcc_silent_wno" = xyes ; then
1458           _gcc_wopt=yes
1459         else
1460           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1461           _gcc_cflags_save=$CFLAGS
1462           CFLAGS="-Wno-missing-field-initializers"
1463           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1464                             [_gcc_wopt=yes],[_gcc_wopt=no])
1465           AC_MSG_RESULT($_gcc_wopt)
1466           CFLAGS=$_gcc_cflags_save;
1467         fi
1468         if test x"$_gcc_wopt" = xyes ; then
1469           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1470         fi
1471
1472         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1473         _gcc_cflags_save=$CFLAGS
1474         CFLAGS="-Wdeclaration-after-statement"
1475         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1476         AC_MSG_RESULT($_gcc_wopt)
1477         CFLAGS=$_gcc_cflags_save;
1478         if test x"$_gcc_wopt" = xyes ; then
1479           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1480         fi
1481     else
1482         CFLAGS="$CFLAGS -Wall"
1483     fi
1484
1485     if test x"$_gcc_silent_wno" = xyes ; then
1486       _gcc_psign=yes
1487     else
1488       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1489       _gcc_cflags_save=$CFLAGS
1490       CFLAGS="-Wno-pointer-sign"
1491       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1492                         [_gcc_psign=yes],[_gcc_psign=no])
1493       AC_MSG_RESULT($_gcc_psign)
1494       CFLAGS=$_gcc_cflags_save;
1495     fi
1496     if test x"$_gcc_psign" = xyes ; then
1497        CFLAGS="$CFLAGS -Wno-pointer-sign"
1498     fi
1499
1500     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1501     _gcc_cflags_save=$CFLAGS
1502     CFLAGS="-Wpointer-arith"
1503     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1504     AC_MSG_RESULT($_gcc_psign)
1505     CFLAGS=$_gcc_cflags_save;
1506     if test x"$_gcc_psign" = xyes ; then
1507        CFLAGS="$CFLAGS -Wpointer-arith"
1508     fi
1509 fi
1510
1511
1512 #
1513 # This is handy for debugging so the compiler doesn't rearrange
1514 # things and eliminate variables.
1515 #
1516 AC_ARG_ENABLE(optimization,
1517    AC_HELP_STRING([--disable-optimization],
1518                   [disable compiler optimization]),
1519                   [if test $enableval = no ; then
1520                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1521                    fi])
1522
1523 #
1524 # Decide what to build
1525 #
1526
1527 build_scdaemon_extra=""
1528 if test "$build_scdaemon" = "yes"; then
1529   if test $have_libusb = no; then
1530      build_scdaemon_extra="without internal CCID driver"
1531   fi
1532   if test -n "$build_scdaemon_extra"; then
1533      build_scdaemon_extra="(${build_scdaemon_extra})"
1534   fi
1535 fi
1536
1537
1538 #
1539 # Set variables for use by automake makefiles.
1540 #
1541 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1542 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1543 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1544 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1545 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1546 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1547 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1548 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1549 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1550 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1551
1552 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1553 AM_CONDITIONAL(NO_TRUST_MODELS, test "$use_trust_models" = no)
1554
1555 AM_CONDITIONAL(RUN_GPG_TESTS,
1556                test x$cross_compiling = xno -a "$build_gpg" = yes )
1557
1558 #
1559 # Set some defines for use gpgconf.
1560 #
1561 if test "$build_gpg" = yes ; then
1562     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1563 fi
1564 if test "$build_gpgsm" = yes ; then
1565     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1566 fi
1567 if test "$build_agent" = yes ; then
1568     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1569 fi
1570 if test "$build_scdaemon" = yes ; then
1571     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1572 fi
1573 if test "$build_dirmngr" = yes ; then
1574     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1575 fi
1576 if test "$build_g13" = yes ; then
1577     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1578 fi
1579
1580
1581 #
1582 # Define Name strings
1583 #
1584 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1585
1586 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1587 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1588
1589 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1590 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1591
1592 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1593 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1594                                         [The displayed name of gpg-agent])
1595
1596 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1597 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1598                                        [The displayed name of scdaemon])
1599
1600 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1601 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1602                                       [The displayed name of dirmngr])
1603
1604 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1605 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1606
1607 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1608 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1609                                       [The displayed name of gpgconf])
1610
1611 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1612
1613 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1614                    [The name of the agent socket])
1615 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1616                    [The name of the agent socket for ssh])
1617 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1618                    [The name of the dirmngr info envvar])
1619 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1620                    [The name of the SCdaemon socket])
1621 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1622                    [The name of the dirmngr socket])
1623
1624 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1625
1626 if test "$have_w32_system" = yes; then
1627   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1628                      [The directory part of the W32 registry keys])
1629 fi
1630
1631
1632 #
1633 # Provide information about the build.
1634 #
1635 BUILD_REVISION="mym4_revision"
1636 AC_SUBST(BUILD_REVISION)
1637 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1638                    [GIT commit id revision used to build this package])
1639
1640 changequote(,)dnl
1641 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1642 changequote([,])dnl
1643 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1644 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1645 AC_SUBST(BUILD_VERSION)
1646 AC_SUBST(BUILD_FILEVERSION)
1647
1648 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1649 AC_SUBST(BUILD_TIMESTAMP)
1650 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1651                    [The time this package was configured for a build])
1652 BUILD_HOSTNAME="$ac_hostname"
1653 AC_SUBST(BUILD_HOSTNAME)
1654
1655
1656 #
1657 # Print errors here so that they are visible all
1658 # together and the user can acquire them all together.
1659 #
1660 die=no
1661 if test "$have_gpg_error" = "no"; then
1662    die=yes
1663    AC_MSG_NOTICE([[
1664 ***
1665 *** You need libgpg-error to build this program.
1666 **  This library is for example available at
1667 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1668 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1669 ***]])
1670 fi
1671 if test "$have_libgcrypt" = "no"; then
1672    die=yes
1673    AC_MSG_NOTICE([[
1674 ***
1675 *** You need libgcrypt to build this program.
1676 **  This library is for example available at
1677 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1678 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1679 ***]])
1680 fi
1681 if test "$have_libassuan" = "no"; then
1682    die=yes
1683    AC_MSG_NOTICE([[
1684 ***
1685 *** You need libassuan to build this program.
1686 *** This library is for example available at
1687 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1688 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1689 ***]])
1690 fi
1691 if test "$have_ksba" = "no"; then
1692     die=yes
1693     AC_MSG_NOTICE([[
1694 ***
1695 *** You need libksba to build this program.
1696 *** This library is for example available at
1697 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1698 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1699 ***]])
1700 fi
1701 if test "$gnupg_have_ldap" = yes; then
1702   if test "$have_w32ce_system" = yes; then
1703     AC_MSG_NOTICE([[
1704 *** Note that CeGCC might be broken, a package fixing this is:
1705 ***    http://files.kolab.org/local/windows-ce/
1706 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1707 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1708 ***]])
1709    fi
1710 fi
1711 if test "$have_npth" = "no"; then
1712     die=yes
1713     AC_MSG_NOTICE([[
1714 ***
1715 *** It is now required to build with support for the
1716 *** New Portable Threads Library (nPth). Please install this
1717 *** library first.  The library is for example available at
1718 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1719 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1720 ***]])
1721 fi
1722
1723 if test "$require_iconv" = yes; then
1724   if test "$am_func_iconv" != yes; then
1725     die=yes
1726     AC_MSG_NOTICE([[
1727 ***
1728 *** The system does not provide a working iconv function.  Please
1729 *** install a suitable library; for example GNU Libiconv which is
1730 *** available at:
1731 ***   http://ftp.gnu.org/gnu/libiconv/
1732 ***]])
1733   fi
1734 fi
1735
1736 if test "$die" = "yes"; then
1737     AC_MSG_ERROR([[
1738 ***
1739 *** Required libraries not found. Please consult the above messages
1740 *** and install them before running configure again.
1741 ***]])
1742 fi
1743
1744
1745
1746 AC_CONFIG_FILES([ m4/Makefile
1747 Makefile
1748 po/Makefile.in
1749 common/Makefile
1750 common/w32info-rc.h
1751 kbx/Makefile
1752 g10/Makefile
1753 sm/Makefile
1754 agent/Makefile
1755 scd/Makefile
1756 g13/Makefile
1757 dirmngr/Makefile
1758 tools/gpg-zip
1759 tools/Makefile
1760 doc/Makefile
1761 tests/Makefile
1762 tests/openpgp/Makefile
1763 tests/pkits/Makefile
1764 g10/gpg.w32-manifest
1765 ])
1766
1767
1768 AC_OUTPUT
1769
1770
1771 echo "
1772         GnuPG v${VERSION} has been configured as follows:
1773
1774         Revision:  mym4_revision  (mym4_revision_dec)
1775         Platform:  $PRINTABLE_OS_NAME ($host)
1776
1777         OpenPGP:   $build_gpg
1778         S/MIME:    $build_gpgsm
1779         Agent:     $build_agent
1780         Smartcard: $build_scdaemon $build_scdaemon_extra
1781         G13:       $build_g13
1782         Dirmngr:   $build_dirmngr
1783         Gpgtar:    $build_gpgtar
1784
1785         Protect tool:      $show_gnupg_protect_tool_pgm
1786         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1787         Default agent:     $show_gnupg_agent_pgm
1788         Default pinentry:  $show_gnupg_pinentry_pgm
1789         Default scdaemon:  $show_gnupg_scdaemon_pgm
1790         Default dirmngr:   $show_gnupg_dirmngr_pgm
1791
1792         Dirmngr auto start:  $dirmngr_auto_start
1793         Readline support:    $gnupg_cv_have_readline
1794         LDAP support:        $gnupg_have_ldap
1795         DNS SRV support:     $use_dns_srv
1796         TLS support:         $use_tls_library
1797 "
1798 if test x"$use_regex" != xyes ; then
1799 echo "
1800         Warning: No regular expression support available.
1801                  OpenPGP trust signatures won't work.
1802                  gpg-check-pattern will not be built.
1803 "
1804 fi
1805 if test "x${gpg_config_script_warn}" != x; then
1806 cat <<G10EOF
1807         Warning: Mismatches between the target platform and the
1808                  to be used libraries have been detected for:
1809                   ${gpg_config_script_warn}
1810                  Please check above for more warning messages.
1811
1812 G10EOF
1813 fi