configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 m4_pattern_forbid([^MAN_])
   3
   4 # Initialise and check we're in the correct directory.
   5 AC_INIT([man-db], [2.6.3], [cjwatson@debian.org])
   6 AC_CONFIG_AUX_DIR([tools])
   7 AM_INIT_AUTOMAKE([1.10 -Wall -Wno-override -Werror foreign dist-xz no-dist-gzip])
   8 AM_MAINTAINER_MODE
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10 AC_PREREQ([2.59])
  11 AC_CONFIG_SRCDIR([src/man.c])
  12 AC_GNU_SOURCE
  13 AM_PROG_AR
  14 LT_INIT([disable-static])
  15
  16 if test ! -f "$srcdir/gnulib/po/Makefile.in.in"; then
  17         AC_MSG_ERROR([you must run ./autogen.sh before ./configure when building from revision control])
  18 fi
  19
  20 AC_CONFIG_HEADER([config.h])
  21 AC_CANONICAL_HOST
  22
  23 # Define below date and version information to be put into man pages etc.
  24 date=2012-09-17
  25 AC_SUBST([date])dnl
  26 roff_version=`echo AC_PACKAGE_VERSION | sed 's/-/\\-/g'`
  27 AC_SUBST([roff_version])dnl
  28
  29 # We have to be a bit naughty here and supply options.
  30 # The autoconf literature states that only features that can be separately
  31 # 'built' should use --enable and friends. Oh well...
  32 AC_ARG_ENABLE([setuid],
  33 [AS_HELP_STRING([--enable-setuid[=ARG]], [install man setuid to user ARG [ARG=man]])
  34 AS_HELP_STRING([--disable-setuid], [don't install man setuid])],
  35           [if test "$enableval" = "yes"
  36            then
  37                 enableval=man
  38            fi
  39            if test "$enableval" = "no"
  40            then
  41                 man_owner=
  42                 man_mode="755"
  43                 AC_MSG_NOTICE([Man will not be installed setuid])
  44            else
  45                 man_owner=$enableval
  46                 man_mode="4755"
  47                 AC_MSG_NOTICE([Man will be installed setuid $enableval])
  48                 AC_DEFINE_UNQUOTED([SECURE_MAN_UID], ["$man_owner"],
  49                                    [Define as the setuid owner of man or undefine if not installing setuid.])
  50            fi],
  51           [man_owner=man
  52            man_mode="4755"
  53            AC_DEFINE_UNQUOTED([SECURE_MAN_UID], ["$man_owner"])])
  54 AC_ARG_ENABLE([undoc],
  55 [AS_HELP_STRING([--enable-undoc=COMMAND], [suggest COMMAND for missing manual pages])],
  56         [if test "$enableval" = "yes" || test "$enableval" = "no"
  57          then
  58                 AC_MSG_ERROR([--enable-undoc requires an argument])
  59          else
  60                 AC_MSG_NOTICE([Suggesting '$enableval' for missing manual pages])
  61                 AC_DEFINE_UNQUOTED([UNDOC_COMMAND], ["$enableval"],
  62                                    [Define as the name of a command you want to suggest when a non-existent page is requested.])
  63          fi])
  64 AC_ARG_WITH([device],
  65 [AS_HELP_STRING([--with-device=DEVICE], [use nroff with the output device DEVICE])],
  66         [if test "$withval" = "yes" || test "$withval" = "no"
  67          then
  68                 AC_MSG_ERROR([--with-device requires an argument])
  69          else
  70                 nroff_device=" -T$withval"
  71          fi])
  72 AC_ARG_WITH([db],
  73 [AS_HELP_STRING([--with-db=LIBRARY], [use database library LIBRARY (db5, db4, db3, db2, db1, db, gdbm, ndbm)])],
  74         [if test "$withval" = "yes" || test "$withval" = "no"
  75          then
  76                 AC_MSG_ERROR([--with-db requires an argument])
  77          else
  78                 db=$withval
  79          fi],
  80         [: ${db=no}])
  81 AC_ARG_WITH([config-file],
  82 [AS_HELP_STRING([--with-config-file=CF], [use config file CF [CF=SYSCONFDIR/man_db.conf]])],
  83         [if test "$withval" = "yes" || test "$withval" = "no"
  84          then
  85                 AC_MSG_ERROR([--with-config-file requires an argument])
  86          else
  87                 config_file=$withval
  88          fi],
  89         [: ${config_file=\$\{sysconfdir\}/man_db.conf}])
  90 config_file_basename=${withval##*/}
  91 config_file_dirname=`AS_DIRNAME(["$config_file"])`
  92 AC_ARG_WITH([sections],
  93 [AS_HELP_STRING([--with-sections=SECTIONS], [use manual page sections SECTIONS @<:@1 n l 8 3 0 2 5 4 9 6 7@:>@])],
  94         [if test "$withval" = "yes" || test "$withval" = "no"
  95          then
  96                 AC_MSG_ERROR([--with-sections requires an argument])
  97          else
  98                 sections="$withval"
  99          fi],
 100         [: ${sections=1 n l 8 3 2 5 4 9 6 7}])
 101 AC_ARG_ENABLE([automatic-create],
 102 [AS_HELP_STRING([--enable-automatic-create], [allow man to create user databases on the fly])],
 103         [if test "$enableval" = "yes"
 104          then
 105                 AC_DEFINE([MAN_DB_CREATES], [1], [Allow man to create user databases on the fly.])
 106          fi])
 107 AC_ARG_ENABLE([automatic-update],
 108 [AS_HELP_STRING([--disable-automatic-update], [don't allow man to update databases on the fly])],
 109         [if test "$enableval" = "yes"
 110          then
 111                 AC_DEFINE([MAN_DB_UPDATES], [1], [Allow man to update databases on the fly.])
 112          fi],
 113         [AC_DEFINE([MAN_DB_UPDATES], [1], [Allow man to update databases on the fly.])])
 114 AC_ARG_ENABLE([cats],
 115 [AS_HELP_STRING([--disable-cats], [don't allow man to create/update cat files])],
 116         [if test "$enableval" = "yes"
 117          then
 118                 AC_DEFINE([MAN_CATS], [1], [Allow man to create/update cat files.])
 119          fi],
 120         [AC_DEFINE([MAN_CATS], [1], [Allow man to create/update cat files.])])
 121
 122 # Finish the argument parsing.
 123 AC_SUBST([man_owner])dnl
 124 AC_SUBST([man_mode])dnl
 125 AC_SUBST([config_file])dnl
 126 AC_SUBST([config_file_basename])dnl
 127 AC_SUBST([config_file_dirname])dnl
 128 AC_SUBST([sections])dnl
 129
 130 # Check $PATH for the following programs and append suitable options.
 131 AC_PROG_CC
 132 gl_EARLY
 133 AC_PROG_CPP
 134 CFLAGS="$CFLAGS -Wall"
 135 case $host_os in
 136         ultrix4.3*)
 137                 dnl When compiled for BSD environment, each running `man'
 138                 dnl increases the system load as reported by uptime(1) by
 139                 dnl one.  The reason for this behaviour is currently
 140                 dnl unknown, but the load increase does *not* reflect actual
 141                 dnl resource usage.  To avoid it, compile for POSIX
 142                 dnl environment:
 143                 CFLAGS="$CFLAGS -YPOSIX"
 144                 ;;
 145 esac
 146 if test "$GCC" = yes
 147 then
 148         gl_WARN_ADD([-W], [CFLAGS])
 149         gl_WARN_ADD([-Wpointer-arith], [CFLAGS])
 150         gl_WARN_ADD([-Wwrite-strings], [CFLAGS])
 151         gl_WARN_ADD([-Wstrict-prototypes], [CFLAGS])
 152         gl_WARN_ADD([-Wshadow], [CFLAGS])
 153         gl_WARN_ADD([-Wformat-security], [CFLAGS])
 154         gl_WARN_ADD([-Wredundant-decls], [CFLAGS])
 155         gl_WARN_ADD([-Wno-missing-field-initializers], [CFLAGS])
 156 fi
 157 AC_PROG_INSTALL
 158 AC_PROG_LN_S
 159 AC_CHECK_PROGS([cat], [cat])
 160 MAN_CHECK_PROGS([browser], [BROWSER], [use BROWSER as default web browser], [www-browser lynx elinks w3m])
 161 test -n "$browser" && browser="exec $browser"
 162 AC_CHECK_PROGS([tr], [tr])
 163 AC_CHECK_PROGS([grep], [grep])
 164 MAN_CHECK_PROGS([pager], [PAGER], [use PAGER as default pager], [pager less more])
 165 test -n "$pager" && pager="$pager -s"
 166
 167 # Define below (in list of preference) *roff macros to check for.
 168 macros="andoc an doc"
 169
 170 # We have problems here, as different systems have different *roff
 171 # formatters and they accept different options and do different things :(
 172 MAN_CHECK_PROGS([nroff], [NROFF], [use NROFF as roff formatter for character devices], [nroff gnroff groff])
 173 if test -n "$nroff"
 174 then
 175         MAN_PROG_GNU_NROFF([$nroff])
 176         if test "$man_cv_prog_gnu_nroff" != "yes"
 177         then
 178                 MAN_PROG_HEIRLOOM_NROFF([$nroff])
 179         fi
 180         if test -n "$nroff_device"
 181         then
 182                 AC_MSG_CHECKING([that nroff works with argument$nroff_device])
 183                 # We cannot cache this result as it can change between runs
 184                 # of configure.
 185                 if $nroff $nroff_device </dev/null >/dev/null 2>&1 3>&1
 186                 then
 187                         AC_MSG_RESULT([yes])
 188                 else
 189                         AC_MSG_RESULT([no])
 190                         AC_MSG_ERROR([nroff does not work with argument$nroff_device])
 191                 fi
 192         fi
 193         AC_MSG_CHECKING([for appropriate nroff macro])
 194         AC_CACHE_VAL([man_cv_prog_nroff_macro], [
 195
 196         for macro in $macros
 197         do
 198                 if $nroff -m$macro $nroff_device </dev/null >/dev/null 2>&1 3>&1
 199                 then
 200                         man_cv_prog_nroff_macro=-m$macro
 201                         break
 202                 fi
 203         done])
 204
 205         if test -n "$man_cv_prog_nroff_macro"
 206         then
 207                 if test "$man_cv_prog_heirloom_nroff" = "yes"
 208                 then
 209                         # Heirloom works best with some extra options:
 210                         #   -mg: groff compatibility
 211                         #   -msafe: disable privileged operations
 212                         #   -mpadj: clean up line breaking
 213                         man_cv_prog_nroff_macro="-mg -msafe -mpadj ${man_cv_prog_nroff_macro}"
 214                 fi
 215                 nroff="$nroff ${man_cv_prog_nroff_macro}"
 216 dnl             nroff="$nroff ${man_cv_prog_nroff_macro}${nroff_device}"
 217                 AC_MSG_RESULT([$man_cv_prog_nroff_macro])
 218         else
 219                 AC_MSG_RESULT([ambiguous])
 220                 AC_MSG_WARN([please edit include/manconfig.h and add nroff definition])
 221         fi
 222 else
 223         AC_MSG_WARN([Cannot find an nroff-like program, formatting of manual page source will not be supported.])
 224         nroff="(nroff not installed)"
 225         AC_DEFINE([NROFF_MISSING], [1], [Define if you don't have nroff.])
 226 fi
 227
 228 dnl It would be nice to use MAN_CHECK_PROGS here, but how do we determine
 229 dnl TROFF_IS_GROFF?
 230 AC_CHECK_PROGS([troff], [groff])
 231 if test -n "$troff"
 232 then
 233         troff_is_groff=yes
 234         AC_DEFINE([TROFF_IS_GROFF], [1], [Define if you are using groff as troff.])
 235         TROFF=groff
 236 else
 237         troff_is_groff=no
 238         AC_CHECK_PROGS([troff], [troff gtroff])
 239         TROFF=troff
 240 fi
 241 AC_SUBST([TROFF])
 242 if test -n "$troff"
 243 then
 244         AC_DEFINE([HAS_TROFF], [1], [Define if you have troff.])
 245         AC_MSG_CHECKING([for appropriate $TROFF options])
 246         AC_CACHE_VAL([man_cv_prog_troff_options], [
 247         # Do a quick test to see if -t works [AIX needs this], groff doesn't
 248         # as it indicates pre-process with tbl.
 249         test "$TROFF" = "troff" && $troff -t </dev/null >/dev/null 2>&1 3>&1 \
 250                                 && troff_filter="-t "
 251         for macro in $macros
 252         do
 253                 if $troff $troff_filter -m$macro </dev/null >/dev/null 2>&1 3>&1
 254                 then
 255                         man_cv_prog_troff_options="${troff_filter}-m${macro}"
 256                         break
 257                 fi
 258         done])
 259         if test -n "$man_cv_prog_troff_options"
 260         then
 261                 if test "$man_cv_prog_heirloom_nroff" = "yes"
 262                 then
 263                         # Heirloom works best with some extra options:
 264                         #   -mg: groff compatibility
 265                         #   -msafe: disable privileged operations
 266                         #   -mpadj: clean up line breaking
 267                         man_cv_prog_troff_options="-mg -msafe -mpadj ${man_cv_prog_troff_options}"
 268                 fi
 269                 troff="$troff $man_cv_prog_troff_options"
 270                 AC_MSG_RESULT([$man_cv_prog_troff_options])
 271         else
 272                 AC_MSG_RESULT([ambiguous])
 273                 AC_MSG_WARN([please edit include/manconfig.h and add troff definition])
 274         fi
 275 else
 276         troff="(troff not installed)"
 277 fi
 278
 279 AC_CHECK_PROGS([preconv], [gpreconv preconv])
 280
 281 AC_MSG_CHECKING([for groff with Debian multibyte patch or real Unicode support])
 282 man_mb_groff=no
 283 AC_ARG_ENABLE([mb-groff],
 284 [AS_HELP_STRING([--enable-mb-groff], [expect groff with Debian multibyte patch or real Unicode support])],
 285         [if test "$enableval" = "yes"
 286          then
 287                 man_mb_groff=yes
 288          fi],
 289         [if test -n "$preconv"
 290          then
 291                 man_mb_groff=yes
 292          elif test -n "$troff" && test "$troff_is_groff" = "yes"
 293          then
 294                 if $troff -Tnippon </dev/null >/dev/null 2>&1
 295                 then
 296                         man_mb_groff=yes
 297                 fi
 298          fi])
 299 AC_MSG_RESULT([$man_mb_groff])
 300 if test "$man_mb_groff" = "yes"
 301 then
 302         AC_DEFINE([MULTIBYTE_GROFF], 1,
 303                   [Define if your groff installation has the Debian multibyte patch.])
 304 fi
 305
 306 MAN_CHECK_PROGS([eqn], [EQN], [use EQN to preprocess equations], [eqn geqn])
 307 MAN_CHECK_PROGS([neqn], [NEQN], [use NEQN to preprocess equations for character devices], [neqn gneqn])
 308 # If we fail to find an neqn, use eqn and try to force it to output for an
 309 # ascii device. As this is only relevant for equations (?), not using latin1
 310 # should be acceptable. -Tlatin1 is ignored by some eqn implementations.
 311 if test -z "$neqn"
 312 then
 313         test -n "$eqn" &&
 314         (test -n "$nroff_device" && neqn="$eqn -T$nroff_device" || neqn="$eqn -Tascii")
 315 fi
 316 MAN_CHECK_PROGS([tbl], [TBL], [use TBL to preprocess tables], [tbl gtbl])
 317 MAN_CHECK_PROGS([col], [COL], [use COL to filter formatting characters from output], [col gcol])
 318 MAN_CHECK_PROGS([vgrind], [VGRIND], [use VGRIND to preprocess program sources], [vgrind gvgrind])
 319 MAN_CHECK_PROGS([refer], [REFER], [use REFER to preprocess bibliographic references], [refer grefer])
 320 MAN_CHECK_PROGS([grap], [GRAP], [use GRAP to preprocess graphs], [grap])
 321 MAN_CHECK_PROGS([pic], [PIC], [use PIC to preprocess pictures], [pic gpic])
 322 test -n "$pic" && pic="$pic -S"
 323
 324 MAN_CHECK_PROGS([gzip], [GZIP], [use GZIP as GNU compression utility], [gzip])
 325 if test -n "$gzip"
 326 then
 327         gunzip="$gzip -dc"
 328         compressor="$gzip -c7"
 329         compress_ext="gz"
 330 fi
 331 MAN_CHECK_PROGS([compress], [COMPRESS], [use COMPRESS as UNIX compression utility], [compress])
 332 if test -n "$compress"
 333 then
 334         uncompress="$compress -dc"
 335         if test -z "$gzip"
 336         then
 337                 compressor="$compress -c"
 338                 compress_ext="Z"
 339         fi
 340 fi
 341 MAN_CHECK_PROGS([bzip2], [BZIP2], [use BZIP2 as block-sorting compression utility], [bzip2])
 342 if test -n "$bzip2"
 343 then
 344         bunzip2="$bzip2 -dc"
 345 fi
 346 MAN_CHECK_PROGS([xz], [XZ], [use XZ as Lempel-Ziv-Markov chain-Algorithm compression utility], [xz])
 347 if test -n "$xz"
 348 then
 349         unxz="$xz -dc"
 350         unlzma=
 351 else
 352         dnl lzma not used/needed if we have xz
 353         MAN_CHECK_PROGS([lzma], [LZMA], [use LZMA as Lempel-Ziv-Markov chain-Algorithm compression utility], [lzma])
 354         if test -n "$lzma"
 355         then
 356                 unlzma="$lzma -dc"
 357         fi
 358 fi
 359 MAN_CHECK_PROGS([lzip], [LZIP], [use LZIP as Lempel-Ziv-Markov chain-Algorithm compression utility], [lzip])
 360 if test -n "$lzip"
 361 then
 362         unlzip="$lzip -dc"
 363 fi
 364 if test -n "$gzip" || test -n "$compress" || test -n "$bzip2" || test -n "$xz" || test -n "$lzip" || test -n "$lzma"
 365 then
 366         AC_DEFINE([COMP_CAT], [1], [Define if you have compressors and want to support compressed cat files.])
 367         AC_DEFINE([COMP_SRC], [1], [Define if you have compressors and want to support compressed manual source.])
 368 fi
 369 AC_SUBST([compressor])
 370 AC_SUBST([compress_ext])
 371 AC_SUBST([gunzip])
 372 AC_SUBST([uncompress])
 373 AC_SUBST([bunzip2])
 374 AC_SUBST([unlzma])
 375 AC_SUBST([unxz])
 376 AC_SUBST([unlzip])
 377 MAN_COMPRESS_LIB([z], [gzopen])
 378 dnl To add more decompressors just follow the scheme above.
 379
 380 # Work out which manual page hierarchy scheme might be in use.
 381 AC_ARG_ENABLE([mandirs],
 382 [AS_HELP_STRING([--enable-mandirs=OS], [select manual page hierarchy organization (GNU, HPUX, IRIX, Solaris, BSD)])],
 383         [AC_MSG_NOTICE([Using $enableval hierarchy organization(s)])
 384          AC_DEFINE_UNQUOTED([MANDIR_LAYOUT], ["$enableval"],
 385                             [Define to the manual page hierarchy organization(s) in use.])],
 386         [case $host in
 387                 *-gnu)          mandirs=GNU;;
 388                 *-hpux*)        mandirs=HPUX;;
 389                 *-irix*)        mandirs=IRIX;;
 390                 *-solaris*)     mandirs=Solaris;;
 391                 *-bsd*)         mandirs=BSD;;
 392                 *)              mandirs=;;
 393          esac
 394          if test -n "$mandirs"; then
 395                 AC_MSG_NOTICE([Using $mandirs hierarchy organization])
 396                 AC_DEFINE_UNQUOTED([MANDIR_LAYOUT], ["$mandirs"])
 397          else
 398                 AC_MSG_NOTICE([Allowing any hierarchy organization])
 399                 AC_DEFINE([MANDIR_LAYOUT], [""])
 400          fi])
 401
 402 # Check for various header files and associated libraries.
 403 AC_ISC_POSIX
 404 dnl AC_PROG_LEX calls AC_TRY_LINK: must come after above 3
 405 AC_PROG_LEX
 406 gl_INIT
 407 AC_HEADER_SYS_WAIT
 408 AC_HEADER_DIRENT
 409 AC_CHECK_HEADERS([fcntl.h sys/file.h])
 410
 411 # Internationalization support.
 412 AM_GNU_GETTEXT([external])
 413 AM_GNU_GETTEXT_VERSION([0.18.1])
 414 AC_SUBST([LINGUAS])
 415 AM_ICONV
 416 MAN_PO4A
 417 MAN_LINGUAS
 418
 419 # Checks for structures and compiler characteristics.
 420 AC_C_CONST
 421 AC_C_INLINE
 422 AC_TYPE_PID_T
 423 AC_TYPE_UID_T
 424 AC_TYPE_SIZE_T
 425
 426 # Check for pipeline library.
 427 PKG_CHECK_MODULES([libpipeline], [libpipeline >= 1.1.0])
 428
 429 # Find a suitable database interface header and library.
 430 #
 431 # Check for GNU dbm routines.
 432 if test "$db" = "no" || test "$db" = "gdbm"
 433 then
 434   AC_CHECK_HEADER([gdbm.h], [
 435     for lib in gdbm c dbm
 436     do
 437       AC_CHECK_LIB([$lib], [gdbm_fetch],
 438                    test "$lib" = "c" || DBLIBS="-l$lib"
 439                    [AC_DEFINE([GDBM], [1], [Define if you have, and want to use, gdbm interface routines.])
 440                     AC_SUBST([DBTYPE], [gdbm])]
 441                    db=yes, db=no)
 442       if test "$db" = "yes"
 443       then
 444         man_save_LIBS="$LIBS"
 445         LIBS="$LIBS $DBLIBS"
 446         AC_CHECK_FUNCS([gdbm_exists])
 447         LIBS="$man_save_LIBS"
 448         break
 449       fi
 450     done], db=no)
 451 fi
 452
 453 # Check for Berkeley db routines (first version API).
 454 MAN_CHECK_BDB([db5 db], [db5/db_185.h db_185.h], [db5 db-5])
 455 MAN_CHECK_BDB([db4 db], [db4/db_185.h db_185.h], [db4 db-4])
 456 MAN_CHECK_BDB([db3 db], [db3/db_185.h db_185.h], [db3])
 457 MAN_CHECK_BDB([db2 db], [db_185.h db2/db_185.h db2_185.h], [db2 db])
 458 MAN_CHECK_BDB([db1 db], [db/db.h db.h db1/db.h], [db db1])
 459
 460 dnl MAN_CHECK_BDB([db2], [db2_185.h], [db2 db c], [AC_DEFINE(DB_ON_LIBC)])
 461 dnl MAN_CHECK_BDB([db2], [db2/db_185.h], [db2 db c])
 462 dnl # from package libdb1-dev
 463 dnl MAN_CHECK_BDB([db], [db/db.h], [db c])
 464 dnl # from package libc6-dev
 465 dnl # ########## statically linked #####
 466 dnl MAN_CHECK_BDB([db], [db1/db.h], [db c], [AC_DEFINE(DB_ON_LIBC)])
 467
 468 # Check for UNIX ndbm routines.
 469 if test "$db" = "no" || test "$db" = "ndbm"
 470 then
 471   AC_CHECK_HEADER([ndbm.h], [
 472     for lib in ndbm c dbm
 473     do
 474       AC_CHECK_LIB([$lib], [dbm_fetch],
 475                    test "$lib" = "c" || DBLIBS="-l$lib"
 476                    [AC_DEFINE([NDBM], [1], [Define if you have, and want to use, ndbm interface routines.])
 477                     AC_SUBST([DBTYPE], [ndbm])]
 478                    db=yes, db=no)
 479       test "$db" = "yes" && break
 480       done], db=no)
 481 fi
 482
 483 if test "$db" != "yes"
 484 then
 485     if test "$db" = "no"
 486     then
 487       AC_MSG_ERROR([Fatal: no supported database library/header found])
 488     else
 489       AC_MSG_ERROR([Fatal: $db: unsupported database library])
 490     fi
 491 fi
 492 AC_SUBST([DBLIBS])
 493
 494 dnl MAN_ECHO_VAR(ENV-VARIABLE)
 495 define([MAN_ECHO_VAR], [AC_MSG_NOTICE([default $1 = "$$1"])])dnl
 496 dnl
 497 MAN_ECHO_VAR([CC])
 498 MAN_ECHO_VAR([CPP])
 499 MAN_ECHO_VAR([CPPFLAGS])
 500 MAN_ECHO_VAR([CFLAGS])
 501 MAN_ECHO_VAR([LDFLAGS])
 502 MAN_ECHO_VAR([LIBS])
 503 MAN_ECHO_VAR([DBLIBS])
 504
 505 # Transformed versions of program names for use in Automake variables.
 506 MAN_TRANS_SUBST([apropos])
 507 MAN_TRANS_SUBST([catman])
 508 MAN_TRANS_SUBST([lexgrog])
 509 MAN_TRANS_SUBST([man])
 510 MAN_TRANS_SUBST([manconv])
 511 MAN_TRANS_SUBST([mandb])
 512 MAN_TRANS_SUBST([manpath])
 513 MAN_TRANS_SUBST([whatis])
 514 MAN_TRANS_SUBST([zsoelim])
 515
 516 # If we're cross-compiling, tests won't work.
 517 AM_CONDITIONAL([CROSS_COMPILING], [test "x$cross_compiling" = xyes])
 518
 519 AC_CONFIG_FILES([Makefile
 520         gnulib/lib/Makefile
 521         gnulib/po/Makefile.in
 522         lib/Makefile
 523         src/Makefile
 524         src/man_db.conf
 525         src/tests/Makefile
 526         man/Makefile
 527         man/replace.sin
 528         man/po4a/Makefile
 529         man/de/Makefile
 530         man/es/Makefile
 531         man/fr/Makefile
 532         man/id/Makefile
 533         man/it/Makefile
 534         man/ja/Makefile
 535         man/nl/Makefile
 536         man/pl/Makefile
 537         man/ru/Makefile
 538         manual/Makefile
 539         libdb/Makefile
 540         docs/Makefile
 541         tools/Makefile
 542         include/comp_src.h
 543         include/manconfig.h
 544         po/Makefile.in])
 545 AC_OUTPUT