configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [5])
   6 m4_define([dbus_micro_version], [9])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22  ## must come before we use the $USE_MAINTAINER_MODE variable later
  23 AM_MAINTAINER_MODE
  24
  25 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  26
  27 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  28
  29 # libtool versioning - this applies to libdbus
  30 #
  31 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  32 #
  33
  34 ## increment if the interface has additions, changes, removals.
  35 LT_CURRENT=9
  36
  37 ## increment any time the source changes; set to
  38 ##  0 if you increment CURRENT
  39 LT_REVISION=4
  40
  41 ## increment if any interfaces have been added; set to 0
  42 ## if any interfaces have been changed or removed. removal has
  43 ## precedence over adding, so set to 0 if both happened.
  44 LT_AGE=6
  45
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 AC_SUBST(LT_AGE)
  49
  50 DBUS_MAJOR_VERSION=dbus_major_version
  51 DBUS_MINOR_VERSION=dbus_minor_version
  52 DBUS_MICRO_VERSION=dbus_micro_version
  53 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  54
  55 AC_SUBST(DBUS_MAJOR_VERSION)
  56 AC_SUBST(DBUS_MINOR_VERSION)
  57 AC_SUBST(DBUS_MICRO_VERSION)
  58 AC_SUBST(DBUS_VERSION)
  59
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_USE_SYSTEM_EXTENSIONS
  64 AC_ISC_POSIX
  65 AC_HEADER_STDC
  66 AC_C_INLINE
  67 AM_PROG_LIBTOOL
  68 AC_PROG_MKDIR_P
  69 COMPILER_COVERAGE
  70 COMPILER_OPTIMISATIONS
  71
  72 # Initialize libtool
  73 LT_INIT([win32-dll])
  74 LT_LANG([Windows Resource])
  75
  76 # Set some internal variables depending on the platform for later use.
  77 dbus_win=no
  78 dbus_cygwin=no
  79 dbus_unix=no
  80 case "${host}" in
  81     *-mingw32ce*)
  82         dbus_win=yes
  83         dbus_wince=yes
  84         ;;
  85     *-mingw32*)
  86         dbus_win=yes
  87         ;;
  88     *-cygwin*)
  89         dbus_cygwin=yes
  90         dbus_unix=yes
  91         ;;
  92     *)
  93         dbus_unix=yes
  94        ;;
  95 esac
  96
  97 # Special defines for certain platforms
  98 if test "$dbus_win" = yes; then
  99     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 100     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 101     AC_SUBST(BUILD_TIMESTAMP)
 102     # Assume DBUS_VERSION is always three numbers
 103     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 104     AC_SUBST(BUILD_FILEVERSION)
 105     AC_CHECK_TOOL(WINDRES, windres, no)
 106     if test "$WINDRES" = no; then
 107       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 108     fi
 109     if test "$dbus_wince" = yes; then
 110       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 111       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 112     fi
 113 else
 114     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 115 fi
 116 if test "$dbus_cygwin" = yes; then
 117     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 118 fi
 119
 120 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 121 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 122 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 123 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 124
 125 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 126 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 127 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 128 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 129 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 130 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 131 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 132 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 133 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 134 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 135 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 136 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 137 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 138 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 139 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 140 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 141
 142 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 143 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 144 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 145 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 146 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 147 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 148 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 149 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 150 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 151 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 152 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 153 AC_ARG_WITH(dbus_session_bus_default_address, AS_HELP_STRING([--with-dbus-session-bus-default-address=[nonce-tcp:/autolaunch:/tcp:host:port]],[Transport Type to be used (default: nonce-tcp:)]),with_dbus_session_bus_default_address=$withval,with_dbus_session_bus_default_address=nonce-tcp:)
 154
 155 AC_ARG_ENABLE([embedded-tests],
 156   AS_HELP_STRING([--enable-embedded-tests],
 157     [enable unit test code in the library and binaries]),
 158   [], [enable_embedded_tests=$USE_MAINTAINER_MODE])
 159 AC_ARG_ENABLE([modular-tests],
 160   AS_HELP_STRING([--enable-modular-tests],
 161     [enable modular regression tests (requires GLib)]),
 162   [], [enable_modular_tests=auto])
 163 # --enable-tests overrides both --enable-embedded-tests and
 164 # --enable-modular-tests
 165 AC_ARG_ENABLE([tests],
 166   AS_HELP_STRING([--enable-tests],
 167     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 168   [
 169   if test "x$enableval" = xyes; then
 170     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 171     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 172   fi
 173   enable_embedded_tests=$enableval
 174   enable_modular_tests=$enableval
 175   ],
 176   [])
 177
 178 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 179 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 180 # name for this.
 181 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 182 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 183   [test "x$enable_embedded_tests" = xyes])
 184 if test "x$enable_embedded_tests" = xyes; then
 185     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 186       [Define to build test code into the library and binaries])
 187     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 188       [Define to build test code into the library and binaries])
 189 fi
 190
 191 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 192 # These use GTest, from GLib, because life's too short. They're enabled by
 193 # default (unless you don't have GLib), because they don't bloat the library
 194 # or binaries.
 195 if test "x$enable_modular_tests" != xno; then
 196   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 197     [],
 198     [if test "x$enable_modular_tests" = xyes; then
 199       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 200       AC_MSG_ERROR([$GLIB_ERRORS])
 201     else # assumed to be "auto"
 202       enable_modular_tests=no
 203     fi])
 204   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 205   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 206     [],
 207     [if test "x$enable_modular_tests" = xyes; then
 208       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 209       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 210     else # assumed to be "auto"
 211       enable_modular_tests=no
 212     fi])
 213   if test "x$enable_modular_tests" != xno; then
 214     # dependencies checked, switch from auto to yes
 215     enable_modular_tests=yes
 216   fi
 217 fi
 218 if test "x$enable_modular_tests" = xyes; then
 219   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 220     [Define to build independent test binaries (requires GLib)])
 221 fi
 222 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 223   [test "x$enable_modular_tests" = xyes])
 224
 225 AC_ARG_ENABLE([installed-tests],
 226   AS_HELP_STRING([--enable-installed-tests],
 227     [enable unit test code in the library and binaries]),
 228   [], [enable_installed_tests=no])
 229 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 230   [test "x$enable_installed_tests" = xyes])
 231
 232 if test "x$enable_tests" = xyes; then
 233   # full test coverage is required, Python is a hard dependency
 234   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 235   AM_PATH_PYTHON([2.6])
 236   AC_MSG_CHECKING([for Python modules for full test coverage])
 237   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 238     AC_MSG_RESULT([yes])
 239   else
 240     AC_MSG_RESULT([no])
 241     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 242   fi
 243 else
 244   # --enable-tests not given: do not abort if Python is missing
 245   AM_PATH_PYTHON([2.6], [], [:])
 246 fi
 247
 248 if test x$enable_verbose_mode = xyes; then
 249     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 250 fi
 251
 252 if test x$enable_asserts = xno; then
 253     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 254     DISABLE_UNUSED_WARNINGS="unused-label"
 255     R_DYNAMIC_LDFLAG=""
 256 else
 257     # -rdynamic is needed for glibc's backtrace_symbols to work.
 258     # No clue how much overhead this adds, but it's useful
 259     # to do this on any assertion failure,
 260     # so for now it's enabled anytime asserts are (currently not
 261     # in production builds).
 262
 263     # To get -rdynamic you pass -export-dynamic to libtool.
 264     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 265     R_DYNAMIC_LDFLAG=-export-dynamic
 266 fi
 267 AC_SUBST(R_DYNAMIC_LDFLAG)
 268
 269 if test x$enable_checks = xno; then
 270     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 271     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 272     DISABLE_UNUSED_WARNINGS="unused-label"
 273 fi
 274
 275 if test x$enable_userdb_cache = xyes; then
 276     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 277 fi
 278
 279 if test x$enable_compiler_coverage = xyes; then
 280      ## so that config.h changes when you toggle gcov support
 281      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 282 fi
 283
 284 # glibc21.m4 serial 3
 285 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 286 dnl This file is free software; the Free Software Foundation
 287 dnl gives unlimited permission to copy and/or distribute it,
 288 dnl with or without modifications, as long as this notice is preserved.
 289
 290 # Test for the GNU C Library, version 2.1 or newer.
 291 # From Bruno Haible.
 292
 293 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 294   ac_cv_gnu_library_2_1,
 295   [AC_EGREP_CPP([Lucky GNU user],
 296     [
 297 #include <features.h>
 298 #ifdef __GNU_LIBRARY__
 299  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 300   Lucky GNU user
 301  #endif
 302 #endif
 303     ],
 304     ac_cv_gnu_library_2_1=yes,
 305     ac_cv_gnu_library_2_1=no)
 306   ]
 307 )
 308
 309 #### Integer sizes
 310
 311 AC_CHECK_SIZEOF(char)
 312 AC_CHECK_SIZEOF(short)
 313 AC_CHECK_SIZEOF(long)
 314 AC_CHECK_SIZEOF(int)
 315 AC_CHECK_SIZEOF(void *)
 316 AC_CHECK_SIZEOF(long long)
 317 AC_CHECK_SIZEOF(__int64)
 318
 319 AC_ARG_WITH([64-bit],
 320   [AS_HELP_STRING([--without-64-bit],
 321     [If you have to use this option, please report it as a bug])],
 322   [],
 323   [with_64_bit=yes])
 324
 325 ### See what our 64 bit type is called
 326 AC_MSG_CHECKING([64-bit integer type])
 327
 328 case 8 in
 329 $ac_cv_sizeof_int)
 330   dbusint64=int
 331   dbusint64_constant='(val)'
 332   dbusuint64_constant='(val)'
 333   dbusint64_printf_modifier='""'
 334   ;;
 335 $ac_cv_sizeof_long)
 336   dbusint64=long
 337   dbusint64_constant='(val##L)'
 338   dbusuint64_constant='(val##UL)'
 339   dbusint64_printf_modifier='"l"'
 340   ;;
 341 $ac_cv_sizeof_long_long)
 342   dbusint64='long long'
 343   dbusint64_constant='(val##LL)'
 344   dbusuint64_constant='(val##ULL)'
 345   # Ideally we discover what the format is, but this is
 346   # only used in verbose mode, so eh...
 347   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 348     dbusint64_printf_modifier='"ll"'
 349   fi
 350   ;;
 351 $ac_cv_sizeof___int64)
 352   dbusint64=__int64
 353   dbusint64_constant='(val##i64)'
 354   dbusuint64_constant='(val##ui64)'
 355   # See above case
 356   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 357     dbusint64_printf_modifier='"ll"'
 358   fi
 359   ;;
 360 esac
 361
 362 AS_IF(
 363   [test "x$with_64_bit" = xno],
 364   [
 365         DBUS_INT64_TYPE="no_int64_type_detected"
 366         DBUS_HAVE_INT64=0
 367         DBUS_INT64_CONSTANT=
 368         DBUS_UINT64_CONSTANT=
 369         AC_MSG_RESULT([disabled via --without-64-bit])
 370   ],
 371   dnl else if
 372   [test -z "$dbusint64"],
 373   [AC_MSG_RESULT([not found])
 374   AC_MSG_ERROR([Could not find a 64-bit integer type.
 375
 376 Please report a bug here with details of your platform and compiler:
 377
 378     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 379
 380 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 381 the option "--without-64-bit".
 382
 383 This option is likely to be removed in future, unless you report that your
 384 platform needs it.])
 385   ],
 386   dnl else
 387   [
 388         DBUS_INT64_TYPE="$dbusint64"
 389         DBUS_HAVE_INT64=1
 390         DBUS_INT64_CONSTANT="$dbusint64_constant"
 391         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 392         if test x"$dbusint64_printf_modifier" != x; then
 393                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 394         fi
 395         AC_MSG_RESULT($DBUS_INT64_TYPE)
 396   ])
 397
 398 AC_SUBST(DBUS_INT64_TYPE)
 399 AC_SUBST(DBUS_INT64_CONSTANT)
 400 AC_SUBST(DBUS_UINT64_CONSTANT)
 401 AC_SUBST(DBUS_HAVE_INT64)
 402
 403 ### see what 32-bit int is called
 404 AC_MSG_CHECKING([32-bit integer type])
 405
 406 case 4 in
 407 $ac_cv_sizeof_short)
 408   dbusint32=short
 409   ;;
 410 $ac_cv_sizeof_int)
 411   dbusint32=int
 412   ;;
 413 $ac_cv_sizeof_long)
 414   dbusint32=long
 415   ;;
 416 esac
 417
 418 if test -z "$dbusint32" ; then
 419         DBUS_INT32_TYPE="no_int32_type_detected"
 420         AC_MSG_ERROR([No 32-bit integer type found])
 421 else
 422         DBUS_INT32_TYPE="$dbusint32"
 423         AC_MSG_RESULT($DBUS_INT32_TYPE)
 424 fi
 425
 426 AC_SUBST(DBUS_INT32_TYPE)
 427
 428 ### see what 16-bit int is called
 429 AC_MSG_CHECKING([16-bit integer type])
 430
 431 case 2 in
 432 $ac_cv_sizeof_short)
 433   dbusint16=short
 434   ;;
 435 $ac_cv_sizeof_int)
 436   dbusint16=int
 437   ;;
 438 esac
 439
 440 if test -z "$dbusint16" ; then
 441         DBUS_INT16_TYPE="no_int16_type_detected"
 442         AC_MSG_ERROR([No 16-bit integer type found])
 443 else
 444         DBUS_INT16_TYPE="$dbusint16"
 445         AC_MSG_RESULT($DBUS_INT16_TYPE)
 446 fi
 447
 448 AC_SUBST(DBUS_INT16_TYPE)
 449
 450 ## byte order
 451 case $host_os in
 452         darwin*)
 453                 # check at compile-time, so that it is possible to build universal
 454                 # (with multiple architectures at once on the compile line)
 455                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 456                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 457                         #if defined(__BIG_ENDIAN__)
 458                         #define WORDS_BIGENDIAN 1
 459                         #endif
 460                 ])
 461                 ;;
 462         *)
 463                 AC_C_BIGENDIAN
 464                 ;;
 465 esac
 466
 467 dnl **********************************
 468 dnl *** va_copy checks (from GLib) ***
 469 dnl **********************************
 470 dnl we currently check for all three va_copy possibilities, so we get
 471 dnl all results in config.log for bug reports.
 472 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 473         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 474 #include <stdlib.h>
 475         static void f (int i, ...) {
 476         va_list args1, args2;
 477         va_start (args1, i);
 478         va_copy (args2, args1);
 479         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 480           exit (1);
 481         va_end (args1); va_end (args2);
 482         }
 483         int main() {
 484           f (0, 42);
 485           return 0;
 486         }])],
 487         [dbus_cv_va_copy=yes],
 488         [dbus_cv_va_copy=no])
 489 ])
 490 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 491         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 492 #include <stdlib.h>
 493         static void f (int i, ...) {
 494         va_list args1, args2;
 495         va_start (args1, i);
 496         __va_copy (args2, args1);
 497         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 498           exit (1);
 499         va_end (args1); va_end (args2);
 500         }
 501         int main() {
 502           f (0, 42);
 503           return 0;
 504         }])],
 505         [dbus_cv___va_copy=yes],
 506         [dbus_cv___va_copy=no])
 507 ])
 508
 509 if test "x$dbus_cv_va_copy" = "xyes"; then
 510   dbus_va_copy_func=va_copy
 511 else if test "x$dbus_cv___va_copy" = "xyes"; then
 512   dbus_va_copy_func=__va_copy
 513 fi
 514 fi
 515
 516 if test -n "$dbus_va_copy_func"; then
 517   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 518 fi
 519
 520 AC_LANG_PUSH(C)
 521 AC_CACHE_CHECK([whether va_lists can be copied by value],
 522         dbus_cv_va_val_copy,
 523         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 524 [[
 525         #include <stdarg.h>
 526         #include <stdlib.h>
 527 ]],
 528 [[
 529         static void f (int i, ...) {
 530         va_list args1, args2;
 531         va_start (args1, i);
 532         args2 = args1;
 533         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 534           exit (1);
 535         va_end (args1); va_end (args2);
 536         }
 537         int main() {
 538           f (0, 42);
 539           return 0;
 540         }
 541 ]])],
 542         [dbus_cv_va_val_copy=yes],
 543         [dbus_cv_va_val_copy=no],
 544         [dbus_cv_va_val_copy=yes])
 545 ])
 546 AC_LANG_POP(C)
 547
 548 if test "x$dbus_cv_va_val_copy" = "xno"; then
 549   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 550 fi
 551
 552
 553 #### Atomic integers
 554
 555 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 556   dbus_cv_sync_sub_and_fetch,
 557   [AC_LINK_IFELSE([
 558      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 559      [dbus_cv_sync_sub_and_fetch=yes],
 560      [dbus_cv_sync_sub_and_fetch=no])
 561   ])
 562
 563 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 564    have_sync=1
 565 else
 566    have_sync=0
 567 fi
 568
 569 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 570
 571 #### Various functions
 572 AC_SEARCH_LIBS(socket,[socket network])
 573 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 574
 575 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 576
 577 AC_CHECK_HEADERS([syslog.h])
 578 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 579   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 580 fi
 581
 582 #### Check for broken poll; taken from Glib's configure
 583
 584 AC_MSG_CHECKING([for broken poll])
 585 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 586     #include <stdlib.h>
 587     #include <fcntl.h>
 588     #include <poll.h>
 589     #ifdef HAVE_SYS_POLL_H
 590     #include <sys/poll.h>
 591     #endif
 592     int main(void) {
 593       struct pollfd fds[1];
 594       int fd;
 595       fd = open("/dev/null", 1);
 596       fds[0].fd = fd;
 597       fds[0].events = POLLIN;
 598       fds[0].revents = 0;
 599       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 600             exit(1);  /* Does not work for devices -- fail */
 601       }
 602       exit(0);
 603     }]])],
 604   [broken_poll=no],
 605   [broken_poll=yes
 606    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 607   [broken_poll="no (cross compiling)"])
 608 AC_MSG_RESULT($broken_poll)
 609
 610 AC_MSG_CHECKING(for dirfd)
 611 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 612 #include <sys/types.h>
 613 #include <dirent.h>
 614 ]], [[
 615 DIR *dirp;
 616 dirp = opendir(".");
 617 dirfd(dirp);
 618 closedir(dirp);
 619 ]])],
 620 [dbus_have_dirfd=yes],
 621 [dbus_have_dirfd=no])
 622 AC_MSG_RESULT($dbus_have_dirfd)
 623 if test "$dbus_have_dirfd" = yes; then
 624         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 625 else
 626         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 627         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 628 #include <sys/types.h>
 629 #include <dirent.h>
 630         ]], [[
 631 DIR *dirp;
 632 int fd;
 633 dirp = opendir(".");
 634 fd = dirp->dd_fd;
 635 closedir(dirp);
 636         ]])],
 637         [dbus_have_ddfd=yes],
 638         [dbus_have_ddfd=no])
 639         AC_MSG_RESULT($dbus_have_ddfd)
 640         if test "$dbus_have_ddfd" = yes; then
 641                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 642         fi
 643 fi
 644
 645 AC_CHECK_HEADERS(sys/resource.h)
 646
 647 AC_CHECK_HEADERS(dirent.h)
 648
 649 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 650
 651 AC_CHECK_HEADERS(errno.h)
 652
 653 AC_CHECK_HEADERS(signal.h)
 654
 655 AC_CHECK_HEADERS(locale.h)
 656
 657 AC_CHECK_HEADERS(byteswap.h)
 658
 659 AC_CHECK_HEADERS(unistd.h)
 660
 661 AC_CHECK_HEADERS(ws2tcpip.h)
 662
 663 AC_CHECK_HEADERS(wspiapi.h)
 664
 665 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 666 #
 667 case $host_os in
 668     solaris*)
 669        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 670 esac
 671
 672 # checking for a posix version of getpwnam_r
 673 # if we are cross compiling and can not run the test
 674 # assume getpwnam_r is the posix version
 675 # it is up to the person cross compiling to change
 676 # this behavior if desired
 677 AC_LANG_PUSH(C)
 678 AC_CACHE_CHECK([for posix getpwnam_r],
 679                 ac_cv_func_posix_getpwnam_r,
 680                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 681 [[
 682 #include <errno.h>
 683 #include <pwd.h>
 684 ]],
 685 [[
 686     char buffer[10000];
 687     struct passwd pwd, *pwptr = &pwd;
 688     int error;
 689     errno = 0;
 690     error = getpwnam_r ("", &pwd, buffer,
 691                         sizeof (buffer), &pwptr);
 692    return (error < 0 && errno == ENOSYS)
 693            || error == ENOSYS;
 694 ]])],
 695         [ac_cv_func_posix_getpwnam_r=yes],
 696         [ac_cv_func_posix_getpwnam_r=no],
 697         [ac_cv_func_posix_getpwnam_r=yes]
 698 )])
 699 AC_LANG_POP(C)
 700
 701 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 702         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 703                 [Have POSIX function getpwnam_r])
 704 else
 705         AC_CACHE_CHECK([for nonposix getpwnam_r],
 706                 ac_cv_func_nonposix_getpwnam_r,
 707                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 708                         struct passwd pwd;
 709                         getpwnam_r ("", &pwd, buffer,
 710                                         sizeof (buffer));]])],
 711                         [ac_cv_func_nonposix_getpwnam_r=yes],
 712                         [ac_cv_func_nonposix_getpwnam_r=no])])
 713                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 714                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 715                         [Have non-POSIX function getpwnam_r])
 716         fi
 717 fi
 718
 719 dnl check for socklen_t
 720 AC_MSG_CHECKING(whether socklen_t is defined)
 721 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 722 #include <sys/types.h>
 723 #include <sys/socket.h>
 724 #include <netdb.h>
 725 ]], [[
 726 socklen_t foo;
 727 foo = 1;
 728 ]])],
 729 [dbus_have_socklen_t=yes],
 730 [dbus_have_socklen_t=no])
 731 AC_MSG_RESULT($dbus_have_socklen_t)
 732
 733 if test "x$dbus_have_socklen_t" = "xyes"; then
 734     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 735 fi
 736
 737 dnl check for writev header and writev function so we're
 738 dnl good to go if HAVE_WRITEV gets defined.
 739 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 740
 741 dnl needed on darwin for NAME_MAX
 742 AC_CHECK_HEADERS(sys/syslimits.h)
 743
 744 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 745 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 746
 747 dnl check for flavours of varargs macros (test from GLib)
 748 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 749 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 750 int a(int p1, int p2, int p3);
 751 #define call_a(...) a(1,__VA_ARGS__)
 752 call_a(2,3);
 753 ]])],
 754 [dbus_have_iso_c_varargs=yes],
 755 [dbus_have_iso_c_varargs=no])
 756 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 757
 758 AC_MSG_CHECKING(for GNUC varargs macros)
 759 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 760 int a(int p1, int p2, int p3);
 761 #define call_a(params...) a(1,params)
 762 call_a(2,3);
 763 ]])],
 764 [dbus_have_gnuc_varargs=yes],
 765 [dbus_have_gnuc_varargs=no])
 766 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 767
 768 dnl Output varargs tests
 769 if test x$dbus_have_iso_c_varargs = xyes; then
 770     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 771 fi
 772 if test x$dbus_have_gnuc_varargs = xyes; then
 773     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 774 fi
 775
 776 dnl Check for various credentials.
 777 AC_MSG_CHECKING(for struct cmsgcred)
 778 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 779 #include <sys/types.h>
 780 #include <sys/socket.h>
 781 ]], [[
 782 struct cmsgcred cred;
 783
 784 cred.cmcred_pid = 0;
 785 ]])],
 786 [dbus_have_struct_cmsgcred=yes],
 787 [dbus_have_struct_cmsgcred=no])
 788 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 789
 790 if test x$dbus_have_struct_cmsgcred = xyes; then
 791     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 792 fi
 793
 794 AC_CHECK_FUNCS(getpeerucred getpeereid)
 795
 796 AC_CHECK_FUNCS(pipe2 accept4)
 797
 798 #### Abstract sockets
 799
 800 if test x$enable_abstract_sockets = xauto; then
 801 AC_LANG_PUSH(C)
 802 warn_on_xcompile=no
 803 AC_CACHE_CHECK([abstract socket namespace],
 804                 ac_cv_have_abstract_sockets,
 805                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 806 [[
 807 #include <sys/types.h>
 808 #include <stdlib.h>
 809 #include <string.h>
 810 #include <stdio.h>
 811 #include <sys/socket.h>
 812 #include <sys/un.h>
 813 #include <errno.h>
 814 ]],
 815 [[
 816   size_t slen;
 817   int listen_fd;
 818   struct sockaddr_un addr;
 819
 820   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 821
 822   if (listen_fd < 0)
 823     {
 824       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 825       exit (1);
 826     }
 827
 828   memset (&addr, '\0', sizeof (addr));
 829   addr.sun_family = AF_UNIX;
 830   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 831   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 832    * beginning.
 833    */
 834   slen = SUN_LEN(&addr);
 835   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 836
 837   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 838     {
 839        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 840                 strerror (errno));
 841        exit (1);
 842     }
 843   else
 844     exit (0);
 845 ]])],
 846               [ac_cv_have_abstract_sockets=yes],
 847               [ac_cv_have_abstract_sockets=no],
 848               [
 849                 ac_cv_have_abstract_sockets=no
 850                 warn_on_xcompile=yes
 851               ]
 852 )])
 853 if test x$warn_on_xcompile = xyes ; then
 854   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 855 fi
 856 AC_LANG_POP(C)
 857 fi
 858
 859 if test x$enable_abstract_sockets = xyes; then
 860     if test x$ac_cv_have_abstract_sockets = xno; then
 861         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 862     fi
 863 fi
 864
 865 if test x$enable_abstract_sockets = xno; then
 866    ac_cv_have_abstract_sockets=no;
 867 fi
 868
 869 if test x$ac_cv_have_abstract_sockets = xyes ; then
 870    DBUS_PATH_OR_ABSTRACT=abstract
 871    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 872 else
 873    DBUS_PATH_OR_ABSTRACT=path
 874 fi
 875
 876 # this is used in addresses to prefer abstract, e.g.
 877 # unix:path=/foo or unix:abstract=/foo
 878 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 879
 880 PKG_PROG_PKG_CONFIG
 881
 882 #### Sort out XML library
 883
 884 # see what we have
 885 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 886              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 887              have_expat=false)
 888
 889 # see what we want to use
 890 dbus_use_libxml=false
 891 dbus_use_expat=false
 892 if test x$with_xml = xexpat; then
 893         if ! $have_expat ; then
 894            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 895         fi
 896         dbus_use_expat=true
 897 elif test x$with_xml = xlibxml; then
 898         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 899         if ! $have_libxml ; then
 900            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 901         fi
 902         dbus_use_libxml=true
 903 else
 904         ### expat is the default because libxml can't currently survive
 905         ### our brutal OOM-handling unit test setup.
 906         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 907         if test x$have_expat = xfalse; then
 908                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 909         fi
 910         ### By default, only use Expat since it's tested and known to work.  If you're a
 911         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 912         ### if your OS is built around libxml, that's another case.
 913         dbus_use_expat=true
 914 fi
 915
 916 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 917 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 918
 919 if $dbus_use_expat; then
 920    XML_LIBS=-lexpat
 921    XML_CFLAGS=
 922 fi
 923 if $dbus_use_libxml; then
 924    XML_LIBS=$LIBXML_LIBS
 925    XML_CFLAGS=$LIBXML_CFLAGS
 926 fi
 927 AC_SUBST([XML_CFLAGS])
 928 AC_SUBST([XML_LIBS])
 929
 930 # Thread lib detection
 931 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 932                                                     [THREAD_LIBS="-lpthread"])])
 933 save_libs="$LIBS"
 934 LIBS="$LIBS $THREAD_LIBS"
 935 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 936 if test x$have_pthread_condattr_setclock = xtrue; then
 937     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 938     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 939     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 940 #include <pthread.h>
 941 ]], [[
 942 struct timespec monotonic_timer;
 943 pthread_condattr_t attr;
 944 pthread_condattr_init (&attr);
 945 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 946 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 947 ]])],
 948 [have_clock_monotonic=true],
 949 [have_clock_monotonic=false])
 950 if test x$have_clock_monotonic = xtrue; then
 951     AC_MSG_RESULT([found])
 952     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 953 else
 954     AC_MSG_RESULT([not found])
 955 fi
 956 fi
 957 LIBS="$save_libs"
 958
 959 AC_SUBST([THREAD_LIBS])
 960
 961 # SELinux detection
 962 if test x$enable_selinux = xno ; then
 963     have_selinux=no;
 964 else
 965     # See if we have SELinux library
 966     AC_CHECK_LIB(selinux, is_selinux_enabled,
 967                  have_selinux=yes, have_selinux=no)
 968
 969     # see if we have the SELinux header with the new D-Bus stuff in it
 970     if test x$have_selinux = xyes ; then
 971         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 972         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 973                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 974                             #else
 975                             #error DBUS__ACQUIRE_SVC not defined
 976                             #endif]])],
 977                           [have_selinux=yes],
 978                           [have_selinux=no])
 979         AC_MSG_RESULT($have_selinux)
 980     fi
 981
 982     if test x$enable_selinux = xauto ; then
 983         if test x$have_selinux = xno ; then
 984                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 985         fi
 986     else
 987         if test x$have_selinux = xno ; then
 988                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 989         fi
 990     fi
 991 fi
 992
 993 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 994
 995 if test x$have_selinux = xyes ; then
 996     # the selinux code creates threads
 997     # which requires libpthread even on linux
 998     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 999                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1000
