configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.13c], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([bin/automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([-Wall -Werror dist-xz filename-length-max=99
  43                   no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2013
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # Our build system is bootstrapped with the bleeding-edge versions of
  67 # aclocal and automake, hence the remake rules must use those versions
  68 # as well.  The extra quoting is to cater to cases when the build
  69 # directory contains whitespace or shell metacharacters.
  70 ACLOCAL="\"`pwd`/t/wrap/aclocal-$APIVERSION\""
  71 AUTOMAKE="\"`pwd`/t/wrap/automake-$APIVERSION\""
  72
  73 AC_PROG_LN_S
  74
  75 AC_PATH_PROG([PERL], [perl])
  76 if test -z "$PERL"; then
  77    AC_MSG_ERROR([perl not found])
  78 fi
  79 # Save details about the selected perl interpreter in config.log.
  80 AM_RUN_LOG([$PERL --version])
  81 $PERL -e 'require 5.006;' || {
  82    AC_MSG_ERROR(
  83 [perl 5.6 or better is required; perl 5.8.2 or better
  84 is recommended.  If you have several perl versions
  85 installed, select the one Automake should use using
  86   ./configure PERL=/path/to/perl])
  87 }
  88
  89 # The test suite will skip some tests if tex is absent.
  90 AC_CHECK_PROG([TEX], [tex], [tex])
  91 # Save details about the selected TeX program in config.log.
  92 # Redirect input from /dev/null, as TeX might otherwise hang waiting
  93 # for input from the terminal.
  94 AM_RUN_LOG([$TEX --version </dev/null])
  95
  96 # The test suite will skip some tests if no lex or yacc program is
  97 # available.
  98 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
  99 #  1. we don't want flex (resp. bison) to be preferred to system lex
 100 #     (resp. system yacc);
 101 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 102 #     by default;
 103 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 104 #     LEXLIB to be calculated and/or AC_SUBST'd;
 105 #  4. we prefer that the YACC and LEX variables are not reported in the
 106 #     configure help screen.
 107 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 108 AC_CHECK_PROGS([LEX], [lex flex], [false])
 109
 110 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 111 # deletion of any files created (such as those added to
 112 # autom4te.cache).  We used to perform only the last of the three
 113 # following tests, but some users were unable to figure out that their
 114 # installation was broken since --version appeared to work.
 115
 116 AC_SUBST([required_autoconf_version], [2.65])
 117 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 118 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 119 then
 120   am_cv_autoconf_installed=yes
 121 else
 122   am_cv_autoconf_installed=no
 123 fi])
 124 if test "$am_cv_autoconf_installed" = no; then
 125   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 126     Please make sure it is installed and in your PATH.])
 127 fi
 128
 129 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 130 [mkdir conftest
 131 echo 'AC''_INIT' > conftest/conftest.ac
 132 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 133 then
 134   am_cv_autoconf_works=yes
 135 else
 136   am_cv_autoconf_works=no
 137 fi
 138 rm -rf conftest])
 139 if test "$am_cv_autoconf_works" = no; then
 140   AC_MSG_ERROR([The installed version of autoconf does not work.
 141     Please check config.log for error messages before this one.])
 142 fi
 143
 144 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 145 [mkdir conftest
 146 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 147 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 148 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 149 then
 150   am_cv_autoconf_version=yes
 151 else
 152   am_cv_autoconf_version=no
 153 fi
 154 rm -rf conftest])
 155 if test "$am_cv_autoconf_version" = no; then
 156   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 157 fi
 158
 159 # Test for ln.  We need use it to install the versioned binaries.
 160 AC_MSG_CHECKING([whether ln works])
 161 AC_CACHE_VAL([am_cv_prog_ln], [
 162 rm -f conftest conftest.file
 163 : >conftest.file
 164 if ln conftest.file conftest 2>/dev/null; then
 165   am_cv_prog_ln=ln
 166 else
 167   am_cv_prog_ln='cp -p'
 168 fi
 169 rm -f conftest conftest.file])
 170 AC_SUBST([LN], [$am_cv_prog_ln])
 171 result=no
 172 test "x$am_cv_prog_ln" = xln && result=yes
 173 AC_MSG_RESULT([$result])
 174
 175 # The amount we should wait after modifying files depends on the platform.
 176 # On Windows '95, '98 and ME, files modifications have 2-seconds
 177 # granularity and can be up to 3 seconds in the future w.r.t. the
 178 # system clock.  When it is important to ensure one file is older
 179 # than another we wait at least 5 seconds between creations.
 180 case $build in
 181   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 182   *)               MODIFICATION_DELAY=2;;
 183 esac
 184 AC_SUBST([MODIFICATION_DELAY])
 185
 186 ## ------------------------------------------- ##
 187 ##  Test for things needed by the test suite.  ##
 188 ## ------------------------------------------- ##
 189
 190 AC_PROG_EGREP
 191 AC_PROG_FGREP
 192
 193 dnl FIXME: could we extract this in a simpler way through autoconf
 194 dnl FIXME: idioms or internals?
 195 AC_DEFUN(
 196   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 197   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 198
 199 dnl
 200 dnl Arguments to this macro:
 201 dnl
 202 dnl   $1 - shell to test
 203 dnl   $2 - description of the tested feature
 204 dnl   $3 - shell code used to check the feature; to indicate success,
 205 dnl        it can either exit with status 77, or have the last command
 206 dnl        returning with exit status of zero
 207 dnl   $4 - shell code to execute if the check on the shell is successful
 208 dnl        (defaults to nothing)
 209 dnl   $5 - shell code to execute if the check on the shell is not
 210 dnl        successful (defaults to nothing)
 211 dnl
 212 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 213   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 214   AC_MSG_CHECKING([whether $1 $2])
 215   if { $1 -c "$am_bourne_compatible
 216 AS_ESCAPE([$3])
 217 test \$? -eq 0 || exit 1
 218 # Use 77 to indicate success (rather than 0), in case some shell
 219 # acts like Solaris 10's /bin/sh, exiting successfully on some
 220 # syntax errors.
 221 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 222   then
 223     AC_MSG_RESULT([yes])
 224     $4
 225   else
 226     AC_MSG_RESULT([no])
 227     $5
 228   fi])
 229
 230 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 231 # -----------------------------------------
 232 #
 233 # Check if the given shell is good enough to run our test scripts.
 234 # Inspired to gnulib's 'tests/init.sh'.
 235 #
 236 # We require POSIX and XSI features (e.g., '$(...)' for command
 237 # substitutions, '$((...))' for shell arithmetic, and support for
 238 # '${var#...}' and '${var%...}' parameter expansions).
 239 #
 240 # We require that the shell can correctly trap EXIT when 'set -e' is in
 241 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 242 #
 243 # We want to able to define shell aliases with the same name of shell
 244 # builtins.
 245 #
 246 # We also prefer shells that, when 'set -x' is in effect, do not also
 247 # redirect traces upon stderr redirections.  For example,
 248 #  $ set -x; echo x 2>file
 249 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 250 #   $ set -x; P=1 true 2>file
 251 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 252 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 253 #
 254 # Use '$am_score' to indicate the degree of acceptability of the shell.
 255 # A score of "10" means that the shell is good enough for our needs;
 256 # a score of "9" means that the shell has some minor bugs or limitation,
 257 # but is still (barely) acceptable for our uses.  Any other score means
 258 # that the shell is broken or unfit.
 259 #
 260 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 261   [am_score=10
 262   while :; do
 263
 264     _AM_CHECK_SHELL_FEATURE([$1],
 265       [supports \$(cmd)],
 266       [test "$(echo x)" = x],
 267       [], [am_score=1; break])
 268
 269     _AM_CHECK_SHELL_FEATURE([$1],
 270       [supports \$((expr))],
 271       [test $((1 + 2 * 3)) = 7],
 272       [], [am_score=1; break])
 273
 274     _AM_CHECK_SHELL_FEATURE([$1],
 275       [supports \${@%:@var}],
 276       [zero='' one='x' twelve=' foobar baz!' \
 277         && test ${@%:@zero} -eq 0 \
 278         && test ${@%:@one} -eq 1 \
 279         && test ${@%:@twelve} -eq 12],
 280       [], [am_score=1; break])
 281
 282     _AM_CHECK_SHELL_FEATURE([$1],
 283       [supports \${var@%:@glob} and \${var%glob}],
 284       [v=a/b/c \
 285         && test ${v@%:@*/} = b/c \
 286         && test ${v@%:@@%:@*/} = c \
 287         && test ${v%/*} = a/b \
 288         && test ${v%%/*} = a],
 289       [], [am_score=1; break])
 290
 291     _AM_CHECK_SHELL_FEATURE([$1],
 292       [preserves exit traps with "set -e"],
 293       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 294       [], [am_score=1; break])
 295
 296     _AM_CHECK_SHELL_FEATURE([$1],
 297       [can define exit traps in a shell function],
 298       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
 299       [], [am_score=1; break])
 300
 301     _AM_CHECK_SHELL_FEATURE([$1],
 302       [corrupts stderr with "set -x"],
 303       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 304       [am_score=9], [])
 305
 306     echo 'return 34' > conftest-return.sh
 307     echo 'ok=no' >> conftest-return.sh
 308     _AM_CHECK_SHELL_FEATURE([$1],
 309       [can return early from "dot-sourced" files],
 310       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
 311       [rm -f conftest-return.sh],
 312       [rm -f conftest-return.sh; am_score=1; break])
 313
 314     echo 'alias false=echo' > conftest-alias.sh
 315     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 316     _AM_CHECK_SHELL_FEATURE([$1],
 317       [supports alias named like shell builtins],
 318       [. ./conftest-alias.sh],
 319       [rm -f conftest-alias.sh],
 320       [rm -f conftest-alias.sh; am_score=1; break])
 321
 322     _AM_CHECK_SHELL_FEATURE([$1],
 323       [supports "test -e"],
 324       [test -e config.log && test -e . && test ! -e nonesuch],
 325       [], [am_score=1; break])
 326
 327     break
 328   done])
 329
 330 # These messages only goes to the config.log file.
 331 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 332
 333 AC_CACHE_VAL(
 334   [ac_cv_AM_TEST_RUNNER_SHELL],
 335   [if test "$AM_TEST_RUNNER_SHELL"; then
 336     # Let the user override it.
 337     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 338   else
 339     ac_cv_AM_TEST_RUNNER_SHELL=no
 340     am_candidate_shells=${CONFIG_SHELL-}
 341     # For the benefit of Solaris.
 342     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 343     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 344       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 345       if test -n "$am_candidate_sh"; then
 346         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 347       fi
 348       AM_SUBST_NOTMAKE([am_candidate_sh])
 349       # Must nullify these in order not to interfere with the checks in
 350       # the next loop.
 351       AS_UNSET([am_candidate_sh])
 352       AS_UNSET([ac_cv_path_am_candidate_sh])
 353     done
 354     AS_UNSET([am_PATH]) # Not required anymore
 355     for am_sh in $am_candidate_shells; do
 356       am_score=0
 357       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 358       if test $am_score -eq 9; then
 359         # The shell is barely acceptable for our needs.  We might
 360         # still find one that is even better, so continue looking.
 361         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 362         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 363       elif test $am_score -eq 10; then
 364         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 365         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 366         break
 367       fi
 368     done
 369   fi
 370   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 371
 372 if test $AM_TEST_RUNNER_SHELL = no; then
 373   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 374                                 enough to be used in our testsuite])])
 375 else
 376   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 377 fi
 378
 379 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 380            [a sturdy POSIX shell for our testsuite])
 381
 382
 383 ###########################################################################
 384
 385 # Look for C, C++ and fortran compilers to be used in the testsuite.
 386
 387 dnl We don't want to abort our configuration script if no C compiler is
 388 dnl available, as such a compiler is only required to run part of the
 389 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 390 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 391 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 392
 393 dnl We want the body of this macro to expand as a single shell statement,
 394 dnl thus we wrap it into { ... } brackets.
 395 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 396   AC_MSG_WARN([$1])
 397   am__failed=yes
 398   break
 399 } ])
 400
 401 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 402   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 403   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 404   am__failed=no
 405   while :; do
 406      $1
 407      break
 408   done
 409   AS_IF([test $am__failed = yes], [$2])
 410   # We have to clear these cache variables, so that future checks on
 411   # compilers for different languages won't be confused.
 412   unset ac_cv_objext ac_cv_exeext
 413   # We also need to meddle with the autoconf internals to ensure that
 414   # checks to find object and executable extensions will be run anew.
 415   # FIXME: In the long run, the better thing to do would be to fix
 416   # FIXME: autoconf instead ...
 417   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 418   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 419   m4_popdef([AC_MSG_FAILURE])
 420   m4_popdef([AC_MSG_ERROR])
 421 ])
 422
 423 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 424   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 425
 426 # Prefer generic compilers to GNU ones when possible.  This will ensure
 427 # more testsuite coverage "in the wild".
 428 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 429 # deliberate; for more discussion and rationale, see:
 430 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 431
 432 AC_MSG_NOTICE([will now look for generic compilers])
 433
 434 # C compiler.
 435 _AM_COMPILER_CAN_FAIL(dnl
 436   [AC_PROG_CC([cc gcc])],
 437   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 438
 439 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 440
 441 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
 442 # we must avoid looking for 'CC', because that would be the same as
 443 # 'cc', and could cause $CXX to point to the C compiler, instead of
 444 # to a C++ compiler as expected (see automake bugs #11893 and #10766).
 445 # Similarly, we must avoid looking for 'RCC', as that can point to the
 446 # Qt4 "Resource Compiler": <http://doc.qt.digia.com/4.2/rcc.html>
 447 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
 448   # Case-insensitive file system, don't look for CC.
 449   am_CC= am_RCC=
 450 else
 451   am_CC=CC am_RCC=RCC
 452 fi
 453
 454 # The list of C++ compilers here has been copied, pasted and edited
 455 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 456 # Keep it in sync, or better again, find out a way to avoid this code
 457 # duplication.
 458 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 459   [aCC $am_CC FCC KCC $am_RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 460   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 461
 462 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 463
 464 # The lists of Fortran compilers here has been copied, pasted and edited
 465 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 466 # Keep it in sync, or better again, find out a way to avoid this code
 467 # duplication.
 468
 469 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 470   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 471   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 472   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 473
 474 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 475
 476 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 477   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 478   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 479
 480 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 481
 482 # Some tests will need the GNU compilers.  Searching for them here would
 483 # be overkill, since our testsuite already handles their search and setup
 484 # pretty well.  But in case the compilers already found are the GNU ones,
 485 # we want to use them in the testsuite where GNU compilers are required.
 486 # Also, in case the compilers detected above (at configure time) are not
 487 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 488 # FFLAGS detected for them with the GNU compilers too, since it's likely
 489 # they won't be compatible.  So we allow the user to define variants of
 490 # these variables for the GNU compilers separately.
 491
 492 AC_MSG_NOTICE([will now look for GNU compilers])
 493
 494 # GNU C compiler.
 495 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 496 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 497 if test $am_CC_is_GNU = yes; then
 498   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 499   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 500 else
 501   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 502 fi
 503 if test "$GNU_CC" != false; then
 504   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 505         [AC_MSG_WARN([botched installation for GNU C compiler])
 506          _AM_SKIP_COMP_TESTS([GNU C])])
 507 fi
 508
 509 # GNU C++ compiler.
 510 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 511 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 512 if test $am_CXX_is_GNU = yes; then
 513   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 514   GNU_CXX=$CXX
 515   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 516 else
 517   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 518 fi
 519 if test "$GNU_CXX" != false; then
 520   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 521         [AC_MSG_WARN([botched installation for GNU C++ compiler])
 522          _AM_SKIP_COMP_TESTS([GNU C++])])
 523 fi
 524
 525 # GNU Fortran compiler.
 526 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 527 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 528 if test $am_FC_is_GNU = yes; then
 529   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 530   GNU_FC=$FC
 531   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 532 else
 533   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 534 fi
 535 if test "$GNU_FC" != false; then
 536   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 537         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 538          _AM_SKIP_COMP_TESTS([GNU Fortran])])
 539 fi
 540
 541 # GNU Fortran 77 compiler.
 542 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 543 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 544 if test $am_F77_is_GNU = yes; then
 545   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 546   GNU_F77=$F77
 547   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 548 else
 549   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 550 fi
 551 if test "$GNU_F77" != false; then
 552   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 553         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 554         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 555 fi
 556
 557 # GNU Java compiler.
 558 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 559 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 560 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 561 if test "$GNU_GCJ" != false; then
 562   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 563         [AC_MSG_WARN([botched installation for GNU Java compiler])
 564         _AM_SKIP_COMP_TESTS([GNU Java])])
 565 fi
 566
 567 # If we have been able to find at least a working compiler above, we
 568 # know what the object and executable extensions for this platform are.
 569 OBJEXT=${ac_cv_objext-UNKNOWN}
 570 EXEEXT=${ac_cv_exeext-UNKNOWN}
 571 AC_SUBST([OBJEXT])
 572 AC_SUBST([EXEEXT])
 573
 574 ###########################################################################
 575
 576 ## ---------------------- ##
 577 ##  Create output files.  ##
 578 ## ---------------------- ##
 579
 580 AC_CONFIG_FILES([Makefile])
 581 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 582
 583 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 584                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 585                 [APIVERSION=$APIVERSION])
 586 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 587                 [chmod +x t/wrap/automake-${APIVERSION}],
 588                 [APIVERSION=$APIVERSION])
 589
 590 AC_OUTPUT
 591
 592 # Inform the user if this version of automake is a beta release or
 593 # a development snapshot.
 594 # According to HACKING, the version of a development snapshot should
 595 # end with an "odd" letter (a, c, ...), the version of a test release
 596 # should end wit an "even" letter (b, d, ...).
 597
 598 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 599 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 600
 601 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 602   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 603   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 604   { print \"development snapshot\"; }"]`
 605
 606 # '$silent' is set to yes if configure is passed the '--quiet' option.
 607 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
 608
 609 WARNING: You are about to use a $am_release_type of automake.
 610 WARNING: It might easily suffer from new bugs or regressions.
 611 WARNING: You are strongly advised not to use it in production code.
 612
 613 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 614 EOF
 615
 616 AS_EXIT([0])