configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.8.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.19.1
  51 GSTPB_REQ=0.10.19.1
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.11.5])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 120 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 121
 122 dnl check for gconftool-2
 123 dnl this macro defines an am conditional, so it needs to be run always
 124 AM_GCONF_SOURCE_2
 125
 126 dnl check for documentation tools
 127 GTK_DOC_CHECK([1.3])
 128 AS_PATH_PYTHON([2.1])
 129 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 AC_CHECK_LIBM
 135 AC_SUBST(LIBM)
 136
 137 dnl *** checks for header files ***
 138
 139 dnl check if we have ANSI C header files
 140 AC_HEADER_STDC
 141
 142 dnl used by ext/wavpack
 143 AX_CREATE_STDINT_H
 144
 145 dnl used in gst/rtp/gstasteriskh263.c
 146 AC_CHECK_HEADERS([netinet/in.h])
 147 AC_CHECK_HEADERS([winsock2.h])
 148 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 149
 150 dnl used in gst/udp
 151 AC_CHECK_HEADERS([sys/time.h])
 152
 153 dnl *** checks for types/defines ***
 154
 155 dnl Check for FIONREAD ioctl declaration.  This check is needed
 156 dnl for the UDP plugin to build on Solaris
 157 GST_CHECK_FIONREAD
 158
 159 dnl *** checks for structures ***
 160
 161 dnl *** checks for compiler characteristics ***
 162
 163 dnl check if we have GCC inline-asm
 164 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 165 if test x$HAVE_GCC_ASM = xyes ; then
 166   AC_DEFINE(HAVE_GCC_ASM, 1,
 167     [Define if compiler supports gcc inline assembly])
 168 fi
 169 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 170
 171 dnl *** checks for library functions ***
 172
 173 LIBS_SAVE=$LIBS
 174 LIBS="$LIBS $LIBM"
 175 AC_CHECK_FUNCS(rint sinh cosh asinh)
 176 LIBS=$LIBS_SAVE
 177
 178 dnl Check for mmap (needed by electricfence plugin)
 179 AC_FUNC_MMAP
 180 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 181
 182 dnl *** checks for dependency libraries ***
 183
 184 dnl GLib is required
 185 AG_GST_GLIB_CHECK([2.12])
 186
 187 dnl liboil is required
 188 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 189 if test "x$HAVE_LIBOIL" != "xyes"; then
 190   AC_ERROR([liboil-0.3.8 or later is required])
 191 fi
 192
 193 dnl checks for gstreamer
 194 dnl uninstalled is selected preferentially -- see pkg-config(1)
 195 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 196 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 197 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 198 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 199 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 200 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 201
 202 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 203 if test -z $GST_TOOLS_DIR; then
 204   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 205 fi
 206 AC_SUBST(GST_TOOLS_DIR)
 207
 208 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 209 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 210
 211 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 212
 213 dnl Check for documentation xrefs
 214 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 215 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 216 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 217 AC_SUBST(GLIB_PREFIX)
 218 AC_SUBST(GST_PREFIX)
 219 AC_SUBST(GSTPB_PREFIX)
 220
 221 dnl GTK is optional and used in examples
 222 HAVE_GTK=NO
 223 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 224 if test "x$HAVE_GTK_22" = "xyes"; then
 225   HAVE_GTK=yes
 226   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 227   AC_SUBST(GTK_VERSION)
 228   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 229   AC_SUBST(GTK_BASE_DIR)
 230   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 231   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 232   AC_SUBST(GTK_BASE_DIR)
 233 else
 234   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 235 fi
 236 if test "x$HAVE_GTK_20" = "xyes"; then
 237   HAVE_GTK=yes
 238 fi
 239 GTK_CFLAGS=$GTK2_CFLAGS
 240 GTK_LIBS=$GTK2_LIBS
 241 AC_SUBST(GTK_LIBS)
 242 AC_SUBST(GTK_CFLAGS)
 243 AC_SUBST(HAVE_GTK)
 244 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 245
 246 dnl should we install schemas ?
 247 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 248 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 249   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 250   if test x$GCONFTOOL = xno; then
 251     AC_MSG_WARN(Not installing GConf schemas)
 252     HAVE_GCONFTOOL="no"
 253   else
 254     HAVE_GCONFTOOL="yes"
 255   fi
 256   AC_SUBST(HAVE_GCONFTOOL)
 257 ])
 258
 259 dnl *** set variables based on configure arguments ***
 260
 261 dnl set license and copyright notice
 262 GST_LICENSE="LGPL"
 263 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 264 AC_SUBST(GST_LICENSE)
 265
 266 dnl set location of plugin directory
 267 AG_GST_SET_PLUGINDIR
 268
 269 dnl define an ERROR_CFLAGS Makefile variable
 270 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 271
 272 dnl define an ERROR_CXXFLAGS Makefile variable
 273 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 274
 275 dnl define correct level for debugging messages
 276 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 277
 278 dnl used in examples
 279 AG_GST_DEFAULT_ELEMENTS
 280
 281 dnl *** plug-ins to include ***
 282
 283 dnl these are all the gst plug-ins, compilable without additional libs
 284 dnl videofilter is at the top because others depend on it
 285 AG_GST_CHECK_PLUGIN(videofilter)
 286 AG_GST_CHECK_PLUGIN(alpha)
 287 AG_GST_CHECK_PLUGIN(apetag)
 288 AG_GST_CHECK_PLUGIN(audiofx)
 289 AG_GST_CHECK_PLUGIN(auparse)
 290 AG_GST_CHECK_PLUGIN(autodetect)
 291 AG_GST_CHECK_PLUGIN(avi)
 292 AG_GST_CHECK_PLUGIN(cutter)
 293 AG_GST_CHECK_PLUGIN(debug)
 294 AG_GST_CHECK_PLUGIN(effectv)
 295 AG_GST_CHECK_PLUGIN(equalizer)
 296 AG_GST_CHECK_PLUGIN(id3demux)
 297 AG_GST_CHECK_PLUGIN(icydemux)
 298 AG_GST_CHECK_PLUGIN(flx)
 299 AG_GST_CHECK_PLUGIN(goom)
 300 AG_GST_CHECK_PLUGIN(goom2k1)
 301 AG_GST_CHECK_PLUGIN(law)
 302 AG_GST_CHECK_PLUGIN(level)
 303 AG_GST_CHECK_PLUGIN(matroska)
 304 AG_GST_CHECK_PLUGIN(monoscope)
 305 AG_GST_CHECK_PLUGIN(multifile)
 306 AG_GST_CHECK_PLUGIN(multipart)
 307 AG_GST_CHECK_PLUGIN(qtdemux)
 308 AG_GST_CHECK_PLUGIN(rtp)
 309 AG_GST_CHECK_PLUGIN(rtsp)
 310 AG_GST_CHECK_PLUGIN(smpte)
 311 AG_GST_CHECK_PLUGIN(spectrum)
 312 AG_GST_CHECK_PLUGIN(udp)
 313 AG_GST_CHECK_PLUGIN(videobox)
 314 AG_GST_CHECK_PLUGIN(videocrop)
 315 AG_GST_CHECK_PLUGIN(videomixer)
 316 AG_GST_CHECK_PLUGIN(wavenc)
 317 AG_GST_CHECK_PLUGIN(wavparse)
 318
 319 dnl disable gst plugins we might not be able to build on this
 320 dnl platform: udp and rtsp (ugly but minimally invasive)
 321 dnl FIXME: maybe move to sys
 322 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 323 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 324
 325 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 326   AG_GST_DISABLE_PLUGIN(udp)
 327   AG_GST_DISABLE_PLUGIN(rtsp)
 328 fi
 329
 330 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 331   WIN32_LIBS="-lws2_32"
 332   AC_SUBST(WIN32_LIBS)
 333 fi
 334
 335 dnl disable experimental plug-ins
 336 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 337   AG_GST_DISABLE_PLUGIN(monoscope)
 338 fi
 339
 340 dnl *** sys plug-ins ***
 341
 342 echo
 343 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 344 echo
 345
 346 dnl DirectDraw
 347 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 348 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 349   HAVE_DIRECTDRAW="no"
 350   save_CFLAGS="$CFLAGS"
 351   save_LDFLAGS="$LDFLAGS"
 352   save_LIBS="$LIBS"
 353   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 354   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 355   LIBS="$LIBS -lddraw -lgdi32"
 356   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 357   AC_LINK_IFELSE([
 358 #include <windows.h>
 359 #include <ddraw.h>
 360
 361 int main ()
 362 {
 363   GetStockObject(0);
 364   DirectDrawCreate(NULL, NULL, NULL);
 365
 366   return 0;
 367 }
 368 ],
 369     [HAVE_DIRECTDRAW="yes"],
 370     [HAVE_DIRECTDRAW="no"])
 371   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 372   CFLAGS=$save_CFLAGS
 373   LDFLAGS=$save_LDFLAGS
 374   LIBS=$save_LIBS
 375
 376   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 377     dnl this is much more than we want
 378     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 379     AC_SUBST(DIRECTDRAW_CFLAGS)
 380     AC_SUBST(DIRECTDRAW_LDFLAGS)
 381     AC_SUBST(DIRECTDRAW_LIBS)
 382   fi
 383   AC_SUBST(HAVE_DIRECTDRAW)
 384 ])
 385
 386 dnl DirectSound
 387 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 388 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 389   HAVE_DIRECTSOUND="no"
 390   save_CFLAGS="$CFLAGS"
 391   save_LDFLAGS="$LDFLAGS"
 392   save_LIBS="$LIBS"
 393   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 394   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 395   LIBS="$LIBS -ldsound -ldxerr9"
 396   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 397   AC_LINK_IFELSE([
 398 #include <windows.h>
 399 #include <dxerr9.h>
 400 #include <dsound.h>
 401
 402 int main ()
 403 {
 404   DXGetErrorString9 (0);
 405   DirectSoundCreate(NULL, NULL, NULL);
 406
 407   return 0;
 408 }
 409 ],
 410     [HAVE_DIRECTSOUND="yes"],
 411     [HAVE_DIRECTSOUND="no"])
 412   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 413   CFLAGS=$save_CFLAGS
 414   LDFLAGS=$save_LDFLAGS
 415   LIBS=$save_LIBS
 416
 417   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 418     dnl this is much more than we want
 419     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 420     AC_SUBST(DIRECTSOUND_CFLAGS)
 421     AC_SUBST(DIRECTSOUND_LDFLAGS)
 422     AC_SUBST(DIRECTSOUND_LIBS)
 423   fi
 424   AC_SUBST(HAVE_DIRECTSOUND)
 425 ])
 426
 427 dnl *** OSS audio *** (Linux, *BSD)
 428 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 429 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 430  HAVE_OSS="yes"
 431 dnl Linux and newer BSD versions :
 432  AC_CHECK_HEADER(sys/soundcard.h, [
 433    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 434    ] , [
 435 dnl Some old BSD versions and also newer OpenBSD versions :
 436    AC_CHECK_HEADER(soundcard.h, [
 437      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 438      ], [
 439   dnl Some old BSD versions :
 440      AC_CHECK_HEADER(machine/soundcard.h, [
 441        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 442          [Define if OSS includes are in /machine/])
 443        ], [
 444        HAVE_OSS="no"
 445      ])
 446    ])
 447  ])
 448 ])
 449
 450 dnl *** Sun Audio ***
 451 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 452 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 453   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 454 ])
 455
 456 dnl *** OSX Audio ***
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 458 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 459   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 460 ])
 461
 462 dnl *** OS X video ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 464 HAVE_OSX_VIDEO="no"
 465 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 466   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 467 ])
 468 dnl in case header OpenGL/gl.h is found on other platforms
 469 case "$host" in
 470   *-*darwin*)
 471     dnl do nothing
 472     ;;
 473   *)
 474     HAVE_OSX_VIDEO="no"
 475     ;;
 476 esac
 477
 478
 479 dnl *** Video 4 Linux 2 ***
 480 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 481 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 482 USE_GST_V4L2=$BUILD_EXPERIMENTAL
 483 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 484 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 485   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 486   AC_TRY_COMPILE([
 487 #include <sys/types.h>
 488 #ifdef __sun /* Solaris */
 489 #include <sys/types.h>
 490 #include <sys/videodev2.h>
 491 #else /* Linux */
 492 #include <linux/types.h>
 493 #define _LINUX_TIME_H
 494 #define __user
 495 #include <linux/videodev2.h>
 496 #endif
 497 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 498 #error too early v4l2 version or no v4l2 at all
 499 #endif
 500     ], [
 501 return 0;
 502     ], [
 503       HAVE_GST_V4L2="yes"
 504       AC_MSG_RESULT(yes)
 505     ], [
 506       HAVE_GST_V4L2="no"
 507       AC_MSG_RESULT(no)
 508
 509       HAVE_VIDEODEV=no
 510       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 511       [
 512         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 513       ])
 514
 515       if test "x$HAVE_VIDEODEV" = "xyes"; then
 516         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 517         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 518       else
 519         AC_MSG_WARN([video4linux2 was not found])
 520       fi
 521     ])
 522
 523   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 524     dnl check for missing v4l2_buffer declaration (see #135919)
 525     MISSING_DECL=0
 526     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 527     AC_TRY_COMPILE([
 528 #include <sys/types.h>
 529 #ifdef __sun /* Solaris */
 530 #include <sys/types.h>
 531 #include <sys/videodev2.h>
 532 #else /* Linux */
 533 #include <linux/types.h>
 534 #define _LINUX_TIME_H
 535 #define __user
 536 #include <linux/videodev2.h>
 537 #endif
 538     ],[
 539 struct v4l2_buffer buf;
 540 buf.index = 0;
 541 return 0;
 542     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 543     if [ test x$MISSING_DECL = x1 ]; then
 544       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 545     fi
 546
 547     dnl check for XOverlay libraries
 548     AG_GST_CHECK_XV
 549   fi
 550 ])
 551
 552 dnl Check for X11
 553 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 554 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 555                   [ximagesrc], [
 556   AC_PATH_XTRA
 557
 558   dnl now try to find the HEADER
 559   ac_cflags_save="$CFLAGS"
 560   ac_cppflags_save="$CPPFLAGS"
 561   CFLAGS="$CFLAGS $X_CFLAGS"
 562   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 563   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 564
 565   if test "x$HAVE_X" = "xno"
 566   then
 567     AC_MSG_NOTICE([cannot find X11 development files])
 568   else
 569     dnl this is much more than we want
 570     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 571     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 572     dnl it does not add the libs; therefore we add them here
 573     X_LIBS="$X_LIBS -lX11"
 574     AC_SUBST(X_CFLAGS)
 575     AC_SUBST(X_LIBS)
 576
 577     dnl check for Xfixes
 578     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 579     if test "x$HAVE_XFIXES" = "xyes"
 580     then
 581         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 582     fi
 583     AC_SUBST(XFIXES_LIBS)
 584     AC_SUBST(XFIXES_CFLAGS)
 585
 586     dnl check for Xdamage
 587     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 588     if test "x$HAVE_XDAMAGE" = "xyes"
 589     then
 590         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 591     fi
 592     AC_SUBST(XDAMAGE_LIBS)
 593     AC_SUBST(XDAMAGE_CFLAGS)
 594   fi
 595   AC_SUBST(HAVE_X)
 596   CFLAGS="$ac_cflags_save"
 597   CPPFLAGS="$ac_cppflags_save"
 598 ])
 599
 600 dnl FIXME: this should be rolled into the test above, it's just an additional
 601 dnl feature of the ximagesrc plug-in
 602 dnl This is the same as in gst-plugins-base
 603 dnl check for X Shm
 604 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 605 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 606   if test x$HAVE_X = xyes; then
 607     AC_CHECK_LIB(Xext, XShmAttach,
 608                  HAVE_XSHM="yes", HAVE_XSHM="no",
 609                  $X_LIBS)
 610     if test "x$HAVE_XSHM" = "xyes"; then
 611       XSHM_LIBS="-lXext"
 612     else
 613       dnl On AIX, it is in XextSam instead, but we still need -lXext
 614       AC_CHECK_LIB(XextSam, XShmAttach,
 615                    HAVE_XSHM="yes", HAVE_XSHM="no",
 616                    $X_LIBS)
 617       if test "x$HAVE_XSHM" = "xyes"; then
 618         XSHM_LIBS="-lXext -lXextSam"
 619       fi
 620     fi
 621   fi
 622 ], ,[
 623   AC_SUBST(HAVE_XSHM)
 624   AC_SUBST(XSHM_LIBS)
 625 ])
 626
 627 dnl for V4L2, we also need to know if we have XVIDEO
 628 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 629 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 630                   [], [
 631   AG_GST_CHECK_XV
 632 ])
 633
 634 dnl *** ext plug-ins ***
 635 dnl keep this list sorted alphabetically !
 636
 637 if test "x$BUILD_EXTERNAL" = "xyes"; then
 638
 639 echo
 640 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 641 echo
 642
 643 dnl *** aalib ***
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 645 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 646   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 647   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 648 ])
 649
 650 dnl *** annodex ***
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 652 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 653   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 654 ])
 655
 656 dnl *** cairo ***
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 658 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 659   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 660 ])
 661
 662 dnl *** cdio ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 664 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 665   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 666 ])
 667
 668 dnl **** ESound ****
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 670 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 671   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 672   if test $HAVE_ESD = no
 673   then
 674     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 675     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 676   fi
 677 ])
 678
 679 dnl *** FLAC ***
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 681 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 682   #if FLAC_API_VERSION_CURRENT < 8
 683   #error "legacy flac API"
 684   #endif
 685   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 686
 687 if test "x$legacy_flac" = "xyes"; then
 688 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 689   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 690   dnl API change in FLAC 1.1.1, so require that...
 691   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 692   if test x$HAVE_FLAC = xyes; then
 693     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 694                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 695 #include <FLAC/seekable_stream_encoder.h>
 696                   ])
 697   fi
 698   AC_SUBST(FLAC_LIBS)
 699 ])
 700 else
 701 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 702   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 703   dnl API change in FLAC 1.1.3, so require that...
 704   if test x$HAVE_FLAC = xyes; then
 705     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 706                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 707 #include <FLAC/stream_encoder.h>
 708                   ])
 709   fi
 710   AC_SUBST(FLAC_LIBS)
 711 ])
 712 fi
 713
 714 dnl *** GConf ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 716 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 717   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 718 ])
 719
 720 dnl *** GDK pixbuf ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 722 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 723   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 724 ])
 725
 726 dnl *** HAL ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 728 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 729   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 730 ])
 731
 732 dnl *** jpeg ***
 733 dnl FIXME: we could use header checks here as well IMO
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 735 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 736   AC_ARG_WITH(jpeg-mmx,
 737     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 738   OLD_LIBS="$LIBS"
 739   if test x$with_jpeg_mmx != x; then
 740     LIBS="$LIBS -L$with_jpeg_mmx"
 741   fi
 742   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 743   JPEG_LIBS="$LIBS -ljpeg-mmx"
 744   LIBS="$OLD_LIBS"
 745   if test x$HAVE_JPEG != xyes; then
 746     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 747     JPEG_LIBS="-ljpeg"
 748   fi
 749   AC_SUBST(JPEG_LIBS)
 750 ])
 751
 752 dnl *** libcaca ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 754 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 755   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 756   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 757   if test "x$HAVE_LIBCACA" != "xyes"; then
 758     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 759     dnl see if it compilation works too, might not if we are cross-compiling
 760     if test "x$HAVE_LIBCACA" = "xyes"; then
 761       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 762                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 763     fi
 764   fi
 765 ])
 766
 767 dnl *** libdv ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 769 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 770   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 771 ])
 772
 773 dnl *** libpng ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 775 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 776   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 777 ])
 778
 779 dnl *** dv1394 ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 781 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 782   dnl first test for libraw1394 >= 1.2.1
 783   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 784   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 785   dnl now see how far we got
 786   if test x$HAVE_RAW1394 = xyes && \
 787      test x$HAVE_LIBIEC61883 = xyes; then
 788        AG_GST_CHECK_LIBHEADER(AVC1394,
 789         avc1394, avc1394_send_command, $RAW1394_LIBS,
 790         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 791        AG_GST_CHECK_LIBHEADER(ROM1394,
 792         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 793         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 794        if test x$HAVE_AVC1394 = xyes && \
 795           test x$HAVE_AVC1394 = xyes && \
 796           test x$HAVE_ROM1394 = xyes; then
 797           HAVE_DV1394=yes
 798           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 799           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 800           AC_SUBST(DV1394_CFLAGS)
 801           AC_SUBST(DV1394_LIBS)
 802         fi
 803   else
 804        if test x$HAVE_RAW1394 = xno; then
 805           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 806           AG_GST_CHECK_LIBHEADER(AVC1394,
 807            avc1394, avc1394_send_command, $RAW1394_LIBS,
 808            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 809           AG_GST_CHECK_LIBHEADER(ROM1394,
 810            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 811            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 812           if test x$HAVE_RAW1394 = xyes && \
 813              test x$HAVE_AVC1394 = xyes && \
 814              test x$HAVE_ROM1394 = xyes; then
 815              HAVE_DV1394=yes
 816              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 817              DV1394_CFLAGS="$RAW1394_CFLAGS"
 818              if test x$HAVE_LIBIEC61883 = xyes; then
 819                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 820                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 821              fi
 822              AC_SUBST(DV1394_CFLAGS)
 823              AC_SUBST(DV1394_LIBS)
 824            fi
 825          fi
 826   fi
 827 ])
 828
 829 dnl *** shout2 ***
 830 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 831 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 832   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 833   if test $HAVE_SHOUT2 = no
 834   then
 835     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 836     AC_SUBST(SHOUT2_CFLAGS)
 837     AC_SUBST(SHOUT2_LIBS)
 838   fi
 839 ])
 840
 841 dnl *** soup ***
 842 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 843 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 844   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.3.2, HAVE_SOUP="yes", [
 845     HAVE_SOUP="no"
 846     AC_MSG_RESULT(no)
 847   ])
 848   AC_SUBST(SOUP_CFLAGS)
 849   AC_SUBST(SOUP_LIBS)
 850 ])
 851
 852 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 853 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 854 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 855 dnl   speex_jitter.h is 1.1.x only
 856 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 857 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 858   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 859   if test $HAVE_SPEEX = no
 860   then
 861     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 862       AC_CHECK_HEADER(speex/speex_jitter.h, [
 863         dnl speex 1.1.x :
 864         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 865           dnl speex 1.1.5 or + :
 866           HAVE_SPEEX="yes"
 867           SPEEX_LIBS="-lspeex"
 868           AC_SUBST(SPEEX_CFLAGS)
 869           AC_SUBST(SPEEX_LIBS)
 870         ],[
 871           HAVE_SPEEX="no"
 872         ])
 873       ],[
 874         dnl speex 1.0.x :
 875           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 876             dnl speex 1.0.4
 877             HAVE_SPEEX="yes"
 878             SPEEX_LIBS="-lspeex"
 879             AC_SUBST(SPEEX_CFLAGS)
 880             AC_SUBST(SPEEX_LIBS)
 881
 882             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 883               [defined if speex 1.0.x API detected])
 884         ],[
 885             HAVE_SPEEX="no"
 886             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 887         ], [
 888 #include <speex/speex.h>
 889         ])
 890       ])
 891     ])
 892   fi
 893 ])
 894
 895 dnl *** taglib ***
 896 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 897 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 898   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 899   if test "x$HAVE_CXX" != "xyes"; then
 900     USE_TAGLIB=false
 901     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 902   fi
 903 ])
 904
 905 dnl *** wavpack ***
 906 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 907 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 908   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 909     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 910       HAVE_WAVPACK=yes
 911       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 912     ],[
 913       HAVE_WAVPACK=no
 914       AC_MSG_RESULT(no)
 915     ])
 916   ])
 917   AC_SUBST(WAVPACK_CFLAGS)
 918   AC_SUBST(WAVPACK_LIBS)
 919 ])
 920
 921 dnl *** qtdemux & id3demux prefer to have zlib ***
 922 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 923 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 924   AG_GST_CHECK_LIBHEADER(ZLIB,
 925     z, uncompress,, zlib.h, [
 926     HAVE_ZLIB="yes"
 927     ZLIB_LIBS="-lz"
 928     AC_SUBST(ZLIB_LIBS)
 929   ])
 930 ])
 931
 932 else
 933
 934 dnl not building plugins with external dependencies,
 935 dnl but we still need to set the conditionals
 936 AM_CONDITIONAL(USE_GCONFTOOL, false)
 937 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 938 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 939 AM_CONDITIONAL(USE_OSS, false)
 940 AM_CONDITIONAL(USE_SUNAUDIO, false)
 941 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 942 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 943 AM_CONDITIONAL(USE_X, false)
 944 AM_CONDITIONAL(USE_XSHM, false)
 945 AM_CONDITIONAL(USE_AALIB, false)
 946 AM_CONDITIONAL(USE_ANNODEX, false)
 947 AM_CONDITIONAL(USE_CAIRO, false)
 948 AM_CONDITIONAL(USE_CDIO, false)
 949 AM_CONDITIONAL(USE_ESD, false)
 950 AM_CONDITIONAL(USE_FLAC, false)
 951 AM_CONDITIONAL(USE_GCONF, false)
 952 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 953 AM_CONDITIONAL(USE_HAL, false)
 954 AM_CONDITIONAL(USE_JPEG, false)
 955 AM_CONDITIONAL(USE_LIBCACA, false)
 956 AM_CONDITIONAL(USE_LIBDV, false)
 957 AM_CONDITIONAL(USE_LIBPNG, false)
 958 AM_CONDITIONAL(USE_DV1394, false)
 959 AM_CONDITIONAL(USE_SHOUT2, false)
 960 AM_CONDITIONAL(USE_SOUP, false)
 961 AM_CONDITIONAL(USE_SPEEX, false)
 962 AM_CONDITIONAL(USE_TAGLIB, false)
 963 AM_CONDITIONAL(USE_WAVPACK, false)
 964 AM_CONDITIONAL(USE_ZLIB, false)
 965
 966 fi dnl of EXT plugins
 967
 968 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 969
 970 dnl Overview:
 971 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 972 dnl GST_*:              flags shared by all built objects
 973 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 974 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 975 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 976 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 977
 978 dnl GST_OPTION_CFLAGS
 979 if test "x$USE_DEBUG" = xyes; then
 980    PROFILE_CFLAGS="-g"
 981 fi
 982 AC_SUBST(PROFILE_CFLAGS)
 983
 984 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 985   dnl Define _only_ during CVS (not pre-releases or releases)
 986   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 987 else
 988   DEPRECATED_CFLAGS=""
 989 fi
 990 AC_SUBST(DEPRECATED_CFLAGS)
 991
 992 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 993 dnl at make time with e.g. make ERROR_CFLAGS=""
 994 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 995 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 996 AC_SUBST(GST_OPTION_CFLAGS)
 997 AC_SUBST(GST_OPTION_CXXFLAGS)
 998
 999 dnl our libraries need to be versioned correctly
