configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.7.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.17
  50 GSTPB_REQ=0.10.17
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 AG_GST_ARG_WITH_PLUGINS
  80
  81 AG_GST_ARG_ENABLE_EXTERNAL
  82
  83 AG_GST_ARG_ENABLE_EXPERIMENTAL
  84
  85 dnl *** checks for platform ***
  86
  87 dnl * hardware/architecture *
  88
  89 dnl common/m4/gst-arch.m4
  90 dnl check CPU type
  91 AG_GST_ARCH
  92
  93 dnl Determine endianness
  94 AC_C_BIGENDIAN
  95
  96 dnl *** checks for programs ***
  97
  98 dnl find a compiler
  99 AC_PROG_CC
 100
 101 dnl determine c++ compiler
 102 AC_PROG_CXX
 103 dnl determine if c++ is available on this system
 104 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 105
 106 dnl determine c++ preprocessor
 107 dnl FIXME: do we need this ?
 108 AC_PROG_CXXCPP
 109
 110 AS_PROG_OBJC
 111
 112 dnl check if the compiler supports '-c' and '-o' options
 113 AM_PROG_CC_C_O
 114
 115 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 116 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 117
 118 dnl check for gconftool-2
 119 dnl this macro defines an am conditional, so it needs to be run always
 120 AM_GCONF_SOURCE_2
 121
 122 dnl check for documentation tools
 123 GTK_DOC_CHECK([1.3])
 124 AS_PATH_PYTHON([2.1])
 125 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 126
 127 dnl *** checks for libraries ***
 128
 129 dnl check for libm, for sin()
 130 AC_CHECK_LIBM
 131 AC_SUBST(LIBM)
 132
 133 dnl *** checks for header files ***
 134
 135 dnl check if we have ANSI C header files
 136 AC_HEADER_STDC
 137
 138 dnl used by ext/wavpack
 139 AX_CREATE_STDINT_H
 140
 141 dnl used in gst/rtp/gstasteriskh263.c
 142 AC_CHECK_HEADERS([netinet/in.h])
 143 AC_CHECK_HEADERS([winsock2.h])
 144 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 145
 146 dnl used in gst/udp
 147 AC_CHECK_HEADERS([sys/time.h])
 148
 149 dnl *** checks for types/defines ***
 150
 151 dnl Check for FIONREAD ioctl declaration.  This check is needed
 152 dnl for the UDP plugin to build on Solaris
 153 GST_CHECK_FIONREAD
 154
 155 dnl *** checks for structures ***
 156
 157 dnl *** checks for compiler characteristics ***
 158
 159 dnl FIXME: check if this is used; was used for floatcast.h in base
 160 dnl Check for fast float to int casting as defined in C99
 161 AC_C99_FUNC_LRINT
 162 AC_C99_FUNC_LRINTF
 163
 164 dnl *** checks for library functions ***
 165
 166 LIBS_SAVE=$LIBS
 167 LIBS="$LIBS $LIBM"
 168 AC_CHECK_FUNCS(rint)
 169 LIBS=$LIBS_SAVE
 170
 171 dnl Check for mmap (needed by electricfence plugin)
 172 AC_FUNC_MMAP
 173 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 174
 175 dnl *** checks for dependency libraries ***
 176
 177 dnl GLib is required
 178 AG_GST_GLIB_CHECK([2.6])
 179
 180 dnl liboil is required
 181 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 182 if test "x$HAVE_LIBOIL" != "xyes"; then
 183   AC_ERROR([liboil-0.3.8 or later is required])
 184 fi
 185
 186 dnl checks for gstreamer
 187 dnl uninstalled is selected preferentially -- see pkg-config(1)
 188 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 189 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 190 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 191 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 192 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 193 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 194
 195 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 196 if test -z $GST_TOOLS_DIR; then
 197   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 198 fi
 199 AC_SUBST(GST_TOOLS_DIR)
 200
 201 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 202 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 203
 204 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 205
 206 dnl Check for documentation xrefs
 207 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 208 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 209 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 210 AC_SUBST(GLIB_PREFIX)
 211 AC_SUBST(GST_PREFIX)
 212 AC_SUBST(GSTPB_PREFIX)
 213
 214 dnl GTK is optional and used in examples
 215 HAVE_GTK=NO
 216 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 217 if test "x$HAVE_GTK_22" = "xyes"; then
 218   HAVE_GTK=yes
 219   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 220   AC_SUBST(GTK_VERSION)
 221   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 222   AC_SUBST(GTK_BASE_DIR)
 223   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 224   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 225   AC_SUBST(GTK_BASE_DIR)
 226 else
 227   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 228 fi
 229 if test "x$HAVE_GTK_20" = "xyes"; then
 230   HAVE_GTK=yes
 231 fi
 232 GTK_CFLAGS=$GTK2_CFLAGS
 233 GTK_LIBS=$GTK2_LIBS
 234 AC_SUBST(GTK_LIBS)
 235 AC_SUBST(GTK_CFLAGS)
 236 AC_SUBST(HAVE_GTK)
 237 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 238
 239 dnl should we install schemas ?
 240 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 241 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 242   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 243   if test x$GCONFTOOL = xno; then
 244     AC_MSG_WARN(Not installing GConf schemas)
 245     HAVE_GCONFTOOL="no"
 246   else
 247     HAVE_GCONFTOOL="yes"
 248   fi
 249   AC_SUBST(HAVE_GCONFTOOL)
 250 ])
 251
 252 dnl *** set variables based on configure arguments ***
 253
 254 dnl set license and copyright notice
 255 GST_LICENSE="LGPL"
 256 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 257 AC_SUBST(GST_LICENSE)
 258
 259 dnl set location of plugin directory
 260 AG_GST_SET_PLUGINDIR
 261
 262 dnl define an ERROR_CFLAGS Makefile variable
 263 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 264
 265 dnl define an ERROR_CXXFLAGS Makefile variable
 266 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 267
 268 dnl define correct level for debugging messages
 269 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 270
 271 dnl used in examples
 272 AG_GST_DEFAULT_ELEMENTS
 273
 274 dnl Check for Yacc and Lex for the goom plugin
 275 AG_GST_BISON_CHECK
 276 AG_GST_FLEX_CHECK
 277 AM_PROG_AS
 278 dnl Check if we have GCC inline-asm
 279 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 280 if test x$HAVE_GCC_ASM = xyes ; then
 281   AC_DEFINE(HAVE_GCC_ASM, 1,
 282     [Define if compiler supports gcc inline assembly])
 283 fi
 284 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 285
 286 dnl *** plug-ins to include ***
 287
 288 dnl these are all the gst plug-ins, compilable without additional libs
 289 dnl videofilter is at the top because others depend on it
 290 AG_GST_CHECK_PLUGIN(videofilter)
 291 AG_GST_CHECK_PLUGIN(alpha)
 292 AG_GST_CHECK_PLUGIN(apetag)
 293 AG_GST_CHECK_PLUGIN(audiofx)
 294 AG_GST_CHECK_PLUGIN(auparse)
 295 AG_GST_CHECK_PLUGIN(autodetect)
 296 AG_GST_CHECK_PLUGIN(avi)
 297 AG_GST_CHECK_PLUGIN(cutter)
 298 AG_GST_CHECK_PLUGIN(debug)
 299 AG_GST_CHECK_PLUGIN(effectv)
 300 AG_GST_CHECK_PLUGIN(equalizer)
 301 AG_GST_CHECK_PLUGIN(id3demux)
 302 AG_GST_CHECK_PLUGIN(icydemux)
 303 AG_GST_CHECK_PLUGIN(flx)
 304 AG_GST_CHECK_PLUGIN(goom)
 305 AG_GST_CHECK_PLUGIN(goom2k1)
 306 AG_GST_CHECK_PLUGIN(law)
 307 AG_GST_CHECK_PLUGIN(level)
 308 AG_GST_CHECK_PLUGIN(matroska)
 309 AG_GST_CHECK_PLUGIN(monoscope)
 310 AG_GST_CHECK_PLUGIN(multifile)
 311 AG_GST_CHECK_PLUGIN(multipart)
 312 AG_GST_CHECK_PLUGIN(qtdemux)
 313 AG_GST_CHECK_PLUGIN(rtp)
 314 AG_GST_CHECK_PLUGIN(rtsp)
 315 AG_GST_CHECK_PLUGIN(smpte)
 316 AG_GST_CHECK_PLUGIN(spectrum)
 317 AG_GST_CHECK_PLUGIN(udp)
 318 AG_GST_CHECK_PLUGIN(videobox)
 319 AG_GST_CHECK_PLUGIN(videocrop)
 320 AG_GST_CHECK_PLUGIN(videomixer)
 321 AG_GST_CHECK_PLUGIN(wavenc)
 322 AG_GST_CHECK_PLUGIN(wavparse)
 323
 324 dnl disable gst plugins we might not be able to build on this
 325 dnl platform: udp and rtsp (ugly but minimally invasive)
 326 dnl FIXME: maybe move to sys
 327 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 328 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 329
 330 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 331   AG_GST_DISABLE_PLUGIN(udp)
 332   AG_GST_DISABLE_PLUGIN(rtsp)
 333 fi
 334
 335 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 336   WIN32_LIBS="-lws2_32"
 337   AC_SUBST(WIN32_LIBS)
 338 fi
 339
 340 dnl disable experimental plug-ins
 341 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 342   AG_GST_DISABLE_PLUGIN(monoscope)
 343 fi
 344
 345 dnl *** sys plug-ins ***
 346
 347 echo
 348 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 349 echo
 350
 351 dnl DirectDraw
 352 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 353 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 354   HAVE_DIRECTDRAW="no"
 355   save_CFLAGS="$CFLAGS"
 356   save_LDFLAGS="$LDFLAGS"
 357   save_LIBS="$LIBS"
 358   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 359   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 360   LIBS="$LIBS -lddraw -lgdi32"
 361   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 362   AC_LINK_IFELSE([
 363 #include <windows.h>
 364 #include <ddraw.h>
 365
 366 int main ()
 367 {
 368   GetStockObject(0);
 369   DirectDrawCreate(NULL, NULL, NULL);
 370
 371   return 0;
 372 }
 373 ],
 374     [HAVE_DIRECTDRAW="yes"],
 375     [HAVE_DIRECTDRAW="no"])
 376   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 377   CFLAGS=$save_CFLAGS
 378   LDFLAGS=$save_LDFLAGS
 379   LIBS=$save_LIBS
 380
 381   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 382     dnl this is much more than we want
 383     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 384     AC_SUBST(DIRECTDRAW_CFLAGS)
 385     AC_SUBST(DIRECTDRAW_LDFLAGS)
 386     AC_SUBST(DIRECTDRAW_LIBS)
 387   fi
 388   AC_SUBST(HAVE_DIRECTDRAW)
 389 ])
 390
 391 dnl DirectSound
 392 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 393 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 394   HAVE_DIRECTSOUND="no"
 395   save_CFLAGS="$CFLAGS"
 396   save_LDFLAGS="$LDFLAGS"
 397   save_LIBS="$LIBS"
 398   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 399   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 400   LIBS="$LIBS -ldsound -ldxerr9"
 401   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 402   AC_LINK_IFELSE([
 403 #include <windows.h>
 404 #include <dxerr9.h>
 405 #include <dsound.h>
 406
 407 int main ()
 408 {
 409   DXGetErrorString9 (0);
 410   DirectSoundCreate(NULL, NULL, NULL);
 411
 412   return 0;
 413 }
 414 ],
 415     [HAVE_DIRECTSOUND="yes"],
 416     [HAVE_DIRECTSOUND="no"])
 417   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 418   CFLAGS=$save_CFLAGS
 419   LDFLAGS=$save_LDFLAGS
 420   LIBS=$save_LIBS
 421
 422   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 423     dnl this is much more than we want
 424     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 425     AC_SUBST(DIRECTSOUND_CFLAGS)
 426     AC_SUBST(DIRECTSOUND_LDFLAGS)
 427     AC_SUBST(DIRECTSOUND_LIBS)
 428   fi
 429   AC_SUBST(HAVE_DIRECTSOUND)
 430 ])
 431
 432 dnl *** OSS audio *** (Linux, *BSD)
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 434 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 435  HAVE_OSS="yes"
 436 dnl Linux and newer BSD versions :
 437  AC_CHECK_HEADER(sys/soundcard.h, [
 438    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 439    ] , [
 440 dnl Some old BSD versions and also newer OpenBSD versions :
 441    AC_CHECK_HEADER(soundcard.h, [
 442      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 443      ], [
 444   dnl Some old BSD versions :
 445      AC_CHECK_HEADER(machine/soundcard.h, [
 446        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 447          [Define if OSS includes are in /machine/])
 448        ], [
 449        HAVE_OSS="no"
 450      ])
 451    ])
 452  ])
 453 ])
 454
 455 dnl *** Sun Audio ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 457 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 458   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 459 ])
 460
 461 dnl *** OSX Audio ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 463 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 464   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 465 ])
 466
 467 dnl *** OS X video ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 469 HAVE_OSX_VIDEO="no"
 470 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 471   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 472 ])
 473 dnl in case header OpenGL/gl.h is found on other platforms
 474 case "$host" in
 475   *-*darwin*)
 476     dnl do nothing
 477     ;;
 478   *)
 479     HAVE_OSX_VIDEO="no"
 480     ;;
 481 esac
 482
 483
 484 dnl *** Video 4 Linux 2 ***
 485 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 486 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 487 USE_GST_V4L2=$BUILD_EXPERIMENTAL
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 489 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 490   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 491   AC_TRY_COMPILE([
 492 #include <sys/types.h>
 493 #ifdef __sun /* Solaris */
 494 #include <sys/types.h>
 495 #include <sys/videodev2.h>
 496 #else /* Linux */
 497 #include <linux/types.h>
 498 #define _LINUX_TIME_H
 499 #define __user
 500 #include <linux/videodev2.h>
 501 #endif
 502 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 503 #error too early v4l2 version or no v4l2 at all
 504 #endif
 505     ], [
 506 return 0;
 507     ], [
 508       HAVE_GST_V4L2="yes"
 509       AC_MSG_RESULT(yes)
 510     ], [
 511       HAVE_GST_V4L2="no"
 512       AC_MSG_RESULT(no)
 513
 514       HAVE_VIDEODEV=no
 515       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 516       [
 517         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 518       ])
 519
 520       if test "x$HAVE_VIDEODEV" = "xyes"; then
 521         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 522         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 523       else
 524         AC_MSG_WARN([video4linux2 was not found])
 525       fi
 526     ])
 527
 528   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 529     dnl check for missing v4l2_buffer declaration (see #135919)
 530     MISSING_DECL=0
 531     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 532     AC_TRY_COMPILE([
 533 #include <sys/types.h>
 534 #ifdef __sun /* Solaris */
 535 #include <sys/types.h>
 536 #include <sys/videodev2.h>
 537 #else /* Linux */
 538 #include <linux/types.h>
 539 #define _LINUX_TIME_H
 540 #define __user
 541 #include <linux/videodev2.h>
 542 #endif
 543     ],[
 544 struct v4l2_buffer buf;
 545 buf.index = 0;
 546 return 0;
 547     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 548     if [ test x$MISSING_DECL = x1 ]; then
 549       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 550     fi
 551
 552     dnl check for XOverlay libraries
 553     AG_GST_CHECK_XV
 554   fi
 555 ])
 556
 557 dnl Check for X11
 558 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 559 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 560                   [ximagesrc], [
 561   AC_PATH_XTRA
 562
 563   dnl now try to find the HEADER
 564   ac_cflags_save="$CFLAGS"
 565   ac_cppflags_save="$CPPFLAGS"
 566   CFLAGS="$CFLAGS $X_CFLAGS"
 567   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 568   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 569
 570   if test "x$HAVE_X" = "xno"
 571   then
 572     AC_MSG_NOTICE([cannot find X11 development files])
 573   else
 574     dnl this is much more than we want
 575     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 576     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 577     dnl it does not add the libs; therefore we add them here
 578     X_LIBS="$X_LIBS -lX11"
 579     AC_SUBST(X_CFLAGS)
 580     AC_SUBST(X_LIBS)
 581
 582     dnl check for Xfixes
 583     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 584     if test "x$HAVE_XFIXES" = "xyes"
 585     then
 586         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 587     fi
 588     AC_SUBST(XFIXES_LIBS)
 589     AC_SUBST(XFIXES_CFLAGS)
 590
 591     dnl check for Xdamage
 592     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 593     if test "x$HAVE_XDAMAGE" = "xyes"
 594     then
 595         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 596     fi
 597     AC_SUBST(XDAMAGE_LIBS)
 598     AC_SUBST(XDAMAGE_CFLAGS)
 599   fi
 600   AC_SUBST(HAVE_X)
 601   CFLAGS="$ac_cflags_save"
 602   CPPFLAGS="$ac_cppflags_save"
 603 ])
 604
 605 dnl FIXME: this should be rolled into the test above, it's just an additional
 606 dnl feature of the ximagesrc plug-in
 607 dnl This is the same as in gst-plugins-base
 608 dnl check for X Shm
 609 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 610 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 611   if test x$HAVE_X = xyes; then
 612     AC_CHECK_LIB(Xext, XShmAttach,
 613                  HAVE_XSHM="yes", HAVE_XSHM="no",
 614                  $X_LIBS)
 615     if test "x$HAVE_XSHM" = "xyes"; then
 616       XSHM_LIBS="-lXext"
 617     else
 618       dnl On AIX, it is in XextSam instead, but we still need -lXext
 619       AC_CHECK_LIB(XextSam, XShmAttach,
 620                    HAVE_XSHM="yes", HAVE_XSHM="no",
 621                    $X_LIBS)
 622       if test "x$HAVE_XSHM" = "xyes"; then
 623         XSHM_LIBS="-lXext -lXextSam"
 624       fi
 625     fi
 626   fi
 627 ], ,[
 628   AC_SUBST(HAVE_XSHM)
 629   AC_SUBST(XSHM_LIBS)
 630 ])
 631
 632 dnl for V4L2, we also need to know if we have XVIDEO
 633 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 634 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 635                   [], [
 636   AG_GST_CHECK_XV
 637 ])
 638
 639 dnl *** ext plug-ins ***
 640 dnl keep this list sorted alphabetically !
 641
 642 if test "x$BUILD_EXTERNAL" = "xyes"; then
 643
 644 echo
 645 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 646 echo
 647
 648 dnl *** aalib ***
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 650 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 651   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 652   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 653 ])
 654
 655 dnl *** annodex ***
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 657 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 658   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 659 ])
 660
 661 dnl *** cairo ***
 662 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 663 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 664   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 665 ])
 666
 667 dnl *** cdio ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 669 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 670   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 671 ])
 672
 673 dnl **** ESound ****
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 675 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 676   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 677   if test $HAVE_ESD = no
 678   then
 679     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 680     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 681   fi
 682 ])
 683
 684 dnl *** FLAC ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 686 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 687   #if FLAC_API_VERSION_CURRENT < 8
 688   #error "legacy flac API"
 689   #endif
 690   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 691
 692 if test "x$legacy_flac" = "xyes"; then
 693 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 694   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 695   dnl API change in FLAC 1.1.1, so require that...
 696   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 697   if test x$HAVE_FLAC = xyes; then
 698     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 699                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 700 #include <FLAC/seekable_stream_encoder.h>
 701                   ])
 702   fi
 703   AC_SUBST(FLAC_LIBS)
 704 ])
 705 else
 706 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 707   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 708   dnl API change in FLAC 1.1.3, so require that...
 709   if test x$HAVE_FLAC = xyes; then
 710     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 711                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 712 #include <FLAC/stream_encoder.h>
 713                   ])
 714   fi
 715   AC_SUBST(FLAC_LIBS)
 716 ])
 717 fi
 718
 719 dnl *** GConf ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 721 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 722   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 723 ])
 724
 725 dnl *** GDK pixbuf ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 727 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 728   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 729 ])
 730
 731 dnl *** HAL ***
 732 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 733 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 734   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 735 ])
 736
 737 dnl *** jpeg ***
 738 dnl FIXME: we could use header checks here as well IMO
 739 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 740 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 741   AC_ARG_WITH(jpeg-mmx,
 742     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 743   OLD_LIBS="$LIBS"
 744   if test x$with_jpeg_mmx != x; then
 745     LIBS="$LIBS -L$with_jpeg_mmx"
 746   fi
 747   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 748   JPEG_LIBS="$LIBS -ljpeg-mmx"
 749   LIBS="$OLD_LIBS"
 750   if test x$HAVE_JPEG != xyes; then
 751     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 752     JPEG_LIBS="-ljpeg"
 753   fi
 754   AC_SUBST(JPEG_LIBS)
 755 ])
 756
 757 dnl *** ladspa ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 759 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 760   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 761 ], disabled)
 762
 763 dnl *** libcaca ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 765 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 766   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 767   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 768   if test "x$HAVE_LIBCACA" != "xyes"; then
 769     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 770     dnl see if it compilation works too, might not if we are cross-compiling
 771     if test "x$HAVE_LIBCACA" = "xyes"; then
 772       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 773                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 774     fi
 775   fi
 776 ])
 777
 778 dnl *** libdv ***
 779 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 780 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 781   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 782 ])
 783
 784 dnl *** libpng ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 786 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 787   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 788 ])
 789
 790 dnl *** dv1394 ***
 791 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 792 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 793   dnl first test for libraw1394 >= 1.2.1
 794   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 795   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 796   dnl now see how far we got
 797   if test x$HAVE_RAW1394 = xyes && \
 798      test x$HAVE_LIBIEC61883 = xyes; then
 799        AG_GST_CHECK_LIBHEADER(AVC1394,
 800         avc1394, avc1394_send_command, $RAW1394_LIBS,
 801         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 802        AG_GST_CHECK_LIBHEADER(ROM1394,
 803         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 804         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 805        if test x$HAVE_AVC1394 = xyes && \
 806           test x$HAVE_AVC1394 = xyes && \
 807           test x$HAVE_ROM1394 = xyes; then
 808           HAVE_DV1394=yes
 809           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 810           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 811           AC_SUBST(DV1394_CFLAGS)
 812           AC_SUBST(DV1394_LIBS)
 813         fi
 814   else
 815        if test x$HAVE_RAW1394 = xno; then
 816           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 817           AG_GST_CHECK_LIBHEADER(AVC1394,
 818            avc1394, avc1394_send_command, $RAW1394_LIBS,
 819            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 820           AG_GST_CHECK_LIBHEADER(ROM1394,
 821            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 822            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 823           if test x$HAVE_RAW1394 = xyes && \
 824              test x$HAVE_AVC1394 = xyes && \
 825              test x$HAVE_ROM1394 = xyes; then
 826              HAVE_DV1394=yes
 827              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 828              DV1394_CFLAGS="$RAW1394_CFLAGS"
 829              if test x$HAVE_LIBIEC61883 = xyes; then
 830                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 831                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 832              fi
 833              AC_SUBST(DV1394_CFLAGS)
 834              AC_SUBST(DV1394_LIBS)
 835            fi
 836          fi
 837   fi
 838 ])
 839
 840 dnl *** shout2 ***
 841 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 842 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 843   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 844   if test $HAVE_SHOUT2 = no
 845   then
 846     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 847     AC_SUBST(SHOUT2_CFLAGS)
 848     AC_SUBST(SHOUT2_LIBS)
 849   fi
 850 ])
 851
 852 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 853 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 854 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 855 dnl   speex_jitter.h is 1.1.x only
 856 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 857 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 858   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 859   if test $HAVE_SPEEX = no
 860   then
 861     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 862       AC_CHECK_HEADER(speex/speex_jitter.h, [
 863         dnl speex 1.1.x :
 864         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 865           dnl speex 1.1.5 or + :
 866           HAVE_SPEEX="yes"
 867           SPEEX_LIBS="-lspeex"
 868           AC_SUBST(SPEEX_CFLAGS)
 869           AC_SUBST(SPEEX_LIBS)
 870         ],[
 871           HAVE_SPEEX="no"
 872         ])
 873       ],[
 874         dnl speex 1.0.x :
 875           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 876             dnl speex 1.0.4
 877             HAVE_SPEEX="yes"
 878             SPEEX_LIBS="-lspeex"
 879             AC_SUBST(SPEEX_CFLAGS)
 880             AC_SUBST(SPEEX_LIBS)
 881
 882             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 883               [defined if speex 1.0.x API detected])
 884         ],[
 885             HAVE_SPEEX="no"
 886             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 887         ], [
 888 #include <speex/speex.h>
 889         ])
 890       ])
 891     ])
 892   fi
 893 ])
 894
 895 dnl *** taglib ***
 896 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 897 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 898   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 899   if test "x$HAVE_CXX" != "xyes"; then
 900     USE_TAGLIB=false
 901     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 902   fi
 903 ])
 904
 905 dnl *** wavpack ***
 906 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 907 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 908   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 909     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 910       HAVE_WAVPACK=yes
 911       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 912     ],[
 913       HAVE_WAVPACK=no
 914       AC_MSG_RESULT(no)
 915     ])
 916   ])
 917   AC_SUBST(WAVPACK_CFLAGS)
 918   AC_SUBST(WAVPACK_LIBS)
 919 ])
 920
 921 dnl *** qtdemux & id3demux prefer to have zlib ***
 922 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 923 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 924   AG_GST_CHECK_LIBHEADER(ZLIB,
 925     z, uncompress,, zlib.h, [
 926     HAVE_ZLIB="yes"
 927     ZLIB_LIBS="-lz"
 928     AC_SUBST(ZLIB_LIBS)
 929   ])
 930 ])
 931
 932 else
 933
 934 dnl not building plugins with external dependencies,
 935 dnl but we still need to set the conditionals
 936 AM_CONDITIONAL(USE_GCONFTOOL, false)
 937 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 938 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 939 AM_CONDITIONAL(USE_OSS, false)
 940 AM_CONDITIONAL(USE_SUNAUDIO, false)
 941 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 942 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 943 AM_CONDITIONAL(USE_X, false)
 944 AM_CONDITIONAL(USE_XSHM, false)
 945 AM_CONDITIONAL(USE_AALIB, false)
 946 AM_CONDITIONAL(USE_ANNODEX, false)
 947 AM_CONDITIONAL(USE_CAIRO, false)
 948 AM_CONDITIONAL(USE_CDIO, false)
 949 AM_CONDITIONAL(USE_ESD, false)
 950 AM_CONDITIONAL(USE_FLAC, false)
 951 AM_CONDITIONAL(USE_GCONF, false)
 952 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 953 AM_CONDITIONAL(USE_HAL, false)
 954 AM_CONDITIONAL(USE_JPEG, false)
 955 AM_CONDITIONAL(USE_LADSPA, false)
 956 AM_CONDITIONAL(USE_LIBCACA, false)
 957 AM_CONDITIONAL(USE_LIBDV, false)
 958 AM_CONDITIONAL(USE_LIBPNG, false)
 959 AM_CONDITIONAL(USE_DV1394, false)
 960 AM_CONDITIONAL(USE_SHOUT2, false)
 961 AM_CONDITIONAL(USE_SPEEX, false)
 962 AM_CONDITIONAL(USE_TAGLIB, false)
 963 AM_CONDITIONAL(USE_WAVPACK, false)
 964 AM_CONDITIONAL(USE_ZLIB, false)
 965
 966 fi dnl of EXT plugins
 967
 968 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 969
 970 dnl Overview:
 971 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 972 dnl GST_*:              flags shared by all built objects
 973 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 974 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 975 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 976 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 977
 978 dnl GST_OPTION_CFLAGS
 979 if test "x$USE_DEBUG" = xyes; then
 980    PROFILE_CFLAGS="-g"
 981 fi
 982 AC_SUBST(PROFILE_CFLAGS)
 983
 984 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 985   dnl Define _only_ during CVS (not pre-releases or releases)
 986   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 987 else
 988   DEPRECATED_CFLAGS=""
 989 fi
 990 AC_SUBST(DEPRECATED_CFLAGS)
 991
 992 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 993 dnl at make time with e.g. make ERROR_CFLAGS=""
 994 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 995 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 996 AC_SUBST(GST_OPTION_CFLAGS)
 997 AC_SUBST(GST_OPTION_CXXFLAGS)
 998
 999 dnl our libraries need to be versioned correctly
