configure.ac

   1 AC_PREREQ(2.65)
   2 AC_CONFIG_MACRO_DIR([m4])
   3
   4 AC_INIT([glib-networking],[2.31.0],[http://bugzilla.gnome.org/enter_bug.cgi?product=glib&component=network])
   5
   6 AC_CONFIG_SRCDIR([proxy/libproxy/glibproxyresolver.h])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 dnl Other initialization
  10 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz -Wno-portability])
  11 AM_MAINTAINER_MODE([enable])
  12 AM_SILENT_RULES([yes])
  13 LT_INIT
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AM_PROG_CC_C_O
  18 AC_PROG_CPP
  19
  20 dnl Checks for libraries.
  21
  22 dnl ****************************
  23 dnl *** Checks for intltool  ***
  24 dnl ****************************
  25
  26 IT_PROG_INTLTOOL([0.35.0])
  27 GETTEXT_PACKAGE=glib-networking
  28
  29 AC_SUBST([GETTEXT_PACKAGE])
  30 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
  31 AM_GLIB_GNU_GETTEXT
  32
  33 dnl *****************************
  34 dnl *** Check GLib GIO        ***
  35 dnl *****************************
  36 AM_PATH_GLIB_2_0(2.31.0,,AC_MSG_ERROR(GLIB not found),gio)
  37
  38 GIO_MODULE_DIR=$($PKG_CONFIG --variable giomoduledir gio-2.0)
  39 AS_IF([test "x$GIO_MODULE_DIR" = "x"],
  40       [AC_MSG_FAILURE(GIO_MODULE_DIR is missing from gio-2.0.pc)])
  41 AC_SUBST(GIO_MODULE_DIR)
  42
  43 AC_PATH_PROG(GIO_QUERYMODULES, gio-querymodules)
  44 AC_SUBST(GIO_QUERYMODULES)
  45
  46 dnl *****************************
  47 dnl *** Checks for LibProxy   ***
  48 dnl *****************************
  49
  50 AC_ARG_WITH(libproxy,
  51     [AC_HELP_STRING([--with-libproxy],
  52                     [support for libproxy @<:@default=check@:>@])],
  53     [],
  54     [with_libproxy=check])
  55 AS_IF([test "x$with_libproxy" != "xno"],
  56     [PKG_CHECK_MODULES(LIBPROXY, [libproxy-1.0 >= 0.3.1],
  57         [with_libproxy=yes; proxy_support=libproxy],
  58         [AS_IF([test "x$with_libproxy" = "xyes"],
  59                [AC_MSG_FAILURE("$LIBPROXY_PKG_ERRORS")])])])
  60 AM_CONDITIONAL(HAVE_LIBPROXY, [test "x$with_libproxy" = "xyes"])
  61 AC_SUBST(LIBPROXY_CFLAGS)
  62 AC_SUBST(LIBPROXY_LIBS)
  63
  64 dnl **************************************
  65 dnl *** Checks for GNOME proxy backend ***
  66 dnl **************************************
  67 AC_ARG_WITH(gnome-proxy,
  68     [AC_HELP_STRING([--with-gnome-proxy],
  69                     [support for GNOME proxy configuration @<:@default=check@:>@])],
  70     [],
  71     [with_gnome_proxy=check])
  72 AS_IF([test "x$with_gnome_proxy" != "xno"],
  73     [PKG_CHECK_MODULES(GSETTINGS_DESKTOP_SCHEMAS, [gsettings-desktop-schemas],
  74         [with_gnome_proxy=yes; proxy_support="gnome $proxy_support"],
  75         [AS_IF([test "x$with_gnome_proxy" = "xyes"],
  76                [AC_MSG_FAILURE("$GSETTINGS_DESKTOP_SCHEMAS_PKG_ERRORS")])])])
  77 AM_CONDITIONAL(HAVE_GNOME_PROXY, [test "x$with_gnome_proxy" = "xyes"])
  78 AC_SUBST(GSETTINGS_DESKTOP_SCHEMAS_CFLAGS)
  79
  80 dnl *****************************
  81 dnl *** Checks for GNUTLS     ***
  82 dnl *****************************
  83
  84 GNUTLS_MIN_REQUIRED=2.11.0
  85 GNUTLS_MIN_PKCS11=2.12.8
  86
  87 AC_ARG_WITH(gnutls,
  88     [AC_HELP_STRING([--with-gnutls],
  89                     [support for GNUTLS @<:@default=yes@:>@])],
  90     [],
  91     [with_gnutls=yes])
  92 if test "x$with_gnutls" != "xno"; then
  93         PKG_CHECK_MODULES(GNUTLS,
  94                           [gnutls >= $GNUTLS_MIN_REQUIRED],
  95                           [with_gnutls=yes
  96                            tls_support="${tls_support}gnutls "
  97                            AM_PATH_LIBGCRYPT([])],
  98                           [AS_IF([test "x$with_gnutls" = "xyes"],
  99                                  [AC_MSG_FAILURE("$GNUTLS_PKG_ERRORS")])])
 100 fi
 101 AM_CONDITIONAL(HAVE_GNUTLS, [test "x$with_gnutls" = "xyes"])
 102 AC_SUBST(GNUTLS_CFLAGS)
 103 AC_SUBST(GNUTLS_LIBS)
 104
 105 if test "x$with_gnutls" = "xyes"; then
 106     AC_MSG_CHECKING([location of system Certificate Authority list])
 107     AC_ARG_WITH(ca-certificates,
 108                 [AC_HELP_STRING([--with-ca-certificates=@<:@path@:>@],
 109                                 [path to system Certificate Authority list])])
 110     if test "$with_ca_certificates" = "no"; then
 111         AC_MSG_RESULT([disabled])
 112     else
 113         if test -z "$with_ca_certificates"; then
 114             for f in /etc/pki/tls/certs/ca-bundle.crt \
 115                      /etc/ssl/certs/ca-certificates.crt; do
 116                 if test -f "$f"; then
 117                     with_ca_certificates="$f"
 118                 fi
 119             done
 120             if test -z "$with_ca_certificates"; then
 121                 AC_MSG_ERROR([could not find. Use --with-ca-certificates=path to set, or --without-ca-certificates to disable])
 122             fi
 123         fi
 124
 125         AC_MSG_RESULT($with_ca_certificates)
 126         AC_DEFINE_UNQUOTED(GTLS_SYSTEM_CA_FILE, ["$with_ca_certificates"], [The system TLS CA list])
 127     fi
 128 fi
 129
 130 dnl *****************************
 131 dnl *** Checks for pkcs11    ***
 132 dnl *****************************
 133
 134 P11_KIT_REQUIRED=0.8
 135
 136 AC_ARG_WITH(pkcs11,
 137         [AC_HELP_STRING([--with-pkcs11],
 138                         [support for pkcs11 @<:@default=check@:>@])],
 139                         [],
 140                         [with_pkcs11=check])
 141 if test "x$with_pkcs11" != "xno"; then
 142         PKG_CHECK_MODULES(PKCS11,
 143                           [p11-kit-1 >= $P11_KIT_REQUIRED gnutls >= $GNUTLS_MIN_PKCS11],
 144                           [with_pkcs11=yes
 145                            pkcs11_support=p11-kit
 146                            tls_support="${tls_support}gnutls-pkcs11 "
 147                            AC_DEFINE_UNQUOTED([HAVE_PKCS11], [1], [Building with PKCS#11 support])],
 148                           [AS_IF([test "x$with_pkcs11" = "xyes"],
 149                                  [AC_MSG_FAILURE("$PKCS11_PKG_ERRORS")])
 150                            pkcs11_support=no])
 151 else
 152         pkcs11_support=no
 153 fi
 154 AM_CONDITIONAL(HAVE_PKCS11, [test "x$with_pkcs11" = "xyes"])
 155 AC_SUBST(PKCS11_CFLAGS)
 156 AC_SUBST(PKCS11_LIBS)
 157
 158 dnl ************************************
 159 dnl *** Enable lcov coverage reports ***
 160 dnl ************************************
 161
 162 AC_ARG_ENABLE(gcov,
 163   AS_HELP_STRING([--enable-gcov],
 164                  [Enable gcov]),
 165   [use_gcov=$enableval], [use_gcov=no])
 166
 167 if test "x$use_gcov" = "xyes"; then
 168   dnl we need gcc:
 169   if test "$GCC" != "yes"; then
 170     AC_MSG_ERROR([GCC is required for --enable-gcov])
 171   fi
 172
 173   ltp_version_list="1.6 1.7 1.8 1.9"
 174   AC_CHECK_PROG(LTP, lcov, lcov)
 175   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
 176
 177   if test "$LTP"; then
 178     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
 179       glib_cv_ltp_version=invalid
 180       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
 181       for ltp_check_version in $ltp_version_list; do
 182         if test "$ltp_version" = "$ltp_check_version"; then
 183           glib_cv_ltp_version="$ltp_check_version (ok)"
 184         fi
 185       done
 186     ])
 187   else
 188     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
 189     AC_MSG_ERROR([$ltp_msg])
 190   fi
 191
 192   case $glib_cv_ltp_version in
 193     ""|invalid[)]
 194       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
 195       AC_MSG_ERROR([$ltp_msg])
 196       LTP="exit 0;"
 197       ;;
 198   esac
 199
 200   if test -z "$LTP_GENHTML"; then
 201     AC_MSG_ERROR([Could not find genhtml from the LTP package])
 202   fi
 203
 204   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
 205
 206   dnl Remove all optimization flags from CFLAGS
 207   changequote({,})
 208   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
 209   changequote([,])
 210
 211   dnl Add the special gcc flags
 212   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
 213   LDFLAGS="$LDFLAGS -lgcov"
 214 fi
 215
 216 dnl ****************************************************
 217 dnl *** Warnings to show if using GCC                ***
 218 dnl *** (do this last so -Werror won't mess up tests ***
 219 dnl ****************************************************
 220
 221 AC_ARG_ENABLE(more-warnings,
 222               AS_HELP_STRING([--disable-more-warnings], [Inhibit compiler warnings]),
 223               set_more_warnings=no)
 224
 225 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 226         CFLAGS="$CFLAGS \
 227                 -Wall -Wstrict-prototypes -Werror=missing-prototypes \
 228                 -Werror=implicit-function-declaration \
 229                 -Werror=pointer-arith -Werror=init-self -Werror=format=2 \
 230                 -Werror=missing-include-dirs -Werror=aggregate-return \
 231                 -Werror=declaration-after-statement"
 232 fi
 233
 234 dnl *****************************
 235 dnl *** done                  ***
 236 dnl *****************************
 237 AC_CONFIG_FILES([Makefile
 238                  po/Makefile.in po/Makefile
 239                  proxy/libproxy/Makefile
 240                  proxy/gnome/Makefile
 241                  proxy/tests/Makefile
 242                  tls/gnutls/Makefile
 243                  tls/pkcs11/Makefile
 244                  tls/tests/Makefile
 245                 ])
 246 AC_OUTPUT
 247
 248 echo ""
 249 echo     "  Proxy support:     ${proxy_support:-no}"
 250 echo     "  TLS support:       ${tls_support:-no}"
 251 if test "$tls_support" != "no"; then
 252     echo "  PKCS#11 Support:   $pkcs11_support"
 253     echo "  TLS CA file:       ${with_ca_certificates:-(none)}"
 254     if test -n "$with_ca_certificates"; then
 255         if ! test -f "$with_ca_certificates"; then
 256             AC_MSG_WARN([Specified certificate authority file '$with_ca_certificates' does not exist])
 257         fi
 258     fi
 259 fi