configure.ac

   1 ## Process this file with autoconf to produce configure.
   2 ## In general, the safest way to proceed is to run the following:
   3 ##    % aclocal -I . -I `pwd`/../autoconf && autoheader && autoconf && automake
   4
   5 # make sure we're interpreted by some minimal autoconf
   6 AC_PREREQ(2.57)
   7
   8 AC_INIT(glog, 0.3.0, opensource@google.com)
   9 # The argument here is just something that should be in the current directory
  10 # (for sanity checking)
  11 AC_CONFIG_SRCDIR(README)
  12 AM_INIT_AUTOMAKE
  13 AM_CONFIG_HEADER(src/config.h)
  14
  15 AC_LANG(C++)
  16
  17 # Checks for programs.
  18 AC_PROG_CC
  19 AC_PROG_CPP
  20 AC_PROG_CXX
  21 AM_CONDITIONAL(GCC, test "$GCC" = yes)   # let the Makefile know if we're gcc
  22
  23 AC_PROG_LIBTOOL
  24 AC_SUBST(LIBTOOL_DEPS)
  25
  26 # Check whether some low-level functions/files are available
  27 AC_HEADER_STDC
  28
  29 # These are tested for by AC_HEADER_STDC, but I check again to set the var
  30 AC_CHECK_HEADER(stdint.h, ac_cv_have_stdint_h=1, ac_cv_have_stdint_h=0)
  31 AC_CHECK_HEADER(sys/types.h, ac_cv_have_systypes_h=1, ac_cv_have_systypes_h=0)
  32 AC_CHECK_HEADER(inttypes.h, ac_cv_have_inttypes_h=1, ac_cv_have_inttypes_h=0)
  33 AC_CHECK_HEADERS(unistd.h, ac_cv_have_unistd_h=1, ac_cv_have_unistd_h=0)
  34 AC_CHECK_HEADERS(syscall.h)
  35 AC_CHECK_HEADERS(sys/syscall.h)
  36 # For backtrace with glibc.
  37 AC_CHECK_HEADERS(execinfo.h)
  38 # For backtrace with libunwind.
  39 AC_CHECK_HEADERS(libunwind.h)
  40 AC_CHECK_HEADERS(ucontext.h)
  41 AC_CHECK_HEADERS(sys/utsname.h)
  42 AC_CHECK_HEADERS(pwd.h)
  43 AC_CHECK_HEADERS(syslog.h)
  44 AC_CHECK_HEADERS(sys/time.h)
  45 AC_CHECK_HEADERS(glob.h)
  46
  47 AC_CHECK_SIZEOF(void *)
  48
  49 # These are the types I need.  We look for them in either stdint.h,
  50 # sys/types.h, or inttypes.h, all of which are part of the default-includes.
  51 AC_CHECK_TYPE(uint16_t, ac_cv_have_uint16_t=1, ac_cv_have_uint16_t=0)
  52 AC_CHECK_TYPE(u_int16_t, ac_cv_have_u_int16_t=1, ac_cv_have_u_int16_t=0)
  53 AC_CHECK_TYPE(__uint16, ac_cv_have___uint16=1, ac_cv_have___uint16=0)
  54
  55 AC_CHECK_FUNC(sigaltstack,
  56               AC_DEFINE(HAVE_SIGALTSTACK, 1,
  57                         [Define if you have the `sigaltstack' function]))
  58 AC_CHECK_FUNC(dladdr,
  59               AC_DEFINE(HAVE_DLADDR, 1,
  60                         [Define if you have the `dladdr' function]))
  61 AC_CHECK_FUNC(fcntl,
  62               AC_DEFINE(HAVE_FCNTL, 1,
  63                         [Define if you have the `fcntl' function]))
  64
  65 AX_C___ATTRIBUTE__
  66 # We only care about these two attributes.
  67 if test x"$ac_cv___attribute__" = x"yes"; then
  68   ac_cv___attribute___noreturn="__attribute__ ((noreturn))"
  69   ac_cv___attribute___printf_4_5="__attribute__((__format__ (__printf__, 4, 5)))"
  70 else
  71   ac_cv___attribute___noreturn=
  72   ac_cv___attribute___printf_4_5=
  73 fi
  74
  75 AX_C___BUILTIN_EXPECT
  76 if test x"$ac_cv___builtin_expect" = x"yes"; then
  77   ac_cv_have___builtin_expect=1
  78 else
  79   ac_cv_have___builtin_expect=0
  80 fi
  81
  82 AX_C___SYNC_VAL_COMPARE_AND_SWAP
  83
  84 # On x86_64, instead of libunwind, we can choose to compile with frame-pointers
  85 # (This isn't needed on i386, where -fno-omit-frame-pointer is the default).
  86 AC_ARG_ENABLE(frame_pointers,
  87               AS_HELP_STRING([--enable-frame-pointers],
  88                              [On x86_64 systems, compile with -fno-omit-frame-pointer (see INSTALL)]),,
  89               enable_frame_pointers=no)
  90 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [return __x86_64__ == 1 ? 0 : 1])],
  91                   [is_x86_64=yes], [is_x86_64=no])
  92 AM_CONDITIONAL(ENABLE_FRAME_POINTERS, test "$enable_frame_pointers" = yes)
  93 AM_CONDITIONAL(X86_64, test "$is_x86_64" = yes)
  94
  95 # Some of the code in this directory depends on pthreads
  96 ACX_PTHREAD
  97 if test x"$acx_pthread_ok" = x"yes"; then
  98   # To make libglog depend on libpthread on Linux, we need to add
  99   # -lpthread in addition to -pthread.
 100   AC_CHECK_LIB(pthread, pthread_self)
 101 fi
 102
 103 # Check if there is google-gflags library installed.
 104 SAVE_CFLAGS="$CFLAGS"
 105 SAVE_LIBS="$LIBS"
 106 AC_ARG_WITH(gflags, AS_HELP_STRING[--with-gflags=GFLAGS_DIR],
 107   GFLAGS_CFLAGS="-I${with_gflags}/include"
 108   GFLAGS_LIBS="-L${with_gflags}/lib -lgflags"
 109   CFLAGS="$CFLAGS $GFLAGS_CFLAGS"
 110   LIBS="$LIBS $GFLAGS_LIBS"
 111 )
 112 AC_CHECK_LIB(gflags, main, ac_cv_have_libgflags=1, ac_cv_have_libgflags=0)
 113 if test x"$ac_cv_have_libgflags" = x"1"; then
 114   AC_DEFINE(HAVE_LIB_GFLAGS, 1, [define if you have google gflags library])
 115   if test x"$GFLAGS_LIBS" = x""; then
 116     GFLAGS_LIBS="-lgflags"
 117   fi
 118 else
 119   GFLAGS_CFLAGS=
 120   GFLAGS_LIBS=
 121 fi
 122 CFLAGS="$SAVE_CFLAGS"
 123 LIBS="$SAVE_LIBS"
 124
 125 # TODO(hamaji): Use official m4 macros provided by testing libraries
 126 #               once the m4 macro of Google Mocking becomes ready.
 127 # Check if there is Google Test library installed.
 128 AC_CHECK_PROG(GTEST_CONFIG, gtest-config, "yes")
 129 if test x"$GTEST_CONFIG" = "xyes"; then
 130   GTEST_CFLAGS=`gtest-config --cppflags --cxxflags`
 131   GTEST_LIBS=`gtest-config --ldflags --libs`
 132   AC_DEFINE(HAVE_LIB_GTEST, 1, [define if you have google gtest library])
 133
 134   # Check if there is Google Mocking library installed.
 135   AC_CHECK_PROG(GMOCK_CONFIG, gmock-config, "yes")
 136   if test x"$GMOCK_CONFIG" = "xyes"; then
 137     GMOCK_CFLAGS=`gmock-config --cppflags --cxxflags`
 138     GMOCK_LIBS=`gmock-config --ldflags --libs`
 139     AC_DEFINE(HAVE_LIB_GMOCK, 1, [define if you have google gmock library])
 140   else
 141     # We don't run test cases which use Google Mocking framework.
 142     GMOCK_CFLAGS=
 143     GMOCK_LIBS=
 144   fi
 145 else
 146   # We'll use src/googletest.h for our unittests.
 147   GTEST_CFLAGS=
 148   GTEST_LIBS=
 149 fi
 150 AM_CONDITIONAL(HAVE_GMOCK, test x"$GMOCK_CONFIG" = "xyes")
 151
 152 # We want to link in libunwind if it exists
 153 UNWIND_LIBS=
 154 # Unfortunately, we need to check the header file in addition to the
 155 # lib file to check if libunwind is available since libunwind-0.98
 156 # doesn't install all necessary header files.
 157 if test x"$ac_cv_have_libunwind_h" = x"1"; then
 158  AC_CHECK_LIB(unwind, backtrace, UNWIND_LIBS=-lunwind)
 159 fi
 160 AC_SUBST(UNWIND_LIBS)
 161 if test x"$UNWIND_LIBS" != x""; then
 162   AC_DEFINE(HAVE_LIB_UNWIND, 1, [define if you have libunwind])
 163 fi
 164
 165 # We'd like to use read/write locks in several places in the code.
 166 # See if our pthreads support extends to that.  Note: for linux, it
 167 # does as long as you define _XOPEN_SOURCE appropriately.
 168 AC_RWLOCK
 169
 170 # Find out what namespace 'normal' STL code lives in, and also what namespace
 171 # the user wants our classes to be defined in
 172 AC_CXX_STL_NAMESPACE
 173 AC_DEFINE_GOOGLE_NAMESPACE(google)
 174
 175 AC_CXX_USING_OPERATOR
 176
 177 AC_PC_FROM_UCONTEXT(AC_MSG_WARN(Could not find the PC.  Will not output failed addresses...))
 178
 179 # These are what's needed by logging.h.in and raw_logging.h.in
 180 AC_SUBST(ac_google_start_namespace)
 181 AC_SUBST(ac_google_end_namespace)
 182 AC_SUBST(ac_google_namespace)
 183 AC_SUBST(ac_cv_cxx_using_operator)
 184 AC_SUBST(ac_cv___attribute___noreturn)
 185 AC_SUBST(ac_cv___attribute___printf_4_5)
 186 AC_SUBST(ac_cv_have___builtin_expect)
 187 AC_SUBST(ac_cv_have_stdint_h)
 188 AC_SUBST(ac_cv_have_systypes_h)
 189 AC_SUBST(ac_cv_have_inttypes_h)
 190 AC_SUBST(ac_cv_have_unistd_h)
 191 AC_SUBST(ac_cv_have_uint16_t)
 192 AC_SUBST(ac_cv_have_u_int16_t)
 193 AC_SUBST(ac_cv_have___uint16)
 194 AC_SUBST(ac_cv_have_libgflags)
 195 AC_SUBST(GFLAGS_CFLAGS)
 196 AC_SUBST(GTEST_CFLAGS)
 197 AC_SUBST(GMOCK_CFLAGS)
 198 AC_SUBST(GFLAGS_LIBS)
 199 AC_SUBST(GTEST_LIBS)
 200 AC_SUBST(GMOCK_LIBS)
 201
 202 # Write generated configuration file
 203 AC_CONFIG_FILES([Makefile src/glog/logging.h src/glog/raw_logging.h src/glog/vlog_is_on.h src/glog/stl_logging.h])
 204 AC_OUTPUT(libglog.pc)