configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [3])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # gstreamer-vaapi library (libtool) version number
  13 m4_define([gst_vaapi_lt_current],  [1])
  14 m4_define([gst_vaapi_lt_revision], [0])
  15 m4_define([gst_vaapi_lt_age],      [0])
  16
  17 # glib version number
  18 m4_define([glib_version], [2.28])
  19
  20 # gstreamer version number
  21 m4_define([gst_api_version],            [0.10])
  22 m4_define([gst0_version],               [0.10.36])
  23 m4_define([gst0_plugins_base_version],  [0.10.31])
  24 m4_define([gst0_plugins_bad_version],   [0.10.22])
  25
  26 # Wayland minimum version number
  27 m4_define([wayland_api_version], [1.0.0])
  28
  29 # VA-API minimum version number
  30 m4_define([va_api_version],     [0.30.4])
  31 m4_define([va_api_drm_version], [0.33.0])
  32 m4_define([va_api_x11_version], [0.31.0])
  33 m4_define([va_api_glx_version], [0.32.0])
  34 m4_define([va_api_wld_version], [0.33.0])
  35
  36 # libva package version number
  37 m4_define([libva_drm_package_version], [1.1.0])
  38 m4_define([libva_x11_package_version], [1.0.3])
  39 m4_define([libva_glx_package_version], [1.0.9])
  40 m4_define([libva_wld_package_version], [1.1.0])
  41
  42 # gtk-doc version number
  43 # XXX: introspection annotations require gtk-doc >= 1.12
  44 m4_define([gtkdoc_version], [1.9])
  45
  46 AC_PREREQ([2.58])
  47 AC_INIT([gst_vaapi], [gst_vaapi_version],
  48     [gwenole.beauchesne@intel.com],
  49     [gstreamer-vaapi])
  50
  51 AC_CONFIG_HEADERS([config.h])
  52 AC_CONFIG_SRCDIR([Makefile.am])
  53 AC_CONFIG_MACRO_DIR([m4])
  54 AC_CONFIG_AUX_DIR([build-aux])
  55
  56 AC_CANONICAL_TARGET
  57
  58 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  59
  60 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  61 AC_SUBST(TODAY)
  62
  63 GST_VAAPI_MAJOR_VERSION=gst_vaapi_lt_current
  64 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  65
  66 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  67 AC_SUBST(LIBVA_PACKAGE_VERSION)
  68
  69 WAYLAND_API_VERSION=wayland_api_version
  70 AC_SUBST(WAYLAND_API_VERSION)
  71
  72 dnl Use pretty build output with automake >= 1.11
  73 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  74   AM_DEFAULT_VERBOSITY=1
  75   AC_SUBST(AM_DEFAULT_VERBOSITY)
  76 ])
  77
  78 dnl Check for tools
  79 AC_PROG_CC
  80 AM_PROG_CC_C_O
  81
  82 AC_ARG_VAR([GIT], [Path to git program, if any])
  83 AC_PATH_PROG([GIT], [git])
  84 AM_CONDITIONAL([HAVE_GIT], [test -n "$GIT"])
  85
  86 dnl Initialize libtool
  87 LT_PREREQ([2.2])
  88 LT_INIT
  89
  90 AC_ARG_ENABLE(drm,
  91     AS_HELP_STRING([--enable-drm],
  92                    [enable DRM backend @<:@default=yes@:>@]),
  93     [], [enable_drm="yes"])
  94
  95 AC_ARG_ENABLE(x11,
  96     AS_HELP_STRING([--enable-x11],
  97                    [enable X11 output @<:@default=yes@:>@]),
  98     [], [enable_x11="yes"])
  99
 100 AC_ARG_ENABLE(glx,
 101     AS_HELP_STRING([--enable-glx],
 102                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 103     [], [enable_glx="yes"])
 104
 105 AC_ARG_ENABLE(wayland,
 106     AC_HELP_STRING([--enable-wayland],
 107                    [enable Wayland output @<:@default=yes@:>@]),
 108     [], [enable_wayland="yes"])
 109
 110 dnl Check for basic libraries
 111 AC_CHECK_LIB(m, tan)
 112
 113 dnl Check for Gtk doc
 114 GTKDOC_VERSION=gtkdoc_version
 115 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 116 m4_ifdef([GTK_DOC_CHECK], [
 117 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 118 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 119 AC_SUBST(GTKDOC_VERSION)
 120
 121 dnl Check for GLib
 122 GLIB_VERSION_REQUIRED=glib_version
 123 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 124 AC_SUBST(GLIB_VERSION_REQUIRED)
 125
 126 dnl ---------------------------------------------------------------------------
 127 dnl -- GStreamer                                                             --
 128 dnl ---------------------------------------------------------------------------
 129
 130 dnl Versions for GStreamer and plugins-base
 131 GST_API_VERSION=gst_api_version
 132 case $GST_API_VERSION in
 133 0.10)
 134     GST_VERSION_REQUIRED=gst0_version
 135     GST_PLUGINS_BASE_VERSION_REQUIRED=gst0_plugins_base_version
 136     GST_PLUGINS_BAD_VERSION_REQUIRED=gst0_plugins_bad_version
 137     ;;
 138 *)
 139     AC_MSG_ERROR([unsupported GStreamer API version $GST_API_VERSION])
 140     ;;
 141 esac
 142 AC_SUBST(GST_API_VERSION)
 143 AC_SUBST(GST_VERSION_REQUIRED)
 144 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 145 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 146
 147 dnl GStreamer Core
 148 PKG_CHECK_MODULES([GST],
 149     [gstreamer-$GST_API_VERSION >= $GST_VERSION_REQUIRED])
 150 PKG_CHECK_MODULES([GST_BASE],
 151     [gstreamer-base-$GST_API_VERSION >= $GST_VERSION_REQUIRED])
 152
 153 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 154     saved_CPPFLAGS="$CPPFLAGS"
 155     CPPFLAGS="$CPPFLAGS $GST_BASE_CFLAGS"
 156     saved_LIBS="$LIBS"
 157     LIBS="$LIBS $GST_BASE_LIBS"
 158     AC_COMPILE_IFELSE(
 159         [AC_LANG_PROGRAM(
 160             [[#include <gst/base/gstbasesink.h>]],
 161             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 162         [ac_cv_have_gst_base_sink_query="yes"],
 163         [ac_cv_have_gst_base_sink_query="no"]
 164     )
 165     CPPFLAGS="$saved_CPPFLAGS"
 166     LIBS="$saved_LIBS"
 167 ])
 168 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 169     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 170 fi
 171
 172 dnl GStreamer -base plugins
 173 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 174     [gstreamer-plugins-base-$GST_API_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 175 PKG_CHECK_MODULES([GST_INTERFACES],
 176     [gstreamer-interfaces-$GST_API_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 177
 178 dnl ... GstVideoOverlayComposition (gstreamer-video)
 179 PKG_CHECK_MODULES([GST_VIDEO],
 180     [gstreamer-video-$GST_API_VERSION >= $GST_PLUGINS_BASE_VERSION_REQUIRED])
 181
 182 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 183     ac_cv_have_gst_video_overlay_composition, [
 184     saved_CPPFLAGS="$CPPFLAGS"
 185     CPPFLAGS="$CPPFLAGS $GST_CFLAGS"
 186     saved_LIBS="$LIBS"
 187     LIBS="$LIBS $GST_LIBS"
 188     AC_COMPILE_IFELSE(
 189         [AC_LANG_PROGRAM(
 190             [[#include <gst/video/video-overlay-composition.h>]],
 191             [[GstVideoOverlayComposition *c;
 192               c = gst_video_overlay_composition_new(0);]])],
 193         [ac_cv_have_gst_video_overlay_composition="yes"],
 194         [ac_cv_have_gst_video_overlay_composition="no"]
 195     )
 196     CPPFLAGS="$saved_CPPFLAGS"
 197     LIBS="$saved_LIBS"
 198 ])
 199 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 200     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 201 fi
 202
 203 AC_CACHE_CHECK([... with advanced format flags],
 204     ac_cv_have_gst_video_overlay_hwcaps, [
 205     saved_CPPFLAGS="$CPPFLAGS"
 206     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_VIDEO_CFLAGS"
 207     saved_LIBS="$LIBS"
 208     LIBS="$LIBS $GST_LIBS $GST_VIDEO_LIBS"
 209     AC_COMPILE_IFELSE(
 210         [AC_LANG_PROGRAM(
 211             [[#include <gst/video/video-overlay-composition.h>]],
 212             [[GstVideoOverlayRectangle *rect;
 213               const guint w = 64, h = 64;
 214               guint flags = (
 215                   GST_VIDEO_OVERLAY_FORMAT_FLAG_PREMULTIPLIED_ALPHA|
 216                   GST_VIDEO_OVERLAY_FORMAT_FLAG_GLOBAL_ALPHA);
 217               rect = gst_video_overlay_rectangle_new_argb(NULL, w, h, w * 4,
 218                   0, 0, w, h, flags);
 219               gst_video_overlay_rectangle_set_global_alpha(rect, 0.5f);]])],
 220         [ac_cv_have_gst_video_overlay_hwcaps="yes"],
 221         [ac_cv_have_gst_video_overlay_hwcaps="no"]
 222     )
 223     CPPFLAGS="$saved_CPPFLAGS"
 224     LIBS="$saved_LIBS"
 225 ])
 226 if test "$ac_cv_have_gst_video_overlay_hwcaps" = "yes"; then
 227     AC_DEFINE_UNQUOTED([HAVE_GST_VIDEO_OVERLAY_HWCAPS], 1,
 228         [Defined to 1 if GstVideoOverlayComposition API supports HW hints.])
 229 fi
 230
 231 dnl ... GstVideoDecoder (gstreamer-video)
 232 AC_CACHE_CHECK([for GstVideoDecoder],
 233     ac_cv_have_gst_video_decoder, [
 234     saved_CPPFLAGS="$CPPFLAGS"
 235     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_VIDEO_CFLAGS"
 236     saved_LIBS="$LIBS"
 237     LIBS="$LIBS $GST_LIBS $GST_VIDEO_LIBS"
 238     AC_COMPILE_IFELSE(
 239         [AC_LANG_PROGRAM(
 240             [[#include <gst/video/gstvideodecoder.h>]],
 241             [[GstVideoCodecFrame *f;
 242               GstVideoDecoder vdec;
 243               f = g_slice_new0(GstVideoCodecFrame);
 244               f->ref_count = 1;
 245               gst_video_decoder_have_frame(&vdec);
 246               gst_video_decoder_finish_frame(&vdec, f);
 247               gst_video_codec_frame_unref(f);]])],
 248         [ac_cv_have_gst_video_decoder="yes"],
 249         [ac_cv_have_gst_video_decoder="no"]
 250     )
 251     CPPFLAGS="$saved_CPPFLAGS"
 252     LIBS="$saved_LIBS"
 253 ])
 254 AM_CONDITIONAL([USE_LOCAL_GST_VIDEO_DECODER],
 255     [test "$ac_cv_have_gst_video_decoder" != "yes"])
 256
 257 dnl GStreamer -bad plugins
 258 PKG_CHECK_MODULES([GST_BASEVIDEO],
 259     [gstreamer-basevideo-$GST_API_VERSION >= $GST_PLUGINS_BAD_VERSION_REQUIRED])
 260
 261 dnl ... bitstream parsers
 262 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 263     [gstreamer-codecparsers-$GST_API_VERSION >= $GST_PLUGINS_BAD_VERSION_REQUIRED])
 264
 265 dnl ... MPEG-2 parser, with the required extensions
 266 AC_CACHE_CHECK([for MPEG-2 parser],
 267     ac_cv_have_gst_mpeg2_parser, [
 268     saved_CPPFLAGS="$CPPFLAGS"
 269     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 270     saved_LIBS="$LIBS"
 271     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 272     AC_COMPILE_IFELSE(
 273         [AC_LANG_PROGRAM(
 274             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 275             [[GstMpegVideoSequenceHdr seq_hdr;
 276               GstMpegVideoSequenceExt seq_ext;
 277               GstMpegVideoSequenceDisplayExt seq_dpy;
 278               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 279                   &seq_ext, &seq_dpy);]])],
 280         [ac_cv_have_gst_mpeg2_parser="yes"],
 281         [ac_cv_have_gst_mpeg2_parser="no"]
 282     )
 283     CPPFLAGS="$saved_CPPFLAGS"
 284     LIBS="$saved_LIBS"
 285 ])
 286 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 287     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 288
 289 dnl ... H.264 parser, with the required extensions
 290 AC_CACHE_CHECK([for H.264 parser],
 291     ac_cv_have_gst_h264_parser, [
 292     saved_CPPFLAGS="$CPPFLAGS"
 293     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 294     saved_LIBS="$LIBS"
 295     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 296     AC_COMPILE_IFELSE(
 297         [AC_LANG_PROGRAM(
 298             [[#include <gst/codecparsers/gsth264parser.h>]],
 299             [[GstH264SliceHdr slice_hdr;
 300               GstH264VUIParams vui_params;
 301               GstH264Profile profile = GST_H264_PROFILE_HIGH;
 302               slice_hdr.n_emulation_prevention_bytes = 0;
 303               vui_params.par_n = 0;
 304               vui_params.par_d = 0;]])],
 305         [ac_cv_have_gst_h264_parser="yes"],
 306         [ac_cv_have_gst_h264_parser="no"]
 307     )
 308     CPPFLAGS="$saved_CPPFLAGS"
 309     LIBS="$saved_LIBS"
 310 ])
 311 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 312     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 313
 314 dnl ... JPEG parser, not upstream yet
 315 AC_CACHE_CHECK([for JPEG parser],
 316     ac_cv_have_gst_jpeg_parser, [
 317     saved_CPPFLAGS="$CPPFLAGS"
 318     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 319     saved_LIBS="$LIBS"
 320     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 321     AC_COMPILE_IFELSE(
 322         [AC_LANG_PROGRAM(
 323             [[#include <gst/codecparsers/gstjpegparser.h>]],
 324             [[GstJpegImage jpeg_image;]])],
 325         [ac_cv_have_gst_jpeg_parser="yes"],
 326         [ac_cv_have_gst_jpeg_parser="no"]
 327     )
 328     CPPFLAGS="$saved_CPPFLAGS"
 329     LIBS="$saved_LIBS"
 330 ])
 331 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 332     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 333
 334 dnl GST_VAAPI_LT_LDFLAGS:
 335 GST_VAAPI_LT_CURRENT=gst_vaapi_lt_current
 336 GST_VAAPI_LT_REV=gst_vaapi_lt_revision
 337 GST_VAAPI_LT_AGE=gst_vaapi_lt_age
 338 GST_VAAPI_LT_VERSION="$GST_VAAPI_LT_CURRENT:$GST_VAAPI_LT_REV:$GST_VAAPI_LT_AGE"
 339 GST_VAAPI_LT_LDFLAGS="-version-info $GST_VAAPI_LT_VERSION"
 340 AC_SUBST(GST_VAAPI_LT_VERSION)
 341 AC_SUBST(GST_VAAPI_LT_LDFLAGS)
 342
 343 dnl GST_ALL_LDFLAGS:
 344 dnl LDFLAGS really should only contain flags, not libs - they get added before
 345 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 346 GST_ALL_LDFLAGS="-no-undefined"
 347 AC_SUBST(GST_ALL_LDFLAGS)
 348
 349 dnl GST_PLUGIN_LDFLAGS:
 350 dnl this really should only contain flags, not libs - they get added before
 351 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 352 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 353 AC_SUBST(GST_PLUGIN_LDFLAGS)
 354
 355 dnl Check for the GStreamer plugins directory
 356 AC_ARG_VAR([GST_PLUGIN_PATH], [installation path for gstreamer-vaapi plugin elements])
 357 AC_MSG_CHECKING([for GStreamer plugins directory])
 358 if test -d "$GST_PLUGIN_PATH"; then
 359     GST_PLUGINS_DIR="$GST_PLUGIN_PATH"
 360 else
 361     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 362     if test -z "$GST_PLUGINS_DIR"; then
 363         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_API_VERSION"
 364     fi
 365 fi
 366 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 367 plugindir="$GST_PLUGINS_DIR"
 368 AC_SUBST(plugindir)
 369
 370 dnl ---------------------------------------------------------------------------
 371 dnl -- Renderers                                                             --
 372 dnl ---------------------------------------------------------------------------
 373
 374 dnl Check for DRM/libudev
 375 USE_DRM=0
 376 if test "$enable_drm" = "yes"; then
 377     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 378     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 379
 380     if test $USE_DRM -eq 1; then
 381         saved_CPPFLAGS="$CPPFLAGS"
 382         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 383         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 384         CPPFLAGS="$saved_CPPFLAGS"
 385     fi
 386 fi
 387
 388 dnl Check for X11
 389 USE_X11=0
 390 if test "$enable_x11" = "yes"; then
 391     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 392     if test $USE_X11 -eq 1; then
 393         saved_CPPFLAGS="$CPPFLAGS"
 394         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 395         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 396         CPPFLAGS="$saved_CPPFLAGS"
 397     fi
 398 fi
 399
 400 dnl Check for XRandR
 401 HAVE_XRANDR=0
 402 if test $USE_X11 -eq 1; then
 403     HAVE_XRANDR=1
 404     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 405     if test $HAVE_XRANDR -eq 1; then
 406         saved_CPPFLAGS="$CPPFLAGS"
 407         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 408         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 409         CPPFLAGS="$saved_CPPFLAGS"
 410     fi
 411 fi
 412 if test $HAVE_XRANDR -eq 1; then
 413     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 414         [Defined to 1 if the XRandR extension exists.])
 415 fi
 416
 417 dnl OpenGL
 418 enable_opengl="no"
 419 if test "$enable_glx" = "yes"; then
 420     enable_opengl="yes"
 421 fi
 422
 423 HAVE_GL=0
 424 if test "$enable_opengl" = "yes"; then
 425     HAVE_GL=1
 426     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 427     saved_CPPFLAGS="$CPPFLAGS"
 428     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 429     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 430 #ifdef HAVE_GL_GL_H
 431 # include <GL/gl.h>
 432 #endif
 433     ])
 434     CPPFLAGS="$saved_CPPFLAGS"
 435 fi
 436
 437 dnl ... GLX
 438 USE_GLX=0
 439 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 440     USE_GLX=1
 441     saved_CPPFLAGS="$CPPFLAGS"
 442     saved_LIBS="$LIBS"
 443     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 444     LIBS="$LIBS $GL_LIBS"
 445     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 446 #ifdef HAVE_GL_GL_H
 447 # include <GL/gl.h>
 448 #endif
 449     ])
 450     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 451     CPPFLAGS="$saved_CPPFLAGS"
 452     LIBS="$saved_LIBS"
 453 fi
 454
 455 dnl Check for Wayland
 456 USE_WAYLAND=0
 457 if test "$enable_wayland" = "yes"; then
 458     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 459         [USE_WAYLAND=1], [USE_WAYLAND=0])
 460
 461     if test $USE_WAYLAND -eq 1; then
 462         saved_CPPFLAGS="$CPPFLAGS"
 463         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 464         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 465         CPPFLAGS="$saved_CPPFLAGS"
 466     fi
 467 fi
 468
 469 dnl ---------------------------------------------------------------------------
 470 dnl -- VA-API                                                                --
 471 dnl ---------------------------------------------------------------------------
 472
 473 dnl Core API
 474 LIBVA_PKGNAME="libva"
 475 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 476 AC_SUBST(LIBVA_PKGNAME)
 477
 478 VA_VERSION=`$PKG_CONFIG --modversion libva`
 479 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 480 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 481 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 482 VA_VERSION_STR="$VA_VERSION"
 483
 484 dnl VA/DRM API
 485 HAVE_VA_DRM=0
 486 if test $USE_DRM -eq 1; then
 487     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 488         [HAVE_VA_DRM=1], [USE_DRM=0])
 489
 490     if test $HAVE_VA_DRM -eq 1; then
 491         saved_CPPFLAGS="$CPPFLAGS"
 492         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 493         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 494         CPPFLAGS="$saved_CPPFLAGS"
 495     fi
 496 fi
 497
 498 dnl VA/X11 API
 499 HAVE_VA_X11=0
 500 LIBVA_X11_PKGNAME="libva-x11"
 501 if test $USE_X11 -eq 1; then
 502     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 503         [HAVE_VA_X11=1], [USE_X11=0])
 504 fi
 505 AC_SUBST(LIBVA_X11_PKGNAME)
 506
 507 dnl VA/GLX API
 508 HAVE_VA_GLX=0
 509 LIBVA_GLX_PKGNAME="libva-glx"
 510 if test $USE_GLX -eq 1; then
 511     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 512         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 513
 514     if test $HAVE_VA_GLX -eq 1; then
 515         saved_CPPFLAGS="$CPPFLAGS"
 516         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 517         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 518         CPPFLAGS="$saved_CPPFLAGS"
 519     fi
 520 fi
 521 AC_SUBST(LIBVA_GLX_PKGNAME)
 522
 523 dnl Check for JPEG decoding API (0.32.1+)
 524 USE_JPEG_DECODER=0
 525 AC_CACHE_CHECK([for JPEG decoding API],
 526     ac_cv_have_jpeg_decoding_api, [
 527     saved_CPPFLAGS="$CPPFLAGS"
 528     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 529     saved_LIBS="$LIBS"
 530     LIBS="$LIBS $LIBVA_LIBS"
 531     AC_COMPILE_IFELSE(
 532         [AC_LANG_PROGRAM(
 533             [[#include <va/va.h>]],
 534             [[VAPictureParameterBufferJPEGBaseline pic_param;
 535               VASliceParameterBufferJPEGBaseline slice_param;
 536               VAHuffmanTableBufferJPEGBaseline huffman_table;
 537               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 538         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 539         [ac_cv_have_jpeg_decoding_api="no"]
 540     )
 541     CPPFLAGS="$saved_CPPFLAGS"
 542     LIBS="$saved_LIBS"
 543 ])
 544
 545 dnl VA/Wayland API
 546 if test "$enable_wayland" = "yes"; then
 547     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 548         [:], [USE_WAYLAND=0])
 549 fi
 550
 551 dnl ---------------------------------------------------------------------------
 552 dnl -- Generate files and summary                                            --
 553 dnl ---------------------------------------------------------------------------
 554
 555 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 556 *:1:*)
 557     ;;
 558 *)
 559     AC_MSG_ERROR([No renderer is enabled])
 560     ;;
 561 esac
 562
 563 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 564     [Defined to 1 if JPEG decoder is used])
 565 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 566
 567 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 568     [Defined to 1 if DRM is enabled])
 569 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 570
 571 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 572     [Defined to 1 if X11 is enabled])
 573 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 574
 575 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 576     [Defined to 1 if GLX is enabled])
 577 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 578
 579 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 580     [Defined to 1 if WAYLAND is enabled])
 581 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 582
 583 pkgconfigdir=${libdir}/pkgconfig
 584 AC_SUBST(pkgconfigdir)
 585
 586 AC_CONFIG_FILES([
 587     Makefile
 588     debian.upstream/Makefile
 589     debian.upstream/changelog
 590     debian.upstream/control
 591     debian.upstream/gstreamer$GST_API_VERSION-vaapi-doc.install:\
 592 debian.upstream/gstreamer-vaapi-doc.install.in
 593     debian.upstream/gstreamer$GST_API_VERSION-vaapi.install:\
 594 debian.upstream/gstreamer-vaapi.install.in
 595     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 596 debian.upstream/libgstvaapi.install.in
 597     debian.upstream/libgstvaapi-dev.install
 598     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 599 debian.upstream/libgstvaapi-drm.install.in
 600     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 601 debian.upstream/libgstvaapi-glx.install.in
 602     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 603 debian.upstream/libgstvaapi-wayland.install.in
 604     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 605 debian.upstream/libgstvaapi-x11.install.in
 606     docs/Makefile
 607     docs/reference/Makefile
 608     docs/reference/libs/Makefile
 609     docs/reference/libs/libs-docs.xml
 610     docs/reference/plugins/Makefile
 611     docs/reference/plugins/plugins-docs.xml
 612     ext/Makefile
 613     gst-libs/Makefile
 614     gst-libs/gst/Makefile
 615     gst-libs/gst/codecparsers/Makefile
 616     gst-libs/gst/vaapi/Makefile
 617     gst-libs/gst/video/Makefile
 618     gst/Makefile
 619     gst/vaapi/Makefile
 620     pkgconfig/Makefile
 621     pkgconfig/gstreamer-vaapi-$GST_API_VERSION.pc:\
 622 pkgconfig/gstreamer-vaapi.pc.in
 623     pkgconfig/gstreamer-vaapi-drm-$GST_API_VERSION.pc:\
 624 pkgconfig/gstreamer-vaapi-drm.pc.in
 625     pkgconfig/gstreamer-vaapi-glx-$GST_API_VERSION.pc:\
 626 pkgconfig/gstreamer-vaapi-glx.pc.in
 627     pkgconfig/gstreamer-vaapi-wayland-$GST_API_VERSION.pc:\
 628 pkgconfig/gstreamer-vaapi-wayland.pc.in
 629     pkgconfig/gstreamer-vaapi-x11-$GST_API_VERSION.pc:\
 630 pkgconfig/gstreamer-vaapi-x11.pc.in
 631     tests/Makefile
 632 ])
 633 AC_OUTPUT
 634
 635 dnl Print summary
 636 yesno() {
 637     test $1 -eq 1 && echo yes || echo no
 638 }
 639
 640 VIDEO_OUTPUTS=""
 641 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 642 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 643 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 644 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 645
 646 echo
 647 echo $PACKAGE configuration summary:
 648 echo
 649 echo GStreamer API version ............ : $GST_API_VERSION
 650 echo VA-API version ................... : $VA_VERSION_STR
 651 echo Video outputs .................... : $VIDEO_OUTPUTS
 652 echo