configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [5])
   6 m4_define([dbus_micro_version], [5])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22  ## must come before we use the $USE_MAINTAINER_MODE variable later
  23 AM_MAINTAINER_MODE
  24
  25 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  26
  27 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  28
  29 # libtool versioning - this applies to libdbus
  30 #
  31 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  32 #
  33
  34 ## increment if the interface has additions, changes, removals.
  35 LT_CURRENT=9
  36
  37 ## increment any time the source changes; set to
  38 ##  0 if you increment CURRENT
  39 LT_REVISION=2
  40
  41 ## increment if any interfaces have been added; set to 0
  42 ## if any interfaces have been changed or removed. removal has
  43 ## precedence over adding, so set to 0 if both happened.
  44 LT_AGE=6
  45
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 AC_SUBST(LT_AGE)
  49
  50 DBUS_MAJOR_VERSION=dbus_major_version
  51 DBUS_MINOR_VERSION=dbus_minor_version
  52 DBUS_MICRO_VERSION=dbus_micro_version
  53 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  54
  55 AC_SUBST(DBUS_MAJOR_VERSION)
  56 AC_SUBST(DBUS_MINOR_VERSION)
  57 AC_SUBST(DBUS_MICRO_VERSION)
  58 AC_SUBST(DBUS_VERSION)
  59
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_USE_SYSTEM_EXTENSIONS
  64 AC_ISC_POSIX
  65 AC_HEADER_STDC
  66 AC_C_INLINE
  67 AM_PROG_LIBTOOL
  68 AC_PROG_MKDIR_P
  69 COMPILER_COVERAGE
  70 COMPILER_OPTIMISATIONS
  71
  72 # Initialize libtool
  73 LT_INIT([win32-dll])
  74 LT_LANG([Windows Resource])
  75
  76 # Set some internal variables depending on the platform for later use.
  77 dbus_win=no
  78 dbus_cygwin=no
  79 dbus_unix=no
  80 case "${host}" in
  81     *-mingw32ce*)
  82         dbus_win=yes
  83         dbus_wince=yes
  84         ;;
  85     *-mingw32*)
  86         dbus_win=yes
  87         ;;
  88     *-cygwin*)
  89         dbus_cygwin=yes
  90         dbus_unix=yes
  91         ;;
  92     *)
  93         dbus_unix=yes
  94        ;;
  95 esac
  96
  97 # Special defines for certain platforms
  98 if test "$dbus_win" = yes; then
  99     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 100     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 101     AC_SUBST(BUILD_TIMESTAMP)
 102     # Assume DBUS_VERSION is always three numbers
 103     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 104     AC_SUBST(BUILD_FILEVERSION)
 105     AC_CHECK_TOOL(WINDRES, windres, no)
 106     if test "$WINDRES" = no; then
 107       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 108     fi
 109     if test "$dbus_wince" = yes; then
 110       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 111       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 112     fi
 113 else
 114     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 115 fi
 116 if test "$dbus_cygwin" = yes; then
 117     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 118 fi
 119
 120 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 121 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 122 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 123 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 124
 125 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 126 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 127 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 128 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 129 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 130 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 131 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 132 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 133 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 134 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 135 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 136 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 137 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 138 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 139 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 140
 141 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 142 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 143 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 144 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 145 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 146 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 147 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 148 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 149 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 150 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 151 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 152
 153 AC_ARG_ENABLE([embedded-tests],
 154   AS_HELP_STRING([--enable-embedded-tests],
 155     [enable unit test code in the library and binaries]),
 156   [], [enable_embedded_tests=$USE_MAINTAINER_MODE])
 157 AC_ARG_ENABLE([modular-tests],
 158   AS_HELP_STRING([--enable-modular-tests],
 159     [enable modular regression tests (requires GLib)]),
 160   [], [enable_modular_tests=auto])
 161 # --enable-tests overrides both --enable-embedded-tests and
 162 # --enable-modular-tests
 163 AC_ARG_ENABLE([tests],
 164   AS_HELP_STRING([--enable-tests],
 165     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 166   [enable_embedded_tests=$enableval; enable_modular_tests=$enableval],
 167   [])
 168
 169 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 170 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 171 # name for this.
 172 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 173 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 174   [test "x$enable_embedded_tests" = xyes])
 175 if test "x$enable_embedded_tests" = xyes; then
 176     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 177       [Define to build test code into the library and binaries])
 178     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 179       [Define to build test code into the library and binaries])
 180 fi
 181
 182 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 183 # These use GTest, from GLib, because life's too short. They're enabled by
 184 # default (unless you don't have GLib), because they don't bloat the library
 185 # or binaries.
 186 if test "x$enable_modular_tests" != xno; then
 187   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22, gio-2.0 >= 2.22],
 188     [],
 189     [if test "x$enable_modular_tests" = xyes; then
 190       AC_MSG_ERROR([GLib is required by the modular tests])
 191     else # assumed to be "auto"
 192       enable_modular_tests=no
 193     fi])
 194   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 195   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 196     [],
 197     [if test "x$enable_modular_tests" = xyes; then
 198       AC_MSG_ERROR([dbus-glib is required by the modular tests (for now)])
 199     else # assumed to be "auto"
 200       enable_modular_tests=no
 201     fi])
 202   if test "x$enable_modular_tests" != xno; then
 203     # dependencies checked, switch from auto to yes
 204     enable_modular_tests=yes
 205   fi
 206 fi
 207 if test "x$enable_modular_tests" = xyes; then
 208   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 209     [Define to build independent test binaries (requires GLib)])
 210 fi
 211 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 212   [test "x$enable_modular_tests" = xyes])
 213
 214 AC_ARG_ENABLE([installed-tests],
 215   AS_HELP_STRING([--enable-installed-tests],
 216     [enable unit test code in the library and binaries]),
 217   [], [enable_installed_tests=no])
 218 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 219   [test "x$enable_installed_tests" = xyes])
 220
 221 if test x$enable_verbose_mode = xyes; then
 222     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 223 fi
 224
 225 if test x$enable_asserts = xno; then
 226     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 227     R_DYNAMIC_LDFLAG=""
 228 else
 229     # -rdynamic is needed for glibc's backtrace_symbols to work.
 230     # No clue how much overhead this adds, but it's useful
 231     # to do this on any assertion failure,
 232     # so for now it's enabled anytime asserts are (currently not
 233     # in production builds).
 234
 235     # To get -rdynamic you pass -export-dynamic to libtool.
 236     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 237     R_DYNAMIC_LDFLAG=-export-dynamic
 238 fi
 239 AC_SUBST(R_DYNAMIC_LDFLAG)
 240
 241 if test x$enable_checks = xno; then
 242     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 243     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 244 fi
 245
 246 if test x$enable_userdb_cache = xyes; then
 247     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 248 fi
 249
 250 if test x$enable_compiler_coverage = xyes; then
 251      ## so that config.h changes when you toggle gcov support
 252      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 253 fi
 254
 255 # glibc21.m4 serial 3
 256 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 257 dnl This file is free software; the Free Software Foundation
 258 dnl gives unlimited permission to copy and/or distribute it,
 259 dnl with or without modifications, as long as this notice is preserved.
 260
 261 # Test for the GNU C Library, version 2.1 or newer.
 262 # From Bruno Haible.
 263
 264 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 265   ac_cv_gnu_library_2_1,
 266   [AC_EGREP_CPP([Lucky GNU user],
 267     [
 268 #include <features.h>
 269 #ifdef __GNU_LIBRARY__
 270  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 271   Lucky GNU user
 272  #endif
 273 #endif
 274     ],
 275     ac_cv_gnu_library_2_1=yes,
 276     ac_cv_gnu_library_2_1=no)
 277   ]
 278 )
 279
 280 #### Integer sizes
 281
 282 AC_CHECK_SIZEOF(char)
 283 AC_CHECK_SIZEOF(short)
 284 AC_CHECK_SIZEOF(long)
 285 AC_CHECK_SIZEOF(int)
 286 AC_CHECK_SIZEOF(void *)
 287 AC_CHECK_SIZEOF(long long)
 288 AC_CHECK_SIZEOF(__int64)
 289
 290 AC_ARG_WITH([64-bit],
 291   [AS_HELP_STRING([--without-64-bit],
 292     [If you have to use this option, please report it as a bug])],
 293   [],
 294   [with_64_bit=yes])
 295
 296 ### See what our 64 bit type is called
 297 AC_MSG_CHECKING([64-bit integer type])
 298
 299 case 8 in
 300 $ac_cv_sizeof_int)
 301   dbusint64=int
 302   dbusint64_constant='(val)'
 303   dbusuint64_constant='(val)'
 304   dbusint64_printf_modifier='""'
 305   ;;
 306 $ac_cv_sizeof_long)
 307   dbusint64=long
 308   dbusint64_constant='(val##L)'
 309   dbusuint64_constant='(val##UL)'
 310   dbusint64_printf_modifier='"l"'
 311   ;;
 312 $ac_cv_sizeof_long_long)
 313   dbusint64='long long'
 314   dbusint64_constant='(val##LL)'
 315   dbusuint64_constant='(val##ULL)'
 316   # Ideally we discover what the format is, but this is
 317   # only used in verbose mode, so eh...
 318   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 319     dbusint64_printf_modifier='"ll"'
 320   fi
 321   ;;
 322 $ac_cv_sizeof___int64)
 323   dbusint64=__int64
 324   dbusint64_constant='(val##i64)'
 325   dbusuint64_constant='(val##ui64)'
 326   # See above case
 327   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 328     dbusint64_printf_modifier='"ll"'
 329   fi
 330   ;;
 331 esac
 332
 333 AS_IF(
 334   [test "x$with_64_bit" = xno],
 335   [
 336         DBUS_INT64_TYPE="no_int64_type_detected"
 337         DBUS_HAVE_INT64=0
 338         DBUS_INT64_CONSTANT=
 339         DBUS_UINT64_CONSTANT=
 340         AC_MSG_RESULT([disabled via --without-64-bit])
 341   ],
 342   dnl else if
 343   [test -z "$dbusint64"],
 344   [AC_MSG_RESULT([not found])
 345   AC_MSG_ERROR([Could not find a 64-bit integer type.
 346
 347 Please report a bug here with details of your platform and compiler:
 348
 349     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 350
 351 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 352 the option "--without-64-bit".
 353
 354 This option is likely to be removed in future, unless you report that your
 355 platform needs it.])
 356   ],
 357   dnl else
 358   [
 359         DBUS_INT64_TYPE="$dbusint64"
 360         DBUS_HAVE_INT64=1
 361         DBUS_INT64_CONSTANT="$dbusint64_constant"
 362         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 363         if test x"$dbusint64_printf_modifier" != x; then
 364                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 365         fi
 366         AC_MSG_RESULT($DBUS_INT64_TYPE)
 367   ])
 368
 369 AC_SUBST(DBUS_INT64_TYPE)
 370 AC_SUBST(DBUS_INT64_CONSTANT)
 371 AC_SUBST(DBUS_UINT64_CONSTANT)
 372 AC_SUBST(DBUS_HAVE_INT64)
 373
 374 ### see what 32-bit int is called
 375 AC_MSG_CHECKING([32-bit integer type])
 376
 377 case 4 in
 378 $ac_cv_sizeof_short)
 379   dbusint32=short
 380   ;;
 381 $ac_cv_sizeof_int)
 382   dbusint32=int
 383   ;;
 384 $ac_cv_sizeof_long)
 385   dbusint32=long
 386   ;;
 387 esac
 388
 389 if test -z "$dbusint32" ; then
 390         DBUS_INT32_TYPE="no_int32_type_detected"
 391         AC_MSG_ERROR([No 32-bit integer type found])
 392 else
 393         DBUS_INT32_TYPE="$dbusint32"
 394         AC_MSG_RESULT($DBUS_INT32_TYPE)
 395 fi
 396
 397 AC_SUBST(DBUS_INT32_TYPE)
 398
 399 ### see what 16-bit int is called
 400 AC_MSG_CHECKING([16-bit integer type])
 401
 402 case 2 in
 403 $ac_cv_sizeof_short)
 404   dbusint16=short
 405   ;;
 406 $ac_cv_sizeof_int)
 407   dbusint16=int
 408   ;;
 409 esac
 410
 411 if test -z "$dbusint16" ; then
 412         DBUS_INT16_TYPE="no_int16_type_detected"
 413         AC_MSG_ERROR([No 16-bit integer type found])
 414 else
 415         DBUS_INT16_TYPE="$dbusint16"
 416         AC_MSG_RESULT($DBUS_INT16_TYPE)
 417 fi
 418
 419 AC_SUBST(DBUS_INT16_TYPE)
 420
 421 ## byte order
 422 case $host_os in
 423         darwin*)
 424                 # check at compile-time, so that it is possible to build universal
 425                 # (with multiple architectures at once on the compile line)
 426                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 427                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 428                         #if defined(__BIG_ENDIAN__)
 429                         #define WORDS_BIGENDIAN 1
 430                         #endif
 431                 ])
 432                 ;;
 433         *)
 434                 AC_C_BIGENDIAN
 435                 ;;
 436 esac
 437
 438 dnl **********************************
 439 dnl *** va_copy checks (from GLib) ***
 440 dnl **********************************
 441 dnl we currently check for all three va_copy possibilities, so we get
 442 dnl all results in config.log for bug reports.
 443 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 444         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 445 #include <stdlib.h>
 446         static void f (int i, ...) {
 447         va_list args1, args2;
 448         va_start (args1, i);
 449         va_copy (args2, args1);
 450         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 451           exit (1);
 452         va_end (args1); va_end (args2);
 453         }
 454         int main() {
 455           f (0, 42);
 456           return 0;
 457         }])],
 458         [dbus_cv_va_copy=yes],
 459         [dbus_cv_va_copy=no])
 460 ])
 461 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 462         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 463 #include <stdlib.h>
 464         static void f (int i, ...) {
 465         va_list args1, args2;
 466         va_start (args1, i);
 467         __va_copy (args2, args1);
 468         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 469           exit (1);
 470         va_end (args1); va_end (args2);
 471         }
 472         int main() {
 473           f (0, 42);
 474           return 0;
 475         }])],
 476         [dbus_cv___va_copy=yes],
 477         [dbus_cv___va_copy=no])
 478 ])
 479
 480 if test "x$dbus_cv_va_copy" = "xyes"; then
 481   dbus_va_copy_func=va_copy
 482 else if test "x$dbus_cv___va_copy" = "xyes"; then
 483   dbus_va_copy_func=__va_copy
 484 fi
 485 fi
 486
 487 if test -n "$dbus_va_copy_func"; then
 488   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 489 fi
 490
 491 AC_LANG_PUSH(C)
 492 AC_CACHE_CHECK([whether va_lists can be copied by value],
 493         dbus_cv_va_val_copy,
 494         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 495 [[
 496         #include <stdarg.h>
 497         #include <stdlib.h>
 498 ]],
 499 [[
 500         static void f (int i, ...) {
 501         va_list args1, args2;
 502         va_start (args1, i);
 503         args2 = args1;
 504         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 505           exit (1);
 506         va_end (args1); va_end (args2);
 507         }
 508         int main() {
 509           f (0, 42);
 510           return 0;
 511         }
 512 ]])],
 513         [dbus_cv_va_val_copy=yes],
 514         [dbus_cv_va_val_copy=no],
 515         [dbus_cv_va_val_copy=yes])
 516 ])
 517 AC_LANG_POP(C)
 518
 519 if test "x$dbus_cv_va_val_copy" = "xno"; then
 520   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 521 fi
 522
 523
 524 #### Atomic integers
 525
 526 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 527   dbus_cv_sync_sub_and_fetch,
 528   [AC_LINK_IFELSE([
 529      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 530      [dbus_cv_sync_sub_and_fetch=yes],
 531      [dbus_cv_sync_sub_and_fetch=no])
 532   ])
 533
 534 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 535    have_sync=1
 536 else
 537    have_sync=0
 538 fi
 539
 540 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 541
 542 #### Various functions
 543 AC_SEARCH_LIBS(socket,[socket network])
 544 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 545
 546 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 547
 548 #### Check for broken poll; taken from Glib's configure
 549
 550 AC_MSG_CHECKING([for broken poll])
 551 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 552     #include <stdlib.h>
 553     #include <fcntl.h>
 554     #include <poll.h>
 555     #ifdef HAVE_SYS_POLL_H
 556     #include <sys/poll.h>
 557     #endif
 558     int main(void) {
 559       struct pollfd fds[1];
 560       int fd;
 561       fd = open("/dev/null", 1);
 562       fds[0].fd = fd;
 563       fds[0].events = POLLIN;
 564       fds[0].revents = 0;
 565       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 566             exit(1);  /* Does not work for devices -- fail */
 567       }
 568       exit(0);
 569     }]])],
 570   [broken_poll=no],
 571   [broken_poll=yes
 572    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 573   [broken_poll="no (cross compiling)"])
 574 AC_MSG_RESULT($broken_poll)
 575
 576 AC_MSG_CHECKING(for dirfd)
 577 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 578 #include <sys/types.h>
 579 #include <dirent.h>
 580 ]], [[
 581 DIR *dirp;
 582 dirp = opendir(".");
 583 dirfd(dirp);
 584 closedir(dirp);
 585 ]])],
 586 [dbus_have_dirfd=yes],
 587 [dbus_have_dirfd=no])
 588 AC_MSG_RESULT($dbus_have_dirfd)
 589 if test "$dbus_have_dirfd" = yes; then
 590         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 591 else
 592         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 593         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 594 #include <sys/types.h>
 595 #include <dirent.h>
 596         ]], [[
 597 DIR *dirp;
 598 int fd;
 599 dirp = opendir(".");
 600 fd = dirp->dd_fd;
 601 closedir(dirp);
 602         ]])],
 603         [dbus_have_ddfd=yes],
 604         [dbus_have_ddfd=no])
 605         AC_MSG_RESULT($dbus_have_ddfd)
 606         if test "$dbus_have_ddfd" = yes; then
 607                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 608         fi
 609 fi
 610
 611 AC_CHECK_HEADERS(sys/resource.h)
 612
 613 AC_CHECK_HEADERS(dirent.h)
 614
 615 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 616
 617 AC_CHECK_HEADERS(errno.h)
 618
 619 AC_CHECK_HEADERS(signal.h)
 620
 621 AC_CHECK_HEADERS(locale.h)
 622
 623 AC_CHECK_HEADERS(byteswap.h)
 624
 625 AC_CHECK_HEADERS(unistd.h)
 626
 627 AC_CHECK_HEADERS(ws2tcpip.h)
 628
 629 AC_CHECK_HEADERS(wspiapi.h)
 630
 631 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 632 #
 633 case $host_os in
 634     solaris*)
 635        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 636 esac
 637
 638 # checking for a posix version of getpwnam_r
 639 # if we are cross compiling and can not run the test
 640 # assume getpwnam_r is the posix version
 641 # it is up to the person cross compiling to change
 642 # this behavior if desired
 643 AC_LANG_PUSH(C)
 644 AC_CACHE_CHECK([for posix getpwnam_r],
 645                 ac_cv_func_posix_getpwnam_r,
 646                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 647 [[
 648 #include <errno.h>
 649 #include <pwd.h>
 650 ]],
 651 [[
 652     char buffer[10000];
 653     struct passwd pwd, *pwptr = &pwd;
 654     int error;
 655     errno = 0;
 656     error = getpwnam_r ("", &pwd, buffer,
 657                         sizeof (buffer), &pwptr);
 658    return (error < 0 && errno == ENOSYS)
 659            || error == ENOSYS;
 660 ]])],
 661         [ac_cv_func_posix_getpwnam_r=yes],
 662         [ac_cv_func_posix_getpwnam_r=no],
 663         [ac_cv_func_posix_getpwnam_r=yes]
 664 )])
 665 AC_LANG_POP(C)
 666
 667 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 668         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 669                 [Have POSIX function getpwnam_r])
 670 else
 671         AC_CACHE_CHECK([for nonposix getpwnam_r],
 672                 ac_cv_func_nonposix_getpwnam_r,
 673                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 674                         struct passwd pwd;
 675                         getpwnam_r ("", &pwd, buffer,
 676                                         sizeof (buffer));]])],
 677                         [ac_cv_func_nonposix_getpwnam_r=yes],
 678                         [ac_cv_func_nonposix_getpwnam_r=no])])
 679                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 680                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 681                         [Have non-POSIX function getpwnam_r])
 682         fi
 683 fi
 684
 685 dnl check for socklen_t
 686 AC_MSG_CHECKING(whether socklen_t is defined)
 687 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 688 #include <sys/types.h>
 689 #include <sys/socket.h>
 690 #include <netdb.h>
 691 ]], [[
 692 socklen_t foo;
 693 foo = 1;
 694 ]])],
 695 [dbus_have_socklen_t=yes],
 696 [dbus_have_socklen_t=no])
 697 AC_MSG_RESULT($dbus_have_socklen_t)
 698
 699 if test "x$dbus_have_socklen_t" = "xyes"; then
 700     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 701 fi
 702
 703 dnl check for writev header and writev function so we're
 704 dnl good to go if HAVE_WRITEV gets defined.
 705 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 706
 707 dnl needed on darwin for NAME_MAX
 708 AC_CHECK_HEADERS(sys/syslimits.h)
 709
 710 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 711 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 712
 713 dnl check for flavours of varargs macros (test from GLib)
 714 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 715 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 716 int a(int p1, int p2, int p3);
 717 #define call_a(...) a(1,__VA_ARGS__)
 718 call_a(2,3);
 719 ]])],
 720 [dbus_have_iso_c_varargs=yes],
 721 [dbus_have_iso_c_varargs=no])
 722 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 723
 724 AC_MSG_CHECKING(for GNUC varargs macros)
 725 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 726 int a(int p1, int p2, int p3);
 727 #define call_a(params...) a(1,params)
 728 call_a(2,3);
 729 ]])],
 730 [dbus_have_gnuc_varargs=yes],
 731 [dbus_have_gnuc_varargs=no])
 732 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 733
 734 dnl Output varargs tests
 735 if test x$dbus_have_iso_c_varargs = xyes; then
 736     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 737 fi
 738 if test x$dbus_have_gnuc_varargs = xyes; then
 739     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 740 fi
 741
 742 dnl Check for various credentials.
 743 AC_MSG_CHECKING(for struct cmsgcred)
 744 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 745 #include <sys/types.h>
 746 #include <sys/socket.h>
 747 ]], [[
 748 struct cmsgcred cred;
 749
 750 cred.cmcred_pid = 0;
 751 ]])],
 752 [dbus_have_struct_cmsgcred=yes],
 753 [dbus_have_struct_cmsgcred=no])
 754 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 755
 756 if test x$dbus_have_struct_cmsgcred = xyes; then
 757     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 758 fi
 759
 760 AC_CHECK_FUNCS(getpeerucred getpeereid)
 761
 762 AC_CHECK_FUNCS(pipe2 accept4)
 763
 764 #### Abstract sockets
 765
 766 if test x$enable_abstract_sockets = xauto; then
 767 AC_LANG_PUSH(C)
 768 warn_on_xcompile=no
 769 AC_CACHE_CHECK([abstract socket namespace],
 770                 ac_cv_have_abstract_sockets,
 771                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 772 [[
 773 #include <sys/types.h>
 774 #include <stdlib.h>
 775 #include <string.h>
 776 #include <stdio.h>
 777 #include <sys/socket.h>
 778 #include <sys/un.h>
 779 #include <errno.h>
 780 ]],
 781 [[
 782   size_t slen;
 783   int listen_fd;
 784   struct sockaddr_un addr;
 785
 786   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 787
 788   if (listen_fd < 0)
 789     {
 790       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 791       exit (1);
 792     }
 793
 794   memset (&addr, '\0', sizeof (addr));
 795   addr.sun_family = AF_UNIX;
 796   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 797   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 798    * beginning.
 799    */
 800   slen = SUN_LEN(&addr);
 801   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 802
 803   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 804     {
 805        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 806                 strerror (errno));
 807        exit (1);
 808     }
 809   else
 810     exit (0);
 811 ]])],
 812               [ac_cv_have_abstract_sockets=yes],
 813               [ac_cv_have_abstract_sockets=no],
 814               [
 815                 ac_cv_have_abstract_sockets=no
 816                 warn_on_xcompile=yes
 817               ]
 818 )])
 819 if test x$warn_on_xcompile = xyes ; then
 820   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 821 fi
 822 AC_LANG_POP(C)
 823 fi
 824
 825 if test x$enable_abstract_sockets = xyes; then
 826     if test x$ac_cv_have_abstract_sockets = xno; then
 827         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 828     fi
 829 fi
 830
 831 if test x$enable_abstract_sockets = xno; then
 832    ac_cv_have_abstract_sockets=no;
 833 fi
 834
 835 if test x$ac_cv_have_abstract_sockets = xyes ; then
 836    DBUS_PATH_OR_ABSTRACT=abstract
 837    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 838 else
 839    DBUS_PATH_OR_ABSTRACT=path
 840 fi
 841
 842 # this is used in addresses to prefer abstract, e.g.
 843 # unix:path=/foo or unix:abstract=/foo
 844 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 845
 846 PKG_PROG_PKG_CONFIG
 847
 848 #### Sort out XML library
 849
 850 # see what we have
 851 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 852              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 853              have_expat=false)
 854
 855 # see what we want to use
 856 dbus_use_libxml=false
 857 dbus_use_expat=false
 858 if test x$with_xml = xexpat; then
 859         if ! $have_expat ; then
 860            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 861         fi
 862         dbus_use_expat=true
 863 elif test x$with_xml = xlibxml; then
 864         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 865         if ! $have_libxml ; then
 866            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 867         fi
 868         dbus_use_libxml=true
 869 else
 870         ### expat is the default because libxml can't currently survive
 871         ### our brutal OOM-handling unit test setup.
 872         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 873         if test x$have_expat = xfalse; then
 874                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 875         fi
 876         ### By default, only use Expat since it's tested and known to work.  If you're a
 877         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 878         ### if your OS is built around libxml, that's another case.
 879         dbus_use_expat=true
 880 fi
 881
 882 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 883 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 884
 885 if $dbus_use_expat; then
 886    XML_LIBS=-lexpat
 887    XML_CFLAGS=
 888 fi
 889 if $dbus_use_libxml; then
 890    XML_LIBS=$LIBXML_LIBS
 891    XML_CFLAGS=$LIBXML_CFLAGS
 892 fi
 893
 894 # Thread lib detection
 895 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 896                                                     [THREAD_LIBS="-lpthread"])])
 897 save_libs="$LIBS"
 898 LIBS="$LIBS $THREAD_LIBS"
 899 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 900 if test x$have_pthread_condattr_setclock = xtrue; then
 901     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 902     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 903     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 904 #include <pthread.h>
 905 ]], [[
 906 struct timespec monotonic_timer;
 907 pthread_condattr_t attr;
 908 pthread_condattr_init (&attr);
 909 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 910 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 911 ]])],
 912 [have_clock_monotonic=true],
 913 [have_clock_monotonic=false])
 914 if test x$have_clock_monotonic = xtrue; then
 915     AC_MSG_RESULT([found])
 916     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 917 else
 918     AC_MSG_RESULT([not found])
 919 fi
 920 fi
 921 LIBS="$save_libs"
 922
 923 # SELinux detection
 924 if test x$enable_selinux = xno ; then
 925     have_selinux=no;
 926 else
 927     # See if we have SELinux library
 928     AC_CHECK_LIB(selinux, is_selinux_enabled,
 929                  have_selinux=yes, have_selinux=no)
 930
 931     # see if we have the SELinux header with the new D-Bus stuff in it
 932     if test x$have_selinux = xyes ; then
 933         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 934         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 935                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 936                             #else
 937                             #error DBUS__ACQUIRE_SVC not defined
 938                             #endif]])],
 939                           [have_selinux=yes],
 940                           [have_selinux=no])
 941         AC_MSG_RESULT($have_selinux)
 942     fi
 943
 944     if test x$enable_selinux = xauto ; then
 945         if test x$have_selinux = xno ; then
 946                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 947         fi
 948     else
 949         if test x$have_selinux = xno ; then
 950                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 951         fi
 952     fi
 953 fi
 954
 955 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 956
 957 if test x$have_selinux = xyes ; then
 958     # the selinux code creates threads
 959     # which requires libpthread even on linux
 960     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 961                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 962
 963     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
 964     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 965 else
 966     SELINUX_LIBS=
 967 fi
 968
 969 # inotify checks
 970 if test x$enable_inotify = xno ; then
 971     have_inotify=no;
 972 else
 973     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 974 fi
 975
 976 dnl check if inotify backend is enabled
 977 if test x$have_inotify = xyes; then
 978    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
 979    AC_CHECK_FUNCS(inotify_init1)
 980 fi
 981
 982 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
 983
 984 # dnotify checks
 985 if test x$enable_dnotify = xno ; then
 986     have_dnotify=no;
 987 else
 988     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
 989         have_dnotify=yes;
 990     else
 991         have_dnotify=no;
 992     fi
 993 fi
 994
 995 dnl check if dnotify backend is enabled
 996 if test x$have_dnotify = xyes; then
 997    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
 998 fi
 999
