configure.ac

   1 AC_INIT(openconnect, 3.20)
   2 PKG_PROG_PKG_CONFIG
   3 AC_LANG_C
   4 AC_CANONICAL_HOST
   5 AM_MAINTAINER_MODE([enable])
   6 AM_INIT_AUTOMAKE([foreign])
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   8
   9 # Define htmldir and localedir for users of ancient autoconf building from git
  10 AC_PREREQ([2.59c], [], [AC_SUBST([htmldir], [m4_ifset([AC_PACKAGE_TARNAME],
  11           ['${datadir}/doc/${PACKAGE_TARNAME}'],
  12           ['${datadir}/doc/${PACKAGE}'])
  13 ])])
  14
  15 AC_PREREQ([2.60], [], [AC_SUBST([localedir], ['$(datadir)/locale'])])
  16
  17 # Upstream's pkg.m4 (since 0.27) offers this now, but define our own
  18 # compatible version in case the local version of pkgconfig isn't new enough.
  19 # https://bugs.freedesktop.org/show_bug.cgi?id=48743
  20 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
  21           [AC_ARG_WITH([pkgconfigdir],
  22                        [AS_HELP_STRING([--with-pkgconfigdir],
  23                        [install directory for openconnect.pc pkg-config file])],
  24                         [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
  25            AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
  26
  27 AC_ARG_WITH([vpnc-script],
  28         [AS_HELP_STRING([--with-vpnc-script],
  29           [default location of vpnc-script helper])])
  30
  31 if test "$with_vpnc_script" = "yes" || test "$with_vpnc_script" = ""; then
  32    with_vpnc_script=/etc/vpnc/vpnc-script
  33    if ! test -x "$with_vpnc_script"; then
  34       AC_MSG_ERROR([${with_vpnc_script} does not seem to be executable.]
  35     [OpenConnect will not function correctly without a vpnc-script.]
  36     [See http://www.infradead.org/openconnect/vpnc-script.html for more details.]
  37     []
  38     [If you are building a distribution package, please ensure that your]
  39     [packaging is correct, and that a vpnc-script will be installed when the]
  40     [user installs your package. You should provide a --with-vpnc-script=]
  41     [argument to this configure script, giving the full path where the script]
  42     [will be installed.]
  43     []
  44     [The standard location is ${with_vpnc_script}. To bypass this error and]
  45     [build OpenConnect to use the script from this location, even though it's]
  46     [not present at the time you are building OpenConnect, pass the argument]
  47     ["--with-vpnc-script=${with_vpnc_script}"])
  48   fi
  49 elif test "$with_vpnc_script" = "no"; then
  50    AC_ERROR([You cannot disable vpnc-script.]
  51    [OpenConnect will not function correctly without it.]
  52    [See http://www.infradead.org/openconnect/vpnc-script.html])
  53 fi
  54
  55 AC_DEFINE_UNQUOTED(DEFAULT_VPNCSCRIPT, "${with_vpnc_script}")
  56 AC_SUBST(DEFAULT_VPNCSCRIPT, "${with_vpnc_script}")
  57
  58 case $host_os in
  59  *linux* | *gnu*)
  60     AC_MSG_NOTICE([Applying feature macros for GNU build])
  61     AC_DEFINE(_POSIX_C_SOURCE, 200112L)
  62     # For strcasecmp()
  63     AC_DEFINE(_BSD_SOURCE)
  64     # For asprintf()
  65     AC_DEFINE(_GNU_SOURCE)
  66     ;;
  67  *netbsd*)
  68     AC_MSG_NOTICE([Applying feature macros for NetBSD build])
  69     AC_DEFINE(_POSIX_C_SOURCE, 200112L)
  70     AC_DEFINE(_NETBSD_SOURCE)
  71     ;;
  72  *)
  73     # On FreeBSD the only way to get vsyslog() visible is to define
  74     #  *nothing*, which makes absolutely everything visible.
  75     # On Darwin enabling _POSIX_C_SOURCE breaks <sys/mount.h> because
  76     # u_long and other types don't get defined. OpenBSD is similar.
  77     ;;
  78 esac
  79
  80 symver_time=
  81 symver_getline=
  82 symver_asprintf=
  83
  84 case $host_os in
  85  *solaris*|*sunos*)
  86     symver_time="openconnect__time;"
  87     ;;
  88 esac
  89
  90 AC_CHECK_FUNC(fdevname_r, [AC_DEFINE(HAVE_FDEVNAME_R, 1)], [])
  91 AC_CHECK_FUNC(getline, [AC_DEFINE(HAVE_GETLINE, 1)], [symver_getline="openconnect__getline;"])
  92 AC_CHECK_FUNC(strcasestr, [AC_DEFINE(HAVE_STRCASESTR, 1)], [])
  93 AC_CHECK_FUNC(asprintf, [AC_DEFINE(HAVE_ASPRINTF, 1)], [symver_asprintf="openconnect__asprintf;"])
  94 if test -n "$symver_asprintf"; then
  95   AC_MSG_CHECKING([for va_copy])
  96   AC_LINK_IFELSE([AC_LANG_PROGRAM([
  97         #include <stdarg.h>
  98         va_list a;],[
  99         va_list b;
 100         va_copy(b,a);
 101         va_end(b);])],
 102         [AC_DEFINE(HAVE_VA_COPY, 1)
 103         AC_MSG_RESULT(va_copy)],
 104         [AC_LINK_IFELSE([AC_LANG_PROGRAM([
 105                 #include <stdarg.h>
 106                 va_list a;],[
 107                 va_list b;
 108                 __va_copy(b,a);
 109                 va_end(b);])],
 110                 [AC_DEFINE(HAVE___VA_COPY, 1)
 111                 AC_MSG_RESULT(__va_copy)],
 112                 [AC_MSG_RESULT(no)
 113                 AC_MSG_ERROR([Your system lacks asprintf() and va_copy()])])
 114         ])
 115 fi
 116 AC_SUBST(SYMVER_TIME, $symver_time)
 117 AC_SUBST(SYMVER_GETLINE, $symver_getline)
 118 AC_SUBST(SYMVER_ASPRINTF, $symver_asprintf)
 119
 120 AS_COMPILER_FLAGS(CFLAGS,
 121         "-Wall
 122          -Wextra
 123          -Wno-missing-field-initializers
 124          -Wno-sign-compare
 125          -Wno-unused-parameter
 126          -Werror=pointer-to-int-cast
 127          -Wdeclaration-after-statement
 128          -Werror-implicit-function-declaration
 129          -Wformat-nonliteral
 130          -Wformat-security
 131          -Winit-self
 132          -Wmissing-declarations
 133          -Wmissing-include-dirs
 134          -Wnested-externs
 135          -Wpointer-arith
 136          -Wwrite-strings")
 137
 138 AC_ENABLE_SHARED
 139 AC_DISABLE_STATIC
 140
 141 AC_ARG_ENABLE([nls],
 142         [  --disable-nls           do not use Native Language Support],
 143         [USE_NLS=$enableval], [USE_NLS=yes])
 144 LIBINTL=
 145 if test "$USE_NLS" = "yes"; then
 146    AC_PATH_PROG(MSGFMT, msgfmt)
 147    if test "$MSGFMT" = ""; then
 148       AC_ERROR([msgfmt could not be found. Try configuring with --disable-nls])
 149    fi
 150 fi
 151 LIBINTL=
 152 if test "$USE_NLS" = "yes"; then
 153    AC_MSG_CHECKING([for functional NLS support])
 154    AC_LINK_IFELSE([AC_LANG_PROGRAM([
 155     #include <locale.h>
 156     #include <libintl.h>],[
 157     setlocale(LC_ALL, "");
 158     bindtextdomain("openconnect", "/tmp");
 159     (void)dgettext("openconnect", "foo");])],
 160     [AC_MSG_RESULT(yes)],
 161     [oldLIBS="$LIBS"
 162      LIBS="$LIBS -lintl"
 163      AC_LINK_IFELSE([AC_LANG_PROGRAM([
 164       #include <locale.h>
 165       #include <libintl.h>],[
 166       setlocale(LC_ALL, "");
 167       bindtextdomain("openconnect", "/tmp");
 168       (void)dgettext("openconnect", "foo");])],
 169       [AC_MSG_RESULT(yes (with -lintl))]
 170        LIBINTL="-lintl",
 171       [AC_MSG_RESULT(no)
 172        USE_NLS=no])
 173      LIBS="$oldLIBS"])
 174 fi
 175
 176 if test "$USE_NLS" = "yes"; then
 177    AC_SUBST(LIBINTL)
 178    AC_DEFINE(ENABLE_NLS, 1)
 179 fi
 180 AM_CONDITIONAL(USE_NLS, [test "$USE_NLS" = "yes"])
 181
 182 AC_ARG_WITH([gnutls],
 183         AS_HELP_STRING([--with-gnutls],
 184                        [Use GnuTLS instead of OpenSSL (EXPERIMENTAL)]))
 185 AC_ARG_WITH([openssl],
 186             AS_HELP_STRING([--with-openssl],
 187                            [Location of OpenSSL build dir]))
 188 ssl_library=
 189
 190 if test "$with_gnutls" = "yes" || test "$with_gnutls" = "shibboleet"; then
 191     if test "$with_openssl" != "no" && test "$with_openssl" != ""; then
 192         AC_MSG_ERROR([Cannot use both OpenSSL and GnuTLS simultaneously])
 193     fi
 194     PKG_CHECK_MODULES(GNUTLS, gnutls)
 195     if ! $PKG_CONFIG --atleast-version=2.12.16 gnutls; then
 196        AC_MSG_ERROR([Your GnuTLS is too old. At least v2.12.16 is required])
 197     fi
 198     with_openssl=no
 199     ssl_library=gnutls
 200     oldlibs="$LIBS"
 201     LIBS="$LIBS $GNUTLS_LIBS"
 202     AC_CHECK_FUNC(gnutls_pkcs12_simple_parse,
 203                  [AC_DEFINE(HAVE_GNUTLS_PKCS12_SIMPLE_PARSE, 1)], [])
 204     AC_CHECK_FUNC(gnutls_session_set_premaster,
 205                  [AC_DEFINE(HAVE_GNUTLS_SESSION_SET_PREMASTER, 1)], [])
 206     AC_CHECK_FUNC(gnutls_pkcs11_add_provider,
 207                  [PKG_CHECK_MODULES(P11KIT, p11-kit-1, [AC_DEFINE(HAVE_P11KIT)
 208                                           AC_SUBST(P11KIT_PC, p11-kit-1)], [:])], [])
 209     LIBS="$oldLIBS"
 210 elif test "$with_gnutls" != "" && test "$with_gnutls" != "no"; then
 211     AC_MSG_ERROR([Values other than 'yes' or 'no' for --with-gnutls are not supported])
 212 fi
 213
 214 if test "$with_openssl" = "yes" || test "$with_openssl" = "" ; then
 215     PKG_CHECK_MODULES(OPENSSL, openssl, [],
 216         [oldLIBS="$LIBS"
 217          LIBS="$LIBS -lssl -lcrypto"
 218          AC_MSG_CHECKING([for OpenSSL without pkg-config])
 219          AC_LINK_IFELSE([AC_LANG_PROGRAM([
 220                                 #include <openssl/ssl.h>
 221                                 #include <openssl/err.h>],[
 222                                 SSL_library_init();
 223                                 ERR_clear_error();
 224                                 SSL_load_error_strings();
 225                                 OpenSSL_add_all_algorithms();])],
 226                         [AC_MSG_RESULT(yes)
 227                          AC_SUBST([OPENSSL_LIBS], ["-lssl -lcrypto"])
 228                          AC_SUBST([OPENSSL_CFLAGS], [])],
 229                         [AC_MSG_RESULT(no)
 230                          AC_ERROR([Could not build against OpenSSL])])
 231          LIBS="$oldLIBS"])
 232     ssl_library=openssl
 233 elif test "$with_openssl" != "no" ; then
 234     OPENSSL_CFLAGS="-I${with_openssl}/include"
 235     OPENSSL_LIBS="${with_openssl}/libssl.a ${with_openssl}/libcrypto.a -ldl -lz"
 236     AC_SUBST(OPENSSL_CFLAGS)
 237     AC_SUBST(OPENSSL_LIBS)
 238     enable_static=yes
 239     enable_shared=no
 240     ssl_library=openssl
 241 fi
 242
 243 case "$ssl_library" in
 244     gnutls)
 245         AC_DEFINE(OPENCONNECT_GNUTLS, 1)
 246         AC_SUBST(SSL_LIBS, [$GNUTLS_LIBS])
 247         AC_SUBST(SSL_CFLAGS, [$GNUTLS_CFLAGS])
 248         AC_SUBST(SSL_DEFINE, [-DOPENCONNECT_GNUTLS])
 249         ;;
 250     openssl)
 251         AC_DEFINE(OPENCONNECT_OPENSSL, 1)
 252         AC_SUBST(SSL_LIBS, [$OPENSSL_LIBS])
 253         AC_SUBST(SSL_CFLAGS, [$OPENSSL_CFLAGS])
 254         AC_SUBST(SSL_DEFINE, [-DOPENCONNECT_OPENSSL])
 255         ;;
 256     *)
 257         AC_MSG_ERROR([Neither OpenSSL nor GnuTLS selected for SSL.])
 258         ;;
 259 esac
 260 AC_SUBST(SSL_LIBRARY, $ssl_library)
 261
 262 # Needs to happen after we default to static/shared libraries based on OpenSSL
 263 AC_PROG_LIBTOOL
 264
 265 # Ick. This seems like it's likely to be very fragile, but I can't see a better
 266 # way. I shall console myself with the observation that the failure mode isn't
 267 # particularly horrible — you just don't get symbol versioning if it fails.
 268 symvers=no
 269 if test "$enable_shared" = "yes" ; then
 270    AC_MSG_CHECKING([if library symbol versioning is available]);
 271    echo 'FOO { global: foo; local: *; };' > conftest.map
 272    echo 'int foo = 0;' > conftest.$ac_ext
 273    if AC_TRY_EVAL(ac_compile); then
 274       soname=conftest
 275       libobjs=conftest.$ac_objext
 276       if AC_TRY_EVAL(archive_cmds ${wl}--version-script ${wl}conftest.map); then
 277          AC_SUBST(VERSION_SCRIPT_ARG, [--version-script])
 278          symvers="yes (with --version-script)"
 279       elif AC_TRY_EVAL(archive_cmds ${wl}-M ${wl}conftest.map); then
 280          AC_SUBST(VERSION_SCRIPT_ARG, [-M])
 281          symvers="yes (with -M)"
 282       fi
 283    fi
 284    AC_MSG_RESULT(${symvers})
 285 fi
 286 AM_CONDITIONAL(HAVE_SYMBOL_VERSIONING, [test "${symvers}" != "no"])
 287
 288 PKG_CHECK_MODULES(LIBXML2, libxml-2.0)
 289
 290 PKG_CHECK_MODULES(ZLIB, zlib, [],
 291                   [oldLIBS="$LIBS"
 292                   LIBS="$LIBS -lz"
 293                   AC_MSG_CHECKING([for zlib without pkg-config])
 294                   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 295                    #include <zlib.h>],[
 296                    z_stream zs;
 297                    deflateInit2(&zs, Z_DEFAULT_COMPRESSION, Z_DEFLATED,
 298                                 -12, 9, Z_DEFAULT_STRATEGY);])],
 299                   [AC_MSG_RESULT(yes)
 300                    AC_SUBST([ZLIB_LIBS], [-lz])
 301                    AC_SUBST([ZLIB_CFLAGS], [])],
 302                   [AC_MSG_RESULT(no)
 303                    AC_ERROR([Could not build against zlib])])
 304                   LIBS="$oldLIBS"])
 305
 306 PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0,
 307                 [AC_SUBST(LIBPROXY_PC, libproxy-1.0)
 308                  AC_DEFINE([LIBPROXY_HDR], ["proxy.h"])
 309                  libproxy_pkg=yes],
 310                  libproxy_pkg=no)
 311 dnl Libproxy *can* exist without a .pc file, and its header may be called
 312 dnl libproxy.h in that case.
 313 if (test "$libproxy_pkg" = "no"); then
 314    AC_MSG_CHECKING([for libproxy])
 315    oldLIBS="$LIBS"
 316    LIBS="$LIBS -lproxy"
 317    AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <libproxy.h>],
 318                            [(void)px_proxy_factory_new();])],
 319           [AC_MSG_RESULT(yes (with libproxy.h))
 320            AC_DEFINE([LIBPROXY_HDR], ["libproxy.h"])
 321            AC_SUBST([LIBPROXY_LIBS], [-lproxy])],
 322           [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <proxy.h>],
 323                                   [(void)px_proxy_factory_new();])],
 324                   [AC_MSG_RESULT(yes (with proxy.h))
 325                    AC_DEFINE([LIBPROXY_HDR], ["proxy.h"])
 326                    AC_SUBST([LIBPROXY_LIBS], [-lproxy])],
 327                    [AC_MSG_RESULT(no)])])
 328    LIBS="$oldLIBS"
 329 fi
 330
 331 AC_CHECK_HEADER([if_tun.h],
 332     [AC_DEFINE([IF_TUN_HDR], ["if_tun.h"])],
 333     [AC_CHECK_HEADER([linux/if_tun.h],
 334         [AC_DEFINE([IF_TUN_HDR], ["linux/if_tun.h"])],
 335         [AC_CHECK_HEADER([net/if_tun.h],
 336             [AC_DEFINE([IF_TUN_HDR], ["net/if_tun.h"])],
 337             [AC_CHECK_HEADER([net/tun/if_tun.h],
 338                 [AC_DEFINE([IF_TUN_HDR], ["net/tun/if_tun.h"])])])])])
 339
 340 if test "${ssl_library}" = "openssl"; then
 341     oldLIBS="$LIBS"
 342     LIBS="$LIBS $OPENSSL_LIBS"
 343
 344     AC_MSG_CHECKING([for ENGINE_by_id() in OpenSSL])
 345     AC_LINK_IFELSE([AC_LANG_PROGRAM(
 346         [#include <openssl/engine.h>],
 347         [ENGINE_by_id("foo");])],
 348         [AC_MSG_RESULT(yes)
 349          AC_DEFINE(HAVE_ENGINE, [1], [OpenSSL has ENGINE support])],
 350         [AC_MSG_RESULT(no)
 351          AC_MSG_NOTICE([Building without OpenSSL TPM ENGINE support])])
 352
 353     AC_MSG_CHECKING([for dtls1_stop_timer() in OpenSSL])
 354     AC_LINK_IFELSE([AC_LANG_PROGRAM(
 355         [#include <openssl/ssl.h>
 356          #include <stdlib.h>
 357          extern void dtls1_stop_timer(SSL *);],
 358         [dtls1_stop_timer(NULL);])],
 359         [AC_MSG_RESULT(yes)
 360          AC_DEFINE(HAVE_DTLS1_STOP_TIMER, [1], [OpenSSL has dtls1_stop_timer() function])],
 361         [AC_MSG_RESULT(no)])
 362     LIBS="$oldLIBS"
 363 fi
 364
 365 AC_PATH_PROG(PYTHON, [python], [], $PATH:/bin:/usr/bin)
 366 if (test -n "${ac_cv_path_PYTHON}"); then
 367    AC_SUBST(PYTHON, ${ac_cv_path_PYTHON})
 368 else
 369    AC_MSG_NOTICE([Python not found; not building HTML pages])
 370 fi
 371 AM_CONDITIONAL(BUILD_WWW, [test -n "${ac_cv_path_PYTHON}"])
 372
 373 AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/po/LINGUAS $(top_srcdir)/openconnect.h'])
 374 RAWLINGUAS=`sed -e "/^#/d" -e "s/#.*//" "${srcdir}/po/LINGUAS"`
 375 # Remove newlines
 376 LINGUAS=`echo $RAWLINGUAS`
 377 AC_SUBST(LINGUAS)
 378
 379 APIMAJOR="`sed -n 's/^#define OPENCONNECT_API_VERSION_MAJOR \(.*\)/\1/p' ${srcdir}/openconnect.h`"
 380 APIMINOR="`sed -n 's/^#define OPENCONNECT_API_VERSION_MINOR \(.*\)/\1/p' ${srcdir}/openconnect.h`"
 381 AC_SUBST(APIMAJOR)
 382 AC_SUBST(APIMINOR)
 383
 384 # We want version.c to depend on the files that would affect the
 385 # output of version.sh. But we cannot assume that they'll exist,
 386 # and we cannot use $(wildcard) in a non-GNU makefile. So we just
 387 # depend on the files which happen to exist at configure time.
 388 GITVERSIONDEPS=
 389 for a in .git/index .git/packed-refs .git/refs/tags .git/HEAD; do
 390     if test -r $a ; then
 391        GITVERSIONDEPS="$GITVERSIONDEPS $a"
 392     fi
 393 done
 394 AC_SUBST(GITVERSIONDEPS)
 395
 396 AC_OUTPUT(Makefile openconnect.pc po/Makefile www/Makefile libopenconnect.map \
 397           openconnect.8 www/styles/Makefile www/inc/Makefile www/images/Makefile)