1001     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1002     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1003 else
1004     SELINUX_LIBS=
1005 fi
1006
1007 # inotify checks
1008 if test x$enable_inotify = xno ; then
1009     have_inotify=no;
1010 else
1011     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1012 fi
1013
1014 dnl check if inotify backend is enabled
1015 if test x$have_inotify = xyes; then
1016    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1017    AC_CHECK_FUNCS(inotify_init1)
1018 fi
1019
1020 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1021
1022 # dnotify checks
1023 if test x$enable_dnotify = xno ; then
1024     have_dnotify=no;
1025 else
1026     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1027         have_dnotify=yes;
1028     else
1029         have_dnotify=no;
1030     fi
1031 fi
1032
1033 dnl check if dnotify backend is enabled
1034 if test x$have_dnotify = xyes; then
1035    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1036 fi
1037
1038 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1039
1040 # For simplicity, we require the userland API for epoll_create1 at
1041 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1042 # not to have it at runtime.
1043 AC_ARG_ENABLE([epoll],
1044               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1045               [enable_epoll=$enableval], [enable_epoll=auto])
1046 if test x$enable_epoll = xno; then
1047     have_linux_epoll=no
1048 else
1049     AC_MSG_CHECKING([for Linux epoll(4)])
1050     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1051         [
1052         #ifndef __linux__
1053         #error This is not Linux
1054         #endif
1055         #include <sys/epoll.h>
1056         ],
1057         [epoll_create1 (EPOLL_CLOEXEC);])],
1058         [have_linux_epoll=yes],
1059         [have_linux_epoll=no])
1060     AC_MSG_RESULT([$have_linux_epoll])
1061 fi
1062 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1063     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1064 fi
1065 if test x$have_linux_epoll = xyes; then
1066   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1067 fi
1068 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1069
1070 # kqueue checks
1071 if test x$enable_kqueue = xno ; then
1072     have_kqueue=no
1073 else
1074     have_kqueue=yes
1075     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1076     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1077
1078     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1079         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1080     fi
1081 fi
1082
1083 dnl check if kqueue backend is enabled
1084 if test x$have_kqueue = xyes; then
1085    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1086 fi
1087
1088 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1089
1090 # launchd checks
1091 if test x$enable_launchd = xno ; then
1092     have_launchd=no
1093 else
1094     have_launchd=yes
1095     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1096     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1097     if test "x$LAUNCHCTL" = "x"; then
1098         have_launchd=no
1099     fi
1100
1101     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1102         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1103     fi
1104 fi
1105
1106 dnl check if launchd is enabled
1107 if test x$have_launchd = xyes; then
1108     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1109 fi
1110
1111 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1112
1113 #### Directory to place launchd agent file
1114 if test "x$with_launchd_agent_dir" = "x"; then
1115    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1116 else
1117    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1118 fi
1119
1120 AC_SUBST(LAUNCHD_AGENT_DIR)
1121
1122 dnl console owner file
1123 if test x$enable_console_owner_file = xno ; then
1124     have_console_owner_file=no;
1125 else
1126     case $host_os in
1127     solaris*)
1128         have_console_owner_file=yes;
1129         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1130         ;;
1131     *)
1132         have_console_owner_file=no;;
1133     esac
1134 fi
1135
1136 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1137
1138 dnl systemd detection
1139 if test x$enable_systemd = xno ; then
1140     have_systemd=no;
1141 else
1142     PKG_CHECK_MODULES(SYSTEMD,
1143         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1144         have_systemd=yes,
1145         have_systemd=no)
1146     AC_SUBST(SYSTEMD_CFLAGS)
1147     AC_SUBST(SYSTEMD_LIBS)
1148 fi
1149
1150 if test x$have_systemd = xyes; then
1151     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1152 fi
1153
1154 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1155     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1156 fi
1157
1158 # libaudit detection
1159 if test x$enable_libaudit = xno ; then
1160     have_libaudit=no;
1161 else
1162     # See if we have audit daemon & capabilities library
1163     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1164                  have_libaudit=yes, have_libaudit=no)
1165     if test x$have_libaudit = xyes ; then
1166         AC_CHECK_LIB(cap-ng, capng_clear,
1167                  have_libaudit=yes, have_libaudit=no)
1168     fi
1169 fi
1170
1171 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1172
1173 if test x$have_libaudit = xyes ; then
1174     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1175     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1176 fi
1177
1178 AC_SUBST([SELINUX_LIBS])
1179
1180 # Check for ADT API (Solaris Basic Security Mode auditing)
1181 AC_MSG_CHECKING(for ADT API)
1182 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1183 #include <bsm/adt.h>
1184 adt_user_context = ADT_USER;
1185 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1186
1187 if test ${check_adt_audit} = yes
1188 then
1189    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1190    ADT_LIBS="-lbsm"
1191    LIBS="-lbsm $LIBS"
1192    AC_MSG_RESULT(yes)
1193 else
1194    AC_MSG_RESULT(no)
1195 fi
1196 AC_SUBST([ADT_LIBS])
1197
1198 # Check for SCM_RIGHTS
1199 AC_MSG_CHECKING([for SCM_RIGHTS])
1200 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1201 #include <sys/socket.h>
1202 #include <sys/un.h>
1203 static int x = SCM_RIGHTS;
1204 ]], [[]])],
1205 [ AC_MSG_RESULT([supported])
1206   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1207 [ AC_MSG_RESULT([not supported]) ])
1208
1209 NETWORK_libs=
1210 if test x$dbus_win = xyes ; then
1211   if test x$dbus_wince = xyes ; then
1212     NETWORK_libs="-lws2"
1213   else
1214     NETWORK_libs="-lws2_32"
1215   fi
1216 fi
1217
1218 AC_SUBST([NETWORK_libs])
1219
1220 #### Set up final flags
1221 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1222 AC_SUBST([LIBDBUS_LIBS])
1223
1224 ### X11 detection
1225 DBUS_X_LIBS=
1226 DBUS_X_CFLAGS=
1227
1228 AC_ARG_ENABLE([x11-autolaunch],
1229   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1230   [], [enable_x11_autolaunch=auto])
1231
1232 if test "x$dbus_win" = xyes; then
1233     if test "x$enable_x11_autolaunch" = xyes; then
1234         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1235     fi
1236
1237     enable_x11_autolaunch=no
1238     have_x11=no
1239 else
1240     AC_PATH_XTRA
1241
1242     if test "x$no_x" = xyes; then
1243         have_x11=no
1244     else
1245         have_x11=yes
1246         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1247         DBUS_X_CFLAGS="$X_CFLAGS"
1248     fi
1249 fi
1250
1251 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1252     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1253 else
1254     # move from "auto" to "yes" or "no" if necessary
1255     if test "x$enable_x11_autolaunch" != xno; then
1256         enable_x11_autolaunch="$have_x11"
1257     fi
1258 fi
1259
1260 if test "x$have_x11" = xyes ; then
1261    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1262 fi
1263
1264 if test "x$enable_x11_autolaunch" = xyes ; then
1265    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1266 fi
1267
1268 AC_SUBST([DBUS_X_CFLAGS])
1269 AC_SUBST([DBUS_X_LIBS])
1270
1271 #### gcc warning flags
1272
1273 cc_supports_flag() {
1274   AC_MSG_CHECKING(whether $CC supports "$*")
1275   save_CFLAGS="$CFLAGS"
1276   CFLAGS="$*"
1277   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1278   CFLAGS="$save_CFLAGS"
1279   AC_MSG_RESULT([$rc])
1280   test "x$rc" = xyes
1281 }
1282
1283 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1284   dnl Use -Werror by default if:
1285   dnl - we're not on Windows (too many warnings), and
1286   dnl - we're in maintainer mode (a D-Bus developer, not a distro or end-user)
1287   dnl Override with --enable-Werror or --disable-Werror
1288   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes],
1289
1290   dnl Enable these warnings if possible:
1291   [all \
1292    extra \
1293    char-subscripts \
1294    missing-declarations \
1295    missing-prototypes \
1296    nested-externs \
1297    pointer-arith \
1298    cast-align \
1299    no-address \
1300    float-equal \
1301    declaration-after-statement \
1302   ],
1303
1304   dnl Disable these warnings if possible, make them non-fatal if possible,
1305   dnl and don't enable -Werror unless we succeeded.
1306   dnl
1307   dnl Intentional:
1308   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1309   dnl   checking or not asserting
1310   dnl - missing field initializers being 0 is a C feature, not a bug
1311   dnl - unused-parameter is to make writing callbacks less annoying
1312   dnl
1313   dnl To be fixed one day:
1314   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1315   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1316   dnl   is better than nothing
1317   [$DISABLE_UNUSED_WARNINGS \
1318    missing-field-initializers \
1319    unused-parameter \
1320    sign-compare \
1321    pointer-sign \
1322    type-limits \
1323   ])
1324
1325 if test "x$GCC" = "xyes"; then
1326   # We're treating -fno-common like a warning: it makes the linker more
1327   # strict, because on some systems the linker is *always* this strict
1328   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1329
1330   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1331   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1332
1333   if test "x$enable_ansi" = "xyes"; then
1334     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1335       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1336   fi
1337 fi
1338
1339 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1340 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1341 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1342 dnl is the next best thing
1343 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1344
1345 case $host_os in
1346     solaris*)
1347         # Solaris' C library apparently needs these runes to be threadsafe...
1348         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1349         # ... and this opt-in to get file descriptor passing support
1350         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1351         ;;
1352 esac
1353
1354 ### Doxygen Documentation
1355
1356 AC_PATH_PROG(DOXYGEN, doxygen, no)
1357
1358 AC_MSG_CHECKING([whether to build Doxygen documentation])
1359
1360 if test x$DOXYGEN = xno ; then
1361     have_doxygen=no
1362 else
1363     have_doxygen=yes
1364 fi
1365
1366 if test x$enable_doxygen_docs = xauto ; then
1367     if test x$have_doxygen = xno ; then
1368         enable_doxygen_docs=no
1369     else
1370         enable_doxygen_docs=yes
1371     fi
1372 fi
1373
1374 if test x$enable_doxygen_docs = xyes; then
1375     if test x$have_doxygen = xno; then
1376         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1377     fi
1378 fi
1379
1380 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1381 AC_MSG_RESULT($enable_doxygen_docs)
1382
1383 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1384 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1385
1386 ### XML Documentation
1387
1388 AC_PATH_PROG(XMLTO, xmlto, no)
1389
1390 AC_MSG_CHECKING([whether to build XML documentation])
1391
1392 if test x$XMLTO = xno ; then
1393     have_xmlto=no
1394 else
1395     have_xmlto=yes
1396 fi
1397
1398 if test x$enable_xml_docs = xauto ; then
1399     if test x$have_xmlto = xno ; then
1400         enable_xml_docs=no
1401     else
1402         enable_xml_docs=yes
1403     fi
1404 fi
1405
1406 if test x$enable_xml_docs = xyes; then
1407     if test x$have_xmlto = xno; then
1408         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1409     fi
1410 fi
1411
1412 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1413 AC_MSG_RESULT($enable_xml_docs)
1414
1415 AC_PATH_PROG([MAN2HTML], [man2html])
1416 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1417 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1418
1419 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1420     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1421          x$MAN2HTML != x)
1422
1423 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1424
1425 #### find the actual value for $prefix that we'll end up with
1426 ##   (I know this is broken and should be done in the Makefile, but
1427 ##    that's a major pain and almost nobody actually seems to care)
1428 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1429 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1430 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1431 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1432 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1433 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1434 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1435
1436 #### Check our operating system
1437 operating_system=unknown
1438 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1439    operating_system=redhat
1440 fi
1441
1442 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1443    operating_system=slackware
1444 fi
1445
1446 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1447    operating_system=cygwin
1448 fi
1449
1450 #### Sort out init scripts
1451
1452 if test x$with_init_scripts = x; then
1453     case x$operating_system in
1454         xredhat)        with_init_scripts=redhat ;;
1455         xslackware)     with_init_scripts=slackware ;;
1456         xcygwin)        with_init_scripts=cygwin ;;
1457         *)                      with_init_scripts=none ;;
1458     esac
1459 fi
1460
1461 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1462 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1463 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1464
1465 ##### systemd unit files
1466 AC_ARG_WITH([systemdsystemunitdir],
1467 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1468     [],
1469     [
1470     PKG_CHECK_EXISTS([systemd],
1471       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1472       [with_systemdsystemunitdir=no])
1473     ])
1474 if test "x$with_systemdsystemunitdir" != xno; then
1475    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1476 fi
1477 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1478
1479 ##### Set up location for system bus socket
1480 if ! test -z "$with_system_socket"; then
1481    DBUS_SYSTEM_SOCKET=$with_system_socket
1482 else
1483    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1484 fi
1485
1486 AC_SUBST(DBUS_SYSTEM_SOCKET)
1487 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1488
1489 ## system bus only listens on local domain sockets, and never
1490 ## on an abstract socket (so only root can create the socket)
1491 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1492 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1493 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1494
1495 #### Set up the pid file
1496 if ! test -z "$with_system_pid_file"; then
1497    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1498 elif test x$with_init_scripts = xredhat ; then
1499    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1500 else
1501    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1502 fi
1503
1504 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1505
1506 #### Directory to check for console ownership
1507 if ! test -z "$with_console_auth_dir"; then
1508    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1509 else
1510    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1511 fi
1512
1513 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1514 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1515
1516 #### File to check for console ownership
1517 if test x$have_console_owner_file = xyes; then
1518    if ! test -z "$with_console_owner_file"; then
1519       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1520    else
1521       DBUS_CONSOLE_OWNER_FILE=/dev/console
1522    fi
1523 else
1524   DBUS_CONSOLE_OWNER_FILE=
1525 fi
1526
1527 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1528 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1529
1530 #### User to start the system bus as
1531 if test -z "$with_dbus_user" ; then
1532     DBUS_USER=messagebus
1533 else
1534     DBUS_USER=$with_dbus_user
1535 fi
1536 AC_SUBST(DBUS_USER)
1537 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1538
1539 #### Prefix to install into
1540 DBUS_PREFIX=$EXPANDED_PREFIX
1541 AC_SUBST(DBUS_PREFIX)
1542 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1543
1544 #### Direcotry to install data files into
1545 DBUS_DATADIR=$EXPANDED_DATADIR
1546 AC_SUBST(DBUS_DATADIR)
1547 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1548
1549 #### Directory to install dbus-daemon
1550 if test -z "$with_dbus_daemondir" ; then
1551     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1552 else
1553     DBUS_DAEMONDIR=$with_dbus_daemondir
1554 fi
1555 AC_SUBST(DBUS_DAEMONDIR)
1556 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1557
1558 #### Directory to install the other binaries
1559 DBUS_BINDIR="$EXPANDED_BINDIR"
1560 AC_SUBST(DBUS_BINDIR)
1561 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1562
1563 #### Directory to install the libexec binaries
1564 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1565 AC_SUBST(DBUS_LIBEXECDIR)
1566 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1567
1568 #### Tell tests where to find certain stuff in builddir
1569
1570 DBUS_PWD=`pwd`
1571 # Useful in a cross-compilation environment, where the tests are run on the host system.
1572 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1573                            DBUS_PWD=$withval)
1574
1575 DBUS_TEST_EXEC="$DBUS_PWD/test"
1576 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1577
1578 AC_SUBST([DBUS_TEST_DATA])
1579 AC_SUBST([DBUS_TEST_EXEC])
1580
1581 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1582                    [Full path to the daemon in the builddir])
1583 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1584                    [Extension for executables, typically empty or .exe])
1585
1586 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1587                    [Full path to the daemon in the builddir])
1588 AC_SUBST(TEST_BUS_BINARY)
1589
1590 ## Export the non-setuid external helper
1591 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1592 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1593 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1594                    [Full path to the launch helper test program in the builddir])
1595
1596 #### Find socket directories
1597 if ! test -z "$TMPDIR" ; then
1598    DEFAULT_SOCKET_DIR=$TMPDIR
1599 elif ! test -z "$TEMP" ; then
1600    DEFAULT_SOCKET_DIR=$TEMP
1601 elif ! test -z "$TMP" ; then
1602    DEFAULT_SOCKET_DIR=$TMP
1603 else
1604    DEFAULT_SOCKET_DIR=/tmp
1605 fi
1606
1607 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1608
1609 if ! test -z "$with_test_socket_dir" ; then
1610    TEST_SOCKET_DIR="$with_test_socket_dir"
1611 else
1612    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1613 fi
1614 AC_SUBST(TEST_SOCKET_DIR)
1615 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1616
1617 if test "x$dbus_unix" = xyes; then
1618   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1619 else
1620   TEST_LISTEN="tcp:host=localhost"
1621 fi
1622 AC_SUBST([TEST_LISTEN])
1623 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1624   [Listening address for regression tests])
1625
1626 if ! test -z "$with_session_socket_dir" ; then
1627    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1628 else
1629    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1630 fi
1631 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1632 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1633
1634 if test x$dbus_win = xyes; then
1635         DBUS_SESSION_BUS_DEFAULT_ADDRESS="$with_dbus_session_bus_default_address"
1636 elif test x$have_launchd = xyes; then
1637         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1638 else
1639         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1640 fi
1641 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1642
1643 # darwin needs this to initialize the environment
1644 AC_CHECK_HEADERS(crt_externs.h)
1645 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1646 AH_VERBATIM(_DARWIN_ENVIRON,
1647 [
1648 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1649 # include <sys/time.h>
1650 # include <crt_externs.h>
1651 # define environ (*_NSGetEnviron())
1652 #endif
1653 ])
1654
1655 AC_ARG_ENABLE([stats],
1656   [AS_HELP_STRING([--enable-stats],
1657     [enable bus daemon usage statistics])],
1658   [], [enable_stats=no])
1659 if test "x$enable_stats" = xyes; then
1660   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1661     [Define to enable bus daemon usage statistics])
1662 fi
1663
1664 AC_CONFIG_FILES([
1665 Doxyfile
1666 dbus/versioninfo.rc
1667 dbus/dbus-arch-deps.h
1668 bus/system.conf
1669 bus/session.conf
1670 bus/messagebus
1671 bus/messagebus-config
1672 bus/org.freedesktop.dbus-session.plist
1673 bus/rc.messagebus
1674 bus/dbus.service
1675 bus/dbus.socket
1676 Makefile
1677 dbus/Makefile
1678 bus/Makefile
1679 tools/Makefile
1680 test/Makefile
1681 test/name-test/Makefile
1682 doc/Makefile
1683 doc/dbus-daemon.1
1684 dbus-1.pc
1685 dbus-1-uninstalled.pc
1686 test/data/valid-config-files/debug-allow-all.conf
1687 test/data/valid-config-files/debug-allow-all-sha1.conf
1688 test/data/valid-config-files-system/debug-allow-all-pass.conf
1689 test/data/valid-config-files-system/debug-allow-all-fail.conf
1690 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1691 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1692 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1693 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1694 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1695 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1696 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1697 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1698 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1699 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1700 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1701 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1702 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1703 ])
1704 AC_OUTPUT
1705
1706 dnl ==========================================================================
1707 echo "
1708                     D-Bus $VERSION
1709                   ==============
1710
1711         prefix:                   ${EXPANDED_PREFIX}
1712         exec_prefix:              ${exec_prefix}
1713         libdir:                   ${EXPANDED_LIBDIR}
1714         libexecdir:               ${EXPANDED_LIBEXECDIR}
1715         bindir:                   ${EXPANDED_BINDIR}
1716         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1717         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1718         datadir:                  ${EXPANDED_DATADIR}
1719         source code location:     ${srcdir}
1720         compiler:                 ${CC}
1721         cflags:                   ${CFLAGS}
1722         cppflags:                 ${CPPFLAGS}
1723         cxxflags:                 ${CXXFLAGS}
1724         64-bit int:               ${DBUS_INT64_TYPE}
1725         32-bit int:               ${DBUS_INT32_TYPE}
1726         16-bit int:               ${DBUS_INT16_TYPE}
1727         Doxygen:                  ${DOXYGEN:-not found}
1728         xmlto:                    ${XMLTO:-not found}
1729         man2html:                 ${MAN2HTML:-not found}"
1730
1731 echo "
1732         Maintainer mode:          ${USE_MAINTAINER_MODE}
1733         gcc coverage profiling:   ${enable_compiler_coverage}
1734         Building embedded tests:  ${enable_embedded_tests}
1735         Building modular tests:   ${enable_modular_tests}
1736         Building verbose mode:    ${enable_verbose_mode}
1737         Building assertions:      ${enable_asserts}
1738         Building checks:          ${enable_checks}
1739         Building bus stats API:   ${enable_stats}
1740         Building SELinux support: ${have_selinux}
1741         Building inotify support: ${have_inotify}
1742         Building dnotify support: ${have_dnotify}
1743         Building kqueue support:  ${have_kqueue}
1744         Building systemd support: ${have_systemd}
1745         Building X11 code:        ${enable_x11}
1746         Building Doxygen docs:    ${enable_doxygen_docs}
1747         Building XML docs:        ${enable_xml_docs}
1748         Building cache support:   ${enable_userdb_cache}
1749         Building launchd support: ${have_launchd}
1750         Using XML parser:         ${with_xml}
1751         Init scripts style:       ${with_init_scripts}
1752         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1753         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1754         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1755         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1756         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1757         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1758         Console owner file:       ${have_console_owner_file}
1759         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1760         System bus user:          ${DBUS_USER}
1761         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1762         'make check' socket dir:  ${TEST_SOCKET_DIR}
1763 "
1764 if test x$have_launchd = xyes; then
1765         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1766 fi
1767 echo
1768
1769 if test x$enable_embedded_tests = xyes; then
1770         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1771 fi
1772 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1773         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1774 fi
1775 if test x$enable_compiler_coverage = xyes; then
1776         echo "NOTE: building with coverage profiling is definitely for developers only."
1777 fi
1778 if test x$enable_verbose_mode = xyes; then
1779         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1780 fi
1781 if test x$enable_asserts = xyes; then
1782         echo "NOTE: building with assertions increases library size and decreases performance."
1783 fi
1784 if test x$enable_checks = xno; then
1785         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1786 fi
1787 if test x$dbus_use_libxml = xtrue; then
1788         echo
1789         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1790 fi
1791
1792 if test "x$DBUS_HAVE_INT64" = x0; then
1793   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1794
1795   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1796   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1797   used if your compiler lacks support for 64-bit integers. Please report a bug
1798   with details of your platform and compiler.
1799
1800   This option is likely to be removed in future, unless the D-Bus developers
1801   receive reports that it is still needed.
1802   ])
1803 fi