configure.ac

   1 m4_define(FULL_PAVER, esyscmd(/usr/bin/pkg-config --silence-errors --modversion pulsecore | tr -d \\n))
   2 m4_define(PAVER, regexp(FULL_PAVER, [\([0123456789.]+\).*], [\1]))
   3
   4 AC_PREREQ(2.61)
   5
   6 AC_INIT([pulseaudio-murphy-ivi],[PAVER],[janos.kovacs@intel.com])
   7
   8 AC_CONFIG_SRCDIR([murphy/module-murphy-ivi.c])
   9 AC_CONFIG_HEADER([foo.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AM_INIT_AUTOMAKE([foreign 1.8.5 -Wall])
  12
  13
  14 # this would not be really needed if everything would be as it should be
  15 AS_IF([test x${exec_prefix} = xNONE], [LIBDIR=$ac_default_prefix/lib], [LIBDIR=${libdir}])
  16 AC_SUBST(LIBDIR)
  17
  18 AC_SUBST(PA_MAJORMINOR, [PAVER])
  19
  20 AC_PROG_MKDIR_P
  21 AC_PROG_CC
  22 AC_PROG_CC_C99
  23 AM_PROG_CC_C_O
  24 AC_PROG_GCC_TRADITIONAL
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 AC_PATH_PROG([M4], [m4 gm4], [no])
  28 if test "x$M4" = xno ; then
  29    AC_MSG_ERROR([m4 missing])
  30 fi
  31
  32 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4")
  33
  34 #dnl Compiler flags
  35 #DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wconversion -Wundef -Wformat -Wlogical-op -Wpacked -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Wno-unused-parameter -ffast-math"
  36
  37 #for flag in $DESIRED_FLAGS ; do
  38 #  CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
  39 #done
  40
  41 AC_LTDL_ENABLE_INSTALL
  42 AC_LIBLTDL_INSTALLABLE
  43 AC_LIBTOOL_DLOPEN
  44 AC_LIBTOOL_WIN32_DLL
  45 AC_PROG_LIBTOOL
  46 AC_SUBST(LTDLINCL)
  47 AC_SUBST(LIBLTDL)
  48 AC_CONFIG_SUBDIRS(libltdl)
  49
  50 AC_HEADER_STDC
  51 AC_C_CONST
  52 AC_C_BIGENDIAN
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
  56     [Define ssize_t if it is not done by the standard libs.])])
  57 AC_TYPE_OFF_T
  58 AC_TYPE_SIGNAL
  59 AC_TYPE_UID_T
  60 AC_CHECK_DECLS(environ)
  61
  62 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
  63
  64 PKG_CHECK_MODULES(LIBPULSE, [libpulse])
  65 AC_SUBST(LIBPULSE_CFLAGS)
  66 AC_SUBST(LIBPULSE_LIBS)
  67
  68
  69 PKG_CHECK_MODULES(PULSEDEVEL, [pulseaudio-module-devel])
  70 AC_SUBST(PULSEDEVEL_CFLAGS)
  71 AC_SUBST(PULSEDEVEL_LIBS)
  72
  73 PKG_CHECK_MODULES(MURPHYCOMMON, [murphy-common])
  74 AC_SUBST(MURPHYCOMMON_CFLAGS)
  75 AC_SUBST(MURPHYCOMMON_LIBS)
  76
  77 PKG_CHECK_MODULES(LUAUTILS, [murphy-lua-utils])
  78 AC_SUBST(LUAUTILS_CFLAGS)
  79 AC_SUBST(LUAUTILS_LIBS)
  80
  81
  82 PKG_CHECK_MODULES(LUA, lua >= 5.1.1)
  83 AC_SUBST(LUA_CFLAGS)
  84 AC_SUBST(LUA_LIBS)
  85
  86
  87 # D-Bus
  88 AC_ARG_WITH([dbus],
  89             [ AS_HELP_STRING([--with-dbus],
  90                              [Use D-Bus towards with Murphy and AudioManager])
  91             ],
  92             [ build_with_dbus="yes" ;
  93               PKG_CHECK_MODULES(DBUS, [dbus-1])
  94               AC_SUBST(DBUS_CFLAGS)
  95               AC_SUBST(DBUS_LIBS)
  96             ],
  97             [ build_with_dbus="no" ]
  98 )
  99
 100 AM_CONDITIONAL(BUILD_WITH_DBUS,  [ test "x$build_with_dbus" = "xyes" ])
 101
 102
 103 # module directory
 104 AC_ARG_WITH([module-dir],
 105             [AS_HELP_STRING([--with-module-dir], [Directory where to install the modules to (defaults to ${LIBDIR}/pulse-${PA_MAJORMINOR}/modules/])],
 106             [modlibexecdir=$withval],
 107             [modlibexecdir=${LIBDIR}/pulse-${PA_MAJORMINOR}/modules]
 108 )
 109
 110 AC_SUBST(modlibexecdir)
 111
 112
 113 # documentation
 114 AC_ARG_WITH([documentation],
 115             [AS_HELP_STRING([--with-documentation],
 116                             [generate pdf, html and other doc files])],
 117             [],
 118             [with_documentation=auto]
 119 )
 120
 121 AS_IF( [ test x$with_documentation = xno ],
 122        [ has_doc_tools="no" ],
 123        [ AC_PATH_TOOL([PA_DOXYGEN], doxygen)
 124          AC_PATH_TOOL([PA_LYX], lyx)
 125          AC_PATH_TOOL([PA_INKSCAPE], inkscape)
 126          AC_PATH_TOOL([PA_PYTHON], python)
 127          AC_PATH_TOOL([PA_TOUCH], touch)
 128          AC_PATH_TOOL([PA_DBLATEX], dblatex)
 129          AC_PATH_TOOL([PA_XMLTO], xmlto)
 130
 131          AS_IF( [ test x$PA_DOXYGEN = x -o x$PA_LYX = x -o \
 132                        x$PA_INKSCAPE = x -o x$PA_PYTHON = x -o \
 133                        x$PA_TOUCH = x],
 134                 [ has_doc_tools="no";
 135                   AC_MSG_WARN([Some essential doc-tool is missing]) ],
 136                 [ has_doc_tools="yes";
 137                   PA_DOCINIT() ]
 138          ) ]
 139 )
 140
 141 AS_IF( [ test x$has_doc_tools == "xno" -o x$PA_DBLATEX = x ],
 142        [ can_make_pdfs="no";
 143          AC_WARN([No PDF documentation will be generated]) ],
 144        [ can_make_pdfs="yes"]
 145 )
 146
 147 AS_IF([ test x$has_doc_tools == "xno" -o x$PA_XMLTO = x ],
 148       [ can_make_html="no";
 149         AC_WARN([No HTML documentation will be generated]) ],
 150       [ can_make_html="yes" ]
 151 )
 152
 153
 154 AM_CONDITIONAL(BUILD_DOCUMENTATION,  [ test x$has_doc_tools = "xyes" ])
 155 AM_CONDITIONAL(BUILD_PDF_DOCUMENTS,  [ test x$can_make_pdfs = "xyes" ])
 156 AM_CONDITIONAL(BUILD_HTML_DOCUMENTS, [ test x$can_make_html = "xyes" ])
 157
 158 AC_SUBST(PA_DOCDIR, [`pwd`/doc])
 159 AC_SUBST(PA_FIGDIR, [$PA_DOCDIR/common/figures])
 160 AC_SUBST(PA_MAKE_DOCRULES, [$PA_DOCDIR/Makefile.rules])
 161 AC_SUBST(PA_DOCSCRIPT_DIR, [$PA_DOCDIR/scripts])
 162 AC_SUBST(PA_DBLYXFIX, [$PA_DOCSCRIPT_DIR/dblyxfix.py])
 163 AC_SUBST(PA_DOXML2DB, [$PA_DOCSCRIPT_DIR/doxml2db.py])
 164 AC_SUBST(PA_DOXYDEPS, [$PA_DOCSCRIPT_DIR/doxydeps.py])
 165
 166
 167 # Shave by default
 168 SHAVE_INIT([build-aux], [enable])
 169
 170 AC_CONFIG_FILES([
 171         build-aux/shave
 172         build-aux/shave-libtool
 173         Makefile
 174         murphy/Makefile
 175         combine/Makefile
 176         augment/Makefile
 177         doc/Makefile
 178         doc/murphy-audio/Makefile
 179         doc/murphy-audio/db/Makefile
 180 ])
 181 AC_OUTPUT
 182
 183 echo "
 184  ---{ $PACKAGE_NAME $VERSION }---
 185
 186     prefix:               ${prefix}
 187     sysconfdir:           ${sysconfdir}
 188     localstatedir:        ${localstatedir}
 189     modlibexecdir:        ${modlibexecdir}
 190     Compiler:             ${CC}
 191     CFLAGS:               ${CFLAGS}
 192     LIBDIR:               ${LIBDIR}
 193     LIBPULSE_CFLAGS:      ${LIBPULSE_CFLAGS}
 194     LIBPULSE_LIBS:        ${LIBPULSE_LIBS}
 195     LIBPULSECORE_CFLAGS:  ${LIBPULSECORE_CFLAGS}
 196     LIBPULSECORE_LIBS:    ${LIBPULSECORE_LIBS}
 197     MAJORMINOR:           ${PA_MAJORMINOR}
 198     DBUS_CFLAGS:          ${DBUS_CFLAGS}
 199     DBUS_LIBS:            ${DBUS_LIBS}
 200     MURPHYCOMMON_CFLAGS   ${MURPHYCOMMON_CFLAGS}
 201     MURPHYCOMMON_LIBS     ${MURPHYCOMMON_LIBS}
 202     LUAUTILS_CFLAGS       ${LUAUTILS_CFLAGS}
 203     LUAUTILS_LIBS         ${LUAUTILS_LIBS}
 204     LUAUTILS_CFLAGS       ${LUAUTILS_CFLAGS}
 205     LUAUTILS_LIBS         ${LUAUTILS_LIBS}
 206     LUA_CFLAGS:           ${LUA_CFLAGS}
 207     LUA_LIBS:             ${LUA_LIBS}
 208 "