1000 AC_SUBST(GST_LT_LDFLAGS)
1001
1002 dnl FIXME: do we want to rename to GST_ALL_* ?
1003 dnl prefer internal headers to already installed ones
1004 dnl also add builddir include for enumtypes and marshal
1005 dnl add ERROR_CFLAGS, but overridable
1006 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1007 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1008 AC_SUBST(GST_CFLAGS)
1009 AC_SUBST(GST_CXXFLAGS)
1010 AC_SUBST(GST_LIBS)
1011
1012 dnl LDFLAGS really should only contain flags, not libs - they get added before
1013 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1014 GST_ALL_LDFLAGS="-no-undefined"
1015 AC_SUBST(GST_ALL_LDFLAGS)
1016
1017 dnl this really should only contain flags, not libs - they get added before
1018 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1019 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1020 AC_SUBST(GST_PLUGIN_LDFLAGS)
1021
1022 dnl *** output files ***
1023
1024 dnl keep this alphabetic per directory, please
1025 AC_CONFIG_FILES(
1026 Makefile
1027 gst/Makefile
1028 gst/alpha/Makefile
1029 gst/apetag/Makefile
1030 gst/audiofx/Makefile
1031 gst/auparse/Makefile
1032 gst/autodetect/Makefile
1033 gst/avi/Makefile
1034 gst/cutter/Makefile
1035 gst/debug/Makefile
1036 gst/effectv/Makefile
1037 gst/equalizer/Makefile
1038 gst/id3demux/Makefile
1039 gst/icydemux/Makefile
1040 gst/goom/Makefile
1041 gst/goom2k1/Makefile
1042 gst/law/Makefile
1043 gst/level/Makefile
1044 gst/matroska/Makefile
1045 gst/monoscope/Makefile
1046 gst/multifile/Makefile
1047 gst/multipart/Makefile
1048 gst/qtdemux/Makefile
1049 gst/rtp/Makefile
1050 gst/rtsp/Makefile
1051 gst/smpte/Makefile
1052 gst/spectrum/Makefile
1053 gst/udp/Makefile
1054 gst/videobox/Makefile
1055 gst/videocrop/Makefile
1056 gst/videofilter/Makefile
1057 gst/videomixer/Makefile
1058 gst/wavenc/Makefile
1059 gst/wavparse/Makefile
1060 gst/flx/Makefile
1061 ext/jpeg/Makefile
1062 ext/Makefile
1063 ext/aalib/Makefile
1064 ext/annodex/Makefile
1065 ext/cairo/Makefile
1066 ext/cdio/Makefile
1067 ext/dv/Makefile
1068 ext/esd/Makefile
1069 ext/flac/Makefile
1070 ext/gconf/Makefile
1071 ext/gdk_pixbuf/Makefile
1072 ext/hal/Makefile
1073 ext/ladspa/Makefile
1074 ext/libcaca/Makefile
1075 ext/libpng/Makefile
1076 ext/raw1394/Makefile
1077 ext/shout2/Makefile
1078 ext/speex/Makefile
1079 ext/taglib/Makefile
1080 ext/wavpack/Makefile
1081 sys/Makefile
1082 sys/directdraw/Makefile
1083 sys/directsound/Makefile
1084 sys/oss/Makefile
1085 sys/sunaudio/Makefile
1086 sys/osxaudio/Makefile
1087 sys/osxvideo/Makefile
1088 sys/v4l2/Makefile
1089 sys/waveform/Makefile
1090 sys/ximage/Makefile
1091 po/Makefile.in
1092 tests/Makefile
1093 tests/check/Makefile
1094 tests/examples/Makefile
1095 tests/examples/equalizer/Makefile
1096 tests/examples/level/Makefile
1097 tests/examples/rtp/Makefile
1098 tests/examples/spectrum/Makefile
1099 tests/files/Makefile
1100 tests/icles/Makefile
1101 gconf/Makefile
1102 gconf/gstreamer.schemas
1103 common/Makefile
1104 common/m4/Makefile
1105 m4/Makefile
1106 docs/Makefile
1107 docs/plugins/Makefile
1108 docs/version.entities
1109 win32/common/config.h
1110 pkgconfig/Makefile
1111 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1112 gst-plugins-good.spec
1113 )
1114 AC_OUTPUT
1115
1116 AG_GST_OUTPUT_PLUGINS