configure.ac

   1 dnl  Copyright 2005 Red Hat, Inc.
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Red Hat not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Red Hat makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  RED HAT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL RED HAT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 AC_PREREQ([2.57])
  24
  25 #   Pixman versioning scheme
  26 #
  27 #   - The version in git has an odd MICRO version number
  28 #
  29 #   - Released versions both development and stable have an even MICRO
  30 #     version number
  31 #
  32 #   - Released development versions have an odd MINOR number
  33 #
  34 #   - Released stable versions have an even MINOR number
  35 #
  36 #   - Versions that break ABI must have a new MAJOR number
  37 #
  38 #   - If you break the ABI, then at least this must be done:
  39 #
  40 #        - increment MAJOR
  41 #
  42 #        - In the first development release where you break ABI, find
  43 #          all instances of "pixman-n" and change them to pixman-(n+1)
  44 #
  45 #          This needs to be done at least in
  46 #                    configure.ac
  47 #                    all Makefile.am's
  48 #                    pixman-n.pc.in
  49 #
  50 #      This ensures that binary incompatible versions can be installed
  51 #      in parallel.  See http://www106.pair.com/rhp/parallel.html for
  52 #      more information
  53 #
  54
  55 m4_define([pixman_major], 0)
  56 m4_define([pixman_minor], 19)
  57 m4_define([pixman_micro], 1)
  58
  59 m4_define([pixman_version],[pixman_major.pixman_minor.pixman_micro])
  60
  61 AC_INIT(pixman, pixman_version, "pixman@lists.freedesktop.org", pixman)
  62 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  63
  64 # Suppress verbose compile lines
  65 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  66
  67 AM_CONFIG_HEADER(config.h)
  68
  69 AC_CANONICAL_HOST
  70
  71 test_CFLAGS=${CFLAGS+set} # We may override autoconf default CFLAGS.
  72
  73 AC_PROG_CC
  74 AM_PROG_AS
  75 AC_PROG_LIBTOOL
  76 AC_CHECK_FUNCS([getisax])
  77 AC_C_BIGENDIAN
  78 AC_C_INLINE
  79
  80 # Check for OpenMP support (only supported by autoconf >=2.62)
  81 OPENMP_CFLAGS=
  82 m4_ifdef([AC_OPENMP], [AC_OPENMP], [AC_SUBST(OPENMP_CFLAGS)])
  83
  84 AC_CHECK_SIZEOF(long)
  85
  86 # Checks for Sun Studio compilers
  87 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  88 AC_CHECK_DECL([__amd64], [AMD64_ABI="yes"], [AMD64_ABI="no"])
  89
  90 # Default CFLAGS to -O -g rather than just the -g from AC_PROG_CC
  91 # if we're using Sun Studio and neither the user nor a config.site
  92 # has set CFLAGS.
  93 if test $SUNCC = yes &&                 \
  94    test "$test_CFLAGS" == "" &&         \
  95    test "$CFLAGS" = "-g"
  96 then
  97   CFLAGS="-O -g"
  98 fi
  99
 100 #
 101 # We ignore pixman_major in the version here because the major version should
 102 # always be encoded in the actual library name. Ie., the soname is:
 103 #
 104 #      pixman-$(pixman_major).0.minor.micro
 105 #
 106 m4_define([lt_current], [pixman_minor])
 107 m4_define([lt_revision], [pixman_micro])
 108 m4_define([lt_age], [pixman_minor])
 109
 110 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 111
 112 PIXMAN_VERSION_MAJOR=pixman_major()
 113 AC_SUBST(PIXMAN_VERSION_MAJOR)
 114 PIXMAN_VERSION_MINOR=pixman_minor()
 115 AC_SUBST(PIXMAN_VERSION_MINOR)
 116 PIXMAN_VERSION_MICRO=pixman_micro()
 117 AC_SUBST(PIXMAN_VERSION_MICRO)
 118
 119 AC_SUBST(LT_VERSION_INFO)
 120
 121 # Check for dependencies
 122 #PKG_CHECK_MODULES(DEP, x11)
 123
 124 changequote(,)dnl
 125 if test "x$GCC" = "xyes"; then
 126
 127   case " $CFLAGS " in
 128   *[\ \ ]-Wall[\ \      ]*) ;;
 129   *) CFLAGS="$CFLAGS -Wall" ;;
 130   esac
 131
 132   case " $CFLAGS " in
 133   *[\ \ ]-fno-strict-aliasing[\ \       ]*) ;;
 134   *) CFLAGS="$CFLAGS -fno-strict-aliasing" ;;
 135   esac
 136
 137 fi changequote([,])dnl
 138
 139 AC_PATH_PROG(PERL, perl, no)
 140 if test "x$PERL" = xno; then
 141     AC_MSG_ERROR([Perl is required to build pixman.])
 142 fi
 143 AC_SUBST(PERL)
 144
 145 dnl =========================================================================
 146 dnl -fvisibility stuff
 147
 148 have_gcc4=no
 149 AC_MSG_CHECKING(for -fvisibility)
 150 AC_COMPILE_IFELSE([
 151 #if defined(__GNUC__) && (__GNUC__ >= 4)
 152 #else
 153 error Need GCC 4.0 for visibility
 154 #endif
 155 int main () { return 0; }
 156 ], have_gcc4=yes)
 157
 158 if test "x$have_gcc4" = "xyes"; then
 159    CFLAGS="$CFLAGS -fvisibility=hidden"
 160 fi
 161 AC_MSG_RESULT($have_gcc4)
 162
 163 have_sunstudio8=no
 164 AC_MSG_CHECKING([for -xldscope (Sun compilers)])
 165 AC_COMPILE_IFELSE([
 166 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
 167 #else
 168 error Need Sun Studio 8 for visibility
 169 #endif
 170 int main () { return 0; }
 171 ], have_sunstudio8=yes)
 172
 173 if test "x$have_sunstudio8" = "xyes"; then
 174    CFLAGS="$CFLAGS -xldscope=hidden"
 175 fi
 176 AC_MSG_RESULT($have_sunstudio8)
 177
 178 dnl ===========================================================================
 179 dnl Check for MMX
 180
 181 if test "x$MMX_CFLAGS" = "x" ; then
 182    if test "x$SUNCC" = "xyes"; then
 183       # Sun Studio doesn't have an -xarch=mmx flag, so we have to use sse
 184       # but if we're building 64-bit, mmx & sse support is on by default and
 185       # -xarch=sse throws an error instead
 186       if test "$AMD64_ABI" = "no" ; then
 187          MMX_CFLAGS="-xarch=sse"
 188       fi
 189    else
 190       MMX_CFLAGS="-mmmx -Winline"
 191    fi
 192 fi
 193
 194 have_mmx_intrinsics=no
 195 AC_MSG_CHECKING(whether to use MMX intrinsics)
 196 xserver_save_CFLAGS=$CFLAGS
 197 CFLAGS="$MMX_CFLAGS $CFLAGS"
 198 AC_COMPILE_IFELSE([
 199 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 200 error "Need GCC >= 3.4 for MMX intrinsics"
 201 #endif
 202 #include <mmintrin.h>
 203 int main () {
 204     __m64 v = _mm_cvtsi32_si64 (1);
 205     return _mm_cvtsi64_si32 (v);
 206 }], have_mmx_intrinsics=yes)
 207 CFLAGS=$xserver_save_CFLAGS
 208
 209 AC_ARG_ENABLE(mmx,
 210    [AC_HELP_STRING([--disable-mmx],
 211                    [disable MMX fast paths])],
 212    [enable_mmx=$enableval], [enable_mmx=auto])
 213
 214 if test $enable_mmx = no ; then
 215    have_mmx_intrinsics=disabled
 216 fi
 217
 218 if test $have_mmx_intrinsics = yes ; then
 219    AC_DEFINE(USE_MMX, 1, [use MMX compiler intrinsics])
 220 else
 221    MMX_CFLAGS=
 222 fi
 223
 224 AC_MSG_RESULT($have_mmx_intrinsics)
 225 if test $enable_mmx = yes && test $have_mmx_intrinsics = no ; then
 226    AC_MSG_ERROR([MMX intrinsics not detected])
 227 fi
 228
 229 AM_CONDITIONAL(USE_MMX, test $have_mmx_intrinsics = yes)
 230
 231 dnl ===========================================================================
 232 dnl Check for SSE2
 233
 234 if test "x$SSE2_CFLAGS" = "x" ; then
 235    if test "x$SUNCC" = "xyes"; then
 236       # SSE2 is enabled by default in the Sun Studio 64-bit environment
 237       if test "$AMD64_ABI" = "no" ; then
 238          SSE2_CFLAGS="-xarch=sse2"
 239       fi
 240    else
 241       SSE2_CFLAGS="-mmmx -msse2 -Winline"
 242    fi
 243 fi
 244
 245 have_sse2_intrinsics=no
 246 AC_MSG_CHECKING(whether to use SSE2 intrinsics)
 247 xserver_save_CFLAGS=$CFLAGS
 248 CFLAGS="$SSE2_CFLAGS $CFLAGS"
 249
 250 AC_COMPILE_IFELSE([
 251 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 2))
 252 #   if !defined(__amd64__) && !defined(__x86_64__)
 253 #      error "Need GCC >= 4.2 for SSE2 intrinsics on x86"
 254 #   endif
 255 #endif
 256 #include <mmintrin.h>
 257 #include <xmmintrin.h>
 258 #include <emmintrin.h>
 259 int main () {
 260     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 261         c = _mm_xor_si128 (a, b);
 262     return 0;
 263 }], have_sse2_intrinsics=yes)
 264 CFLAGS=$xserver_save_CFLAGS
 265
 266 AC_ARG_ENABLE(sse2,
 267    [AC_HELP_STRING([--disable-sse2],
 268                    [disable SSE2 fast paths])],
 269    [enable_sse2=$enableval], [enable_sse2=auto])
 270
 271 if test $enable_sse2 = no ; then
 272    have_sse2_intrinsics=disabled
 273 fi
 274
 275 if test $have_sse2_intrinsics = yes ; then
 276    AC_DEFINE(USE_SSE2, 1, [use SSE2 compiler intrinsics])
 277 fi
 278
 279 AC_MSG_RESULT($have_sse2_intrinsics)
 280 if test $enable_sse2 = yes && test $have_sse2_intrinsics = no ; then
 281    AC_MSG_ERROR([SSE2 intrinsics not detected])
 282 fi
 283
 284 AM_CONDITIONAL(USE_SSE2, test $have_sse2_intrinsics = yes)
 285
 286 dnl ===========================================================================
 287 dnl Other special flags needed when building code using MMX or SSE instructions
 288 case $host_os in
 289    solaris*)
 290       # When building 32-bit binaries, apply a mapfile to ensure that the
 291       # binaries aren't flagged as only able to run on MMX+SSE capable CPUs
 292       # since they check at runtime before using those instructions.
 293       # Not all linkers grok the mapfile format so we check for that first.
 294       if test "$AMD64_ABI" = "no" ; then
 295          use_hwcap_mapfile=no
 296          AC_MSG_CHECKING(whether to use a hardware capability map file)
 297          hwcap_save_LDFLAGS="$LDFLAGS"
 298          HWCAP_LDFLAGS='-Wl,-M,$(srcdir)/solaris-hwcap.mapfile'
 299          LDFLAGS="$LDFLAGS -Wl,-M,pixman/solaris-hwcap.mapfile"
 300          AC_LINK_IFELSE([int main() { return 0; }],
 301                         use_hwcap_mapfile=yes,
 302                         HWCAP_LDFLAGS="")
 303          LDFLAGS="$hwcap_save_LDFLAGS"
 304          AC_MSG_RESULT($use_hwcap_mapfile)
 305       fi
 306       if test "x$MMX_LDFLAGS" = "x" ; then
 307          MMX_LDFLAGS="$HWCAP_LDFLAGS"
 308       fi
 309       if test "x$SSE2_LDFLAGS" = "x" ; then
 310          SSE2_LDFLAGS="$HWCAP_LDFLAGS"
 311       fi
 312       ;;
 313 esac
 314
 315 AC_SUBST(MMX_CFLAGS)
 316 AC_SUBST(MMX_LDFLAGS)
 317 AC_SUBST(SSE2_CFLAGS)
 318 AC_SUBST(SSE2_LDFLAGS)
 319
 320 dnl ===========================================================================
 321 dnl Check for VMX/Altivec
 322 if test -n "`$CC -v 2>&1 | grep version | grep Apple`"; then
 323     VMX_CFLAGS="-faltivec"
 324 else
 325     VMX_CFLAGS="-maltivec -mabi=altivec"
 326 fi
 327
 328 have_vmx_intrinsics=no
 329 AC_MSG_CHECKING(whether to use VMX/Altivec intrinsics)
 330 xserver_save_CFLAGS=$CFLAGS
 331 CFLAGS="$VMX_CFLAGS $CFLAGS"
 332 AC_COMPILE_IFELSE([
 333 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 334 error "Need GCC >= 3.4 for sane altivec support"
 335 #endif
 336 #include <altivec.h>
 337 int main () {
 338     vector unsigned int v = vec_splat_u32 (1);
 339     v = vec_sub (v, v);
 340     return 0;
 341 }], have_vmx_intrinsics=yes)
 342 CFLAGS=$xserver_save_CFLAGS
 343
 344 AC_ARG_ENABLE(vmx,
 345    [AC_HELP_STRING([--disable-vmx],
 346                    [disable VMX fast paths])],
 347    [enable_vmx=$enableval], [enable_vmx=auto])
 348
 349 if test $enable_vmx = no ; then
 350    have_vmx_intrinsics=disabled
 351 fi
 352
 353 if test $have_vmx_intrinsics = yes ; then
 354    AC_DEFINE(USE_VMX, 1, [use VMX compiler intrinsics])
 355 else
 356    VMX_CFLAGS=
 357 fi
 358
 359 AC_MSG_RESULT($have_vmx_intrinsics)
 360 if test $enable_vmx = yes && test $have_vmx_intrinsics = no ; then
 361    AC_MSG_ERROR([VMX intrinsics not detected])
 362 fi
 363
 364 AC_SUBST(VMX_CFLAGS)
 365
 366 AM_CONDITIONAL(USE_VMX, test $have_vmx_intrinsics = yes)
 367
 368 dnl ==========================================================================
 369 dnl Check if assembler is gas compatible and supports ARM SIMD instructions
 370 have_arm_simd=no
 371 AC_MSG_CHECKING(whether to use ARM SIMD assembler)
 372 xserver_save_CFLAGS=$CFLAGS
 373 CFLAGS="-x assembler-with-cpp $CFLAGS"
 374 AC_COMPILE_IFELSE([[
 375 .text
 376 .arch armv6
 377 .object_arch armv4
 378 .arm
 379 .altmacro
 380 #ifndef __ARM_EABI__
 381 #error EABI is required (to be sure that calling conventions are compatible)
 382 #endif
 383 pld [r0]
 384 uqadd8 r0, r0, r0]], have_arm_simd=yes)
 385 CFLAGS=$xserver_save_CFLAGS
 386
 387 AC_ARG_ENABLE(arm-simd,
 388    [AC_HELP_STRING([--disable-arm-simd],
 389                    [disable ARM SIMD fast paths])],
 390    [enable_arm_simd=$enableval], [enable_arm_simd=auto])
 391
 392 if test $enable_arm_simd = no ; then
 393    have_arm_simd=disabled
 394 fi
 395
 396 if test $have_arm_simd = yes ; then
 397    AC_DEFINE(USE_ARM_SIMD, 1, [use ARM SIMD assembly optimizations])
 398 fi
 399
 400 AM_CONDITIONAL(USE_ARM_SIMD, test $have_arm_simd = yes)
 401
 402 AC_MSG_RESULT($have_arm_simd)
 403 if test $enable_arm_simd = yes && test $have_arm_simd = no ; then
 404    AC_MSG_ERROR([ARM SIMD intrinsics not detected])
 405 fi
 406
 407 dnl ==========================================================================
 408 dnl Check if assembler is gas compatible and supports NEON instructions
 409 have_arm_neon=no
 410 AC_MSG_CHECKING(whether to use ARM NEON assembler)
 411 xserver_save_CFLAGS=$CFLAGS
 412 CFLAGS="-x assembler-with-cpp $CFLAGS"
 413 AC_COMPILE_IFELSE([[
 414 .text
 415 .fpu neon
 416 .arch armv7a
 417 .object_arch armv4
 418 .eabi_attribute 10, 0
 419 .arm
 420 .altmacro
 421 #ifndef __ARM_EABI__
 422 #error EABI is required (to be sure that calling conventions are compatible)
 423 #endif
 424 pld [r0]
 425 vmovn.u16 d0, q0]], have_arm_neon=yes)
 426 CFLAGS=$xserver_save_CFLAGS
 427
 428 AC_ARG_ENABLE(arm-neon,
 429    [AC_HELP_STRING([--disable-arm-neon],
 430                    [disable ARM NEON fast paths])],
 431    [enable_arm_neon=$enableval], [enable_arm_neon=auto])
 432
 433 if test $enable_arm_neon = no ; then
 434    have_arm_neon=disabled
 435 fi
 436
 437 if test $have_arm_neon = yes ; then
 438    AC_DEFINE(USE_ARM_NEON, 1, [use ARM NEON assembly optimizations])
 439 fi
 440
 441 AM_CONDITIONAL(USE_ARM_NEON, test $have_arm_neon = yes)
 442
 443 AC_MSG_RESULT($have_arm_neon)
 444 if test $enable_arm_neon = yes && test $have_arm_neon = no ; then
 445    AC_MSG_ERROR([ARM NEON intrinsics not detected])
 446 fi
 447
 448 dnl =========================================================================================
 449 dnl Check for GNU-style inline assembly support
 450
 451 have_gcc_inline_asm=no
 452 AC_MSG_CHECKING(whether to use GNU-style inline assembler)
 453 AC_COMPILE_IFELSE([
 454 int main () {
 455     /* Most modern architectures have a NOP instruction, so this is a fairly generic test. */
 456         asm volatile ( "\tnop\n" : : : "cc", "memory" );
 457     return 0;
 458 }], have_gcc_inline_asm=yes)
 459
 460 AC_ARG_ENABLE(gcc-inline-asm,
 461    [AC_HELP_STRING([--disable-gcc-inline-asm],
 462                    [disable GNU-style inline assembler])],
 463    [enable_gcc_inline_asm=$enableval], [enable_gcc_inline_asm=auto])
 464
 465 if test $enable_gcc_inline_asm = no ; then
 466    have_gcc_inline_asm=disabled
 467 fi
 468
 469 if test $have_gcc_inline_asm = yes ; then
 470    AC_DEFINE(USE_GCC_INLINE_ASM, 1, [use GNU-style inline assembler])
 471 fi
 472
 473 AC_MSG_RESULT($have_gcc_inline_asm)
 474 if test $enable_gcc_inline_asm = yes && test $have_gcc_inline_asm = no ; then
 475    AC_MSG_ERROR([GNU-style inline assembler not detected])
 476 fi
 477
 478 AM_CONDITIONAL(USE_GCC_INLINE_ASM, test $have_gcc_inline_asm = yes)
 479
 480 dnl ==============================================
 481 dnl Timers
 482
 483 AC_ARG_ENABLE(timers,
 484    [AC_HELP_STRING([--enable-timers],
 485                    [enable TIMER_BEGIN and TIMER_END macros [default=no]])],
 486    [enable_timers=$enableval], [enable_timers=no])
 487
 488 if test $enable_timers = yes ; then
 489    AC_DEFINE(PIXMAN_TIMERS, 1, [enable TIMER_BEGIN/TIMER_END macros])
 490 fi
 491 AC_SUBST(PIXMAN_TIMERS)
 492
 493 dnl ===================================
 494 dnl GTK+
 495
 496 AC_ARG_ENABLE(gtk,
 497    [AC_HELP_STRING([--enable-gtk],
 498                    [enable tests using GTK+ [default=auto]])],
 499    [enable_gtk=$enableval], [enable_gtk=auto])
 500
 501 PKG_PROG_PKG_CONFIG
 502 if test $enable_gtk = auto ; then
 503    PKG_CHECK_EXISTS([gtk+-2.0], [enable_gtk=yes], [enable_gtk=no])
 504 fi
 505 if test $enable_gtk = yes ; then
 506    PKG_CHECK_MODULES(GTK, [gtk+-2.0])
 507 fi
 508
 509 AM_CONDITIONAL(HAVE_GTK, [test "x$enable_gtk" = xyes])
 510
 511 AC_SUBST(GTK_CFLAGS)
 512 AC_SUBST(GTK_LIBS)
 513 AC_SUBST(DEP_CFLAGS)
 514 AC_SUBST(DEP_LIBS)
 515
 516 dnl =====================================
 517 dnl posix_memalign
 518
 519 AC_CHECK_FUNC(posix_memalign, have_posix_memalign=yes, have_posix_memalign=no)
 520 if test x$have_posix_memalign = xyes; then
 521    AC_DEFINE(HAVE_POSIX_MEMALIGN, 1, [Whether we have posix_memalign()])
 522 fi
 523
 524 dnl =====================================
 525 dnl Thread local storage
 526
 527 support_for__thread=no
 528
 529 AC_MSG_CHECKING(for __thread)
 530 AC_LINK_IFELSE([
 531 #ifdef __MINGW32__
 532 #error MinGW has broken __thread support
 533 #endif
 534 #ifdef __OpenBSD__
 535 #error OpenBSD has broken __thread support
 536 #endif
 537 static __thread int x ;
 538 int main () { x = 123; return x; }
 539 ], support_for__thread=yes)
 540
 541 if test $support_for__thread = yes; then
 542    AC_DEFINE([TOOLCHAIN_SUPPORTS__THREAD],[],[Whether the tool chain supports __thread])
 543 fi
 544
 545 AC_MSG_RESULT($support_for__thread)
 546
 547 dnl
 548 dnl posix tls
 549 dnl
 550
 551 m4_define([pthread_test_program],[dnl
 552 #include <stdlib.h>
 553 #include <pthread.h>
 554
 555 static pthread_once_t once_control = PTHREAD_ONCE_INIT;
 556 static pthread_key_t key;
 557
 558 static void
 559 make_key (void)
 560 {
 561     pthread_key_create (&key, NULL);
 562 }
 563
 564 int
 565 main ()
 566 {
 567     void *value = NULL;
 568
 569     if (pthread_once (&once_control, make_key) != 0)
 570     {
 571         value = NULL;
 572     }
 573     else
 574     {
 575         value = pthread_getspecific (key);
 576         if (!value)
 577         {
 578             value = malloc (100);
 579             pthread_setspecific (key, value);
 580         }
 581     }
 582     return 0;
 583 }
 584 ])
 585
 586 AC_DEFUN([PIXMAN_CHECK_PTHREAD],[dnl
 587     if test "z$support_for_pthread_setspecific" != "zyes"; then
 588         save_CFLAGS="$CFLAGS"
 589         save_LDFLAGS="$LDFLAGS"
 590         save_LIBS="$LIBS"
 591         CFLAGS=""
 592         LDFLAGS=""
 593         LIBS=""
 594         $1
 595         AC_LINK_IFELSE([pthread_test_program],
 596                 [PTHREAD_CFLAGS="$CFLAGS"
 597                  PTHREAD_LIBS="$LIBS"
 598                  PTHREAD_LDFLAGS="$LDFLAGS"
 599                  support_for_pthread_setspecific=yes])
 600         CFLAGS="$save_CFLAGS"
 601         LDFLAGS="$save_LDFLAGS"
 602         LIBS="$save_LIBS"
 603     fi
 604 ])
 605
 606 if test $support_for__thread = no; then
 607     support_for_pthread_setspecific=no
 608
 609     AC_MSG_CHECKING(for pthread_setspecific)
 610
 611     PIXMAN_CHECK_PTHREAD([CFLAGS="-D_REENTRANT"; LIBS="-lpthread"])
 612     PIXMAN_CHECK_PTHREAD([CFLAGS="-pthread"; LDFLAGS="-pthread"])
 613
 614     if test $support_for_pthread_setspecific = yes; then
 615         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 616         AC_DEFINE([HAVE_PTHREAD_SETSPECIFIC], [], [Whether pthread_setspecific() is supported])
 617     fi
 618
 619     AC_MSG_RESULT($support_for_pthread_setspecific);
 620 fi
 621
 622 AC_SUBST(TOOLCHAIN_SUPPORTS__THREAD)
 623 AC_SUBST(HAVE_PTHREAD_SETSPECIFIC)
 624 AC_SUBST(PTHREAD_LDFLAGS)
 625 AC_SUBST(PTHREAD_LIBS)
 626
 627 AC_OUTPUT([pixman-1.pc
 628            pixman-1-uninstalled.pc
 629            Makefile
 630            pixman/Makefile
 631            pixman/pixman-version.h
 632            test/Makefile])