1000 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1001
1002 # kqueue checks
1003 if test x$enable_kqueue = xno ; then
1004     have_kqueue=no
1005 else
1006     have_kqueue=yes
1007     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1008     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1009
1010     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1011         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1012     fi
1013 fi
1014
1015 dnl check if kqueue backend is enabled
1016 if test x$have_kqueue = xyes; then
1017    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1018 fi
1019
1020 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1021
1022 # launchd checks
1023 if test x$enable_launchd = xno ; then
1024     have_launchd=no
1025 else
1026     have_launchd=yes
1027     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1028     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1029     if test "x$LAUNCHCTL" = "x"; then
1030         have_launchd=no
1031     fi
1032
1033     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1034         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1035     fi
1036 fi
1037
1038 dnl check if launchd is enabled
1039 if test x$have_launchd = xyes; then
1040     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1041 fi
1042
1043 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1044
1045 #### Directory to place launchd agent file
1046 if test "x$with_launchd_agent_dir" = "x"; then
1047    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1048 else
1049    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1050 fi
1051
1052 AC_SUBST(LAUNCHD_AGENT_DIR)
1053
1054 dnl console owner file
1055 if test x$enable_console_owner_file = xno ; then
1056     have_console_owner_file=no;
1057 else
1058     case $host_os in
1059     solaris*)
1060         have_console_owner_file=yes;
1061         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1062         ;;
1063     *)
1064         have_console_owner_file=no;;
1065     esac
1066 fi
1067
1068 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1069
1070 # libaudit detection
1071 if test x$enable_libaudit = xno ; then
1072     have_libaudit=no;
1073 else
1074     # See if we have audit daemon & capabilities library
1075     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1076                  have_libaudit=yes, have_libaudit=no)
1077     if test x$have_libaudit = xyes ; then
1078         AC_CHECK_LIB(cap-ng, capng_clear,
1079                  have_libaudit=yes, have_libaudit=no)
1080     fi
1081 fi
1082
1083 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1084
1085 if test x$have_libaudit = xyes ; then
1086     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1087     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1088 fi
1089
1090 # Check for ADT API
1091 AC_MSG_CHECKING(for ADT API)
1092 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1093 #include <bsm/adt.h>
1094 adt_user_context = ADT_USER;
1095 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1096
1097 if test ${check_adt_audit} = yes
1098 then
1099    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1100    ADT_LIBS="-lbsm"
1101    LIBS="-lbsm $LIBS"
1102    AC_MSG_RESULT(yes)
1103 else
1104    AC_MSG_RESULT(no)
1105 fi
1106
1107 # Check for SCM_RIGHTS
1108 AC_MSG_CHECKING([for SCM_RIGHTS])
1109 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1110 #include <sys/socket.h>
1111 #include <sys/un.h>
1112 static int x = SCM_RIGHTS;
1113 ]], [[]])],
1114 [ AC_MSG_RESULT([supported])
1115   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1116 [ AC_MSG_RESULT([not supported]) ])
1117
1118 NETWORK_libs=
1119 if test x$dbus_win = xyes ; then
1120   if test x$dbus_wince = xyes ; then
1121     NETWORK_libs="-lws2"
1122   else
1123     NETWORK_libs="-lws2_32"
1124   fi
1125 fi
1126
1127 #### Set up final flags
1128 DBUS_CLIENT_CFLAGS=
1129 DBUS_CLIENT_LIBS="$THREAD_LIBS $NETWORK_libs"
1130 AC_SUBST(DBUS_CLIENT_CFLAGS)
1131 AC_SUBST(DBUS_CLIENT_LIBS)
1132
1133 DBUS_BUS_CFLAGS="$XML_CFLAGS"
1134 DBUS_BUS_LIBS="$XML_LIBS $SELINUX_LIBS $THREAD_LIBS $ADT_LIBS $NETWORK_libs"
1135 AC_SUBST(DBUS_BUS_CFLAGS)
1136 AC_SUBST(DBUS_BUS_LIBS)
1137
1138 DBUS_LAUNCHER_CFLAGS="$XML_CFLAGS"
1139 DBUS_LAUNCHER_LIBS="$XML_LIBS $THREAD_LIBS $NETWORK_libs"
1140 AC_SUBST(DBUS_LAUNCHER_CFLAGS)
1141 AC_SUBST(DBUS_LAUNCHER_LIBS)
1142
1143 DBUS_TEST_CFLAGS=
1144 DBUS_TEST_LIBS="$THREAD_LIBS $NETWORK_libs"
1145 AC_SUBST(DBUS_TEST_CFLAGS)
1146 AC_SUBST(DBUS_TEST_LIBS)
1147
1148 ### X11 detection
1149 DBUS_X_LIBS=
1150 DBUS_X_CFLAGS=
1151
1152 AC_ARG_ENABLE([x11-autolaunch],
1153   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1154   [], [enable_x11_autolaunch=auto])
1155
1156 if test "x$dbus_win" = xyes; then
1157     if test "x$enable_x11_autolaunch" = xyes; then
1158         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1159     fi
1160
1161     enable_x11_autolaunch=no
1162     have_x11=no
1163 else
1164     AC_PATH_XTRA
1165
1166     if test "x$no_x" = xyes; then
1167         have_x11=no
1168     else
1169         have_x11=yes
1170         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1171         DBUS_X_CFLAGS="$X_CFLAGS"
1172     fi
1173 fi
1174
1175 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1176     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1177 else
1178     # move from "auto" to "yes" or "no" if necessary
1179     if test "x$enable_x11_autolaunch" != xno; then
1180         enable_x11_autolaunch="$have_x11"
1181     fi
1182 fi
1183
1184 if test "x$have_x11" = xyes ; then
1185    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1186 fi
1187
1188 if test "x$enable_x11_autolaunch" = xyes ; then
1189    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1190 fi
1191
1192 AC_SUBST([DBUS_X_CFLAGS])
1193 AC_SUBST([DBUS_X_LIBS])
1194
1195 #### gcc warning flags
1196
1197 cc_supports_flag() {
1198   AC_MSG_CHECKING(whether $CC supports "$*")
1199   save_CFLAGS="$CFLAGS"
1200   CFLAGS="$*"
1201   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1202   CFLAGS="$save_CFLAGS"
1203   AC_MSG_RESULT([$rc])
1204   test "x$rc" = xyes
1205 }
1206
1207 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1208   dnl Use -Werror by default if:
1209   dnl - we're not on Windows (too many warnings), and
1210   dnl - we're in maintainer mode (a D-Bus developer, not a distro or end-user)
1211   dnl Override with --enable-Werror or --disable-Werror
1212   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes],
1213
1214   dnl enable these warnings if possible:
1215   [all \
1216    char-subscripts \
1217    missing-declarations \
1218    missing-prototypes \
1219    nested-externs \
1220    pointer-arith \
1221    cast-align \
1222    no-address \
1223    float-equal \
1224    declaration-after-statement \
1225   ],
1226
1227   dnl disable these warnings if possible, make them non-fatal if possible,
1228   dnl and don't enable -Werror unless we succeeded:
1229   dnl (unused is by design, sign-compare and pointer-sign are fd.o #17433)
1230   [unused \
1231    sign-compare \
1232    pointer-sign \
1233   ])
1234
1235 if test "x$GCC" = "xyes"; then
1236   # We're treating -fno-common like a warning: it makes the linker more
1237   # strict, because on some systems the linker is *always* this strict
1238   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1239
1240   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1241   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1242
1243   if test "x$enable_ansi" = "xyes"; then
1244     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1245       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1246   fi
1247 fi
1248
1249 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1250 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1251 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1252 dnl is the next best thing
1253 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1254
1255 case $host_os in
1256     solaris*)
1257         # Solaris' C library apparently needs these runes to be threadsafe...
1258         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1259 esac
1260
1261 ### Doxygen Documentation
1262
1263 AC_PATH_PROG(DOXYGEN, doxygen, no)
1264
1265 AC_MSG_CHECKING([whether to build Doxygen documentation])
1266
1267 if test x$DOXYGEN = xno ; then
1268     have_doxygen=no
1269 else
1270     have_doxygen=yes
1271 fi
1272
1273 if test x$enable_doxygen_docs = xauto ; then
1274     if test x$have_doxygen = xno ; then
1275         enable_doxygen_docs=no
1276     else
1277         enable_doxygen_docs=yes
1278     fi
1279 fi
1280
1281 if test x$enable_doxygen_docs = xyes; then
1282     if test x$have_doxygen = xno; then
1283         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1284     fi
1285 fi
1286
1287 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1288 AC_MSG_RESULT($enable_doxygen_docs)
1289
1290 XSLTPROC=false
1291 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1292 AM_CONDITIONAL(DBUS_HAVE_XSLTPROC, test "$XSLTPROC" != false)
1293
1294 ### XML Documentation
1295
1296 AC_PATH_PROG(XMLTO, xmlto, no)
1297
1298 AC_MSG_CHECKING([whether to build XML documentation])
1299
1300 if test x$XMLTO = xno ; then
1301     have_xmlto=no
1302 else
1303     have_xmlto=yes
1304 fi
1305
1306 if test x$enable_xml_docs = xauto ; then
1307     if test x$have_xmlto = xno ; then
1308         enable_xml_docs=no
1309     else
1310         enable_xml_docs=yes
1311     fi
1312 fi
1313
1314 if test x$enable_xml_docs = xyes; then
1315     if test x$have_xmlto = xno; then
1316         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1317     fi
1318 fi
1319
1320 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1321 AC_MSG_RESULT($enable_xml_docs)
1322
1323 AC_PATH_PROG([MAN2HTML], [man2html])
1324 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1325 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1326
1327 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1328     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1329          x$MAN2HTML != x)
1330
1331 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1332
1333 #### find the actual value for $prefix that we'll end up with
1334 ##   (I know this is broken and should be done in the Makefile, but
1335 ##    that's a major pain and almost nobody actually seems to care)
1336 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1337 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1338 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1339 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1340 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1341 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1342 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1343
1344 #### Check our operating system
1345 operating_system=unknown
1346 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1347    operating_system=redhat
1348 fi
1349
1350 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1351    operating_system=slackware
1352 fi
1353
1354 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1355    operating_system=cygwin
1356 fi
1357
1358 #### Sort out init scripts
1359
1360 if test x$with_init_scripts = x; then
1361     case x$operating_system in
1362         xredhat)        with_init_scripts=redhat ;;
1363         xslackware)     with_init_scripts=slackware ;;
1364         xcygwin)        with_init_scripts=cygwin ;;
1365         *)                      with_init_scripts=none ;;
1366     esac
1367 fi
1368
1369 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1370 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1371 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1372
1373 ##### systemd unit files
1374 AC_ARG_WITH([systemdsystemunitdir],
1375 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1376         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
1377 if test "x$with_systemdsystemunitdir" != xno; then
1378    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1379 fi
1380 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1381
1382 ##### Set up location for system bus socket
1383 if ! test -z "$with_system_socket"; then
1384    DBUS_SYSTEM_SOCKET=$with_system_socket
1385 else
1386    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1387 fi
1388
1389 AC_SUBST(DBUS_SYSTEM_SOCKET)
1390 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1391
1392 ## system bus only listens on local domain sockets, and never
1393 ## on an abstract socket (so only root can create the socket)
1394 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1395 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1396 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1397
1398 #### Set up the pid file
1399 if ! test -z "$with_system_pid_file"; then
1400    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1401 elif test x$with_init_scripts = xredhat ; then
1402    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1403 else
1404    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1405 fi
1406
1407 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1408
1409 #### Directory to check for console ownership
1410 if ! test -z "$with_console_auth_dir"; then
1411    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1412 else
1413    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1414 fi
1415
1416 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1417 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1418
1419 #### File to check for console ownership
1420 if test x$have_console_owner_file = xyes; then
1421    if ! test -z "$with_console_owner_file"; then
1422       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1423    else
1424       DBUS_CONSOLE_OWNER_FILE=/dev/console
1425    fi
1426 else
1427   DBUS_CONSOLE_OWNER_FILE=
1428 fi
1429
1430 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1431 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1432
1433 #### User to start the system bus as
1434 if test -z "$with_dbus_user" ; then
1435     DBUS_USER=messagebus
1436 else
1437     DBUS_USER=$with_dbus_user
1438 fi
1439 AC_SUBST(DBUS_USER)
1440 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1441
1442 #### Prefix to install into
1443 DBUS_PREFIX=$EXPANDED_PREFIX
1444 AC_SUBST(DBUS_PREFIX)
1445 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1446
1447 #### Direcotry to install data files into
1448 DBUS_DATADIR=$EXPANDED_DATADIR
1449 AC_SUBST(DBUS_DATADIR)
1450 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1451
1452 #### Directory to install dbus-daemon
1453 if test -z "$with_dbus_daemondir" ; then
1454     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1455 else
1456     DBUS_DAEMONDIR=$with_dbus_daemondir
1457 fi
1458 AC_SUBST(DBUS_DAEMONDIR)
1459 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1460
1461 #### Directory to install the other binaries
1462 DBUS_BINDIR="$EXPANDED_BINDIR"
1463 AC_SUBST(DBUS_BINDIR)
1464 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1465
1466 #### Directory to install the libexec binaries
1467 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1468 AC_SUBST(DBUS_LIBEXECDIR)
1469 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1470
1471 #### Tell tests where to find certain stuff in builddir
1472
1473 DBUS_PWD=`pwd`
1474 # Useful in a cross-compilation environment, where the tests are run on the host system.
1475 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1476                            DBUS_PWD=$withval)
1477 AC_DEFUN([TEST_PATH], [
1478 TEST_$1=${DBUS_PWD}/test/$2
1479 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
1480                    [Full path to test file test/$2 in builddir])
1481 AC_SUBST(TEST_$1)
1482 ])
1483 AC_DEFUN([TEST_PROG], [
1484 TEST_$1=${DBUS_PWD}/test/$2
1485 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1$EXEEXT",
1486                    [Full path to test file test/$2 in builddir])
1487 AC_SUBST(TEST_$1)
1488 ])
1489
1490 TEST_PATH(VALID_SERVICE_DIR, data/valid-service-files)
1491 TEST_PATH(INVALID_SERVICE_DIR, data/invalid-service-files)
1492 TEST_PATH(VALID_SERVICE_SYSTEM_DIR, data/valid-service-files-system)
1493 TEST_PATH(INVALID_SERVICE_SYSTEM_DIR, data/invalid-service-files-system)
1494 TEST_PROG(SERVICE_BINARY, test-service)
1495 TEST_PROG(SHELL_SERVICE_BINARY, test-shell-service)
1496 TEST_PROG(EXIT_BINARY, test-exit)
1497 TEST_PROG(SEGFAULT_BINARY, test-segfault)
1498 TEST_PROG(SLEEP_FOREVER_BINARY, test-sleep-forever)
1499 TEST_PROG(PRIVSERVER_BINARY, name-test/test-privserver)
1500
1501 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, "$DBUS_PWD/bus/dbus-daemon$EXEEXT",
1502                    [Full path to the daemon in the builddir])
1503 AC_SUBST(TEST_BUS_BINARY)
1504
1505 ## Export the non-setuid external helper
1506 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1507 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1508 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1509                    [Full path to the launch helper test program in the builddir])
1510
1511 #### Find socket directories
1512 if ! test -z "$TMPDIR" ; then
1513    DEFAULT_SOCKET_DIR=$TMPDIR
1514 elif ! test -z "$TEMP" ; then
1515    DEFAULT_SOCKET_DIR=$TEMP
1516 elif ! test -z "$TMP" ; then
1517    DEFAULT_SOCKET_DIR=$TMP
1518 else
1519    DEFAULT_SOCKET_DIR=/tmp
1520 fi
1521
1522 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1523
1524 if ! test -z "$with_test_socket_dir" ; then
1525    TEST_SOCKET_DIR="$with_test_socket_dir"
1526 else
1527    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1528 fi
1529 AC_SUBST(TEST_SOCKET_DIR)
1530 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1531
1532 if ! test -z "$with_session_socket_dir" ; then
1533    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1534 else
1535    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1536 fi
1537 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1538 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1539
1540 if test x$dbus_win = xyes; then
1541         DBUS_SESSION_BUS_DEFAULT_ADDRESS="nonce-tcp:"
1542 elif test x$have_launchd = xyes; then
1543         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1544 else
1545         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1546 fi
1547 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1548
1549 # darwin needs this to initialize the environment
1550 AC_CHECK_HEADERS(crt_externs.h)
1551 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1552 AH_VERBATIM(_DARWIN_ENVIRON,
1553 [
1554 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1555 # include <sys/time.h>
1556 # include <crt_externs.h>
1557 # define environ (*_NSGetEnviron())
1558 #endif
1559 ])
1560
1561 AC_ARG_ENABLE([stats],
1562   [AS_HELP_STRING([--enable-stats],
1563     [enable bus daemon usage statistics])],
1564   [], [enable_stats=no])
1565 if test "x$enable_stats" = xyes; then
1566   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1567     [Define to enable bus daemon usage statistics])
1568 fi
1569
1570 AC_CONFIG_FILES([
1571 Doxyfile
1572 dbus/versioninfo.rc
1573 dbus/dbus-arch-deps.h
1574 bus/system.conf
1575 bus/session.conf
1576 bus/messagebus
1577 bus/messagebus-config
1578 bus/org.freedesktop.dbus-session.plist
1579 bus/rc.messagebus
1580 bus/dbus.service
1581 bus/dbus.socket
1582 Makefile
1583 dbus/Makefile
1584 bus/Makefile
1585 tools/Makefile
1586 test/Makefile
1587 test/name-test/Makefile
1588 doc/Makefile
1589 doc/dbus-daemon.1
1590 dbus-1.pc
1591 dbus-1-uninstalled.pc
1592 test/data/valid-config-files/debug-allow-all.conf
1593 test/data/valid-config-files/debug-allow-all-sha1.conf
1594 test/data/valid-config-files-system/debug-allow-all-pass.conf
1595 test/data/valid-config-files-system/debug-allow-all-fail.conf
1596 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1597 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1598 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1599 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1600 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1601 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1602 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1603 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1604 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1605 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1606 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1607 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1608 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1609 ])
1610 AC_OUTPUT
1611
1612 dnl ==========================================================================
1613 echo "
1614                     D-Bus $VERSION
1615                   ==============
1616
1617         prefix:                   ${EXPANDED_PREFIX}
1618         exec_prefix:              ${exec_prefix}
1619         libdir:                   ${EXPANDED_LIBDIR}
1620         libexecdir:               ${EXPANDED_LIBEXECDIR}
1621         bindir:                   ${EXPANDED_BINDIR}
1622         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1623         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1624         datadir:                  ${EXPANDED_DATADIR}
1625         source code location:     ${srcdir}
1626         compiler:                 ${CC}
1627         cflags:                   ${CFLAGS}
1628         cppflags:                 ${CPPFLAGS}
1629         cxxflags:                 ${CXXFLAGS}
1630         64-bit int:               ${DBUS_INT64_TYPE}
1631         32-bit int:               ${DBUS_INT32_TYPE}
1632         16-bit int:               ${DBUS_INT16_TYPE}
1633         Doxygen:                  ${DOXYGEN:-not found}
1634         xmlto:                    ${XMLTO:-not found}
1635         man2html:                 ${MAN2HTML:-not found}"
1636
1637 echo "
1638         Maintainer mode:          ${USE_MAINTAINER_MODE}
1639         gcc coverage profiling:   ${enable_compiler_coverage}
1640         Building embedded tests:  ${enable_embedded_tests}
1641         Building modular tests:   ${enable_modular_tests}
1642         Building verbose mode:    ${enable_verbose_mode}
1643         Building assertions:      ${enable_asserts}
1644         Building checks:          ${enable_checks}
1645         Building bus stats API:   ${enable_stats}
1646         Building SELinux support: ${have_selinux}
1647         Building inotify support: ${have_inotify}
1648         Building dnotify support: ${have_dnotify}
1649         Building kqueue support:  ${have_kqueue}
1650         Building X11 code:        ${enable_x11}
1651         Building Doxygen docs:    ${enable_doxygen_docs}
1652         Building XML docs:        ${enable_xml_docs}
1653         Building cache support:   ${enable_userdb_cache}
1654         Building launchd support: ${have_launchd}
1655         Using XML parser:         ${with_xml}
1656         Init scripts style:       ${with_init_scripts}
1657         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1658         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1659         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1660         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1661         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1662         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1663         Console owner file:       ${have_console_owner_file}
1664         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1665         System bus user:          ${DBUS_USER}
1666         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1667         'make check' socket dir:  ${TEST_SOCKET_DIR}
1668 "
1669 if test x$have_launchd = xyes; then
1670         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1671 fi
1672 echo
1673
1674 if test x$enable_embedded_tests = xyes; then
1675         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1676 fi
1677 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1678         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1679 fi
1680 if test x$enable_compiler_coverage = xyes; then
1681         echo "NOTE: building with coverage profiling is definitely for developers only."
1682 fi
1683 if test x$enable_verbose_mode = xyes; then
1684         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1685 fi
1686 if test x$enable_asserts = xyes; then
1687         echo "NOTE: building with assertions increases library size and decreases performance."
1688 fi
1689 if test x$enable_checks = xno; then
1690         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1691 fi
1692 if test x$dbus_use_libxml = xtrue; then
1693         echo
1694         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1695 fi
1696
1697 if test "x$DBUS_HAVE_INT64" = x0; then
1698   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1699
1700   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1701   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1702   used if your compiler lacks support for 64-bit integers. Please report a bug
1703   with details of your platform and compiler.
1704
1705   This option is likely to be removed in future, unless the D-Bus developers
1706   receive reports that it is still needed.
1707   ])
1708 fi