configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.57)
  22 AC_INIT([libdrm], 2.4.6, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_CONFIG_SRCDIR([Makefile.am])
  24 AM_INIT_AUTOMAKE([dist-bzip2])
  25
  26 AM_CONFIG_HEADER([libdrm/config.h])
  27
  28 AC_DISABLE_STATIC
  29 AC_PROG_LIBTOOL
  30 AC_PROG_CC
  31
  32 AC_HEADER_STDC
  33 AC_SYS_LARGEFILE
  34
  35 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  36 AC_SUBST(PTHREADSTUBS_CFLAGS)
  37 AC_SUBST(PTHREADSTUBS_LIBS)
  38
  39 pkgconfigdir=${libdir}/pkgconfig
  40 AC_SUBST(pkgconfigdir)
  41 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
  42                                 [Enable support for using udev instead of mknod (default: disabled)]),
  43                                 [UDEV=$enableval], [UDEV=no])
  44
  45 AC_ARG_ENABLE(nouveau-experimental-api,
  46               AS_HELP_STRING([--enable-nouveau-experimental-api],
  47               [Enable support for nouveau's experimental API (default: disabled)]),
  48               [NOUVEAU=$enableval], [NOUVEAU=no])
  49
  50 dnl ===========================================================================
  51 dnl check compiler flags
  52 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  53   AC_MSG_CHECKING([whether $CC supports $1])
  54
  55   libdrm_save_CFLAGS="$CFLAGS"
  56   CFLAGS="$CFLAGS $1"
  57
  58   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  59   CFLAGS="$libdrm_save_CFLAGS"
  60
  61   if test "x$libdrm_cc_flag" = "xyes"; then
  62     ifelse([$2], , :, [$2])
  63   else
  64     ifelse([$3], , :, [$3])
  65   fi
  66   AC_MSG_RESULT([$libdrm_cc_flag])
  67 ])
  68
  69 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
  70
  71 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
  72                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
  73                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
  74 AC_SUBST([CLOCK_LIB])
  75
  76 dnl Use lots of warning flags with with gcc and compatible compilers
  77
  78 dnl Note: if you change the following variable, the cache is automatically
  79 dnl skipped and all flags rechecked.  So there's no need to do anything
  80 dnl else.  If for any reason you need to force a recheck, just change
  81 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
  82
  83 MAYBE_WARN="-Wall -Wextra \
  84 -Wsign-compare -Werror-implicit-function-declaration \
  85 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
  86 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
  87 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
  88 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
  89 -Wdeclaration-after-statement -Wold-style-definition \
  90 -Wno-missing-field-initializers -Wno-unused-parameter \
  91 -Wno-attributes -Wno-long-long -Winline"
  92
  93 # invalidate cached value if MAYBE_WARN has changed
  94 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
  95         unset libdrm_cv_warn_cflags
  96 fi
  97 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
  98         echo
  99         WARN_CFLAGS=""
 100
 101         # Some warning options are not supported by all versions of
 102         # gcc, so test all desired options against the current
 103         # compiler.
 104         #
 105         # Note that there are some order dependencies
 106         # here. Specifically, an option that disables a warning will
 107         # have no net effect if a later option then enables that
 108         # warnings, (perhaps implicitly). So we put some grouped
 109         # options (-Wall and -Wextra) up front and the -Wno options
 110         # last.
 111
 112         for W in $MAYBE_WARN; do
 113                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 114         done
 115
 116         libdrm_cv_warn_cflags=$WARN_CFLAGS
 117         libdrm_cv_warn_maybe=$MAYBE_WARN
 118
 119         AC_MSG_CHECKING([which warning flags were supported])])
 120 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 121
 122 if test "x$UDEV" = xyes; then
 123         AC_DEFINE(UDEV, 1, [Have UDEV support])
 124 fi
 125
 126 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 127
 128 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 129 if test "x$HAVE_CAIRO" = xyes; then
 130         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
 131 fi
 132 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
 133
 134 # For enumerating devices in test case
 135 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 136 if test "x$HAVE_LIBUDEV" = xyes; then
 137         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 138 fi
 139 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 140
 141
 142 AC_SUBST(WARN_CFLAGS)
 143 AC_OUTPUT([
 144         Makefile
 145         libdrm/Makefile
 146         libdrm/intel/Makefile
 147         libdrm/nouveau/Makefile
 148         libdrm/nouveau/libdrm_nouveau.pc
 149         shared-core/Makefile
 150         tests/Makefile
 151         tests/modeprint/Makefile
 152         tests/modetest/Makefile
 153         libdrm.pc
 154         libdrm_intel.pc])