configure.ac

   1 AC_PREREQ(2.65)
   2 AC_CONFIG_MACRO_DIR([m4])
   3
   4 AC_INIT([glib-networking],[0.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=glib-networking])
   5
   6 AC_CONFIG_SRCDIR([proxy/libproxy/glibproxyresolver.h])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 dnl Other initialization
  10 AM_INIT_AUTOMAKE
  11 AM_MAINTAINER_MODE
  12 GTK_DOC_CHECK
  13 LT_INIT
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18
  19 dnl We need to get variables using pkg-config
  20 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  21 AS_IF([test "x$PKG_CONFIG" = "xno"],
  22       [AC_MSG_FAILURE(Can't find pkg-config tool.)])
  23
  24 dnl Checks for libraries.
  25
  26 dnl ****************************
  27 dnl *** Checks for intltool  ***
  28 dnl ****************************
  29
  30 IT_PROG_INTLTOOL([0.35.0])
  31 GETTEXT_PACKAGE=glib-networking
  32
  33 AC_SUBST([GETTEXT_PACKAGE])
  34 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
  35 AM_GLIB_GNU_GETTEXT
  36
  37 dnl *****************************
  38 dnl *** Check GLib GIO        ***
  39 dnl *****************************
  40
  41 PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.25.13])
  42 AC_SUBST(GIO_CFLAGS)
  43 AC_SUBST(GIO_LIBS)
  44
  45 GIO_MODULE_DIR=$($PKG_CONFIG --variable giomoduledir gio-2.0)
  46 AS_IF([test "x$GIO_MODULE_DIR" = "x"],
  47       [AC_MSG_FAILURE(GIO_MODULE_DIR is missing from gio-2.0.pc)])
  48 AC_SUBST(GIO_MODULE_DIR)
  49
  50 dnl *****************************
  51 dnl *** Checks for LibProxy   ***
  52 dnl *****************************
  53
  54 AC_ARG_WITH(libproxy,
  55     [AC_HELP_STRING([--with-libproxy],
  56                     [support for libproxy @<:@default=check@:>@])],
  57     [],
  58     [with_libproxy=check])
  59 AS_IF([test "x$with_libproxy" != "xno"],
  60     [PKG_CHECK_MODULES(LIBPROXY, [libproxy-1.0 >= 0.3.1],
  61         [with_libproxy=yes],
  62         [AS_IF([test "x$with_libproxy" = "xyes"],
  63                [AC_MSG_FAILURE("$LIBPROXY_PKG_ERRORS")])])])
  64 AM_CONDITIONAL(HAVE_LIBPROXY, [test "x$with_libproxy" = "xyes"])
  65 AC_SUBST(LIBPROXY_CFLAGS)
  66 AC_SUBST(LIBPROXY_LIBS)
  67
  68 dnl Checks for header files.
  69 AC_CHECK_HEADERS([stdlib.h string.h])
  70
  71 dnl Checks for typedefs, structures, and compiler characteristics.
  72
  73 dnl Checks for library functions.
  74
  75 AC_CONFIG_FILES([Makefile
  76                  po/Makefile.in po/Makefile
  77                  proxy/libproxy/Makefile])
  78 AC_OUTPUT