configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [11])
   6 m4_define([dbus_micro_version], [17])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 m4_pattern_forbid([^AX_],
  14   [Unexpanded AX_ macro found. Please install GNU autoconf-archive])
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 AM_INIT_AUTOMAKE([1.13 tar-ustar -Wno-portability subdir-objects])
  22
  23 GETTEXT_PACKAGE=dbus-1
  24 AC_SUBST(GETTEXT_PACKAGE)
  25 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  26
  27 # By default, rebuild autotools files on demand; only use ./missing if the
  28 # user says --disable-maintainer-mode (some distributions like to do this)
  29 AM_MAINTAINER_MODE([enable])
  30
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32
  33 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  34
  35 # libtool versioning - this applies to libdbus
  36 #
  37 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  38 #
  39
  40 ## increment if the interface has additions, changes, removals.
  41 LT_CURRENT=21
  42
  43 ## increment any time the source changes; set to
  44 ##  0 if you increment CURRENT
  45 LT_REVISION=0
  46
  47 ## increment if any interfaces have been added; set to 0
  48 ## if any interfaces have been changed or removed. removal has
  49 ## precedence over adding, so set to 0 if both happened.
  50 LT_AGE=18
  51
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55 SOVERSION=`expr ${LT_CURRENT} - ${LT_AGE}`
  56 AC_SUBST([SOVERSION])
  57
  58 DBUS_MAJOR_VERSION=dbus_major_version
  59 DBUS_MINOR_VERSION=dbus_minor_version
  60 DBUS_MICRO_VERSION=dbus_micro_version
  61 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  62
  63 AC_SUBST(DBUS_MAJOR_VERSION)
  64 AC_SUBST(DBUS_MINOR_VERSION)
  65 AC_SUBST(DBUS_MICRO_VERSION)
  66 AC_SUBST(DBUS_VERSION)
  67
  68 dnl
  69 dnl Build configuration
  70 dnl
  71
  72 dnl This must come first: other options use this to set their defaults. Don't
  73 dnl enable developer mode on production builds.
  74 AC_ARG_ENABLE([developer],
  75   [AS_HELP_STRING([--enable-developer],
  76     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
  77   [enable_developer=$enableval],
  78   [enable_developer=no])
  79
  80 dnl 'disable_developer' is the negation of 'enable_developer'. If
  81 dnl 'enable-developer' is set to 'no' (the default), the value of
  82 dnl 'disable_developer' is set to 'yes', and vice versa. It's used
  83 dnl for macros that require the opposite of 'enable_developer', such
  84 dnl as several AX_ macros.
  85 dnl See https://bugs.freedesktop.org/show_bug.cgi?id=97357
  86 AS_IF([test "x$enable_developer" = "xyes"],[
  87     disable_developer=no
  88   ],[
  89     disable_developer=yes
  90   ])
  91
  92 # The debugging check must run before the compiler tests. Other command-line
  93 # options also use it to set their defaults. We disable debugging by default,
  94 # except for developer builds.
  95 AX_CHECK_ENABLE_DEBUG([$enable_developer])
  96
  97 AC_PROG_CC
  98 AM_PROG_CC_C_O
  99 AC_PROG_CXX
 100 AC_USE_SYSTEM_EXTENSIONS
 101 AC_SYS_LARGEFILE
 102 AC_ISC_POSIX
 103 AC_HEADER_STDC
 104 AC_C_INLINE
 105 AM_PROG_LIBTOOL
 106 AC_PROG_MKDIR_P
 107 PKG_PROG_PKG_CONFIG
 108
 109 # TAP test driver support
 110 AC_PROG_AWK
 111 AC_REQUIRE_AUX_FILE([tap-driver.sh])
 112
 113 # This must come before we set up compiler warnings because it assumes
 114 # non-use of -Werror=missing-prototypes
 115 gl_VISIBILITY
 116 AM_CONDITIONAL([HAVE_VISIBILITY], [test "x$HAVE_VISIBILITY" = x1])
 117
 118 # Initialize libtool
 119 LT_INIT([win32-dll])
 120 LT_LANG([Windows Resource])
 121
 122 # Set some internal variables depending on the platform for later use.
 123 dbus_win=no
 124 dbus_cygwin=no
 125 dbus_unix=no
 126 case "${host}" in
 127     *-mingw32ce*)
 128         dbus_win=yes
 129         dbus_wince=yes
 130         ;;
 131     *-mingw32*)
 132         dbus_win=yes
 133         ;;
 134     *-cygwin*)
 135         dbus_cygwin=yes
 136         dbus_unix=yes
 137         ;;
 138     *)
 139         dbus_unix=yes
 140        ;;
 141 esac
 142
 143 # Special defines for certain platforms
 144 if test "$dbus_win" = yes; then
 145     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 146     # Yes, on Windows it really does work like this.
 147     # http://support.microsoft.com/kb/111855
 148     AC_DEFINE(FD_SETSIZE,8192,[The maximum number of connections that can be handled at once])
 149     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 150     AC_SUBST(BUILD_TIMESTAMP)
 151     # Assume DBUS_VERSION is always three numbers
 152     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 153     AC_SUBST(BUILD_FILEVERSION)
 154     AC_CHECK_TOOL(WINDRES, windres, no)
 155     if test "$WINDRES" = no; then
 156       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 157     fi
 158     if test "$dbus_wince" = yes; then
 159       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 160       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 161     fi
 162 else
 163     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 164 fi
 165 if test "$dbus_cygwin" = yes; then
 166     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 167 fi
 168
 169 # For best security, assume that all non-Windows platforms can do
 170 # credentials-passing.
 171 AS_IF([test "$dbus_win" = yes],
 172     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<!--<auth>EXTERNAL</auth>-->"],
 173     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<auth>EXTERNAL</auth>"])
 174 AC_SUBST([DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL])
 175
 176 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 177 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 178 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 179 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 180
 181 DBUS_STATIC_BUILD_CPPFLAGS=
 182 if test "x$enable_shared" = xno; then
 183     # On Windows, linking against the static library requires special effort
 184     # to turn off DLL import/export processing. We normally link some things
 185     # against the dynamic library, but if we're not building that, we'll
 186     # have to link everything statically.
 187     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 188 fi
 189 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 190
 191 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 192 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 193 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 194 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 195 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 196 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 197 AC_ARG_ENABLE([ducktype-docs],
 198               AS_HELP_STRING([--enable-ducktype-docs],
 199                              [build Ducktype documentation (requires Ducktype)]),
 200               [enable_ducktype_docs=$enableval], [enable_ducktype_docs=auto])
 201 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 202 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 203 AC_ARG_ENABLE([apparmor],
 204   [AS_HELP_STRING([--enable-apparmor], [build with AppArmor support])],
 205   [enable_apparmor=$enableval],
 206   [enable_apparmor=auto])
 207 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 208 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 209 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 210 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 211 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 212 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 213
 214 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 215 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 216 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 217 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 218 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 219 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 220 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 221 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 222 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 223 AC_ARG_WITH([test_user],
 224   [AS_HELP_STRING([--with-test-user=<user>],
 225     [Unprivileged user for regression tests, other than root and the dbus_user (default: nobody)])])
 226 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 227
 228 AC_ARG_ENABLE([embedded-tests],
 229   AS_HELP_STRING([--enable-embedded-tests],
 230     [enable unit test code in the library and binaries]),
 231   [], [enable_embedded_tests=$enable_developer])
 232 AC_ARG_ENABLE([modular-tests],
 233   AS_HELP_STRING([--enable-modular-tests],
 234     [enable modular regression tests (requires GLib)]),
 235   [], [enable_modular_tests=auto])
 236 # --enable-tests overrides both --enable-embedded-tests and
 237 # --enable-modular-tests
 238 AC_ARG_ENABLE([tests],
 239   AS_HELP_STRING([--enable-tests],
 240     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 241   [
 242   if test "x$enableval" = xyes; then
 243     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 244     AC_MSG_NOTICE([This has many dependencies (GLib, Python etc.)])
 245   fi
 246   enable_embedded_tests=$enableval
 247   enable_modular_tests=$enableval
 248   ],
 249   [])
 250
 251 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 252 # and also some stuff in the test/ subdir.
 253 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 254   [test "x$enable_embedded_tests" = xyes])
 255 if test "x$enable_embedded_tests" = xyes; then
 256     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 257       [Define to build test code into the library and binaries])
 258 fi
 259
 260 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 261 # These use GTest, from GLib, because life's too short. They're enabled by
 262 # default (unless you don't have GLib), because they don't bloat the library
 263 # or binaries.
 264
 265 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_40], [Ignore post-2.40 deprecations])
 266 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_40], [Prevent post-2.40 APIs])
 267
 268 with_glib=yes
 269
 270 AS_IF([test "x$enable_modular_tests" != xno],
 271   [
 272   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.40, gio-2.0 >= 2.40],
 273     [
 274       AS_IF([test "x$dbus_unix" = xyes],
 275         [PKG_CHECK_MODULES([GIO_UNIX], [gio-unix-2.0],
 276            [AC_DEFINE([HAVE_GIO_UNIX], [1], [Define if you have gio-unix-2.0])], [])])
 277     ],
 278     [if test "x$enable_modular_tests" = xyes; then
 279       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 280       AC_MSG_ERROR([$GLIB_ERRORS])
 281     else # assumed to be "auto"
 282       with_glib=no
 283     fi])
 284   ],
 285   [with_glib=no])
 286
 287 if test "x$enable_modular_tests" != xno; then
 288   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 289     [Define to build independent test binaries])
 290 fi
 291 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 292   [test "x$enable_modular_tests" != xno])
 293
 294 if test "x$with_glib" != xno; then
 295   AC_DEFINE([DBUS_WITH_GLIB], [1],
 296     [Define if GLib, GObject, GIO are available])
 297 fi
 298 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 299
 300 AC_ARG_ENABLE([installed-tests],
 301   AS_HELP_STRING([--enable-installed-tests],
 302     [enable unit test code in the library and binaries]),
 303   [], [enable_installed_tests=no])
 304 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 305   [test "x$enable_installed_tests" = xyes])
 306
 307 if test "x$enable_tests" = xyes; then
 308   # full test coverage is required, Python is a hard dependency
 309   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygi])
 310   AM_PATH_PYTHON([2.6])
 311   AC_MSG_CHECKING([for Python modules for full test coverage])
 312   if "$PYTHON" -c "import dbus, gi.repository.GObject, dbus.mainloop.glib"; then
 313     AC_MSG_RESULT([yes])
 314   else
 315     AC_MSG_RESULT([no])
 316     AC_MSG_ERROR([cannot import dbus, gi.repository.GObject, dbus.mainloop.glib Python modules])
 317   fi
 318 else
 319   # --enable-tests not given: do not abort if Python is missing
 320   AM_PATH_PYTHON([2.6], [], [:])
 321 fi
 322
 323 if test x$enable_verbose_mode = xyes; then
 324     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 325 fi
 326
 327 dnl Intentional:
 328 dnl - $DISABLE_WARNINGS disables unused-label warnings if not
 329 dnl   checking or not asserting (tested further below)
 330 dnl - missing field initializers being 0 is a C feature, not a bug
 331 dnl - unused-parameter is to make writing callbacks less annoying
 332 DISABLE_WARNINGS="$DISABLE_WARNINGS
 333                   -Wno-missing-field-initializers
 334                   -Wno-unused-parameter"
 335
 336 if test x$enable_asserts = xno; then
 337     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 338     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 339     R_DYNAMIC_LDFLAG=""
 340     if test x$enable_embedded_tests = xyes; then
 341         DISABLE_WARNINGS="$DISABLE_WARNINGS
 342                           -Wno-unused-but-set-variable
 343                           -Wno-unused-variable
 344                           -Wno-unused-function"
 345     fi
 346 else
 347     # -rdynamic is needed for glibc's backtrace_symbols to work.
 348     # No clue how much overhead this adds, but it's useful
 349     # to do this on any assertion failure,
 350     # so for now it's enabled anytime asserts are (currently not
 351     # in production builds).
 352
 353     # To get -rdynamic you pass -export-dynamic to libtool.
 354     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 355     R_DYNAMIC_LDFLAG=-export-dynamic
 356 fi
 357 AC_SUBST(R_DYNAMIC_LDFLAG)
 358
 359 if test x$enable_checks = xno; then
 360     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 361     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 362     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 363 fi
 364
 365 AH_BOTTOM([
 366 /* explicitly define these macros to get less confusing conditions */
 367 #ifndef DBUS_DISABLE_ASSERT
 368 #  define DBUS_ENABLE_ASSERT 1
 369 #endif
 370 #ifndef DBUS_DISABLE_CHECKS
 371 #  define DBUS_ENABLE_CHECKS 1
 372 #endif])
 373
 374 # Test for code-coverage tools if --enable-code-coverage
 375 AX_CODE_COVERAGE
 376
 377 AS_IF([test x$enable_code_coverage = xyes],[
 378     AC_DEFINE_UNQUOTED(
 379       [DBUS_GCOV_ENABLED], [1],
 380       [Defined if gcov is enabled to force a rebuild due to config.h changing])
 381   ])
 382
 383 #### Integer sizes
 384
 385 AC_CHECK_SIZEOF(char)
 386 AC_CHECK_SIZEOF(short)
 387 AC_CHECK_SIZEOF(long)
 388 AC_CHECK_SIZEOF(int)
 389 AC_CHECK_SIZEOF(void *)
 390 AC_CHECK_SIZEOF(long long)
 391 AC_CHECK_SIZEOF(__int64)
 392
 393 ### See what our 64 bit type is called
 394 AC_MSG_CHECKING([64-bit integer type])
 395
 396 case 8 in
 397 $ac_cv_sizeof_int)
 398   dbusint64=int
 399   dbusint64_constant='(val)'
 400   dbusuint64_constant='(val)'
 401   ;;
 402 $ac_cv_sizeof_long)
 403   dbusint64=long
 404   dbusint64_constant='(val##L)'
 405   dbusuint64_constant='(val##UL)'
 406   ;;
 407 $ac_cv_sizeof_long_long)
 408   dbusint64='long long'
 409   dbusint64_constant='(val##LL)'
 410   dbusuint64_constant='(val##ULL)'
 411   ;;
 412 $ac_cv_sizeof___int64)
 413   dbusint64=__int64
 414   dbusint64_constant='(val##i64)'
 415   dbusuint64_constant='(val##ui64)'
 416   ;;
 417 esac
 418
 419 AS_IF(
 420   [test -z "$dbusint64"],
 421   [AC_MSG_RESULT([not found])
 422   AC_MSG_ERROR([Could not find a 64-bit integer type.
 423
 424 Please report a bug here with details of your platform and compiler:
 425
 426     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core])
 427   ],
 428   dnl else
 429   [
 430         DBUS_INT64_TYPE="$dbusint64"
 431         DBUS_INT64_CONSTANT="$dbusint64_constant"
 432         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 433         AC_MSG_RESULT($DBUS_INT64_TYPE)
 434   ])
 435
 436 AC_SUBST(DBUS_INT64_TYPE)
 437 AC_SUBST(DBUS_INT64_CONSTANT)
 438 AC_SUBST(DBUS_UINT64_CONSTANT)
 439
 440 ### see what 32-bit int is called
 441 AC_MSG_CHECKING([32-bit integer type])
 442
 443 case 4 in
 444 $ac_cv_sizeof_short)
 445   dbusint32=short
 446   ;;
 447 $ac_cv_sizeof_int)
 448   dbusint32=int
 449   ;;
 450 $ac_cv_sizeof_long)
 451   dbusint32=long
 452   ;;
 453 esac
 454
 455 if test -z "$dbusint32" ; then
 456         DBUS_INT32_TYPE="no_int32_type_detected"
 457         AC_MSG_ERROR([No 32-bit integer type found])
 458 else
 459         DBUS_INT32_TYPE="$dbusint32"
 460         AC_MSG_RESULT($DBUS_INT32_TYPE)
 461 fi
 462
 463 AC_SUBST(DBUS_INT32_TYPE)
 464
 465 ### see what 16-bit int is called
 466 AC_MSG_CHECKING([16-bit integer type])
 467
 468 case 2 in
 469 $ac_cv_sizeof_short)
 470   dbusint16=short
 471   ;;
 472 $ac_cv_sizeof_int)
 473   dbusint16=int
 474   ;;
 475 esac
 476
 477 if test -z "$dbusint16" ; then
 478         DBUS_INT16_TYPE="no_int16_type_detected"
 479         AC_MSG_ERROR([No 16-bit integer type found])
 480 else
 481         DBUS_INT16_TYPE="$dbusint16"
 482         AC_MSG_RESULT($DBUS_INT16_TYPE)
 483 fi
 484
 485 AC_SUBST(DBUS_INT16_TYPE)
 486
 487 ## byte order
 488 case $host_os in
 489         darwin*)
 490                 # check at compile-time, so that it is possible to build universal
 491                 # (with multiple architectures at once on the compile line)
 492                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 493                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 494                         #if defined(__BIG_ENDIAN__)
 495                         #define WORDS_BIGENDIAN 1
 496                         #endif
 497                 ])
 498                 ;;
 499         *)
 500                 AC_C_BIGENDIAN
 501                 ;;
 502 esac
 503
 504 # As a GNU extension, glibc declares environ in unistd.h, which is one of
 505 # the AC_INCLUDES_DEFAULT.
 506 AC_CHECK_DECLS([environ])
 507
 508 dnl **********************************
 509 dnl *** va_copy checks (from GLib) ***
 510 dnl **********************************
 511 dnl we currently check for all three va_copy possibilities, so we get
 512 dnl all results in config.log for bug reports.
 513 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 514         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 515 #include <stdlib.h>
 516         static void f (int i, ...) {
 517         va_list args1, args2;
 518         va_start (args1, i);
 519         va_copy (args2, args1);
 520         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 521           exit (1);
 522         va_end (args1); va_end (args2);
 523         }
 524         int main() {
 525           f (0, 42);
 526           return 0;
 527         }])],
 528         [dbus_cv_va_copy=yes],
 529         [dbus_cv_va_copy=no])
 530 ])
 531 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 532         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 533 #include <stdlib.h>
 534         static void f (int i, ...) {
 535         va_list args1, args2;
 536         va_start (args1, i);
 537         __va_copy (args2, args1);
 538         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 539           exit (1);
 540         va_end (args1); va_end (args2);
 541         }
 542         int main() {
 543           f (0, 42);
 544           return 0;
 545         }])],
 546         [dbus_cv___va_copy=yes],
 547         [dbus_cv___va_copy=no])
 548 ])
 549
 550 if test "x$dbus_cv_va_copy" = "xyes"; then
 551   dbus_va_copy_func=va_copy
 552 else if test "x$dbus_cv___va_copy" = "xyes"; then
 553   dbus_va_copy_func=__va_copy
 554 fi
 555 fi
 556
 557 if test -n "$dbus_va_copy_func"; then
 558   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 559 fi
 560
 561 AC_LANG_PUSH(C)
 562 AC_CACHE_CHECK([whether va_lists can be copied by value],
 563         dbus_cv_va_val_copy,
 564         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 565 [[
 566         #include <stdarg.h>
 567         #include <stdlib.h>
 568 ]],
 569 [[
 570         static void f (int i, ...) {
 571         va_list args1, args2;
 572         va_start (args1, i);
 573         args2 = args1;
 574         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 575           exit (1);
 576         va_end (args1); va_end (args2);
 577         }
 578         int main() {
 579           f (0, 42);
 580           return 0;
 581         }
 582 ]])],
 583         [dbus_cv_va_val_copy=yes],
 584         [dbus_cv_va_val_copy=no],
 585         [dbus_cv_va_val_copy=yes])
 586 ])
 587 AC_LANG_POP(C)
 588
 589 if test "x$dbus_cv_va_val_copy" = "xno"; then
 590   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 591 fi
 592
 593
 594 #### Atomic integers
 595
 596 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 597   dbus_cv_sync_sub_and_fetch,
 598   [AC_LINK_IFELSE([
 599      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 600      [dbus_cv_sync_sub_and_fetch=yes],
 601      [dbus_cv_sync_sub_and_fetch=no])
 602   ])
 603
 604 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 605    have_sync=1
 606 else
 607    have_sync=0
 608 fi
 609
 610 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 611
 612 #### Various functions
 613 AC_SEARCH_LIBS(socket,[socket network])
 614 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 615
 616 AC_CHECK_FUNCS([vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid setresuid getrlimit])
 617
 618 AC_CHECK_HEADERS([syslog.h])
 619 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 620   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 621 fi
 622
 623 # For test-segfault.c
 624 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 625 AC_CHECK_FUNCS_ONCE([prctl raise])
 626
 627 #### Check for broken poll; taken from Glib's configure
 628
 629 AC_MSG_CHECKING([for broken poll])
 630 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 631     #include <stdlib.h>
 632     #include <fcntl.h>
 633     #include <poll.h>
 634     #ifdef HAVE_SYS_POLL_H
 635     #include <sys/poll.h>
 636     #endif
 637     int main(void) {
 638       struct pollfd fds[1];
 639       int fd;
 640       fd = open("/dev/null", 1);
 641       fds[0].fd = fd;
 642       fds[0].events = POLLIN;
 643       fds[0].revents = 0;
 644       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 645             exit(1);  /* Does not work for devices -- fail */
 646       }
 647       exit(0);
 648     }]])],
 649   [broken_poll=no],
 650   [broken_poll=yes
 651    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 652   [broken_poll="no (cross compiling)"])
 653 AC_MSG_RESULT($broken_poll)
 654
 655 AC_MSG_CHECKING(for dirfd)
 656 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 657 #include <sys/types.h>
 658 #include <dirent.h>
 659 ]], [[
 660 DIR *dirp;
 661 dirp = opendir(".");
 662 dirfd(dirp);
 663 closedir(dirp);
 664 ]])],
 665 [dbus_have_dirfd=yes],
 666 [dbus_have_dirfd=no])
 667 AC_MSG_RESULT($dbus_have_dirfd)
 668 if test "$dbus_have_dirfd" = yes; then
 669         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 670 else
 671         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 672         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 673 #include <sys/types.h>
 674 #include <dirent.h>
 675         ]], [[
 676 DIR *dirp;
 677 int fd;
 678 dirp = opendir(".");
 679 fd = dirp->dd_fd;
 680 closedir(dirp);
 681         ]])],
 682         [dbus_have_ddfd=yes],
 683         [dbus_have_ddfd=no])
 684         AC_MSG_RESULT($dbus_have_ddfd)
 685         if test "$dbus_have_ddfd" = yes; then
 686                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 687         fi
 688 fi
 689
 690 AC_CHECK_HEADERS(sys/resource.h)
 691
 692 AC_CHECK_HEADERS(dirent.h)
 693
 694 AC_CHECK_HEADERS([execinfo.h],
 695         [AC_SEARCH_LIBS([backtrace], [execinfo],
 696                 [AC_DEFINE([HAVE_BACKTRACE], [1],
 697                         [Define to 1 if you have backtrace().])])])
 698
 699 AC_CHECK_HEADERS(errno.h)
 700
 701 AC_CHECK_HEADERS(signal.h)
 702
 703 AC_CHECK_HEADERS(locale.h)
 704
 705 AC_CHECK_HEADERS(byteswap.h)
 706
 707 AC_CHECK_HEADERS(unistd.h)
 708
 709 AC_CHECK_HEADERS([stdint.h])
 710
 711 AC_CHECK_HEADERS(ws2tcpip.h)
 712
 713 AC_CHECK_HEADERS(alloca.h)
 714
 715 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 716 #
 717 case $host_os in
 718     solaris*)
 719        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 720 esac
 721
 722 # checking for a posix version of getpwnam_r
 723 # if we are cross compiling and can not run the test
 724 # assume getpwnam_r is the posix version
 725 # it is up to the person cross compiling to change
 726 # this behavior if desired
 727 AC_LANG_PUSH(C)
 728 AC_CACHE_CHECK([for posix getpwnam_r],
 729                 ac_cv_func_posix_getpwnam_r,
 730                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 731 [[
 732 #include <errno.h>
 733 #include <pwd.h>
 734 ]],
 735 [[
 736     char buffer[10000];
 737     struct passwd pwd, *pwptr = &pwd;
 738     int error;
 739     errno = 0;
 740     error = getpwnam_r ("", &pwd, buffer,
 741                         sizeof (buffer), &pwptr);
 742    return (error < 0 && errno == ENOSYS)
 743            || error == ENOSYS;
 744 ]])],
 745         [ac_cv_func_posix_getpwnam_r=yes],
 746         [ac_cv_func_posix_getpwnam_r=no],
 747         [ac_cv_func_posix_getpwnam_r=yes]
 748 )])
 749 AC_LANG_POP(C)
 750
 751 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 752         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 753                 [Have POSIX function getpwnam_r])
 754 else
 755         AC_CACHE_CHECK([for nonposix getpwnam_r],
 756                 ac_cv_func_nonposix_getpwnam_r,
 757                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 758                         struct passwd pwd;
 759                         getpwnam_r ("", &pwd, buffer,
 760                                         sizeof (buffer));]])],
 761                         [ac_cv_func_nonposix_getpwnam_r=yes],
 762                         [ac_cv_func_nonposix_getpwnam_r=no])])
 763                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 764                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 765                         [Have non-POSIX function getpwnam_r])
 766         fi
 767 fi
 768
 769 dnl check for socklen_t
 770 AC_MSG_CHECKING(whether socklen_t is defined)
 771 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 772 #include <sys/types.h>
 773 #include <sys/socket.h>
 774 #include <netdb.h>
 775 ]], [[
 776 socklen_t foo;
 777 foo = 1;
 778 ]])],
 779 [dbus_have_socklen_t=yes],
 780 [dbus_have_socklen_t=no])
 781 AC_MSG_RESULT($dbus_have_socklen_t)
 782
 783 if test "x$dbus_have_socklen_t" = "xyes"; then
 784     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 785 fi
 786
 787 dnl check for writev header and writev function so we're
 788 dnl good to go if HAVE_WRITEV gets defined.
 789 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 790
 791 dnl needed on darwin for NAME_MAX
 792 AC_CHECK_HEADERS(sys/syslimits.h)
 793
 794 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 795 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 796 #include <sys/socket.h> ]])
 797
 798 dnl check for flavours of varargs macros (test from GLib)
 799 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 800 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 801 int a(int p1, int p2, int p3);
 802 #define call_a(...) a(1,__VA_ARGS__)
 803 call_a(2,3);
 804 ]])],
 805 [dbus_have_iso_c_varargs=yes],
 806 [dbus_have_iso_c_varargs=no])
 807 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 808
 809 AC_MSG_CHECKING(for GNUC varargs macros)
 810 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 811 int a(int p1, int p2, int p3);
 812 #define call_a(params...) a(1,params)
 813 call_a(2,3);
 814 ]])],
 815 [dbus_have_gnuc_varargs=yes],
 816 [dbus_have_gnuc_varargs=no])
 817 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 818
 819 dnl Output varargs tests
 820 if test x$dbus_have_iso_c_varargs = xyes; then
 821     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 822 fi
 823 if test x$dbus_have_gnuc_varargs = xyes; then
 824     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 825 fi
 826
 827 dnl Check for various credentials.
 828 AC_MSG_CHECKING(for struct cmsgcred)
 829 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 830 #include <sys/types.h>
 831 #include <sys/socket.h>
 832 ]], [[
 833 struct cmsgcred cred;
 834
 835 cred.cmcred_pid = 0;
 836 ]])],
 837 [dbus_have_struct_cmsgcred=yes],
 838 [dbus_have_struct_cmsgcred=no])
 839 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 840
 841 if test x$dbus_have_struct_cmsgcred = xyes; then
 842     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 843 fi
 844
 845 AC_CHECK_MEMBER([struct unpcbid.unp_pid],
 846                 [AC_DEFINE([HAVE_UNPCBID], 1, [Have unpcbid structure])],
 847                 [],
 848                 [[#include <sys/un.h>]])
 849
 850 AC_CHECK_FUNCS(getpeerucred getpeereid)
 851
 852 AC_CHECK_FUNCS(pipe2 accept4)
 853
 854 #### Abstract sockets
 855
 856 if test x$enable_abstract_sockets = xauto; then
 857 AC_LANG_PUSH(C)
 858 warn_on_xcompile=no
 859 AC_CACHE_CHECK([abstract socket namespace],
 860                 ac_cv_have_abstract_sockets,
 861                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 862 [[
 863 #include <sys/types.h>
 864 #include <stdlib.h>
 865 #include <string.h>
 866 #include <stdio.h>
 867 #include <sys/socket.h>
 868 #include <sys/un.h>
 869 #include <errno.h>
 870 ]],
 871 [[
 872   size_t slen;
 873   int listen_fd;
 874   struct sockaddr_un addr;
 875
 876   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 877
 878   if (listen_fd < 0)
 879     {
 880       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 881       exit (1);
 882     }
 883
 884   memset (&addr, '\0', sizeof (addr));
 885   addr.sun_family = AF_UNIX;
 886   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 887   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 888    * beginning.
 889    */
 890   slen = SUN_LEN(&addr);
 891   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 892
 893   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 894     {
 895        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 896                 strerror (errno));
 897        exit (1);
 898     }
 899   else
 900     exit (0);
 901 ]])],
 902               [ac_cv_have_abstract_sockets=yes],
 903               [ac_cv_have_abstract_sockets=no],
 904               [
 905                 ac_cv_have_abstract_sockets=no
 906                 warn_on_xcompile=yes
 907               ]
 908 )])
 909 if test x$warn_on_xcompile = xyes ; then
 910   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 911 fi
 912 AC_LANG_POP(C)
 913 fi
 914
 915 if test x$enable_abstract_sockets = xyes; then
 916     if test x$ac_cv_have_abstract_sockets = xno; then
 917         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 918     fi
 919 fi
 920
 921 if test x$enable_abstract_sockets = xno; then
 922    ac_cv_have_abstract_sockets=no;
 923 fi
 924
 925 if test x$ac_cv_have_abstract_sockets = xyes ; then
 926    DBUS_PATH_OR_ABSTRACT=abstract
 927    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 928 else
 929    DBUS_PATH_OR_ABSTRACT=path
 930 fi
 931
 932 # this is used in addresses to prefer abstract, e.g.
 933 # unix:path=/foo or unix:abstract=/foo
 934 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 935
 936 PKG_CHECK_MODULES([EXPAT], [expat])
 937
 938 save_cflags="$CFLAGS"
 939 save_libs="$LIBS"
 940 CFLAGS="$CFLAGS $EXPAT_CFLAGS"
 941 LIBS="$LIBS $EXPAT_LIBS"
 942 AC_CHECK_FUNCS([XML_SetHashSalt])
 943 CFLAGS="$save_cflags"
 944 LIBS="$save_libs"
 945
 946 # Thread lib detection
 947 AC_ARG_VAR([THREAD_LIBS])
 948 save_libs="$LIBS"
 949 LIBS="$LIBS $THREAD_LIBS"
 950
 951 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 952
 953 # Don't do these automatic checks if the user set THREAD_LIBS on the
 954 # configure command-line. If they did, we assume they're right.
 955 #
 956 # We also don't do these checks on Windows, because you don't need magical
 957 # linker flags to have threading support there.
 958 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 959   [
 960     # Mandatory pthread functions. In principle, some of these could be made
 961     # optional if there are platforms that don't have them.
 962     #
 963     # Currently, we only look in -lpthread.
 964     # In principle we might need to look in -lpthreads, -lthreads, ...
 965     # as well - please file a bug if your platform needs this.
 966     AC_SEARCH_LIBS([pthread_cond_timedwait],
 967         [pthread],
 968         [THREAD_LIBS="$LIBS"],
 969         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 970         [])
 971     AC_SEARCH_LIBS([pthread_mutexattr_init],
 972         [pthread],
 973         [THREAD_LIBS="$LIBS"],
 974         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 975         [])
 976     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 977         [pthread],
 978         [THREAD_LIBS="$LIBS"],
 979         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 980         [])
 981
 982     # Optional, for monotonic clocks. Because it's optional, this check
 983     # is non-fatal if we don't find it.
 984     AC_SEARCH_LIBS([pthread_condattr_setclock],
 985         [pthread],
 986         [THREAD_LIBS="$LIBS"])
 987
 988     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 989       [
 990         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 991         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 992         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 993 [[#include <time.h>
 994 #include <pthread.h>
 995 ]], [[
 996 struct timespec monotonic_timer;
 997 pthread_condattr_t attr;
 998 pthread_condattr_init (&attr);
 999 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
1000 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
1001 ]])],
1002             [have_clock_monotonic=true],
1003             [have_clock_monotonic=false])
1004         AS_IF([test x$have_clock_monotonic = xtrue],
1005           [
1006             AC_MSG_RESULT([found])
1007             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
1008           ],
1009           [AC_MSG_RESULT([not found])])
1010       ]) dnl have pthread_condattr_setclock
1011   ]) dnl on Unix
1012
1013 LIBS="$save_libs"
1014
1015 AC_SUBST([THREAD_LIBS])
1016
1017 # SELinux detection
1018 if test x$enable_selinux = xno ; then
1019     have_selinux=no;
1020 else
1021     # See if we have SELinux library
1022     PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0.86],
1023                  [have_selinux=yes], [have_selinux=no])
1024
1025     if test x$enable_selinux = xauto ; then
1026         if test x$have_selinux = xno ; then
1027                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1028         fi
1029     else
1030         if test x$have_selinux = xno ; then
1031                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1032         fi
1033     fi
1034 fi
1035
1036 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1037
1038 if test x$have_selinux = xyes ; then
1039     # the selinux code creates threads
1040     # which requires libpthread even on linux
1041     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1042                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1043
1044     SELINUX_LIBS="$SELINUX_LIBS $SELINUX_THREAD_LIBS"
1045     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1046 else
1047     SELINUX_LIBS=
1048 fi
1049
1050 # AppArmor detection
1051 AS_IF([test x$enable_apparmor = xno],
1052   [have_apparmor=no],
1053   [
1054   PKG_CHECK_MODULES([APPARMOR], [libapparmor >= 2.8.95],
1055                     [have_apparmor=yes], [have_apparmor=no])
1056   PKG_CHECK_MODULES([APPARMOR_2_10], [libapparmor >= 2.10],
1057                     [have_apparmor_2_10=yes], [have_apparmor_2_10=no])
1058
1059   AS_IF([test x$enable_apparmor = xauto && test x$have_apparmor = xno],
1060         [AC_MSG_WARN([Sufficiently new AppArmor library not found])])
1061   AS_IF([test x$enable_apparmor != xauto && test x$have_apparmor = xno],
1062         [AC_MSG_ERROR([AppArmor explicitly required, and AppArmor library not found])])
1063   ])
1064
1065 AS_IF([test x$have_apparmor = xyes],
1066       [AC_DEFINE([HAVE_APPARMOR], [1], [AppArmor Support])])
1067 AS_IF([test x$have_apparmor_2_10 = xyes],
1068       [AC_DEFINE([HAVE_APPARMOR_2_10], [1],
1069                  [Define if libapparmor is version 2.10 or later])])
1070
1071 # inotify checks
1072 if test x$enable_inotify = xno ; then
1073     have_inotify=no;
1074 else
1075     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1076 fi
1077
1078 dnl check if inotify backend is enabled
1079 if test x$have_inotify = xyes; then
1080    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1081    AC_CHECK_FUNCS(inotify_init1)
1082 fi
1083
1084 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1085
1086 # For simplicity, we require the userland API for epoll_create1 at
1087 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1088 # not to have it at runtime.
1089 AC_ARG_ENABLE([epoll],
1090               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1091               [enable_epoll=$enableval], [enable_epoll=auto])
1092 if test x$enable_epoll = xno; then
1093     have_linux_epoll=no
1094 else
1095     AC_MSG_CHECKING([for Linux epoll(4)])
1096     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1097         [
1098         #ifndef __linux__
1099         #error This is not Linux
1100         #endif
1101         #include <sys/epoll.h>
1102         ],
1103         [epoll_create1 (EPOLL_CLOEXEC);])],
1104         [have_linux_epoll=yes],
1105         [have_linux_epoll=no])
1106     AC_MSG_RESULT([$have_linux_epoll])
1107 fi
1108 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1109     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1110 fi
1111 if test x$have_linux_epoll = xyes; then
1112   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1113 fi
1114 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1115
1116 # kqueue checks
1117 if test x$enable_kqueue = xno ; then
1118     have_kqueue=no
1119 else
1120     have_kqueue=yes
1121     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1122     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1123
1124     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1125         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1126     fi
1127 fi
1128
1129 dnl check if kqueue backend is enabled
1130 if test x$have_kqueue = xyes; then
1131    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1132 fi
1133
1134 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1135
1136 # launchd checks
1137 if test x$enable_launchd = xno ; then
1138     have_launchd=no
1139 else
1140     have_launchd=yes
1141     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1142     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1143     if test "x$LAUNCHCTL" = "x"; then
1144         have_launchd=no
1145     fi
1146
1147     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1148         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1149     fi
1150 fi
1151
1152 dnl check if launchd is enabled
1153 if test x$have_launchd = xyes; then
1154     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1155 fi
1156
1157 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1158
1159 #### Directory to place launchd agent file
1160 if test "x$with_launchd_agent_dir" = "x"; then
1161    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1162 else
1163    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1164 fi
1165
1166 AC_SUBST(LAUNCHD_AGENT_DIR)
1167
1168 dnl console owner file
1169 if test x$enable_console_owner_file = xno ; then
1170     have_console_owner_file=no;
1171 else
1172     case $host_os in
1173     solaris*)
1174         have_console_owner_file=yes;
1175         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1176         ;;
1177     *)
1178         have_console_owner_file=no;;
1179     esac
1180 fi
1181
1182 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1183
1184 dnl systemd detection
1185 if test x$enable_systemd = xno ; then
1186     have_systemd=no;
1187 else
1188     PKG_CHECK_MODULES([SYSTEMD],
1189         [libsystemd >= 209],
1190         [have_systemd=yes],
1191         [PKG_CHECK_MODULES([SYSTEMD],
1192             [libsystemd-login >= 32, libsystemd-daemon >= 32, libsystemd-journal >= 32],
1193             [have_systemd=yes],
1194             [have_systemd=no])])
1195 fi
1196
1197 if test x$have_systemd = xyes; then
1198     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1199 fi
1200
1201 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1202     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1203 fi
1204
1205 # If not found in $PATH, we might still have systemd and systemctl at runtime
1206 # (perhaps dbus is being compiled in a minimal chroot with no systemd).
1207 # Assume the upstream-recommended location. Distributors with split /usr
1208 # can override this with ./configure SYSTEMCTL=/bin/systemctl
1209 AC_PATH_PROG([SYSTEMCTL], [systemctl], [/usr/bin/systemctl])
1210
1211 # libaudit detection
1212 if test x$enable_libaudit = xno ; then
1213     have_libaudit=no;
1214 else
1215     # See if we have audit daemon & capabilities library
1216     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1217                  have_libaudit=yes, have_libaudit=no)
1218     if test x$have_libaudit = xyes ; then
1219         AC_CHECK_LIB(cap-ng, capng_clear,
1220                  have_libaudit=yes, have_libaudit=no)
1221     fi
1222 fi
1223
1224 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1225
1226 if test x$have_libaudit = xyes ; then
1227     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1228     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1229 fi
1230
1231 AC_SUBST([SELINUX_LIBS])
1232
1233 # Check for ADT API (Solaris Basic Security Mode auditing)
1234 AC_MSG_CHECKING(for ADT API)
1235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1236 #include <bsm/adt.h>
1237 adt_user_context = ADT_USER;
1238 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1239
1240 if test ${check_adt_audit} = yes
1241 then
1242    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1243    ADT_LIBS="-lbsm"
1244    LIBS="-lbsm $LIBS"
1245    AC_MSG_RESULT(yes)
1246 else
1247    AC_MSG_RESULT(no)
1248 fi
1249 AC_SUBST([ADT_LIBS])
1250
1251 # Check for SCM_RIGHTS
1252 AC_MSG_CHECKING([for SCM_RIGHTS])
1253 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1254 #include <sys/types.h>
1255 #include <sys/socket.h>
1256 #include <sys/un.h>
1257 static int x = SCM_RIGHTS;
1258 ]], [[]])],
1259 [ AC_MSG_RESULT([supported])
1260   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1261 [ AC_MSG_RESULT([not supported]) ])
1262
1263 NETWORK_libs=
1264 if test x$dbus_win = xyes ; then
1265   if test x$dbus_wince = xyes ; then
1266     NETWORK_libs="-lws2"
1267   else
1268     NETWORK_libs="-lws2_32 -liphlpapi -ldbghelp"
1269   fi
1270 fi
1271
1272 AC_SUBST([NETWORK_libs])
1273
1274 AC_ARG_WITH([valgrind],
1275   [AS_HELP_STRING([--with-valgrind],
1276      [Add instrumentation to help valgrind to understand our allocator])],
1277   [],
1278   [with_valgrind=no])
1279
1280 AS_IF([test "x$with_valgrind" = xauto],
1281   [PKG_CHECK_EXISTS([valgrind >= 3.6],
1282     [with_valgrind=yes], [with_valgrind=no])])
1283
1284 if test x$with_valgrind != xno; then
1285   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1286   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1287 fi
1288
1289 #### Set up final flags
1290 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs $SYSTEMD_LIBS"
1291 AC_SUBST([LIBDBUS_LIBS])
1292
1293 ### X11 detection
1294 DBUS_X_LIBS=
1295 DBUS_X_CFLAGS=
1296
1297 AC_ARG_ENABLE([x11-autolaunch],
1298   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1299   [], [enable_x11_autolaunch=auto])
1300
1301 if test "x$dbus_win" = xyes; then
1302     if test "x$enable_x11_autolaunch" = xyes; then
1303         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1304     fi
1305
1306     enable_x11_autolaunch=no
1307     have_x11=no
1308 else
1309     AC_PATH_XTRA
1310
1311     if test "x$no_x" = xyes; then
1312         have_x11=no
1313     else
1314         have_x11=yes
1315         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1316         DBUS_X_CFLAGS="$X_CFLAGS"
1317     fi
1318 fi
1319
1320 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1321     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1322 else
1323     # move from "auto" to "yes" or "no" if necessary
1324     if test "x$enable_x11_autolaunch" != xno; then
1325         enable_x11_autolaunch="$have_x11"
1326     fi
1327 fi
1328
1329 if test "x$have_x11" = xyes ; then
1330    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1331 fi
1332
1333 if test "x$enable_x11_autolaunch" = xyes ; then
1334    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1335 fi
1336 AM_CONDITIONAL([DBUS_ENABLE_X11_AUTOLAUNCH],
1337   [test "x$enable_x11_autolaunch" = xyes])
1338
1339 AC_SUBST([DBUS_X_CFLAGS])
1340 AC_SUBST([DBUS_X_LIBS])
1341
1342 # We're treating -fno-common like a warning: it makes the linker more
1343 # strict, because on some systems the linker is *always* this strict
1344 TEST_CFLAGS="$TEST_CFLAGS -fno-common"
1345
1346 AS_IF([test "x$enable_ansi" = "xyes"],[
1347     TEST_CFLAGS="$TEST_CFLAGS -ansi -pedantic"
1348     AC_DEFINE([_POSIX_C_SOURCE],[199309L],[Define to enable POSIX features])
1349     AC_DEFINE([_BSD_SOURCE],[1],[Define to enable BSD features])
1350   ])
1351
1352 dnl We are only calling this for its side-effect of setting up
1353 dnl --enable-compile-warnings; the WARN_CFLAGS, etc. are ignored,
1354 dnl to work around https://github.com/peti/autoconf-archive/pull/96
1355 AX_COMPILER_FLAGS([], [], [$disable_developer])
1356
1357 dnl Work around https://github.com/peti/autoconf-archive/pull/96 by using
1358 dnl a non-default variable name here (in particular there is no way to tell
1359 dnl AX_COMPILER_FLAGS to not use WARN_CXXFLAGS)
1360 AX_COMPILER_FLAGS_CFLAGS([EXTRA_CFLAGS],
1361                          [$disable_developer],
1362                          [$TEST_CFLAGS],
1363                          [-Wchar-subscripts \
1364                           -Wfloat-equal \
1365                           -Wpointer-sign \
1366                           $DISABLE_WARNINGS])
1367 dnl cc1plus: warning: command line option ‘-Wpointer-sign’ is valid for
1368 dnl C/ObjC but not for C++
1369 AX_COMPILER_FLAGS_CXXFLAGS([EXTRA_CXXFLAGS],
1370                            [$disable_developer],
1371                            [],
1372                            [-Wchar-subscripts \
1373                             -Wfloat-equal \
1374                             $DISABLE_WARNINGS])
1375 AX_COMPILER_FLAGS_LDFLAGS([EXTRA_LDFLAGS],
1376                           [$disable_developer])
1377
1378 dnl TODO: In principle we should put EXTRA_CFLAGS in each Makefile.am like
1379 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1380 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1381 dnl is the next best thing.
1382 CFLAGS="$EXTRA_CFLAGS $CFLAGS"
1383 CXXFLAGS="$EXTRA_CXXFLAGS $CXXFLAGS"
1384 LDFLAGS="$EXTRA_LDFLAGS $LDFLAGS"
1385
1386 case $host_os in
1387     solaris*)
1388         # Solaris' C library apparently needs these runes to be threadsafe...
1389         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1390         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1391         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1392         # ... and this opt-in to get file descriptor passing support
1393         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1394         ;;
1395 esac
1396
1397 ### Detect if ld supports --version-script
1398
1399 gl_LD_VERSION_SCRIPT
1400 AM_CONDITIONAL([HAVE_LD_VERSION_SCRIPT],
1401                [test "x$have_ld_version_script" = xyes])
1402 ### Doxygen Documentation
1403
1404 AC_PATH_PROG(DOXYGEN, doxygen, no)
1405
1406 AC_MSG_CHECKING([whether to build Doxygen documentation])
1407
1408 if test x$DOXYGEN = xno ; then
1409     have_doxygen=no
1410 else
1411     have_doxygen=yes
1412 fi
1413
1414 if test x$enable_doxygen_docs = xauto ; then
1415     if test x$have_doxygen = xno ; then
1416         enable_doxygen_docs=no
1417     else
1418         enable_doxygen_docs=yes
1419     fi
1420 fi
1421
1422 if test x$enable_doxygen_docs = xyes; then
1423     if test x$have_doxygen = xno; then
1424         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1425     fi
1426 fi
1427
1428 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1429 AC_MSG_RESULT($enable_doxygen_docs)
1430
1431 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1432 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1433
1434 ### Ducktype/Yelp documentation
1435
1436 AC_PATH_PROG([DUCKTYPE],[ducktype],[no])
1437 AC_PATH_PROG([YELP_BUILD],[yelp-build],[no])
1438
1439 AC_MSG_CHECKING([whether to build Ducktype documentation])
1440
1441 AS_IF([test "$DUCKTYPE" = "no"],[have_ducktype=no],[have_ducktype=yes])
1442 AS_IF([test "$YELP_BUILD" = "no"],[have_yelp_build=no],[have_yelp_build=yes])
1443
1444 AS_IF([test "$enable_ducktype_docs" = "auto"],[
1445     AS_IF([test "$have_ducktype" = "no" || test "$have_yelp_build" = "no"],[
1446         enable_ducktype_docs=no
1447     ],[
1448         enable_ducktype_docs=yes
1449     ])
1450 ])
1451
1452 AS_IF([test "$enable_ducktype_docs" = "yes"],[
1453     AS_IF([test "$have_ducktype" = "no"],[
1454         AC_MSG_ERROR([Building Ducktype docs explicitly required, but ducktype not found])
1455     ])
1456     AS_IF([test "$have_yelp_build" = "no"],[
1457         AC_MSG_ERROR([Building Ducktype docs explicitly required, but yelp-build not found])
1458     ])
1459 ])
1460
1461 AM_CONDITIONAL([DBUS_DUCKTYPE_DOCS_ENABLED],[test "$enable_ducktype_docs" = "yes"])
1462 AC_MSG_RESULT([$enable_ducktype_docs])
1463
1464 ### XML Documentation
1465
1466 AC_PATH_PROG(XMLTO, xmlto, no)
1467
1468 AC_MSG_CHECKING([whether to build XML documentation])
1469
1470 if test x$XMLTO = xno ; then
1471     have_xmlto=no
1472 else
1473     have_xmlto=yes
1474 fi
1475
1476 if test x$enable_xml_docs = xauto ; then
1477     if test x$have_xmlto = xno ; then
1478         enable_xml_docs=no
1479     else
1480         enable_xml_docs=yes
1481     fi
1482 fi
1483
1484 if test x$enable_xml_docs = xyes; then
1485     if test x$have_xmlto = xno; then
1486         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1487     fi
1488 fi
1489
1490 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1491 AC_MSG_RESULT($enable_xml_docs)
1492
1493 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1494     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes &&
1495      test x$enable_ducktype_docs = xyes])
1496
1497 # Autoconf 2.70 will support this, and many distros patch this option in,
1498 # but Autoconf 2.70 hasn't actually been released yet.
1499 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
1500 AC_SUBST([runstatedir])
1501
1502 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1503
1504 #### find the actual value for $prefix that we'll end up with
1505 ##   (I know this is broken and should be done in the Makefile, but
1506 ##    that's a major pain and almost nobody actually seems to care)
1507 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1508 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1509 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1510 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1511 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1512 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1513 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1514 AS_AC_EXPAND(EXPANDED_RUNSTATEDIR, "$runstatedir")
1515
1516 #### Check our operating system
1517 operating_system=unknown
1518 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1519    operating_system=redhat
1520 fi
1521
1522 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1523    operating_system=slackware
1524 fi
1525
1526 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1527    operating_system=cygwin
1528 fi
1529
1530 #### Sort out init scripts
1531
1532 if test x$with_init_scripts = x; then
1533     case x$operating_system in
1534         xredhat)        with_init_scripts=redhat ;;
1535         xslackware)     with_init_scripts=slackware ;;
1536         xcygwin)        with_init_scripts=cygwin ;;
1537         *)                      with_init_scripts=none ;;
1538     esac
1539 fi
1540
1541 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1542 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1543 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1544
1545 ##### systemd unit files
1546 AC_ARG_WITH([systemdsystemunitdir],
1547 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1548     [],
1549     [
1550     PKG_CHECK_EXISTS([systemd],
1551       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1552       [with_systemdsystemunitdir=no])
1553     ])
1554 if test "x$with_systemdsystemunitdir" != xno; then
1555    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1556 fi
1557 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" != "xno" -a -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1558
1559 AC_ARG_WITH([systemduserunitdir],
1560 AS_HELP_STRING([--with-systemduserunitdir=DIR], [Directory for systemd user service files]),
1561     [],
1562     [
1563     PKG_CHECK_EXISTS([systemd],
1564       [with_systemduserunitdir=$($PKG_CONFIG --variable=systemduserunitdir systemd)],
1565       [with_systemduserunitdir='${libdir}/systemd/user'])
1566     ])
1567 AC_SUBST([systemduserunitdir], [$with_systemduserunitdir])
1568
1569 ##### Set up location for system bus socket
1570 if ! test -z "$with_system_socket"; then
1571    DBUS_SYSTEM_SOCKET=$with_system_socket
1572 else
1573    # We don't use runstatedir for this (yet?), because /var/run has been the
1574    # interoperable system bus socket for 10+ years.
1575    # See https://bugs.freedesktop.org/show_bug.cgi?id=101628
1576    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1577 fi
1578
1579 AC_SUBST(DBUS_SYSTEM_SOCKET)
1580 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1581
1582 ## System bus only listens on local domain sockets, and never
1583 ## on an abstract socket (so only root can create the socket).
1584 ##
1585 ## This won't work on Windows. It's not meant to - the system bus is
1586 ## meaningless on Windows anyway.
1587 ##
1588 ## This has to be suitable for hard-coding in client libraries as well as
1589 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1590 ## and also to connect to. If this ever changes, it'll need to be split into
1591 ## two variables, one for the listening address and one for the connecting
1592 ## address.
1593 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1594 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1595 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1596
1597 #### Set up the pid file
1598 if ! test -z "$with_system_pid_file"; then
1599    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1600 elif test x$with_init_scripts = xredhat ; then
1601    DBUS_SYSTEM_PID_FILE="${EXPANDED_RUNSTATEDIR}/messagebus.pid"
1602 else
1603    DBUS_SYSTEM_PID_FILE="${EXPANDED_RUNSTATEDIR}/dbus/pid"
1604 fi
1605
1606 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1607
1608 #### Directory to check for console ownership
1609 if ! test -z "$with_console_auth_dir"; then
1610    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1611 else
1612    # We don't use runstatedir for this, because /var/run is the
1613    # path that was traditionally used by pam_console and pam_foreground.
1614    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1615 fi
1616
1617 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1618 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1619
1620 #### File to check for console ownership
1621 if test x$have_console_owner_file = xyes; then
1622    if ! test -z "$with_console_owner_file"; then
1623       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1624    else
1625       DBUS_CONSOLE_OWNER_FILE=/dev/console
1626    fi
1627 else
1628   DBUS_CONSOLE_OWNER_FILE=
1629 fi
1630
1631 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1632 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1633
1634 #### User to start the system bus as
1635 if test -z "$with_dbus_user" ; then
1636     DBUS_USER=messagebus
1637 else
1638     DBUS_USER=$with_dbus_user
1639 fi
1640 AC_SUBST(DBUS_USER)
1641 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1642
1643 #### User for regression tests
1644 AS_IF([test -z "$with_test_user"], [with_test_user=nobody])
1645 DBUS_TEST_USER="$with_test_user"
1646 AC_SUBST([DBUS_TEST_USER])
1647 AC_DEFINE_UNQUOTED([DBUS_TEST_USER], ["$DBUS_TEST_USER"],
1648   [Unprivileged user used in some regression tests])
1649
1650 #### Prefix to install into
1651 DBUS_PREFIX=$EXPANDED_PREFIX
1652 AC_SUBST(DBUS_PREFIX)
1653 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1654
1655 #### Direcotry to install data files into
1656 DBUS_DATADIR=$EXPANDED_DATADIR
1657 AC_SUBST(DBUS_DATADIR)
1658 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1659
1660 #### Directory to install dbus-daemon
1661 if test -z "$with_dbus_daemondir" ; then
1662     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1663     dbus_daemondir='$bindir'
1664 else
1665     DBUS_DAEMONDIR=$with_dbus_daemondir
1666     dbus_daemondir=$with_dbus_daemondir
1667 fi
1668 AC_SUBST(DBUS_DAEMONDIR)
1669 AC_SUBST(dbus_daemondir)
1670 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1671
1672 #### Directory to install the other binaries
1673 DBUS_BINDIR="$EXPANDED_BINDIR"
1674 AC_SUBST(DBUS_BINDIR)
1675 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1676
1677 #### Directory to install the libexec binaries
1678 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1679 AC_SUBST(DBUS_LIBEXECDIR)
1680 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1681
1682 AC_ARG_ENABLE([relocation],
1683   [AS_HELP_STRING([--enable-relocation[=yes/no/auto]],
1684     [Make pkg-config metadata relocatable [default=auto]])],
1685   [], [enable_relocation=auto])
1686
1687 can_relocate=yes
1688
1689 AS_CASE(["${exec_prefix}"],
1690   ['NONE'|'${prefix}'],
1691     [:],
1692   [*],
1693     [can_relocate=no])
1694
1695 AS_CASE(["${libdir}"],
1696   ['${prefix}/lib'|'${prefix}/lib64'|'${exec_prefix}/lib'|'${exec_prefix}/lib64'],
1697     [:],
1698   [*],
1699     [can_relocate=no])
1700
1701 # If the user said --enable-relocation but we can't do it, error out
1702 AS_IF([test "x$can_relocate" = xno && test "x$enable_relocation" = xyes],
1703   [AC_MSG_ERROR([Relocatable pkg-config metadata requires --exec-prefix='\${prefix}' and the default libdir])])
1704
1705 # By default, on Windows we are relocatable if possible
1706 AS_IF([test "x$enable_relocation" = xauto && test "x$dbus_win" = xyes],
1707   [enable_relocation="$can_relocate"])
1708
1709 # By default, on non-Windows we are not relocatable because it can interfere
1710 # with pkg-config's ability to filter out system include directories,
1711 # resulting in linking an outdated system-wide library in preference to a
1712 # newer version installed elsewhere
1713 AS_IF([test "x$enable_relocation" = xauto],
1714   [enable_relocation="no"])
1715
1716
1717 AS_IF([test "x$enable_relocation" = xyes],
1718   [AC_SUBST([pkgconfig_prefix], ['${pcfiledir}/../../'])],
1719   [AC_SUBST([pkgconfig_prefix], ['${original_prefix}'])])
1720
1721 #### Directory to source sysconfdir configuration from
1722
1723 # On Windows this is relative to where we put the bus setup, in
1724 # ${datadir}/dbus-1. For simplicity, we only do this if
1725 # ${sysconfdir} = ${prefix}/etc and ${datadir} = ${prefix}/share.
1726 #
1727 # On Unix, or on Windows with weird install layouts, it's the absolute path.
1728 AS_IF([test "${dbus_win}" = yes && \
1729        test "$EXPANDED_SYSCONFDIR" = "$EXPANDED_PREFIX/etc" && \
1730        test "$EXPANDED_DATADIR" = "$EXPANDED_PREFIX/share"],
1731       [SYSCONFDIR_FROM_PKGDATADIR="../../etc"
1732        DATADIR_FROM_PKGSYSCONFDIR="../../share"],
1733       [SYSCONFDIR_FROM_PKGDATADIR="$EXPANDED_SYSCONFDIR"
1734        DATADIR_FROM_PKGSYSCONFDIR="$EXPANDED_DATADIR"])
1735 AC_SUBST([SYSCONFDIR_FROM_PKGDATADIR])
1736 AC_SUBST([DATADIR_FROM_PKGSYSCONFDIR])
1737
1738 #### Tell tests where to find certain stuff in builddir
1739
1740 DBUS_PWD=`pwd`
1741 # Useful in a cross-compilation environment, where the tests are run on the host system.
1742 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1743                            DBUS_PWD=$withval)
1744
1745 DBUS_TEST_EXEC="$DBUS_PWD/test"
1746 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1747
1748 AC_SUBST([DBUS_TEST_DATA])
1749 AC_SUBST([DBUS_TEST_EXEC])
1750
1751 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1752                    [Extension for executables, typically empty or .exe])
1753
1754 ## Export the non-setuid external helper
1755 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1756 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1757 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1758                    [Full path to the launch helper test program in the builddir])
1759
1760 #### Find socket directories
1761 if ! test -z "$TMPDIR" ; then
1762    DEFAULT_SOCKET_DIR=$TMPDIR
1763 elif ! test -z "$TEMP" ; then
1764    DEFAULT_SOCKET_DIR=$TEMP
1765 elif ! test -z "$TMP" ; then
1766    DEFAULT_SOCKET_DIR=$TMP
1767 else
1768    DEFAULT_SOCKET_DIR=/tmp
1769 fi
1770
1771 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1772
1773 if ! test -z "$with_test_socket_dir" ; then
1774    TEST_SOCKET_DIR="$with_test_socket_dir"
1775 else
1776    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1777 fi
1778 AC_SUBST(TEST_SOCKET_DIR)
1779 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1780
1781 if test "x$dbus_unix" = xyes; then
1782   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1783 else
1784   TEST_LISTEN="tcp:host=localhost"
1785 fi
1786 AC_SUBST([TEST_LISTEN])
1787 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1788   [Listening address for regression tests])
1789
1790 if ! test -z "$with_session_socket_dir" ; then
1791    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1792 else
1793    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1794 fi
1795 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1796 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1797
1798 # This must be a listening address. It doesn't necessarily need to be an
1799 # address you can connect to - it can be something vague like
1800 # "nonce-tcp:".
1801 #
1802 # The default varies by platform.
1803 AC_ARG_WITH([dbus_session_bus_listen_address],
1804             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1805                            [default address for a session bus to listen on (see configure.ac)]),
1806             [with_dbus_session_bus_listen_address=$withval],
1807             [with_dbus_session_bus_listen_address=])
1808
1809 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1810         # the user specified something, trust them
1811         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1812 elif test x$dbus_win = xyes; then
1813         # On Windows, you can (and should) listen on autolaunch addresses,
1814         # because autolaunching is different.
1815         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1816         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1817 elif test x$have_launchd = xyes; then
1818         # Mac OS X default is to use launchd
1819         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1820 else
1821         # The default on all other Unix platforms (notably Linux)
1822         # is to create a randomly named socket in /tmp or similar
1823         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1824 fi
1825 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1826
1827 # This must be an address you can connect to. It doesn't necessarily
1828 # need to be an address you can listen on - it can be "autolaunch:",
1829 # even on Unix.
1830 #
1831 # The default varies by platform.
1832 AC_ARG_WITH([dbus_session_bus_connect_address],
1833             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1834                            [fallback address for a session bus client to connect to (see configure.ac)]),
1835             [with_dbus_session_bus_connect_address=$withval],
1836             [with_dbus_session_bus_connect_address=])
1837
1838 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1839         # the user specified something, trust them
1840         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1841 elif test x$dbus_win = xyes; then
1842         # Windows autolaunching is a bit different; leaving it in its own
1843         # branch of the conditional because the default might conceivably
1844         # change (see #38201)
1845         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1846 else
1847         # The default on all other Unix platforms (notably Linux)
1848         # is to use auto-launching - this works a bit differently on Mac OS X
1849         # but comes out basically the same in the end
1850         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1851 fi
1852 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1853 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1854   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1855   [Fallback address for session bus clients])
1856
1857 # darwin needs this to initialize the environment
1858 AC_CHECK_HEADERS(crt_externs.h)
1859 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1860 AH_VERBATIM(_DARWIN_ENVIRON,
1861 [
1862 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1863 # include <sys/time.h>
1864 # include <crt_externs.h>
1865 # define environ (*_NSGetEnviron())
1866 #endif
1867 ])
1868
1869 AC_ARG_ENABLE([stats],
1870   [AS_HELP_STRING([--disable-stats],
1871     [disable bus daemon usage statistics])],
1872   [], [enable_stats=yes])
1873 if test "x$enable_stats" = xyes; then
1874   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1875     [Define to enable bus daemon usage statistics])
1876 fi
1877
1878 AC_ARG_ENABLE([user-session],
1879   [AS_HELP_STRING([--enable-user-session],
1880     [enable user-session semantics for session bus under systemd])],
1881   [], [enable_user_session=no])
1882 AM_CONDITIONAL([DBUS_ENABLE_USER_SESSION],
1883   [test "x$enable_user_session" = xyes])
1884
1885 AC_CONFIG_FILES([
1886 Doxyfile
1887 dbus/Version
1888 dbus/versioninfo.rc
1889 dbus/dbus-arch-deps.h
1890 bus/system.conf
1891 bus/session.conf
1892 bus/legacy-config/system.conf
1893 bus/legacy-config/session.conf
1894 bus/example-system-enable-stats.conf
1895 bus/example-session-disable-stats.conf
1896 bus/messagebus
1897 bus/messagebus-config
1898 bus/org.freedesktop.dbus-session.plist
1899 bus/rc.messagebus
1900 bus/dbus.service
1901 bus/dbus.socket
1902 bus/systemd-user/dbus.service
1903 bus/systemd-user/dbus.socket
1904 bus/sysusers.d/dbus.conf
1905 bus/tmpfiles.d/dbus.conf
1906 Makefile
1907 dbus/Makefile
1908 bus/Makefile
1909 tools/Makefile
1910 test/Makefile
1911 test/name-test/Makefile
1912 doc/Makefile
1913 doc/dbus-cleanup-sockets.1.xml
1914 doc/dbus-daemon.1.xml
1915 doc/dbus-launch.1.xml
1916 doc/dbus-monitor.1.xml
1917 doc/dbus-run-session.1.xml
1918 doc/dbus-send.1.xml
1919 doc/dbus-test-tool.1.xml
1920 doc/dbus-update-activation-environment.1.xml
1921 doc/dbus-uuidgen.1.xml
1922 dbus-1.pc
1923 dbus-1-uninstalled.pc
1924 cmake/DBus1Config.cmake:cmake/DBus1Config.pkgconfig.in
1925 cmake/DBus1ConfigVersion.cmake
1926 ])
1927 AC_OUTPUT
1928
1929 dnl ==========================================================================
1930 echo "
1931                     D-Bus $VERSION
1932                   ==============
1933
1934         prefix:                   ${EXPANDED_PREFIX}
1935         exec_prefix:              ${exec_prefix}
1936         libdir:                   ${EXPANDED_LIBDIR}
1937         libexecdir:               ${EXPANDED_LIBEXECDIR}
1938         bindir:                   ${EXPANDED_BINDIR}
1939         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1940         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1941         runstatedir:              ${EXPANDED_RUNSTATEDIR}
1942         datadir:                  ${EXPANDED_DATADIR}
1943         source code location:     ${srcdir}
1944         compiler:                 ${CC}
1945         cflags:                   ${CFLAGS}
1946         cppflags:                 ${CPPFLAGS}
1947         cxxflags:                 ${CXXFLAGS}
1948         ldflags:                  ${LDFLAGS}
1949         64-bit int:               ${DBUS_INT64_TYPE}
1950         32-bit int:               ${DBUS_INT32_TYPE}
1951         16-bit int:               ${DBUS_INT16_TYPE}
1952         Doxygen:                  ${DOXYGEN:-not found}
1953         xmlto:                    ${XMLTO:-not found}
1954         ducktype:                 ${DUCKTYPE:-not found}
1955         yelp-build:               ${YELP_BUILD:-not found}"
1956
1957 echo "
1958         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1959         gcc coverage profiling:   ${enable_code_coverage}
1960         Building embedded tests:  ${enable_embedded_tests}
1961         Building modular tests:   ${enable_modular_tests}
1962             - with GLib:          ${with_glib}
1963         Installing tests:         ${enable_installed_tests}
1964         Building verbose mode:    ${enable_verbose_mode}
1965         Building assertions:      ${enable_asserts}
1966         Building checks:          ${enable_checks}
1967         Building bus stats API:   ${enable_stats}
1968         Building SELinux support: ${have_selinux}
1969         Building AppArmor support: ${have_apparmor}
1970         Building inotify support: ${have_inotify}
1971         Building kqueue support:  ${have_kqueue}
1972         Building systemd support: ${have_systemd}
1973         Building X11 code:        ${have_x11}
1974         Building Doxygen docs:    ${enable_doxygen_docs}
1975         Building Ducktype docs:   ${enable_ducktype_docs}
1976         Building XML docs:        ${enable_xml_docs}
1977         Building launchd support: ${have_launchd}
1978         Init scripts style:       ${with_init_scripts}
1979         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1980         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1981         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1982         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1983         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1984         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1985         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1986         Console owner file:       ${have_console_owner_file}
1987         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1988         System bus user:          ${DBUS_USER}
1989         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1990         'make check' socket dir:  ${TEST_SOCKET_DIR}
1991 "
1992 if test x$have_launchd = xyes; then
1993         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1994 fi
1995 echo
1996
1997 if test x$enable_embedded_tests = xyes; then
1998         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1999 fi
2000 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
2001         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
2002 fi
2003 AS_IF([test x$enable_code_coverage = xyes],[
2004     AC_MSG_WARN([Building with coverage profiling is definitely for developers only.])
2005   ])
2006 if test x$enable_verbose_mode = xyes; then
2007         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
2008 fi
2009 if test x$enable_asserts = xyes; then
2010         echo "NOTE: building with assertions increases library size and decreases performance."
2011 fi
2012 if test x$enable_checks = xno; then
2013         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
2014 fi