1000 AC_SUBST(GST_LT_LDFLAGS)
1001
1002 dnl FIXME: do we want to rename to GST_ALL_* ?
1003 dnl prefer internal headers to already installed ones
1004 dnl also add builddir include for enumtypes and marshal
1005 dnl add ERROR_CFLAGS, but overridable
1006 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1007 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1008 AC_SUBST(GST_CFLAGS)
1009 AC_SUBST(GST_CXXFLAGS)
1010 AC_SUBST(GST_LIBS)
1011
1012 dnl LDFLAGS really should only contain flags, not libs - they get added before
1013 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1014 GST_ALL_LDFLAGS="-no-undefined"
1015 AC_SUBST(GST_ALL_LDFLAGS)
1016
1017 dnl this really should only contain flags, not libs - they get added before
1018 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1019 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1020 AC_SUBST(GST_PLUGIN_LDFLAGS)
1021
1022 dnl *** output files ***
1023
1024 dnl keep this alphabetic per directory, please
1025 AC_CONFIG_FILES(
1026 Makefile
1027 gst/Makefile
1028 gst/alpha/Makefile
1029 gst/apetag/Makefile
1030 gst/audiofx/Makefile
1031 gst/auparse/Makefile
1032 gst/autodetect/Makefile
1033 gst/avi/Makefile
1034 gst/cutter/Makefile
1035 gst/debug/Makefile
1036 gst/effectv/Makefile
1037 gst/equalizer/Makefile
1038 gst/id3demux/Makefile
1039 gst/icydemux/Makefile
1040 gst/goom/Makefile
1041 gst/goom2k1/Makefile
1042 gst/law/Makefile
1043 gst/level/Makefile
1044 gst/matroska/Makefile
1045 gst/monoscope/Makefile
1046 gst/multifile/Makefile
1047 gst/multipart/Makefile
1048 gst/qtdemux/Makefile
1049 gst/rtp/Makefile
1050 gst/rtsp/Makefile
1051 gst/smpte/Makefile
1052 gst/spectrum/Makefile
1053 gst/udp/Makefile
1054 gst/videobox/Makefile
1055 gst/videocrop/Makefile
1056 gst/videofilter/Makefile
1057 gst/videomixer/Makefile
1058 gst/wavenc/Makefile
1059 gst/wavparse/Makefile
1060 gst/flx/Makefile
1061 ext/jpeg/Makefile
1062 ext/Makefile
1063 ext/aalib/Makefile
1064 ext/annodex/Makefile
1065 ext/cairo/Makefile
1066 ext/cdio/Makefile
1067 ext/dv/Makefile
1068 ext/esd/Makefile
1069 ext/flac/Makefile
1070 ext/gconf/Makefile
1071 ext/gdk_pixbuf/Makefile
1072 ext/hal/Makefile
1073 ext/ladspa/Makefile
1074 ext/libcaca/Makefile
1075 ext/libpng/Makefile
1076 ext/raw1394/Makefile
1077 ext/shout2/Makefile
1078 ext/soup/Makefile
1079 ext/speex/Makefile
1080 ext/taglib/Makefile
1081 ext/wavpack/Makefile
1082 sys/Makefile
1083 sys/directdraw/Makefile
1084 sys/directsound/Makefile
1085 sys/oss/Makefile
1086 sys/sunaudio/Makefile
1087 sys/osxaudio/Makefile
1088 sys/osxvideo/Makefile
1089 sys/v4l2/Makefile
1090 sys/waveform/Makefile
1091 sys/ximage/Makefile
1092 po/Makefile.in
1093 tests/Makefile
1094 tests/check/Makefile
1095 tests/examples/Makefile
1096 tests/examples/equalizer/Makefile
1097 tests/examples/level/Makefile
1098 tests/examples/rtp/Makefile
1099 tests/examples/spectrum/Makefile
1100 tests/files/Makefile
1101 tests/icles/Makefile
1102 gconf/Makefile
1103 gconf/gstreamer.schemas
1104 common/Makefile
1105 common/m4/Makefile
1106 m4/Makefile
1107 docs/Makefile
1108 docs/plugins/Makefile
1109 docs/version.entities
1110 win32/common/config.h
1111 pkgconfig/Makefile
1112 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1113 gst-plugins-good.spec
1114 )
1115 AC_OUTPUT
1116
1117 AG_GST_OUTPUT_PLUGINS