configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.62])
  25 AC_INIT([libxkbcommon], [0.3.2],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=libxkbcommon],
  27         [libxkbcommon], [http://xkbcommon.org])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_HEADERS([src/config.h])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-dist-gzip subdir-objects color-tests parallel-tests check-news])
  35 AM_MAINTAINER_MODE([enable])
  36
  37 # Get _GNU_SOURCE and friends
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 # Initialize libtool
  41 LT_INIT
  42
  43 # Add xorg-macros stuff
  44 m4_ifndef([XORG_MACROS_VERSION],
  45           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  46 XORG_MACROS_VERSION(1.16)
  47 XORG_DEFAULT_OPTIONS
  48 XORG_MEMORY_CHECK_FLAGS
  49 XORG_ENABLE_DOCS
  50 XORG_WITH_DOXYGEN
  51
  52 # Needed in older Automakes for subdir-objects
  53 AM_PROG_CC_C_O
  54
  55 # Check for compiler features
  56 AC_C_INLINE
  57
  58 # Check for programs
  59 AC_PROG_MKDIR_P
  60 PKG_PROG_PKG_CONFIG
  61
  62 # Note: we use some yacc extensions, which work with either GNU bison
  63 # (preferred) or byacc. Other yacc's may or may not work.
  64 AC_PROG_YACC
  65 AC_PATH_PROG([YACC_INST], $YACC)
  66 if test ! -f "src/xkbcomp/parser.c"; then
  67    if test -z "$YACC_INST"; then
  68       AC_MSG_ERROR([yacc not found - unable to compile src/xkbcomp/parser.y])
  69    fi
  70 fi
  71
  72 # Checks for library functions.
  73 AC_CHECK_FUNCS([strcasecmp strncasecmp])
  74 if test "x$ac_cv_func_strcasecmp" = xno || \
  75    test "x$ac_cv_func_strncasecmp" = xno; then
  76     AC_MSG_ERROR([C library does not support strcasecmp/strncasecmp])
  77 fi
  78
  79 AC_CHECK_FUNCS([eaccess euidaccess mmap])
  80
  81 # Some tests use Linux-specific headers
  82 AC_CHECK_HEADER([linux/input.h])
  83 AM_CONDITIONAL(BUILD_LINUX_TESTS, [test "x$ac_cv_header_linux_input_h" = xyes])
  84
  85 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-fvisibility=hidden])
  86
  87 XORG_CHECK_LINKER_FLAGS([-Wl,--no-undefined], [have_no_undefined=yes])
  88 AM_CONDITIONAL([HAVE_NO_UNDEFINED], [test "x$have_no_undefined" = xyes])
  89
  90 # Define a configuration option for the XKB config root
  91 xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config`
  92 if test "x$xkb_base" = x; then
  93     xkb_base=$datadir/X11/xkb
  94 fi
  95 AC_ARG_WITH([xkb_config_root],
  96     [AS_HELP_STRING([--with-xkb-config-root=<path>],
  97         [Set default XKB config root (default: xkeyboard-config install path)])],
  98     [XKBCONFIGROOT="$withval"],
  99     [XKBCONFIGROOT="$xkb_base"])
 100 AC_SUBST([XKBCONFIGROOT])
 101
 102 AC_ARG_WITH([default_rules],
 103     [AS_HELP_STRING([--with-default-rules=<path>],
 104         [Default XKB ruleset (default: evdev)])],
 105     [DEFAULT_XKB_RULES="$withval"],
 106     [DEFAULT_XKB_RULES="evdev"])
 107 AC_DEFINE_UNQUOTED([DEFAULT_XKB_RULES], ["$DEFAULT_XKB_RULES"],
 108                    [Default XKB ruleset])
 109
 110 AC_ARG_WITH([default_model],
 111     [AS_HELP_STRING([--with-default-model=<path>],
 112         [Default XKB model (default: pc105)])],
 113     [DEFAULT_XKB_MODEL="$withval"],
 114     [DEFAULT_XKB_MODEL="pc105"])
 115 AC_DEFINE_UNQUOTED([DEFAULT_XKB_MODEL], ["$DEFAULT_XKB_MODEL"],
 116                    [Default XKB model])
 117
 118 AC_ARG_WITH([default_layout],
 119     [AS_HELP_STRING([--with-default-layout=<path>],
 120         [Default XKB layout (default: us)])],
 121     [DEFAULT_XKB_LAYOUT="$withval"],
 122     [DEFAULT_XKB_LAYOUT="us"])
 123 AC_DEFINE_UNQUOTED([DEFAULT_XKB_LAYOUT], ["$DEFAULT_XKB_LAYOUT"],
 124                    [Default XKB layout])
 125
 126 AC_ARG_WITH([default_variant],
 127     [AS_HELP_STRING([--with-default-variant=<path>],
 128         [Default XKB variant (default: (none))])],
 129     [DEFAULT_XKB_VARIANT="$withval"],
 130     [DEFAULT_XKB_VARAINT=])
 131 if ! test "x$DEFAULT_XKB_VARIANT" = x; then
 132     AC_DEFINE_UNQUOTED([DEFAULT_XKB_VARIANT], ["$DEFAULT_XKB_VARIANT"],
 133                        [Default XKB variant])
 134 fi
 135
 136 AC_ARG_WITH([default_options],
 137     [AS_HELP_STRING([--with-default-options=<path>],
 138         [Default XKB options (default: (none))])],
 139     [DEFAULT_XKB_OPTIONS="$withval"],
 140     [DEFAULT_XKB_OPTIONS=])
 141 if ! test "x$DEFAULT_XKB_OPTIONS" = x; then
 142     AC_DEFINE_UNQUOTED([DEFAULT_XKB_OPTIONS], ["$DEFAULT_XKB_OPTIONS"],
 143                        [Default XKB options])
 144 fi
 145
 146 AC_ARG_ENABLE([x11],
 147     [AS_HELP_STRING([--disable-x11],
 148         [Disable support for creating keymaps with the X11 protocol (default: enabled)])],
 149     [], [enable_x11=yes])
 150 if test "x$enable_x11" == xyes; then
 151     PKG_CHECK_MODULES([XCB_XKB], [xcb xcb-xkb >= 1.10], [],
 152         [AC_MSG_ERROR([xkbcommon-x11 requires xcb-xkb >= 1.10 which was not found. \
 153 You can disable X11 support with --disable-x11.])])
 154 fi
 155 AM_CONDITIONAL([ENABLE_X11], [test "x$enable_x11" == xyes])
 156
 157 AC_CONFIG_FILES([
 158     Makefile
 159     xkbcommon-uninstalled.pc
 160     xkbcommon.pc
 161     xkbcommon-x11.pc
 162     xkbcommon-x11-uninstalled.pc
 163     doc/Doxyfile
 164 ])
 165 AC_OUTPUT