configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.62],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Require xorg-macros minimum of 1.12 for XORG_WITH_XSLTPROC
  33 m4_ifndef([XORG_MACROS_VERSION],
  34           [m4_fatal([must install xorg-macros 1.12 or later before running autoconf/autogen])])
  35 XORG_MACROS_VERSION(1.12)
  36 XORG_WITH_XSLTPROC
  37 XORG_MANPAGE_SECTIONS
  38
  39 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  40
  41 # Enable quiet compiles on automake 1.11.
  42 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  43
  44 # Check for programs
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47
  48 if test "x$ac_cv_prog_cc_c99" = xno; then
  49         AC_MSG_ERROR([Building libdrm requires C99 enabled compiler])
  50 fi
  51
  52 AC_USE_SYSTEM_EXTENSIONS
  53 AC_SYS_LARGEFILE
  54 AC_FUNC_ALLOCA
  55
  56 AC_CHECK_HEADERS([sys/mkdev.h sys/sysctl.h])
  57
  58 # Initialize libtool
  59 LT_PREREQ([2.2])
  60 LT_INIT([disable-static])
  61
  62
  63 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  64 AC_SUBST(PTHREADSTUBS_CFLAGS)
  65 AC_SUBST(PTHREADSTUBS_LIBS)
  66
  67 pkgconfigdir=${libdir}/pkgconfig
  68 AC_SUBST(pkgconfigdir)
  69 AC_ARG_ENABLE([udev],
  70               [AS_HELP_STRING([--enable-udev],
  71                               [Enable support for using udev instead of mknod (default: disabled)])],
  72               [UDEV=$enableval], [UDEV=no])
  73
  74 AC_ARG_ENABLE(libkms,
  75               AS_HELP_STRING([--disable-libkms],
  76               [Disable KMS mm abstraction library (default: auto, enabled on supported platforms)]),
  77               [LIBKMS=$enableval], [LIBKMS=auto])
  78
  79 AC_ARG_ENABLE(intel,
  80               AS_HELP_STRING([--disable-intel],
  81               [Enable support for intel's KMS API (default: auto, enabled on x86)]),
  82               [INTEL=$enableval], [INTEL=auto])
  83
  84 AC_ARG_ENABLE(radeon,
  85               AS_HELP_STRING([--disable-radeon],
  86               [Enable support for radeon's KMS API (default: auto)]),
  87               [RADEON=$enableval], [RADEON=auto])
  88
  89 AC_ARG_ENABLE(amdgpu,
  90               AS_HELP_STRING([--disable-amdgpu],
  91               [Enable support for amdgpu's KMS API (default: auto)]),
  92               [AMDGPU=$enableval], [AMDGPU=auto])
  93
  94 AC_ARG_ENABLE(nouveau,
  95               AS_HELP_STRING([--disable-nouveau],
  96               [Enable support for nouveau's KMS API (default: auto)]),
  97               [NOUVEAU=$enableval], [NOUVEAU=auto])
  98
  99 AC_ARG_ENABLE(vmwgfx,
 100               AS_HELP_STRING([--disable-vmwgfx],
 101               [Enable support for vmwgfx's KMS API (default: yes)]),
 102               [VMWGFX=$enableval], [VMWGFX=yes])
 103
 104 AC_ARG_ENABLE(omap-experimental-api,
 105               AS_HELP_STRING([--enable-omap-experimental-api],
 106               [Enable support for OMAP's experimental API (default: disabled)]),
 107               [OMAP=$enableval], [OMAP=no])
 108
 109 AC_ARG_ENABLE(exynos-experimental-api,
 110               AS_HELP_STRING([--enable-exynos-experimental-api],
 111               [Enable support for EXYNOS's experimental API (default: disabled)]),
 112               [EXYNOS=$enableval], [EXYNOS=no])
 113
 114 AC_ARG_ENABLE(freedreno,
 115               AS_HELP_STRING([--disable-freedreno],
 116               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
 117               [FREEDRENO=$enableval], [FREEDRENO=auto])
 118
 119 AC_ARG_ENABLE(freedreno-kgsl,
 120               AS_HELP_STRING([--enable-freedreno-kgsl],
 121               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 122               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 123
 124 AC_ARG_ENABLE(tegra-experimental-api,
 125               AS_HELP_STRING([--enable-tegra-experimental-api],
 126               [Enable support for Tegra's experimental API (default: disabled)]),
 127               [TEGRA=$enableval], [TEGRA=no])
 128
 129 AC_ARG_ENABLE(install-test-programs,
 130                   AS_HELP_STRING([--enable-install-test-programs],
 131                   [Install test programs (default: no)]),
 132                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 133
 134 dnl ===========================================================================
 135 dnl check compiler flags
 136 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 137   AC_MSG_CHECKING([whether $CC supports $1])
 138
 139   libdrm_save_CFLAGS="$CFLAGS"
 140   CFLAGS="$CFLAGS $1"
 141
 142   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 143   CFLAGS="$libdrm_save_CFLAGS"
 144
 145   if test "x$libdrm_cc_flag" = "xyes"; then
 146     ifelse([$2], , :, [$2])
 147   else
 148     ifelse([$3], , :, [$3])
 149   fi
 150   AC_MSG_RESULT([$libdrm_cc_flag])
 151 ])
 152
 153 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 154
 155 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 156                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 157                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 158 AC_SUBST([CLOCK_LIB])
 159
 160 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 161
 162 dnl Use lots of warning flags with with gcc and compatible compilers
 163
 164 dnl Note: if you change the following variable, the cache is automatically
 165 dnl skipped and all flags rechecked.  So there's no need to do anything
 166 dnl else.  If for any reason you need to force a recheck, just change
 167 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 168
 169 MAYBE_WARN="-Wall -Wextra \
 170 -Wsign-compare -Werror-implicit-function-declaration \
 171 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 172 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 173 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 174 -Wstrict-aliasing=2 -Winit-self \
 175 -Wdeclaration-after-statement -Wold-style-definition \
 176 -Wno-missing-field-initializers -Wno-unused-parameter \
 177 -Wno-attributes -Wno-long-long -Winline"
 178
 179 # invalidate cached value if MAYBE_WARN has changed
 180 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 181         unset libdrm_cv_warn_cflags
 182 fi
 183 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 184         echo
 185         WARN_CFLAGS=""
 186
 187         # Some warning options are not supported by all versions of
 188         # gcc, so test all desired options against the current
 189         # compiler.
 190         #
 191         # Note that there are some order dependencies
 192         # here. Specifically, an option that disables a warning will
 193         # have no net effect if a later option then enables that
 194         # warnings, (perhaps implicitly). So we put some grouped
 195         # options (-Wall and -Wextra) up front and the -Wno options
 196         # last.
 197
 198         for W in $MAYBE_WARN; do
 199                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 200         done
 201
 202         libdrm_cv_warn_cflags=$WARN_CFLAGS
 203         libdrm_cv_warn_maybe=$MAYBE_WARN
 204
 205         AC_MSG_CHECKING([which warning flags were supported])])
 206 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 207
 208 # Check for atomic intrinsics
 209 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 210         drm_cv_atomic_primitives="none"
 211
 212         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 213         int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 214         int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 215                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 216
 217         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 218                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 219         fi
 220
 221         # atomic functions defined in <atomic.h> & libc on Solaris
 222         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 223                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 224         fi
 225 ])
 226
 227 if test "x$drm_cv_atomic_primitives" = xIntel; then
 228         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 229                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 230 fi
 231 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 232         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 233 fi
 234
 235 dnl Print out the approapriate message considering the value set be the
 236 dnl respective in $1.
 237 dnl $1 - value to be evaluated. Eg. $INTEL, $NOUVEAU, ...
 238 dnl $2 - libdrm shortname. Eg. intel, freedreno, ...
 239 dnl $3 - GPU name/brand. Eg. Intel, NVIDIA Tegra, ...
 240 dnl $4 - Configure switch. Eg. intel, omap-experimental-api, ...
 241 AC_DEFUN([LIBDRM_ATOMICS_NOT_FOUND_MSG], [
 242         case "x$1" in
 243                 xyes)   AC_MSG_ERROR([libdrm_$2 depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for $3 GPUs by passing --disable-$4 to ./configure]) ;;
 244                 xauto)  AC_MSG_WARN([Disabling $2. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.]) ;;
 245                 *)      ;;
 246         esac
 247 ])
 248
 249 if test "x$drm_cv_atomic_primitives" = "xnone"; then
 250         LIBDRM_ATOMICS_NOT_FOUND_MSG($INTEL, intel, Intel, intel)
 251         INTEL=no
 252
 253         LIBDRM_ATOMICS_NOT_FOUND_MSG($RADEON, radeon, Radeon, radeon)
 254         RADEON=no
 255
 256         LIBDRM_ATOMICS_NOT_FOUND_MSG($AMDGPU, amdgpu, AMD, amdgpu)
 257         AMDGPU=no
 258
 259         LIBDRM_ATOMICS_NOT_FOUND_MSG($NOUVEAU, nouveau, NVIDIA, nouveau)
 260         NOUVEAU=no
 261
 262         LIBDRM_ATOMICS_NOT_FOUND_MSG($OMAP, omap, OMAP, omap-experimental-api)
 263         OMAP=no
 264
 265         LIBDRM_ATOMICS_NOT_FOUND_MSG($FREEDRENO, freedreno, Qualcomm Adreno, freedreno)
 266         FREEDRENO=no
 267
 268         LIBDRM_ATOMICS_NOT_FOUND_MSG($TEGRA, tegra, NVIDIA Tegra, tegra-experimental-api)
 269         TEGRA=no
 270 else
 271         if test "x$INTEL" = xauto; then
 272                 case $host_cpu in
 273                         i?86|x86_64)    INTEL=yes ;;
 274                         *)              INTEL=no ;;
 275                 esac
 276         fi
 277         if test "x$RADEON" = xauto; then
 278                 RADEON=yes
 279         fi
 280         if test "x$AMDGPU" = xauto; then
 281                 AMDGPU=yes
 282         fi
 283         if test "x$NOUVEAU" = xauto; then
 284                 NOUVEAU=yes
 285         fi
 286         if test "x$FREEDRENO" = xauto; then
 287                 case $host_cpu in
 288                         arm*|aarch64)   FREEDRENO=yes ;;
 289                         *)              FREEDRENO=no ;;
 290                 esac
 291         fi
 292 fi
 293
 294 if test "x$INTEL" != "xno"; then
 295         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 296 fi
 297 AC_SUBST(PCIACCESS_CFLAGS)
 298 AC_SUBST(PCIACCESS_LIBS)
 299
 300 if test "x$UDEV" = xyes; then
 301         AC_DEFINE(UDEV, 1, [Have UDEV support])
 302 fi
 303
 304 AC_CANONICAL_HOST
 305 if test "x$LIBKMS" = xauto ; then
 306         case $host_os in
 307                 linux*)         LIBKMS="yes" ;;
 308                 freebsd* | kfreebsd*-gnu)
 309                                 LIBKMS="yes" ;;
 310                 dragonfly*)     LIBKMS="yes" ;;
 311                 *)              LIBKMS="no" ;;
 312         esac
 313 fi
 314
 315 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 316
 317 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 318 if test "x$INTEL" = xyes; then
 319         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 320 fi
 321
 322 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 323 if test "x$VMWGFX" = xyes; then
 324         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 325 fi
 326
 327 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 328 if test "x$NOUVEAU" = xyes; then
 329         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 330 fi
 331
 332 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 333 if test "x$OMAP" = xyes; then
 334         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 335 fi
 336
 337 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 338 if test "x$EXYNOS" = xyes; then
 339         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 340 fi
 341
 342 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 343 if test "x$FREEDRENO" = xyes; then
 344         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 345 fi
 346
 347 if test "x$FREEDRENO_KGSL" = xyes; then
 348         if test "x$FREEDRENO" != xyes; then
 349                 AC_MSG_ERROR([Cannot enable freedreno KGSL interface if freedreno is disabled])
 350         fi
 351 fi
 352 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 353 if test "x$FREEDRENO_KGSL" = xyes; then
 354         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 355 fi
 356
 357 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 358 if test "x$RADEON" = xyes; then
 359         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 360 fi
 361
 362 # Detect cunit library
 363 PKG_CHECK_MODULES([CUNIT], [cunit >= 2.1], [have_cunit=yes], [have_cunit=no])
 364 # If pkg-config does not find cunit, check it using AC_CHECK_LIB.  We
 365 # do this because Debian (Ubuntu) lacks pkg-config file for cunit.
 366 if test "x${have_cunit}" = "xno"; then
 367         AC_CHECK_LIB([cunit], [CU_initialize_registry], [have_cunit=yes], [have_cunit=no])
 368         if test "x${have_cunit}" = "xyes"; then
 369                 CUNIT_LIBS="-lcunit"
 370                 CUNIT_CFLAGS=""
 371                 AC_SUBST([CUNIT_LIBS])
 372                 AC_SUBST([CUNIT_CFLAGS])
 373         fi
 374 fi
 375 AM_CONDITIONAL(HAVE_CUNIT, [test "x$have_cunit" != "xno"])
 376
 377 AM_CONDITIONAL(HAVE_AMDGPU, [test "x$AMDGPU" = xyes])
 378 if test "x$AMDGPU" = xyes; then
 379         AC_DEFINE(HAVE_AMDGPU, 1, [Have amdgpu support])
 380
 381         AC_DEFINE(HAVE_CUNIT, [test "x$have_cunit" != "xno"], [Enable CUNIT Have amdgpu support])
 382
 383         if test "x$have_cunit" = "xno"; then
 384                 AC_MSG_WARN([Could not find cunit library. Disabling amdgpu tests])
 385         fi
 386 fi
 387
 388 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 389 if test "x$TEGRA" = xyes; then
 390         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 391 fi
 392
 393 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 394 if test "x$INSTALL_TESTS" = xyes; then
 395         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 396 fi
 397
 398 AC_ARG_ENABLE([cairo-tests],
 399               [AS_HELP_STRING([--enable-cairo-tests],
 400                               [Enable support for Cairo rendering in tests (default: auto)])],
 401               [CAIRO=$enableval], [CAIRO=auto])
 402 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 403 AC_MSG_CHECKING([whether to enable Cairo tests])
 404 if test "x$CAIRO" = xauto; then
 405         CAIRO="$HAVE_CAIRO"
 406 fi
 407 if test "x$CAIRO" = xyes; then
 408         if ! test "x$HAVE_CAIRO" = xyes; then
 409                 AC_MSG_ERROR([Cairo support required but not present])
 410         fi
 411         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 412 fi
 413 AC_MSG_RESULT([$CAIRO])
 414 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 415
 416 # For enumerating devices in test case
 417 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 418 if test "x$HAVE_LIBUDEV" = xyes; then
 419         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 420 fi
 421 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 422
 423 # xsltproc for docbook manpages
 424 AC_ARG_ENABLE([manpages],
 425               AS_HELP_STRING([--enable-manpages], [enable manpages @<:@default=auto@:>@]),
 426               [MANS=$enableval], [MANS=auto])
 427 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 428
 429 # check for offline man-pages stylesheet
 430 AC_MSG_CHECKING([for docbook manpages stylesheet])
 431 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 432 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 433                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 434                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 435 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 436         AC_SUBST(MANPAGES_STYLESHEET)
 437         AC_MSG_RESULT([yes])
 438 else
 439         AC_MSG_RESULT([no])
 440 fi
 441 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 442
 443 AC_ARG_ENABLE(valgrind,
 444               [AS_HELP_STRING([--enable-valgrind],
 445                              [Build libdrm with  valgrind support (default: auto)])],
 446                              [VALGRIND=$enableval], [VALGRIND=auto])
 447 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 448 AC_MSG_CHECKING([whether to enable Valgrind support])
 449 if test "x$VALGRIND" = xauto; then
 450         VALGRIND="$have_valgrind"
 451 fi
 452
 453 if test "x$VALGRIND" = "xyes"; then
 454         if ! test "x$have_valgrind" = xyes; then
 455                 AC_MSG_ERROR([Valgrind support required but not present])
 456         fi
 457         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 458 fi
 459
 460 AC_MSG_RESULT([$VALGRIND])
 461
 462 AC_ARG_WITH([kernel-source],
 463             [AS_HELP_STRING([--with-kernel-source],
 464               [specify path to linux kernel source])],
 465             [kernel_source="$with_kernel_source"])
 466 AC_SUBST(kernel_source)
 467
 468 AC_MSG_CHECKING([whether $CC supports __attribute__(("hidden"))])
 469 AC_LINK_IFELSE([AC_LANG_PROGRAM([
 470     int foo_hidden( void ) __attribute__((visibility("hidden")));
 471 ])], HAVE_ATTRIBUTE_VISIBILITY="yes"; AC_MSG_RESULT([yes]), AC_MSG_RESULT([no]));
 472
 473 if test "x$HAVE_ATTRIBUTE_VISIBILITY" = xyes; then
 474     AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler supports __attribute__(("hidden"))])
 475 fi
 476
 477 AC_SUBST(WARN_CFLAGS)
 478 AC_CONFIG_FILES([
 479         Makefile
 480         libkms/Makefile
 481         libkms/libkms.pc
 482         intel/Makefile
 483         intel/libdrm_intel.pc
 484         radeon/Makefile
 485         radeon/libdrm_radeon.pc
 486         amdgpu/Makefile
 487         amdgpu/libdrm_amdgpu.pc
 488         nouveau/Makefile
 489         nouveau/libdrm_nouveau.pc
 490         omap/Makefile
 491         omap/libdrm_omap.pc
 492         exynos/Makefile
 493         exynos/libdrm_exynos.pc
 494         freedreno/Makefile
 495         freedreno/libdrm_freedreno.pc
 496         tegra/Makefile
 497         tegra/libdrm_tegra.pc
 498         tests/Makefile
 499         tests/modeprint/Makefile
 500         tests/modetest/Makefile
 501         tests/kmstest/Makefile
 502         tests/proptest/Makefile
 503         tests/radeon/Makefile
 504         tests/amdgpu/Makefile
 505         tests/vbltest/Makefile
 506         tests/exynos/Makefile
 507         tests/tegra/Makefile
 508         tests/nouveau/Makefile
 509         man/Makefile
 510         libdrm.pc])
 511 AC_OUTPUT
 512
 513 echo ""
 514 echo "$PACKAGE_STRING will be compiled with:"
 515 echo ""
 516 echo "  libkms         $LIBKMS"
 517 echo "  Intel API      $INTEL"
 518 echo "  vmwgfx API     $VMWGFX"
 519 echo "  Radeon API     $RADEON"
 520 echo "  AMDGPU API     $AMDGPU"
 521 echo "  Nouveau API    $NOUVEAU"
 522 echo "  OMAP API       $OMAP"
 523 echo "  EXYNOS API     $EXYNOS"
 524 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 525 echo "  Tegra API      $TEGRA"
 526 echo ""